Convert SECONDS to HOURS and MINUTES in ASP vbscript

Hello.

I have a integer second value, for example 89493 seconds.

I would like to get two values from that:

1) Hours
2) Minutes

So ideally, it would return 3 separate values - hours, minutes, and seconds.

It would accept one input parameter - the SECONDS to calcuate.

I've tried all kinds of bulit in stuff, but none of it helps. I already am using the DATEDIFF function in SQL to get the seconds.

THank you for your help!

nTotalSeconds = 89493
nHours = CInt(nTotalSeconds/3600)
nTotalSeconds = nTotalSeconds - (3600 * nHours)
nMinutes = CInt(nTotalSeconds/60)
nSeconds = nTotalSeconds - (60 * nMinutes)

Now you have three variables that hold the data you want. nHours, nMinutes, and nSeconds.

Hi - Thanks so much for your reply!

I plugged in the code and it is pretty much what I am looking for.

The only thing is, with the value "89493"

Hours return: 25
Minutes return: -8

Is the minutes calculating the left over values?

I would like to format it like this:

     25 Hours and 8 Minutes

Which kinda translates to:

     25:08

so I'm just wondering what is going on with minutes, why it is negative, and if that is the left over minutes from hours?

Thanks.

-- shawn

As there is no datatype conversion involved, you should use
Int() (or Fix()) instead of CInt().

thanks for that tip. ill try it out see if its a bit more efficient.

can you explain the logic behind the (3600 * nHours) calculation?

also can someone help me find the remainder from the HOURS, as in the above code sample?

for exampple:

nTotalSeconds = 89493
nHours = CInt(nTotalSeconds/3600)
nTotalSeconds = nTotalSeconds - (3600 * nHours) 

"89493"
Hours return: 25
Minutes return: -8

why -8? is that the remainder? as i said above I need [0]Hours and [1]Minutes

Thanks so much.

Use the VBScript Docs to learn about conversion functions
like CInt(), mathematical/number manipulating functions
like Int(), Fix(), Round(), and their differences.

Demo code:

   Dim nTest
   For Each nTest In Array( _
       60, 3600, 89493, 90, 5400 _
   )
       Dim nTotalSeconds
       Dim nHours, nMinutes, nSeconds
       WScript.Echo nTest
 
       nTotalSeconds = nTest
       nHours        = CInt( nTotalSeconds / 3600 )
       nTotalSeconds = nTotalSeconds - (3600 * nHours)
       nMinutes      = CInt( nTotalSeconds / 60 )
       nSeconds      = nTotalSeconds - (60 * nMinutes)
       WScript.Echo Join( Array( "wrong CInt:", nHours, nMinutes, nSeconds ) )
 
       nTotalSeconds = nTest
       nHours        = Int( nTotalSeconds / 3600 )
       nTotalSeconds = nTotalSeconds - (3600 * nHours)
       nMinutes      = Int( nTotalSeconds / 60 )
       nSeconds      = nTotalSeconds - (60 * nMinutes)
       WScript.Echo Join( Array( "Int:       ", nHours, nMinutes, nSeconds ) )
 
       nTotalSeconds = nTest
       nHours        = nTotalSeconds \   3600
       nTotalSeconds = nTotalSeconds Mod 3600
       nMinutes      = nTotalSeconds \     60
       nSeconds      = nTotalSeconds Mod   60
       WScript.Echo Join( Array( "\ Mod:     ", nHours, nMinutes, nSeconds ) )
 
       WScript.Echo
 
   Next
 

output:

 ---------------------------------
 60
 wrong CInt: 0 1 0
 Int:        0 1 0
 \ Mod:      0 1 0
 
 3600
 wrong CInt: 1 0 0
 Int:        1 0 0
 \ Mod:      1 0 0
 
 89493
 wrong CInt: 25 -8 -27
 Int:        24 51 33
 \ Mod:      24 51 33
 
 90
 wrong CInt: 0 2 -30
 Int:        0 1 30
 \ Mod:      0 1 30
 
 5400
 wrong CInt: 2 -30 0
 Int:        1 30 0
 \ Mod:      1 30 0
 
 =================================