Pinging script that prompts for address range.

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Pinging script that prompts for address range.

Logged in as: Guest

arrSession:exec spGetSession 2,2,1731

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Pinging script that prompts for address range.
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Pinging script that prompts for address range. - 12/20/2004 12:43:36 PM

ned4spd8874

Posts: 1
Score: 0
Joined: 12/20/2004
From: USA
Status: offline

I am very new to scripting and I am sure this is something very simple to do. I need a script that will as me for a starting address, an ending address and then simply ping those addresses and output the results to a file.

Any help would be appreciated!

Post #: 1

Re: Pinging script that prompts for address range. - 12/21/2004 12:53:11 AM

mbouchard

Posts: 1856
Score: 14
Joined: 5/15/2003
From: USA
Status: offline

Here is a script that I use to ping a range of IP's from a text file. You could modify this to use a range of ip's instead.

'Ping multiple computers taken from a list in a text file out put to an Excel Spreadsheet
'******************************************************************************************
' File Name:             IP Ping.vbs
' Version:               1.0
' Author:                Michael Bouchard
' Department:        BSS/IT/CLTI
' Created:              8/19/2003
' Modified:
' Modified by:
' Command-Line....
'   Arguments Used:      None
'   Arguments Switches:  N/A
'   Arguments required:  N/A
'
' Requirments: List of IP Addresses in a file called (See strFileName for the required text file)
'						One IP Address per line
'						Excel is needed
'						Script was written in Windows XP using Wscript 5.6
'           No blank line at the end of the script
'
' Description:   Using a text file for input, multiple ip addresses are pinged: the computer name and status out outputted to an Excel Spreadsheet.
'						For the coimputer name the returns will be the name or a N/A  while the returns will be a sucess, a could not find host, and a request timed out.
'
' Functions: Function GetIP(ByVal reply):  Used to parse the return from the ping and retrieve the Computer name
'					Sub Show(strName, strValue, strIP): Writes the meat of the spreadsheet with the returns from the Ping.
'
' Comments:
'
'******************************************************************************************
Option Explicit
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8

Dim strFileName : strFileName = "IPAddress.txt"

Dim Fso : Set Fso = CreateObject("Scripting.FileSystemObject")
Dim oXLS : Set oXLS = WScript.CreateObject("Excel.Application")
Dim WshShell : Set WshShell = createobject("wscript.shell")

Dim i
Dim intIndex
Dim oFile
Dim png
Dim strComputerIP()
Dim strIpAddress
Dim strPing
Dim strReply
Dim strRet
Dim strCname

If Not Fso.FileExists(strFileName) then
strRet = Msgbox("The file, " & strFileName & " is not available" & vbCr _
& "The file must be located in the same folder as the script." & vbCR _
& "Please check for the file <<" & strFileName & ">> in the folder" & vbCR _
& "<<" & Fso.GetParentFolderName(Wscript.ScriptFullName) & ">>")
Wscript.Quit
End if

Set oFile = Fso.OpenTextFile(strFileName, 1)

'Configure Excel while leaving the spreadsheet hidden

oXLS.WorkBooks.Add
oXLS.Columns(1).ColumnWidth = 20
oXLS.Columns(2).ColumnWidth = 30
oXLS.Columns(3).ColumnWidth = 40

'Set column headers
oXLS.Cells(1, 1).Value = "IP Address"
oXLS.Cells(1, 2).Value = "Computer Name"
oXLS.Cells(1, 3).Value = "Return"

'Format text (bold)
oXLS.Range("A1:C1").Select
oXLS.Selection.Font.Bold = True
oXLS.Selection.Interior.ColorIndex = 1
oXLS.Selection.Interior.Pattern = 1 'xlSolid
oXLS.Selection.Font.ColorIndex = 2
'Left Align text
oXLS.Columns("B:B").Select
oXLS.Selection.HorizontalAlignment = &hFFFFEFDD ' xlLeft

intIndex = 2
i = 0
Do Until oFile.AtEndOfStream
Redim Preserve strComputerIP(i)
strComputerIP(i) = oFile.ReadLine
'Ping Ip Addresses
set png = WshShell.exec("ping -a -n 1 " & strComputerIP(i))
do until png.status = 1 : wscript.sleep 10 : loop
strPing = png.stdout.readall

