Creating collections explicitly

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Creating collections explicitly

Logged in as: Guest

arrSession:exec spGetSession 2,3,24008

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> ASP >> Creating collections explicitly
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Creating collections explicitly - 7/25/2005 3:11:28 AM

RenzoF

Posts: 1
Score: 0
Joined: 7/25/2005
Status: offline

I want to know if there's a way to create a Collection explicitly.

Something like:

Dim myCol

Set myCol = New Server.CreateObject("Collection")
mycol.Add Object

and so on.

Post #: 1

RE: Creating collections explicitly - 2/17/2006 9:22:26 AM

ebgreen

Posts: 4960
Score: 31
Joined: 7/12/2005
Status: offline

Old question, but I will answer it anyway. In vbscript, there is no stand alone collection data type. The functionality of collections is contained in the Array and Dictionary types instead. It would be simple to write a collection class however. I can do that if it would be helpful to anyone.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to RenzoF)

Post #: 2

RE: Creating collections explicitly - 2/17/2006 9:48:20 AM

ebgreen

Posts: 4960
Score: 31
Joined: 7/12/2005
Status: offline

Ok, well I decided to make a collection class of my own just for fun. What Methods/Properties should I give it? So far I can think of:

.Add      - Add an Item to the collection
.Count   - The number of items in the collection
.Items   - Returns an array of the items in the collection for use in a for-next loop.
.GetItem(nIndex) - Returns the Indexth item from the collection

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ebgreen)

Post #: 3

RE: Creating collections explicitly - 3/30/2006 5:52:28 AM

ebgreen

Posts: 4960
Score: 31
Joined: 7/12/2005
Status: offline

Here is the collection class I made. It is far from perfect and I may make changes going forward, but for the time being it gives me basic functionality.

'=====================================================================================
'
'    Class:        Collection
'    Author:        EBGreen
'
'    Public Properties:
'            Count - Read only property representing the number of objects in the Collection
'            Items - Read only property that returns an array of the items in the collection
'    Public Methods:
'            Add(oItem) - Adds oItem as the last element in the Collection
'            Sort() - Returns an array of the objects in the collection sorted if possible
'            SortInPlace - Sorts the actual collection itself if possible.
'            Exists(oItem) - Returns the index of the first instance of oItem and returns -1
'                    if oItem does not exist in the collection.
'            Remove(nIndex) - Removes the nIndexth item from the collection.
'    Revision History:
'            3/1/06 - EBG - Created
'======================================================================================

Class Collection
   Private arrContents()
   Private bFirstAdd
   
   Private Sub Class_Initialize()
       bFirstAdd = True        
   End Sub
   Public Sub Add(oItem)
       If bFirstAdd Then
           ReDim arrContents(0)
           bFirstAdd = False
       Else
           ReDim Preserve arrContents(UBound(arrContents) + 1)
       End If
       arrContents(UBound(arrContents)) = oItem
   End Sub
   Public Property Get Count()
       If bFirstAdd Then
           Count = 0
           Exit Property
       End If
       Count = UBound(arrContents) + 1
   End Property
   Public Property Get Items()
       Items = arrContents
   End Property
   Public Function Sort()
       'Returns a sorted array of the items
       Sort = BubbleSort(arrContents)
   End Function
   Public Sub SortInPlace()
       BubbleSortInPlace()
   End Sub
   Private Function BubbleSort( arr )
       dim arr_j, arr_j1, i, j, temp
       for i = UBound(arr) - 1 To 0 Step -1
           for j = 0 to i
               arr_j = arr( j )
               arr_j1 = arr( j + 1 )
               if arr_j > arr_j1 Then
                   temp=arr_j1
                   arr(j+1)=arr_j
                   arr(j)=temp
               end If
           Next
       Next
       BubbleSort = arr
   End Function
   Private Sub BubbleSortInPlace()
       dim arr_j, arr_j1, i, j, temp
       for i = UBound(arrContents) - 1 To 0 Step -1
           for j = 0 to i
               arr_j = arrContents( j )
               arr_j1 = arrContents( j + 1 )
               if arr_j > arr_j1 Then
                   temp=arr_j1
                   arrContents(j+1)=arr_j
                   arrContents(j)=temp
               end If
           Next
       Next
   End Sub
   Public Function Exists(oItem)
       Dim oContentItem
       Dim i
       
       i = 0
       For Each oContentItem In arrContents
           If oContentItem = oItem Then
               Exists = i
               Exit Function
           End If
           i = i + 1
       Next
       Exists = -1
   End Function
   Public Function Remove(nIndex)
       Dim i, j
       Dim arrTemp
       
       arrTemp = arrContents
       ReDim arrContents(UBound(arrTemp) -1)
       j = 0
       For i = 0 To UBound(arrTemp)
           If Not i = nIndex Then
               arrContents(j) = arrTemp(i)
               j = j + 1
           Else
               Remove = arrTemp(i)
           End If
       Next
   End Function
End Class

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ebgreen)