select directory box

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

select directory box

Logged in as: Guest

arrSession:exec spGetSession 2,2,2190

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> select directory box
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1] 2 next > >>

Message

<< Older Topic Newer Topic >>

select directory box - 2/28/2005 12:25:25 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

Hi all,
I had a quick question. I am trying to create a box that is similar to a 'save as' box, where a user can select a directory to install files. Any suggestions would be greatly appreciate. Thanks

Post #: 1

Re: select directory box - 2/28/2005 12:47:44 AM

Zifter

Posts: 318
Score: 0
Joined: 1/5/2005
From: Belgium
Status: offline

You need at least Windows XP for the following scripts:

HTH

(in reply to wetarded1)

Post #: 2

Re: select directory box - 2/28/2005 3:55:55 AM

token

Posts: 1917
Score: 0
Joined: 1/14/2005
From:
Status: offline

Zifter, interesting post :)

(in reply to wetarded1)

Post #: 3

Re: select directory box - 2/28/2005 5:35:57 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

zifter. Do you know of one that will allow the user to select a directory instead of a file?

(in reply to wetarded1)

Post #: 4

Re: select directory box - 2/28/2005 7:02:56 AM

mbouchard

Posts: 1916
Score: 16
Joined: 5/15/2003
From: USA
Status: offline

Wetarded1,

Are you looking for something like this? I did not write this but came across it a while ago and it is commented pretty well.

'--this script uses the shell.application object's BrowseForFolder.
'--Properties in shell.application are different from the FSO.
'-- If the folder has files in it, getting the folder path is easy.
'--If not, the method is circuitous.
'--there are various options demonstrated in this script. The other script,
'--BrowseFunction.vbs, contains one funtion to just return the path of selected item.

Dim sh, fol, s, fils, fil, i, sn, s1, sp, fpar
Set sh = CreateObject("Shell.Application")
set fol = sh.browseforfolder(clng(0), "Browser", clng(0))

'--get title of chosen folder.
on error resume next
sn = fol.title
if err.number <> 0 then  '--cancel was clicked.
msgbox "Cancel was clicked.", 64, "Folder Browse"
wscript.Quit
else
msgbox sn
end if

'--This next part goes through the folder files, getting name, size and DateLastModified
'-- for each file. On the first file found, it uses the file path to get path of folder selected.
'-- if the folder contains no files the path will have to be got below.
'-- This function doesn't work for namespaces. For instance, it will list the applets
'-- in control panel but gets no path for them.

