Politely Close all open windows

 'Author Rischip
 'Home page [link=http://www.thegrimlinker.com]www.thegrimlinker.com[/link]
 'This script closes all open windows on the workstation
 'The script does not forcefully close applications 
 'therefore you will get a Save dialog on text editor apps and the like
 'before they close
 'This script requires Microsoft Word to be installed on your computer
 
 On Error Resume Next
 
 'check to ensure running under wscript
 'if we are not it would be possible 
 'for the script to kill itself in the 
 'command window that cscript would have open
 'if we are cool, if not relaunch under wscript
 
 If Not LCase(Right(Wscript.FullName, 11)) = "wscript.exe" Then
    Set objShell = CreateObject("Wscript.Shell")
    objShell.Run "Wscript.exe " & WScript.ScriptFullName , 0, False
    WScript.quit
 End If
 
 'create Word object
 Set objWord = CreateObject("Word.Application")
 'get collection of open windows 
 Set colTasks = objWord.Tasks
 'enumerate open windows
 'checking for visibility
 'verify task is not program manager
 'otherwise you will get the logoff/shutdown/restart window
 
 for each objTask in colTasks
    If objTask.Visible Then
         If Not objTask.Name = "Program Manager" then
            colTasks(objTask.Name).Close
        End If
    End If
    
 next
 
 objWord.Quit
 
 

Very handy.
 
This chunk:
 
If Not LCase(Right(Wscript.FullName, 11)) = "wscript.exe" Then
   Set objShell = CreateObject("Wscript.Shell")
   objShell.Run WScript.ScriptFullName , 0, False
   WScript.quit
End If
 
would re-run the script with whatever the default engine is for that user. In my case, the default engine is CSCript. This means that it would essentially just keep killing itself and starting over. Instead then you should probably have it explicitly run itself with WSCript.exe.

Yeah my mistake, I posted it before I fixed it.
 
Ok, it's fixed.

Works like a charm!

And personaly I like the fact that it doesn't requires WMI so that I can run it on my w98++ machine.

If you're interested in seeing what else can be done with the word document regarding processes check this article out: http://www.microsoft.com/technet/scriptcenter/topics/office/tasks.mspx

doesn't seem to work with office 2007, bombs here: Set objWord = CreateObject("Word.Application")

*UPDATE*  It works, my bad

What about when you don't have Microsoft Word installed and you wanna search for a window with a specific title?