Writing to a text file (should be easy...)

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Writing to a text file (should be easy...)

Logged in as: Guest

arrSession:exec spGetSession 2,2,1189

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Writing to a text file (should be easy...)
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Writing to a text file (should be easy...) - 7/28/2004 2:50:26 AM

cobolexpert

Posts: 7
Score: 0
Joined: 7/22/2004
From:
Status: offline

Hey everyone,
I was wondering if someone could check out this script I made. It's a wscript vbscript that checks to see if someone is using certain locations on two servers, if not it copies files from one location to another and then compares the directories to make sure the copy went alright. I am having a small problem with my log though. The log writes just fine the first couple times but then errors out on one of the writes. Doesn't make any sense to me... Here is the error:

Line 349, Char 2, Object doesn't support this property or method: 'oFileObject.OpenTextFile'

I can only get the error to show up if I comment out some lines dealing with spreadsheets (because they need the on error resume next line). I bolded those lines as well as the specific write that is giving me problems. If you take a close look at the script, you can see that I have already written to the log three times. I am trying to figure out why it would error out on something it already did sucessfully multiple times...

Here's the code. Any ideas??? THANKS! - JB

'==============================================================================
'
'
' Program:      YOURSERVER1 to YOURSERVER2 copy.vbs
'
' Version:      1.1
'
' Description:
'
'==============================================================================
' Calls scripts in library:
'
'
'
'
'
'
'==============================================================================
' Reference
'
's = String
'a = Array
'o = Object
'
'==============================================================================
' History:
'
'   01jul04 jlb Created.
'    16jul04 jlb Modified, added in excel
'    21jul04 jlb Modified, added in log file
'
'==============================================================================
' Force definition of variables before they are used.
Option Explicit

'----------------
' Constants
'----------------
'
Const OVERWRITEFILES = True
Const LOGDIR = "\\YOURSERVER2\common\IGold\Scripts\YOURSERVER1 Copy\Log"
Const APPEND = 8
Const SRCTOOLDIR = "\\YOURSERVER1\gold Dev\Build\Setup\Tools"
Const SRCNETWDIR = "\\YOURSERVER1\gold Dev\Build\Release"
Const SRCSETUDIR = "\\YOURSERVER1\gold Dev\Build\Setup\Release"
Const RCPTOOLDIR = "\\YOURSERVER2\common\IGold\Tools"
Const RCPNETWDIR = "\\YOURSERVER2\common\IGold\Network\Release"
Const RCPSETUDIR = "\\YOURSERVER2\common\IGold\Setup\Release"
Const SRCTOOLPATH = "Build\Setup\Tools"
Const SRCNETWPATH = "Build\Network"
Const SRCSETUPATH = "Build\Setup"
Const RCPTOOLPATH = "IGold\Tools"
Const RCPNETWPATH = "IGold\Network"
Const RCPSETUPATH = "IGold\Setup"
Const SRCSERVER = "YOURSERVER1"
Const RCPSERVER = "YOURSERVER2"
'
'----------------
' user variables
'----------------
'
'
Dim iLogCounter         ' Counter to decide whether to create of modify the log file
Dim sLogMessage
Dim sDate
Dim sTime
Dim sLog
Dim oFile
Dim sServer
Dim sUser
Dim sPath
Dim oTextFile
Dim sLoop
Dim sExtraField
Dim sInput
Dim sSourceServer
Dim sSourcePath
Dim sRecipientServer
Dim sRecipientPath
Dim sSourceDir
Dim sRecipientDir
Dim sUserCheckCounter
Dim oColumnNumber
Dim oRowNumber
Dim oXL
Dim sResource
Dim oFindPOS
Dim sSourceFolder
Dim sRecipientFolder
Dim oFolder

'==============================================
' standard variables (part of script template)
'==============================================
Dim aExtraFlds()     ' 1D array of extra field names for a record structure
Dim oFSO            ' ref to a file system object
Dim oIExplore        ' ref to an Internet Explorer window
Dim oInFile          ' ref to input file
Dim oLibScript       ' ref to library script file
Dim oOutFile         ' ref to output file
Dim oInRS            ' disconnected record set to store source data
Dim oWshShell        ' ref to a scripting shell object
Dim sFldDelimeter    ' field delimeter used in the IN_FNAME and OUT_FNAME files
Dim sMsg             ' for user interface messages
Dim sPathInFile      ' fully qualified path to input file folder
Dim sPathLibFile     ' fully qualified path to library folder
Dim sPathMain        ' fully qualified path to main script folder
Dim sPathOutFile     ' fully qualified path to output file folder
'==============================================
' standard run-script warning
'==============================================
sMsg = "Are you sure you want to run this script?"