'NOTE:  The string being looked for in the Instr is case sensitive.
'Do not change the case of any character which appears on the
'same line as a Case InStr.  As this will result in a failure.
Select Case True
Case InStr(strPing, "Request timed out") > 1
strReply = "Request timed out"
strCname = lcase(getcName(strPing))
Case InStr(strPing, "could not find host") > 1
strReply = "Host not reachable"
strCname = lcase(getcName(strPing))
Case InStr(strPing, "Reply from") > 1
strReply = "Ping Succesful"
strCname = lcase(getcName(strPing))
End Select
If strCName = "" then
strCname = "N/A"
End If
Call Show(strComputerIP(i), strCName, strReply)
i = i + 1
Loop

'Make the spreadsheet visable
oXLS.Visible = TRUE

'Get the Computer Name
Function GetcName(ByVal reply)
Dim C, tempcName
C = Instr(reply,"[")
If C = 0 Then Exit Function
TempcName = mid(reply,12,C-12)
'Used to remove the FQDN from the computer name.
GetcName = replace(tempcName, ".ci.charlotte.nc.us", "",1)
End Function

Sub Show(strIP, strName, strValue)
oXLS.Cells(intIndex, 1).Value = strIP
oXLS.Cells(intIndex, 2).Value = strName
oXLS.Cells(intIndex, 3).Value = strValue
intIndex = intIndex + 1
oXLS.Cells(intIndex, 1).Select
End Sub

(in reply to ned4spd8874)

Post #: 2

Re: Pinging script that prompts for address range. - 1/28/2005 12:04:36 AM

Thierry

Posts: 1
Score: 0
Joined: 1/28/2005
From:
Status: offline

HI,

Could you inform how to minimize windows opened by the Ping method.

such as the
*** set png = WshShell.RUN("ping -a -n 1 " & strComputerIP(i)),6***

Thanks in advance!

quote:
Originally posted by mbouchard