i = 0
set fils = fol.items
for each fil in fils
if isfolder = false then  '--get list of folder files.  ****this doesn't seem to work. it still returns folders!
s = s & fil.name & " - " & fil.size & " bytes" & " - " & fil.modifydate & vbcrlf
i = i + 1
if i = 1 then '--get full path of sel. folder by getting path of first folderitem.
s1 = fil.path
spath = left(s1, len(s1) - (len(fil.name) + 1))
if instr(spath, "\") = 0 then    '--add a backslash if it's a drive.
spath = spath & "\"
end if
end if
end if
next

'--show msgbox with file list:

msgbox s

'--show msgbox with path of folder selected, if found:

if spath <> "" then
msgbox "Path of chosen folder:" & vbcrlf & spath
else

'--if there were no files in folder then path is not yet found.
'--this routine will get the path by getting successive parent folder names
'--until it finds one with a colon ( : ). It then parses that name to get the drive
'--and quits the Do Loop.

sp = "a"                  '--make sp something so loop can start.

Do while sp <> ""
on error resume next
Set fpar = fol.parentfolder
sp = fpar.title
'--an error here means no parent folder and no : has been found below
if err.number <> 0 then            '--so it must be a drive or namespace (control panel, etc.)

pt1 = instr(sn, ":")
if pt1 = 0 then                   '--it's a namespace. clean it up.
pt = instrrev(sn, "\")
if pt <> 0 then
sn = right(sn, len(sn) - pt)
end if
exit do
else                                '--it's a drive. extract root folder path (ex.: C:\ )
sp =  mid(sn, pt1 - 1, 2)
sn = sp & "\"
exit do
end if
end if
err.clear
Set fol = fpar
If sp <> "" then   '--look for a colon. if found then quit loop. if not then keep going.
col = instr(sp, ":")
if col = 0 then         '-- no colon. add folder name to path and keep going.
sn = sp & "\" & sn
else                      '--colon found. get root folder, add to path and quit loop.
sp = mid(sp, col - 1, 2)
sn = sp & "\" & sn
exit do
end if
end if
loop

msgbox "Path of chosen folder:" & vbcrlf & sn
end if
set fils = nothing
set fpar = nothing
set fol = nothing
set sh = nothing

(in reply to wetarded1)

Post #: 5

Re: select directory box - 2/28/2005 10:16:58 AM

beaker

Posts: 78
Score: 0
Joined: 1/27/2005
From: USA
Status: offline

As a follow-on to mbouchard's post, the 'BrowseForFolder' method of the Shell.Application object takes as its third parameter a bitwise combination of various flags to control the features of the dialog box. In his example, the default value of '0' is used. Here are all of the possible values for the third parameter:

Const BIF_RETURNONLYFSDIRS   = &H0001
Const BIF_DONTGOBELOWDOMAIN  = &H0002
Const BIF_STATUSTEXT         = &H0004
Const BIF_RETURNFSANCESTORS  = &H0008
Const BIF_EDITBOX            = &H0010
Const BIF_VALIDATE           = &H0020
Const BIF_BROWSEFORCOMPUTER  = &H1000
Const BIF_BROWSEFORPRINTER   = &H2000
Const BIF_BROWSEINCLUDEFILES = &H4000

'BIF_RETURNONLYFSDIRS   - Only return file system directories. If
'                       - the user selects folders that are not part
'                       - of the file system, the OK button is grayed.
'BIF_DONTGOBELOWDOMAIN  - Do not include network folders below the
'                       - domain level in the tree view control.
'BIF_STATUSTEXT         - Include a status area in the dialog box.
'                       - The callback function can set the status
'                       - text by sending messages to the dialog box.
'BIF_RETURNFSANCESTORS  - Only return file system ancestors. If
'                       - the user selects anything other than a
'                       - file system ancestor, the OK button is grayed.
'BIF_EDITBOX            - Version 4.71. The browse dialog includes an
'                       - edit control in which the user can type the name of an item.
'BIF_VALIDATE           - Version 4.71. If the user types an invalid name
'                       - into the edit box, the browse dialog will call
'                       - the application's BrowseCallbackProc with the
'                       - BFFM_VALIDATEFAILED message. This flag is ignored
'                       - if BIF_EDITBOX is not specified.
'BIF_BROWSEFORCOMPUTER  - Only return computers. If the user selects anything
'                       - other than a computer, the OK button is grayed.
'BIF_BROWSEFORPRINTER   - Only return printers. If the user selects anything
'                       - other than a printer, the OK button is grayed.
'BIF_BROWSEINCLUDEFILES - The browse dialog will display files as well as folders.

Here is an example of combining more than one flag together to show the optional edit box and to show files as well as folders:

Set oFolder = oShell.BrowseForFolder (0, "Select Folder", _
(BIF_BROWSEINCLUDEFILES Or BIF_EDITBOX))

(in reply to wetarded1)

Post #: 6

Re: select directory box - 3/1/2005 1:03:18 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

you guys are awesome. You hit the nail right on the head. Exactly what I was looking for.

Thank you very much

(in reply to wetarded1)

Post #: 7

Re: select directory box - 3/1/2005 3:09:47 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

do you guys have an idea on how to implement that? I tried placing it in to a script I have already written with a function statement at the beginning and an end statement, but I run into a problem with the recursion of if it. I am fairly new to vbscript and not really sure what is going. If I run the script by itself, it works fine, but if I put it into a function it wont work.

(in reply to wetarded1)

Post #: 8

Re: select directory box - 3/1/2005 4:03:23 AM

beaker

Posts: 78
Score: 0
Joined: 1/27/2005
From: USA
Status: offline

Step by step, without recopying the whole thing, so that you can learn:
1. Place, 'Function BrowseForFolder' at the top.
2. Place, 'End Function' at the end.
3. Replace both lines 'msgbox "Path of chosen folder:" & vbcrlf & spath' with
line 'BrowseForFolder = "Path of chosen folder:" & vbcrlf & sn'.
4. Call the function with 'MsgBox BrowseForFolder' to see the return value.

That should do it.

(in reply to wetarded1)

Post #: 9

Re: select directory box - 3/1/2005 4:23:08 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

That isnt the problem. I can call the function just fine. The problem lies in the function itself. If I select a folder that does not have a subfolder, the recursion does not find the path of the folder. I cant really read what is going on with it because I dont have much experience reading the code and debugging. I have tried placing msgbox's through out the code to see where it fails, and it seems to fail as soon as it checks the folder and finds no subfolder/files and tries to get the path.

(in reply to wetarded1)

Post #: 10

Re: select directory box - 3/1/2005 5:32:28 AM

beaker

Posts: 78
Score: 0
Joined: 1/27/2005
From: USA
Status: offline

I just wrote this. Please try it and see if it is better:

Option Explicit
On Error Resume Next
Err.Clear

Dim oShell
Dim oFolder
Dim oParent
Dim cItems
Dim oItem
Dim sTitle

Set oShell = CreateObject ("Shell.Application")
Set oFolder = oShell.BrowseForFolder (0, "Select Folder", (0))

If (Err.Number = 0) Then        ' user did not press Cancel button
sTitle = oFolder.Title
Set oParent = oFolder.ParentFolder
Set cItems = oParent.Items
For Each oItem In cItems
If oItem.IsFolder = True Then
If (StrComp(oItem.Name, sTitle, 1) = 0) Then
Wscript.Echo "Type: " & oItem.Type & vbLf
Wscript.Echo "Path: " & oItem.Path & vbLf
End If
End If
Next
End If
Set oShell = Nothing
Set oFolder = Nothing
Set cItems = Nothing
Set oItem = Nothing

If that works for you, we can set about customizing it specifically for your application.

(in reply to wetarded1)

Post #: 11

Re: select directory box - 3/1/2005 5:45:44 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

beaker. I figured out what it was that was causing a problem. I had Option Explicit in there and it wouldnt allow it to find the directory. I took that out and it works great now. Thanks for all your help on this. I really appreciate it.

(in reply to wetarded1)

Post #: 12

Re: select directory box - 3/1/2005 5:54:15 AM

beaker

Posts: 78
Score: 0
Joined: 1/27/2005
From: USA
Status: offline

I actually got some buggy behavior, too, when I tried mbouchard's (found) version. When I would navigate to a folder on my desktop, it would append the first three letters of the first filename onto the path for the folder. When I tried to fix that, it broke other situations. Also, if the use of 'Option Explicit' determines whether or not it works, it probably is not written correctly. I like my new version better.

By the way, you do not see too much use of this 'folder browser' dialog box, but coincidentally today I noticed that Windows Media Player uses it to help the user navigate to a folder containing media files. So even the big boys still use this method!

(in reply to wetarded1)

Post #: 13

Re: select directory box - 3/1/2005 5:57:09 AM

wetarded1

Posts: 17
Score: 0
Joined: 2/17/2005
From:
Status: offline

it did have really odd behavior with option explicit.
what does that mean? I am still trying to learn this stuff as I go.
but it works now, I am going to try the code that you wrote. I might implement that code because it is shorter and nicer on the eyes.

(in reply to wetarded1)

Post #: 14

Re: select directory box - 3/1/2005 6:53:59 AM

beaker

Posts: 78
Score: 0
Joined: 1/27/2005
From: USA
Status: offline

'Option Explicit' means that you must explicitly declare all variables before use. As you may or may not know, VBS is flexible on this point. If you do not use 'Option Explicit', you can create and start using variables without previously reserving memory for them with the Dim, Public, or Private statements. As an overall programming practice, most people recommend the use of Option Explicit because it prevents a typographical error from inadvertantly creating a new variable when you thought the variable already existed. I also recommend its use. My earlier statement from a couple of posts ago was dumb. What must have happened is that the original author did indeed create a variable somewhere in the procedure that he did not declare at the top. When you put 'Option Explicit' in there, it exposed that fact, which then became a problem. It usually causes a runtime error when the program attempts to use the undeclared variable. By the way, you only use the 'Option Explicit' statement one time in a module, and it is placed at the top of the module.

(in reply to wetarded1)

Post #: 15

Re: select directory box - 6/9/2005 9:36:04 PM

kya_karey

Posts: 39
Score: 0
Joined: 5/11/2005
From: India
Status: offline

what should i do if i need to search some perticular file ??

For to search all vbs file this is good

objDialog.Filter = "VBScript Scripts|*.vbs|All Files|*.*"

But when i want some file like vbs file whose names start with "A"

i am writing as follow

objDialog.Filter = "VBScript Scripts|*.vbs|All Files|*A.*"

But its not working can anybody tell me what i have to do

and also if i want to search file from whole computer not just in one directory like "C:/scripts"

objDialog.InitialDir = "C:\Scripts"

(in reply to wetarded1)

Post #: 16

Re: select directory box - 6/9/2005 9:50:55 PM

Zifter

Posts: 318
Score: 0
Joined: 1/5/2005
From: Belgium
Status: offline

If you want to search for a particular file somewhere on the computer, you better use a FileSystemObject or a WMI query.
This dialog is used to give a user the ability the select a file from his/her computer, not to search for files.

The filter property of the dialog is used to make it easier for the user to find a specific type of file.
If you want to filter for files starting with an "A", you could use this:
objDialog.Filter = "Files starting with A|A*.*"

HTH

(in reply to wetarded1)

Post #: 17

Re: select directory box - 6/9/2005 11:15:42 PM

kya_karey

Posts: 39
Score: 0
Joined: 5/11/2005
From: India
Status: offline

And what i need to do if i want to search file from whole computer not perticular Drive like.

objDialog.InitialDir = "C:\Scripts"

WHat i need to write if i want to serach from whole computer

(in reply to wetarded1)

Post #: 18

Re: select directory box - 6/10/2005 12:00:04 AM

Zifter

Posts: 318
Score: 0
Joined: 1/5/2005
From: Belgium
Status: offline

The dialog is not designed to search for files. It is designed to let a user select a file.
The filter property and the initialdir property are there to make it easier for the user to find the file he/she wants to select, not for searching for a file.

If you want to search for a file, you can use the FileSystemObject to iterate through each folder and check each file if it meets your search requirements.

(in reply to wetarded1)

Post #: 19

Re: select directory box - 6/10/2005 1:26:02 AM

kya_karey

Posts: 39
Score: 0
Joined: 5/11/2005
From: India
Status: offline

Would you please provide me script for that b'coz i tried hard but couldnt able to find anything

If you can provide me this scipt it will be very thankful to u

(in reply to wetarded1)