' warn user that they've started the script, give them a chance to cancel
If MsgBox(sMsg, vbOKCancel) = vbOK Then
sMsg = ""

Call Start()
Else
Call Cleanup()
End If

'------------------------------------------------------------------------------
' user procedures
'------------------------------------------------------------------------------
'Main menu - Choose whether to update just the tools, setup files, network files
'or do all of it.

Sub Start()
'Create Log
CALL CreateLog(sLog, oFSO, oFile)
'Write to Log
sLogMessage = "Reached Start()" & vbTab & vbTab & "-" & vbTab & "Main menu"
CALL WriteLog(sLog, sLogMessage, oFSO)

sMsg = "What would you like to update?" & VbCrLf & VbCrLf
sMsg = sMsg & "1.  Tool Files" & VbCrLf
sMsg = sMsg & "2. Setup Files" & VbCrLf
sMsg = sMsg & "3.    Network Files" & VbCrLf
sMsg = sMsg & "4.  All Files (Tools, Setup, Network)" & VbCrLf
sMsg = sMsg & "5.  *COMING SOON* Run DBUpdate" & VbCrLf
sMsg = sMsg & "6. *COMING SOON* Copy to FTP site" & VbCrLf
sMsg = sMsg & "7. Quit"
sInput = InputBox(sMsg)
CALL CaseSelect(sInput)
End Sub

Sub CaseSelect(byref sUserInput)
'Write to Log
sLogMessage = "Reached CaseSelect()" & vbTab & vbTab & "-" & vbTab & "Chooses what variables to use"
CALL WriteLog(sLog, sLogMessage, oFSO)

'Depending on what the user wants to do, it will change the global variables used throughout the program.

Select Case sUserInput
Case "1"      sSourceServer = SRCSERVER
sSourcePath = SRCTOOLPATH
sRecipientServer = RCPSERVER
sRecipientPath = RCPTOOLPATH
sSourceDir = SRCTOOLDIR
sRecipientDir = RCPTOOLDIR
Call UserCheck(sSourceServer, sSourcePath, sRecipientServer, sRecipientPath, sUserInput, sSourceDir, sRecipientDir)
Case "2"        sSourceServer = SRCSERVER
sSourcePath = SRCSETUPATH
sRecipientServer = RCPSERVER
sRecipientPath = RCPSETUPATH
sSourceDir = SRCSETUDIR
sRecipientDir = RCPSETUDIR
Call UserCheck(sSourceServer, sSourcePath, sRecipientServer, sRecipientPath, sUserInput, sSourceDir, sRecipientDir)
Case "3"        sSourceServer = SRCSERVER
sSourcePath = SRCNETWPATH
sRecipientServer = RCPSERVER
sRecipientPath = RCPNETWPATH
sSourceDir = SRCNETWDIR
sRecipientDir = RCPNETWDIR
Call UserCheck(sSourceServer, sSourcePath, sRecipientServer, sRecipientPath, sUserInput, sSourceDir, sRecipientDir)
Case "4"        Call UserCheck(sSourceServer, sSourcePath, sRecipientServer, sRecipientPath, sUserInput, sSourceDir, sRecipientDir)
Case "5"       Call Start()
Case "6"      Call Start()
Case "7"      Call Cleanup
Case ""           Call Start()
Case Else     Call Start()
End Select
Call Cleanup
End Sub

Sub UserCheck(byref sSrcServer,byref sSrcPath,byref sRcpServer,byref sRcpPath,byref sUserData,byref sSrcDir,byref sRcpDir)
'Write to Log
sLogMessage = "Reached UserCheck()" & vbTab & vbTab & "-" & vbTab & "Checks for users using the files"
CALL WriteLog(sLog, sLogMessage, oFSO)

'Main Program Loop.  If the user chooses Option 4, the program will loop through the same procedures,
'disguising itself as options 1, 2 and 3.  It goes through the whole process of checking for option 1 users and
'copying and comparing option 1 files before going on to option 2.

If sUserData = "4" THEN
sExtraField = sUserData
Select Case sLoop
Case ""        sUserData = "1"
sLoop = "1"
CALL CaseSelect(sUserData)
Case "1"  sUserData = "2"
sLoop = "2"
CALL CaseSelect(sUserData)
Case "2"  sUserData = "3"
sLoop = "3"
CALL CaseSelect(sUserData)
End Select
End If

'This nested loop loops twice.  Once to check for users on YOURSERVER1 and once for users on YOURSERVER2.
'It knows to do this by referencing the sUserCheckCounter counter and sets variables depending on the
'counter variable.