Here is a script that I use to ping a range of IP's from a text file. You could modify this to use a range of ip's instead.
'Ping multiple computers taken from a list in a text file out put to an Excel Spreadsheet '****************************************************************************************** ' File Name: IP Ping.vbs ' Version: 1.0 ' Author: Michael Bouchard ' Department: BSS/IT/CLTI ' Created: 8/19/2003 ' Modified: ' Modified by: ' Command-Line.... ' Arguments Used: None ' Arguments Switches: N/A ' Arguments required: N/A ' ' Requirments: List of IP Addresses in a file called (See strFileName for the required text file) ' One IP Address per line ' Excel is needed ' Script was written in Windows XP using Wscript 5.6 ' No blank line at the end of the script ' ' Description: Using a text file for input, multiple ip addresses are pinged: the computer name and status out outputted to an Excel Spreadsheet. ' For the coimputer name the returns will be the name or a N/A while the returns will be a sucess, a could not find host, and a request timed out. ' ' Functions: Function GetIP(ByVal reply): Used to parse the return from the ping and retrieve the Computer name ' Sub Show(strName, strValue, strIP): Writes the meat of the spreadsheet with the returns from the Ping. ' ' Comments: ' '****************************************************************************************** Option Explicit Const ForReading = 1 Const ForWriting = 2 Const ForAppending = 8 Dim strFileName : strFileName = "IPAddress.txt" Dim Fso : Set Fso = CreateObject("Scripting.FileSystemObject") Dim oXLS : Set oXLS = WScript.CreateObject("Excel.Application") Dim WshShell : Set WshShell = createobject("wscript.shell") Dim i Dim intIndex Dim oFile Dim png Dim strComputerIP() Dim strIpAddress Dim strPing Dim strReply Dim strRet Dim strCname If Not Fso.FileExists(strFileName) then strRet = Msgbox("The file, " & strFileName & " is not available" & vbCr _ & "The file must be located in the same folder as the script." & vbCR _ & "Please check for the file <<" & strFileName & ">> in the folder" & vbCR _ & "<<" & Fso.GetParentFolderName(Wscript.ScriptFullName) & ">>") Wscript.Quit End if Set oFile = Fso.OpenTextFile(strFileName, 1) 'Configure Excel while leaving the spreadsheet hidden oXLS.WorkBooks.Add oXLS.Columns(1).ColumnWidth = 20 oXLS.Columns(2).ColumnWidth = 30 oXLS.Columns(3).ColumnWidth = 40 'Set column headers oXLS.Cells(1, 1).Value = "IP Address" oXLS.Cells(1, 2).Value = "Computer Name" oXLS.Cells(1, 3).Value = "Return" 'Format text (bold) oXLS.Range("A1:C1").Select oXLS.Selection.Font.Bold = True oXLS.Selection.Interior.ColorIndex = 1 oXLS.Selection.Interior.Pattern = 1 'xlSolid oXLS.Selection.Font.ColorIndex = 2 'Left Align text oXLS.Columns("B:B").Select oXLS.Selection.HorizontalAlignment = &hFFFFEFDD ' xlLeft intIndex = 2 i = 0 Do Until oFile.AtEndOfStream Redim Preserve strComputerIP(i) strComputerIP(i) = oFile.ReadLine 'Ping Ip Addresses set png = WshShell.exec("ping -a -n 1 " & strComputerIP(i)) do until png.status = 1 : wscript.sleep 10 : loop strPing = png.stdout.readall 'NOTE: The string being looked for in the Instr is case sensitive. 'Do not change the case of any character which appears on the 'same line as a Case InStr. As this will result in a failure. Select Case True Case InStr(strPing, "Request timed out") > 1 strReply = "Request timed out" strCname = lcase(getcName(strPing)) Case InStr(strPing, "could not find host") > 1 strReply = "Host not reachable" strCname = lcase(getcName(strPing)) Case InStr(strPing, "Reply from") > 1 strReply = "Ping Succesful" strCname = lcase(getcName(strPing)) End Select If strCName = "" then strCname = "N/A" End If Call Show(strComputerIP(i), strCName, strReply) i = i + 1 Loop 'Make the spreadsheet visable oXLS.Visible = TRUE 'Get the Computer Name Function GetcName(ByVal reply) Dim C, tempcName C = Instr(reply,"[") If C = 0 Then Exit Function TempcName = mid(reply,12,C-12) 'Used to remove the FQDN from the computer name. GetcName = replace(tempcName, ".ci.charlotte.nc.us", "",1) End Function Sub Show(strIP, strName, strValue) oXLS.Cells(intIndex, 1).Value = strIP oXLS.Cells(intIndex, 2).Value = strName oXLS.Cells(intIndex, 3).Value = strValue intIndex = intIndex + 1 oXLS.Cells(intIndex, 1).Select End Sub

(in reply to ned4spd8874)

Post #: 3

Re: Pinging script that prompts for address range. - 1/28/2005 1:08:28 AM

mbouchard

Posts: 1856
Score: 14
Joined: 5/15/2003
From: USA
Status: offline

Thierry,

I responded to your email but as some might be interested in this, here is code that uses .RUN instead of .EXEC, it creates a file using >ECHO and runs the cmd window minimized. I then read the file and set a variable which is then used to check for ping status. Right before the excel spreadsheet is displayed I delete the txt file created using >ECHO.

Dim strFileName : strFileName = "IPAddress.txt"

Dim Fso : Set Fso = CreateObject("Scripting.FileSystemObject")
Dim oXLS : Set oXLS = WScript.CreateObject("Excel.Application")
Dim WshShell : Set WshShell = createobject("wscript.shell")

Dim i
Dim f
Dim intIndex
Dim oFile
Dim png
Dim strComputerIP()
Dim strIpAddress
Dim strPing
Dim strReply
Dim strRet
Dim strCname

Set oFile = Fso.OpenTextFile(strFileName, 1)

'Configure Excel while leaving the spreadsheet hidden

oXLS.WorkBooks.Add
oXLS.Columns(1).ColumnWidth = 20
oXLS.Columns(2).ColumnWidth = 30
oXLS.Columns(3).ColumnWidth = 40

'Set column headers
oXLS.Cells(1, 1).Value = "IP Address"
oXLS.Cells(1, 2).Value = "Computer Name"
oXLS.Cells(1, 3).Value = "Return"

