VBS to check for active internet connection?

I have a number of VBScripts that open programs which slurp data from the internet, do something else, then end. 

If the internet is down for any reason I get an error message which stops any later scripts from executing the same routine at a later time when the internet may be up. 

A solution would be to check for an active internet connection, if True continue, if False end.

Is this possible?  Any ideas?

Thanks in advance

k
 

choose some random site, like google and then ping the website every once in awhile or use xmlhttprequest

Both ideas would seem to do what I want but I can't figure out how to inject the "TRUE" into my VBS routine.

I Goggled xmlhttprequestand and it would seem the best of the 2 solutions.  While there is a lot of stuff on the subject out there I'm just not skilled enough to proceed.

Thanks


k

 Dim WshShell
 Set WshShell = createobject("wscript.shell") 
 strURL = "www.yahoo.com"
 set png = WshShell.exec("ping -n 1 " & strURL) 
     do until png.status = 1 
  wscript.sleep 100 
  loop 
 strPing = lcase(png.stdout.readall) 
     Select Case True 
         Case InStr(strPing, "reply from") > 1 
             strReply = True      '------"Request timed out" 
         Case Else 
             strReply = False 
     End Select 
 msgbox strReply 

 
HTH

Thank you 10^6

So far as I can see (and tested) I need to insert my run if connected as shown below:

Dim WshShell
Set WshShell = createobject("wscript.shell")
strURL = "www.yahoo.com"
set png = WshShell.exec("ping -n 1 " & strURL)
do until png.status = 1
wscript.sleep 100
loop
strPing = lcase(png.stdout.readall)
Select Case True
     Case InStr(strPing, "reply from") > 1

' INSERT CODE TO RUN HERE - IF INTERNET CONNECTION ACTIVE

  Case Else
  End Select

If there is no connection the procedure ends.  Is this right?


Thanks

k

Well to be more specific, for the code that you posted if the connection doesn't exist, the connection specific code just never runs.

If there is no connection the procedure ends.  Is this right?

 
I think you'r right.

ebgreen,

    That is exactly what I need, to have the procedure run ONLY if the connection to the internet is active.

fred,

    Thanks for the code and the feedback.  This has already proven to be of value.  BTW, by changing the line "wscript.sleep 1000" to
"Application.Wait (Now + TimeValue("0:00:01"))" your code runs as VBA within Excel; also of value to me.


Wonderful forum.

k

could it be this source always returns false?
see you!

you could also use webpage load test to verify content comes back and use a list of pings and loads combined to afford icmp blocks for pings or a url that is down which, both could lead to a false internet failure indicator.  This way if a particular site or ping fails it may not be indicitive of true no internet.
 
 
    
on error resume next

arraywebsite = array("www.google.com","www.yahoo.com")

 

for each objUrl in arraywebsite 

Set objHTTP = CreateObject("MSXML2.XMLHTTP")

strurl = "http://" & objUrl 

 

objHTTP.Open "GET", strURL, FALSE

objHTTP.Send

 

  if objHTTP.statusText = "OK" then

    wscript.echo now & " Url Status " & objHTTP.statusText & " For " & strUrl

 

   else

     wscript.echo now & " Error Connecting to " & strurl

 

  end if

 

next
 

thank you for your source... but it tried to connect and return me the errors.

I tested it before I ran it.  maybe something didn't come across right in the paste.  I have had issues before.  Anyway it was more of an idea to help make the scripts decision internet up or down more accurate.   I use similar code above to monitor internal web server pages so I know they are down before they are even reported. 

okay.
thank you! i resolved.
 
here's the code: (i trasformed it into a function!)
 

 Function Connessione()
Set WshShell = CreateObject("WScript.Shell")
PINGFlag = Not CBool(WshShell.run("ping -n 1 www.google.it",0,True))
 If PINGFlag = True Then
 'Successful ping
 Connessione = True
 Else
 'Unsuccessful ping
 Connessione = False
 End If
End Function 

You need to declare your variables

what do you mean?

Try to run your code with Option Explicit and you'll see what I mean:
 

 Option Explicit
Function Connessione()
Set WshShell = CreateObject("WScript.Shell")
PINGFlag = Not CBool(WshShell.run("ping -n 1 www.google.it",0,True))
 If PINGFlag = True Then
 'Successful ping
 Connessione = True
 Else
 'Unsuccessful ping
 Connessione = False
 End If
End Function 

Dim Result : Result = Connessione() 

 
You need to "Dim" variables before you assign to them:
 
Dim foo : foo = "bar"
Dim quux : Set quux = SomeObject

okay... sorry.
 
i posted only the function.
 
see you :-)

binarydigit0101


okay... sorry.

i posted only the function.

see you :-)

Nothing to apologize about. The point is that if you don't do that then you could be changing the values of variables outside the function leading to weird bugs that are hard to fix

i didn't declare variables because i used the name of the function inside a conditional statement.
 
anyway... okay, thank you for the suggestion! ;-)