sUserCheckCounter = 0
While sUserCheckCounter < 2
IF sUserCheckCounter = 0 THEN
sUserCheckCounter = 1
oColumnNumber = 1
oRowNumber = 1
sServer = sSrcServer
sPath = sSrcPath
Set oXL = CreateObject("Excel.Application")
oXL.workbooks.add
oXL.Visible = False
oXL.Cells(oRowNumber, oColumnNumber).Value = "Server"
oXL.Cells(oRowNumber, oColumnNumber+1).Value = "User"
oXL.Cells(oRowNumber, oColumnNumber+2).Value = "Path"
oRowNumber=oRowNumber+1
ELSE
sUserCheckCounter = 2
sServer = sRcpServer
sPath = sRcpPath
End IF
Set oFSO = GetObject("WinNT://" & sServer & "/LanmanServer")
<b>'      On Error Resume Next
'        If (IsEmpty(oFSO) = False) Then
'         For Each sResource In oFSO.Resources
'        If (Not sResource.User = "") And (Not Right(sResource.User,1) = "$") Then
'           oFindPos = Instr(1, sResource.path, sPath ,1)
'       If (oFindPos <> 0 and Left(Right(CStr(sResource.Path),4),1) = ".") Then
'           oXL.Cells(oRowNumber, oColumnNumber).Value = sServer
'            oXL.Cells(oRowNumber, oColumnNumber+1).Value = sResource.User
'           oXL.Cells(oRowNumber, oColumnNumber+2).Value = sResource.Path
'           oRowNumber=oRowNumber+1
'     End if
'      End If
'      Next
'        End If</b>
Wend
If oRowNumber <= 4 Then
oXL.ActiveWorkbook.Close False
wscript.echo "Files are not in use"
<b>'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Files not in use"
Call WriteLog(sLog, sLogMessage, oFSO)</b>
Call CopyAndCompare(sExtraField, sLoop, sUserData, sSrcDir, sRcpDir)
ELSE
oXL.Cells.EntireColumn.Autofit
oXL.Visible = TRUE
'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Files are in use"
Call WriteLog(sLog, sLogMessage, oFSO)
sMsg = "Refresh in-use files?" &VbCrLf
sMsg = sMsg & "Press Retry to refresh or cancel to go back"
sMsg = sMsg & " to the main menu."
If MsgBox(sMsg, vbRetryCancel) = vbRetry Then
oXL.ActiveWorkbook.Close False
'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Retrying CopyAndCompare after kicking users"
Call WriteLog(sLog, sLogMessage, oFSO)
CALL UserCheck(sSourceServer, sSourcePath, sRecipientServer, sRecipientPath, sUserData, sSourceDir, sRecipientDir)
ELSE
CALL Start()
End If
End If
End Sub

Sub CopyAndCompare(byref sExtraF,byref sTheLoop,byref sUserInput,byref sSrcDir,byref sRcpDir)

'Copy from Source Directory to Recipient Directory (YOURSERVER1 to YOURSERVER2 for example)
Set oFSO = CreateObject("Scripting.FileSystemObject")
oFSO.CopyFolder sSourceDir , sRecipientDir , OVERWRITEFILES

'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Copying Files..."
Call WriteLog(sLog, sLogMessage, oFSO)

'Get Source Folder Size
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFso.GetFolder(sSrcDir)
sSourceFolder = oFolder.Size

'Get Recipient Folder Size
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oFolder = oFso.GetFolder(sRcpDir)
sRecipientFolder = oFolder.Size
'Write to Log
sLogMessage = "Source Folder Size - " & sSourceFolder & vbTab & "|" & vbTab & "Recipient Folder Size - " &sRecipientFolder
Call WriteLog(sLog, sLogMessage, oFSO)
'Compare Folders
If sSourceFolder = sRecipientFolder Then
If (sExtraField = "4") AND (sTheLoop < 3) Then
'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Going back to UserCheck for All File Loop"
Call WriteLog(sLog, sLogMessage, oFSO)
sUserInput = sExtraField
CALL UserCheck(sSourceServer, sSourcePath, sRecipientServer, sRecipientPath, sUserInput, sSourceDir, sRecipientDir)
Else
wscript.echo "Folder sizes are the same"
'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Folder Sizes are the same (see above)"
Call WriteLog(sLog, sLogMessage, oFSO)
Call Start()
End If
Else
wscript.echo "Folder sizes not the same"
'Write to Log
sLogMessage = "Reached CopyAndCompare()" & vbTab & vbTab & "-" & vbTab & "Folder Sizes are not the same (see above)"
Call WriteLog(sLog, sLogMessage, oFSO)
Call Start()
End If
End Sub