intIndex = 2
i = 0
Do Until oFile.AtEndOfStream
Redim Preserve strComputerIP(i)
strComputerIP(i) = oFile.ReadLine
'Ping Ip Addresses
'Change exec to run and add code to read all file created.
WshShell.Run("CMD /c ping -a -n 1 " & strComputerIP(i) & ">c:\ipping.txt"),0,TRUE
Set f = fso.OpenTextFile("c:\ipping.txt", ForReading)
strPing = f.ReadAll
f.close
'NOTE:  The string being looked for in the Instr is case sensitive.
'Do not change the case of any character which appears on the
'same line as a Case InStr.  As this will result in a failure.
Select Case True
Case InStr(strPing, "Request timed out") > 1
strReply = "Request timed out"
strCname = lcase(getcName(strPing))
Case InStr(strPing, "could not find host") > 1
strReply = "Host not reachable"
strCname = lcase(getcName(strPing))
Case InStr(strPing, "Reply from") > 1
strReply = "Ping Succesful"
strCname = lcase(getcName(strPing))
End Select
If strCName = "" then
strCname = "N/A"
End If
Call Show(strComputerIP(i), strCName, strReply)
i = i + 1
Loop
'***added next line to clean up created file.
If fso.FileExists("c:\ipping.txt") then Fso.Deletefile "c:\ipping.txt"
'Make the spreadsheet visable
oXLS.Visible = TRUE

(in reply to ned4spd8874)

Post #: 4

Re: Pinging script that prompts for address range. - 2/6/2005 1:52:00 AM

johnny_boy

Posts: 1
Score: 0
Joined: 2/6/2005
From:
Status: offline

Here's my script that prompts for start and end IP address, pings the range, performst and nbtstat -A on devices that reply and creates 4 text .log files of the results in C:\ with filenames that starts with Ping

'*******************************************************************************
'
' Ping IP Range v1.0
'
' (c) 2005 Jonathan Wallace
'
'*******************************************************************************

'*******************************************************************************
'
' Main Program
'
'*******************************************************************************

On Error Resume Next

'-------------------------------------------------------------------------------
' Declare Constants
'-------------------------------------------------------------------------------

Const FOR_WRITING = 2
Const LOG_FILE_PATH = "C:\"
Const ECHOES = 4

'-------------------------------------------------------------------------------
' Set Global Variable Values
'-------------------------------------------------------------------------------

strPingAllLogFilePath = LOG_FILE_PATH & "Ping All Output.log"
strPingReplyLogFilePath = LOG_FILE_PATH & "Ping Reply.log"
strPingNoReplyLogFilePath = LOG_FILE_PATH & "Ping No Reply.log"
strPingPartialLossLogFilePath = LOG_FILE_PATH & "Ping Partial Packet Loss.log"

'-------------------------------------------------------------------------------
' Get Start of Range IP address
'-------------------------------------------------------------------------------

strIPStart = " "
bValid = False
While (bValid = False) AND (strIPStart <> "")
strIPStart = InputBox("Enter Start of Range IP address:", "Ping IP Range")
'Remove leading and trailing spaces
strIPStart = Trim(strIPStart)
'Test that entry is a valid IP address
bValid = ValidIP(strIPStart)
If (bValid = False) AND (strIPStart <> "") Then MsgBox strIPStart & " is not a valid IP address", vbCritical, "Ping IP Range"
WEnd

'-------------------------------------------------------------------------------
' Get End of Range IP address
'-------------------------------------------------------------------------------

strIPEnd = " "
bValid = False
While (bValid = False) AND (strIPStart <> "") AND (strIPEnd <> "")
strIPEnd = InputBox("Start of Range: " & strIPStart & VBLF & VBLF & "Enter End of Range IP address:", "Ping IP Range", strIPStart)
'Remove leading and trailing spaces
strIPEnd = Trim(strIPEnd)
'Test that entry is a valid IP address
bValid = ValidIP(strIPEnd)
If (bValid = False) AND (strIPEnd <> "") Then
MsgBox strIPEnd & " is not a valid IP address", vbCritical, "Ping IP Range"
ElseIf (iIPEnd < iIPStart) AND (strIPEnd <> "") Then
MsgBox strIPEnd & " is before the Start of Range: " & strIPStart, vbCritical, "Ping IP Range"
bValid = False
End If
WEnd

'-------------------------------------------------------------------------------
' Get Number of Ping Echoes to Send
'-------------------------------------------------------------------------------

strEchoes = " "
bValid = False
While (bValid = False) AND (strIPStart <> "") AND (strIPEnd <> "") AND (strEchoes <> "")
strEchoes = InputBox("Enter Number of Ping Echoes to Send:", "Ping IP Range", ECHOES)
'Remove leading and trailing spaces
strEchoes = Trim(strEchoes)
'Test that entry is a Number
bValid = ValidNumber(strEchoes)
If (bValid = False) AND (strEchoes <> "") Then MsgBox strEchoes & " is not a valid number", vbCritical, "Ping IP Range"
WEnd

'-------------------------------------------------------------------------------
' Ping Range
'-------------------------------------------------------------------------------

'If User did not Cancel
If (strIPStart <> "") AND (strIPEnd <> "") AND (strEchoes <> "") Then
Set objShell = CreateObject("WScript.Shell")

Set objFSO = CreateObject("Scripting.FileSystemObject")

'Create Log Files
Set objPingAllLogFile = objFSO.CreateTextFile(strPingAllLogFilePath, False)
Set objPingReplyLogFile = objFSO.CreateTextFile(strPingReplyLogFilePath, False)
Set objPingNoReplyLogFile = objFSO.CreateTextFile(strPingNoReplyLogFilePath, False)
Set objPingPartialLossLogFile = objFSO.CreateTextFile(strPingPartialLossLogFilePath, False)

'Open Log Files for OverWriting
Set objPingAllLogFile = objFSO.OpenTextFile(strPingAllLogFilePath, FOR_WRITING)
Set objPingReplyLogFile = objFSO.OpenTextFile(strPingReplyLogFilePath, FOR_WRITING)
Set objPingNoReplyLogFile = objFSO.OpenTextFile(strPingNoReplyLogFilePath, FOR_WRITING)
Set objPingPartialLossLogFile = objFSO.OpenTextFile(strPingPartialLossLogFilePath, FOR_WRITING)

'Write Start of Log Files
objPingAllLogFile.WriteLine Date & " " & Time & vbTab & "Ping IP Range: " & strIPStart & " to " & strIPEnd & vbTab & "All Output Log"

(in reply to ned4spd8874)

Post #: 5

Re: Pinging script that prompts for address range. - 2/6/2005 5:00:21 AM

token

Posts: 1917
Score: 0
Joined: 1/14/2005
From:
Status: offline

Wow, that looked awfully complicated :D

(in reply to ned4spd8874)

Post #: 6

RE: Re: Pinging script that prompts for address range. - 8/14/2007 8:00:41 AM

trsix

Posts: 18
Score: 0
Joined: 12/6/2006
From: Vancouver BC
Status: offline

quote:

ORIGINAL: Thierry

HI,

Could you inform how to minimize windows opened by the Ping method.

such as the
*** set png = WshShell.RUN("ping -a -n 1 " & strComputerIP(i)),6***

Thanks in advance!

Hi I know that this is long overdue, but i thought i'd post my code here. I didnt like the way that windows kept on getting openend up and such so i used wmi to do the ping.
Tell me what you think.

'This script was written mostly as a learning tool
'Its function is to sweep a range of IP Addresses on a network and do a nslookup on any address which is live
'The address entered determines what will be pinged.
'If the address is entered as "172.20.65" then the whole subnet will be pinged from 0 to 255
'If the address is entered as "172.20.65.35-45" then just the range from 172.20.65.35 to 172.20.65.45 will be pinged
'If the address is entered as "172.20.65.45" then just that address will be pinged

Option Explicit

'Seting up the Dims
Dim objPing, objStatus, arrWmi, objWmi, objShell, objNslookup, i
Dim strNslookup, strTitle, strOctet, isValid
Dim strLowerRange, strUpperRange, strUseCustom, strInputAddress, strCurrentTest, strCustomRange
Dim bDebug

i = 0 'This is the counter for the 4'th octet in the ip address
strLowerRange = i
strUpperRange = 255

'toggles debug output to screen
bDebug = false
'sets the flag for the custom ping range
'0 will do a full sweep of the subnet, 1 will sweep a particular range ie.20-30, 2 will just ping a specific address
strUseCustom = 0