Sub CreateLog(byref sLogFile, byref oFileObject, byref oCreateFile)
IF iLogCounter = "" THEN    ' If this is the first time to CreateLog()
sDate = replace(date,"/",".")  ' Get the date, replace all the /'s with .'s
sTime = replace(time,":",".")  ' Get the time, replace all the :'s with .'s
sLogFile = "\Log File - " & sDate & "_" & sTime & ".txt"   ' Create a variable holding the log file name
sLogFile = LOGDIR & sLogFile ' Create a variable with the log directory and file name to be used for writing the log
Set oFileObject = CreateObject("Scripting.FileSystemObject")
Set oCreateFile = oFileObject.CreateTextFile(sLogFile) ' Create the log if this is the first time to CreateLog()
iLogCounter = iLogCounter + 1   ' Add 1 to the counter so we don't do this again until the next first time
oCreateFile.Close
ELSE
End IF   ' End iLogCounter
End Sub ' End CreateLog()

Sub WriteLog(byref sLogFile, byref sLogText, byref oFileObject)  'Get the Log Directory and the Log Message from Start()
Set oTextFile = oFileObject.OpenTextFile(sLogFile, APPEND, False)  ' Open the Log file in Append mode, do not create
oTextFile.WriteLine(sLogText)   ' Write the Log Message
oTextFile.Close   ' Close the Log file
Set oTextFile = nothing
End Sub ' End WriteLog(sLog, sLogMessage)

Sub Cleanup()
WScript.Echo "Quitting."
'Write to Log
sLogMessage = "Reached Cleanup()" & vbTab & vbTab & "-" & vbTab & "Clear variables and quit"
Call WriteLog(sLog, sLogMessage, oFSO)
Set iLogCounter    = nothing
Set sLogMessage  = nothing
Set sDate    = nothing
Set sTime    = nothing
Set sLog = nothing
Set oFile    = nothing
Set sServer  = nothing
Set sUser    = nothing
Set sPath    = nothing
Set oTextFile    = nothing
Set sLoop    = nothing
Set sExtraField  = nothing
Set sInput   = nothing
Set sSourceServer    = nothing
Set sSourcePath  = nothing
Set sRecipientServer = nothing
Set sRecipientPath   = nothing
Set sSourceDir   = nothing
Set sRecipientDir    = nothing
Set sUserCheckCounter    = nothing
Set oColumnNumber    = nothing
Set oRowNumber   = nothing
Set oXL  = nothing
Set sResource    = nothing
Set oFindPOS = nothing
Set sSourceFolder    = nothing
Set sRecipientFolder = nothing
Set oFolder  = nothing
WScript.Quit
End Sub

'==============================================================================
' standard functions (part of script template)
'==============================================================================

Post #: 1

Re: Writing to a text file (should be easy...) - 7/29/2004 1:22:20 AM

mbouchard

Posts: 1916
Score: 16
Joined: 5/15/2003
From: USA
Status: offline

Some things that look wrong to me.

1-Right before you get to the commented text you set this.
Set oFSO = GetObject("WinNT://" & sServer & "/LanmanServer")

2-Use this line several places
Set oFso = CreateObject("Scripting.FileSystemObject")

3-Line where you get your error, you are passing oFSO to the writelog sub but right before you are setting oFSO to #1 and are using oFileObject to open the text file.
Call WriteLog(sLog, sLogMessage, oFSO)

4-This is set inside of createlog, do not think it is ever dim'd
Set oFileObject = CreateObject("Scripting.FileSystemObject")

Some recomendations:

- Set oFSO at the top of the script when you dim it ex., remove from all subs/functions and pass it like you are doing with the writelog sub.
Dim oFSO : Set oFso = CreateObject("Scripting.FileSystemObject")

-Change this to something else.
Set oFSO = GetObject("WinNT://" & sServer & "/LanmanServer")

-Use oFSO instead of oFileObject.

(in reply to cobolexpert)

Post #: 2

Re: Writing to a text file (should be easy...) - 7/30/2004 3:59:14 AM

cobolexpert

Posts: 7
Score: 0
Joined: 7/22/2004
From:
Status: offline

Hey,
Thanks for the reply. You are right on, I actually found what you pointed out a little while after I posted. I was setting oFso to something different in the middle of my script so that when it went to write the log at a certain point and use oFso, it was not at the correct setting. I changed the one 'getobject' set to be oLso (Lanmanserver Service Object) instead of oFso for it to make more sense and tada, all my logs work fine now. Thanks for the help!!

(in reply to cobolexpert)