SET objshell = CreateObject("WScript.Shell")
strTitle = "Enter address or range for ping" & vbCrLf & "You can ping a whole subnet - X . X . X" & vbCrLf & "A Range - X . X . X . X - Y"  & vbCrLf & "Or a specific address - X . X . X . X"
strInputAddress = InputBox(strTitle,,"172.21.97.44")

'Function Call to check if the entered address is a valid address or not.
isValidIp(strInputAddress)

'The following will check to see if there has been a proper ip address entered in the InputBox
'If an incorrect address is entered then the user will be prompted with a note stating that 
'their input is inaccurate and they then have a chance to enter in a new address.
'If the Cancel button is pressed or the user deletes the field, the script exits
Do Until IsValid = True
   'checking to see if cancel is pressed
   If strInputAddress = vbEmpty Then
           WScript.Quit
   'checking to see if intputbox is cleared
   ElseIf strinputAddress = "" Then
           WScript.Quit
   End If
   'shows the user that their address is not in the proper format and prompts again for 
   'an accurate input, then checks the input again.
   strInputAddress = InputBox(strTitle,,strInputAddress & " is not a valid address")
   isValidIp(strInputAddress)
Loop

'Determining what should be the math involved in pinging the specific addresses
If strUseCustom = 1 Then
'This is the custom range, it will ping the addresses from the strLowerRange to the strUpperRange
'which were defined by the user entering a dash in the ip address
   i = strLowerRange
   WScript.Echo "Ping range is from " & strCustomRange & "." & strLowerRange & " to " & strUpperRange
   Do Until i = strUpperRange + 1
       strCurrentTest = strCustomRange & "." & i
       PingSilent(strCurrentTest)
       i = i + 1
   Loop
'This is the standard range which will ping in sequence from 0(zero) to 255 on the subnet
ElseIF strUseCustom = 0 Then
   WScript.Echo "Ping range is from " & strInputAddress & "." & strLowerRange & " to " & strUpperRange
   Do Until i = strUpperRange + 1
       strCurrentTest = strInputAddress & "." & i
       PingSilent(strCurrentTest)
       i = i + 1
   Loop
Else
   'If the user enters a specific ip address, it will just ping that address and attempt an nslookup if live
   WScript.Echo "Pinging " & strInputAddress
   PingSilent(strInputAddress)
End If

Function isValidIp(strIP)
   'arrTmpIp is used for the entered address from the input box
   'arrTmpIpb is used if the 4th octet has a "dash" in it, this will be used to seperate the octet into its lower and upper range
   Dim arrTmpIp, arrTmpIpb, strOctetB
   'sets the flag for determining if the entered ip is a valid one or not
   IsValid = False
   'check to see if the entered value is empty, user clicks cancel
   If strIP = vbEmpty Then Exit Function
   'check to see if the value is empty, user delets information and clicks ok
   If strIP = "" Then Exit Function
   'split the entered ip address to an array
   arrTmpIp = split(strIP,".")
       'The following will determine which should be used in setting the ping parameters
   If UBound(arrTmpIp) < 2 Then Exit Function 
       'If there are less than 3 numbers in the range then there is not enough information for the ping
       'to continue, will exit out and then show user where the error is in the inputbox
   If UBound(arrTmpIp) = 2 Then 
   'If there are 3 numbers in the array then we will assume that the range will be from 0 to 255
       For Each strOctet in arrTmpIp
           'now we validate the numbers to make sure that they fit the criteria for an ip address
               isNumberValid(strOctet)
               If isValid = True Then
                   'if all numbers are valid then the user has typed in an address requesting that the entire range of
                   'ip addressed be pinged 0-255 so the flag for strUseCustom is set to 0                    
                   strUseCustom = 0
               End If
       Next
       'all numbers check out ok, flag is set, exit function
       Exit Function
   End If
   
   'The following will check to see if a specific range is requested to be pinged, or a single address
   'example 172.20.97.1-45 which will ping addresses from 1 to 45 inclusive
   If UBound(arrTmpIp) = 3 Then
           'check to see if the first 3 numbers are ok
           isNumberValid(arrTmpIp(0))
           If isValid = False Then Exit Function
           isNumberValid(arrTmpIp(1))
           If isValid = False Then Exit Function
           isNumberValid(arrTmpIp(2))
           If isValid = False Then Exit Function
           If Instr(arrTmpIp(3), "-") > 0 Then

arrTmpIpb = split(arrTmpIp(3), "-")
               'checking to see if there is a range requested
               'if there is a range requested, split the two numbers to the lower and upper ranges
               For Each strOctetb in arrTmpIpb
                   'now validate each number to be sure that its a valid number
                   isNumberValid(strOctetb)
                   'both numbers pass validation so we assign the lower and upper ranges
                   If IsValid = False Then Exit Function
                   strLowerRange = arrTmpIpb(0)
                   strUpperRange = arrTmpIpb(1)
                   'make sure that the numbers are in the correct order
                   If strLowerRange > strUpperRange Then Exit Function
                   'set the custom range to begin pinging at
                   strCustomRange = arrTmpIp(0) & "." & arrTmpIp(1) & "." & arrTmpIp(2)
                   'set the flag so that it uses the custom ping range and uses the variables set
                   strUseCustom = 1
               Next
                   Exit Function
           Else
               For Each strOctet in arrTmpIp
               'if there is no "-" in the input box then assume that we want to ping a specific address
               'verify the numbers
                   isNumberValid(strOctet)
                   'if the numbers pass validation then set the flag to use the single ping
                   If isValid = True Then
                       strUseCustom = 2
                   End If
               Next
           End If
   End If

End Function

'Number validation function - I use this instead of ipValid because of the ability to ping a range will be taken out if 
'not used this way
Function isNumberValid(octet)
   'verify that the entered field is indeed numeric
   If Not isNumeric(octet) Then 
       isValid = False 
       Exit Function
   End If
   
   If octet > 255 Then 
       'verify that the number is less than 255
       isValid = False 
       Exit Function
   End If
   'if number passes checks, set the isValid flag to true
   isValid = True
End Function

Function PingSilent(strIP) 
'Using ping this way makes it so that there are no popup windows at all, everything is done on the back end
       Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery("select * from Win32_PingStatus where address = '" & strIP & "'")
       For Each objStatus in objPing
       'verify that there was a response from the pingstatus
           If IsNull(objStatus.StatusCode) or objStatus.StatusCode <> 0 Then 
               'PingSilent = 0 'not reachable
           Else
               On Error Resume Next
               PingSilent = 1 'Live
               'here is where things start to show up on the screen
               WScript.Echo vbCrLf & strIP & " is reachable"
               'attempt a query to find out the system name from the device
               Set arrWmi = GetObject("WinMgmts:\\" & strIP & "\root\cimv2").ExecQuery("Select * FROM Win32_ComputerSystem")
               For Each objWmi in arrWmi
                 WScript.Echo "   WMI Query : " & objWmi.Name
               Next
               'now attmept to do a nslookup on the ip address to see if there is a dns entry for the device
               Set arrWmi = Nothing
               'using the .exec will not pop up a window, or its so fast that you dont see it, either way, fast
               Set objNslookup = objShell.Exec("%comspec% /c nslookup " & strIP)
               'post the output of the nslookup
               Do While Not objNslookup.StdOut.AtEndOfStream
                   strNslookup = objNslookup.StdOut.ReadLine()
                   'we dont want any useless information, so only display what we want to see
                   If Not Instr(strNslookup, "Name:") = False Then
                       strNsLookup = split(strNsLookup, ":")
                       Wscript.Echo "   NsLookup  : " & Trim(strNslookup(1))
                   End If
               Loop
           End If
       Next
End Function

'this is just for debugging, usage is to put
'debug {string or variable or anything else}
Function debug(strMsg)
   If bDebug Then
       WScript.Echo strMsg
   End IF
End Function

(in reply to Thierry)

Post #: 7

RE: Re: Pinging script that prompts for address range. - 8/14/2007 10:55:12 PM

Rischip

Posts: 468
Score: 2
Joined: 3/26/2007
Status: offline

Just keep in mind that the last octet 0-255 does not define an entire subnet.

The code in this post will ping an entire subnet. It requires an IP address on the subnet (any one of them) and the subnet mask.

http://www.visualbasicscript.com/m_48274/mpage_1/key_/tm.htm#48297

_____________________________

Rischip
Author of - The Grim Linker

(in reply to trsix)

Post #: 8

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Pinging script that prompts for address range.

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts