Install Patches using XML source

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Install Patches using XML source

Logged in as: Guest

arrSession:exec spGetSession 2,16,24676

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Install Patches using XML source
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Install Patches using XML source - 8/10/2005 3:32:13 AM

mbouchard

Posts: 1804
Score: 12
Joined: 5/15/2003
From: USA
Status: online

Here is the script that I use to install patches on NEW installs. This is meant to be run on PC's that have

Windows XP SP1 with IE6 sp1
Windows XP SP2 with IE6 sp2
Windows 2000 SP4 with IE6 sp1

It can run on others but the patches that I download only support the above combo's.

It was designed to run from the network, but I have added in support for running from a CD/local disk. Look at the code in the script file for more comments.

The folder structure of the patches is this

Something\Patches\MS0x-0xx\media\OS\Patchfile
ex. C:\Folder\Patches\MS05-037\Media\WinXP\Patchfile.exe
Where
Something can = \\server\share\folder\blah OR c:\folder\blah
and OS can equal
WinXPSP1
WinXPSP2
Win2000SP4

I hope that this is fairly easy to follow, but if you have any questions let me know.

_____________________________

Mike

For useful Scripting links see the Read Me First stickey!

Always remember Search is your friend.

Post #: 1

RE: Install Patches using XML source - 8/10/2005 3:32:39 AM

mbouchard

Posts: 1804
Score: 12
Joined: 5/15/2003
From: USA
Status: online

Patches.VBS

------------------------------------------------------------------------

'Moved Patch variable to the xml file
 ' To do: Add support for checking without running patch.  Create script/add to current script the ability to output all patches being installed and what is being checked.
 Option Explicit
 Const CHECKXPSP1 = "SP1"
 Const CHECKXPSP2 = "SP2"
 Const CHECK2KSP = "SP4"
 Const CHECKIESP1 = "IE6SP1"
 Const CHECKIESP2 = "IE6SP2"
 
 Const HKLM = &H80000002
 Const FORREADING = 1
 Const FORWRITING = 2
 Const FORAPPENDING = 8
 
 Dim Fso : Set Fso = CreateObject("Scripting.FileSystemObject")
 Dim WshShell : Set WshShell = CreateObject("WScript.Shell")
 Dim WshSysEnv : Set WshSysEnv = WshShell.Environment("SYSTEM")
 Dim doPatch : doPatch = False 'Used to set Patch Version Variable
 Dim checkOS : checkOS = False 'Used to determine if OS is supported
 Dim checkIE : checkIE = False 'Used to determine if IE is supported
 Dim strOS, strSP, strIE, spMsg,spIEMsg
 Dim strPatchPath,PatchList, PatchNode, PatchVer
 Dim CriterionList, Criterion, PatchPath
 Dim Doc,CheckList
 Dim CriteriaList, CriteriaOK, Checks, Criteria
 Dim OSname, OSValue, TestValue, CurValue, CurVal
 Dim InstallFile,cmd, msg, strPathToPatch
 Dim FileCheckList, FileCheck, FolderPath, FileName, FileVer
 Dim strFolder
 Dim RegCheckList, RegistryCheck, Reghive, Regkey, RegCheck, regchecktype
 Dim ret, T
 Dim PatchDone, OS, svcRestart
 Dim thepatchscriptver,PatchScriptVer
 Dim strServer : strServer = "\\SERVER\SHARE" 'Path to the server
 Dim strPathToScript : strPathToScript = Fso.GetParentFolderName(Wscript.ScriptFullName)'Used for location of XML file
 Dim strPathToXml : strPathToXml = strPathToScript & "/Patches.xml" 'Path to the XML file
 
 '*********************************************************************
 ' Set Where Patches will be run from
 '*********************************************************************
 'Used to signify where the MS patches are stored
 If instr(lcase(strPathToScript), "wmdt\support") Then 'This is the path to a share on the network where all patches are stored.
   strPatchPath = strServer & "\standard\microsoft\Patches"
 Else
     If Right(strPathToScript,2) = ":\" Then 'makes sure that "\\" does not occure if script is in root of drive.
         strPathToScript = Replace(strPathToScript,":\",":")'See note below
     End If
   strPatchPath = strPathToScript & "\Patches"
   'This will allow the patches script to find patches anyplace as long as the EXE's are stored in a folder Patches and the script is one level up.
   'Patch.vbs script is located in c:\nt
   'The Patches folder is located in c:\nt\patches
   'strPatchPath = c:\nt\patches
 End if
 
 '*********************************************************************
 ' Set variable to indicate the version of the Windows operating system
 '*********************************************************************
 strOS = GetTheOS 'WXP, W2K, NT4, or W98
 strSP = GetServicePack 'SP1, SP2, SP3, Or None
 strIE = GetIEVersion 'IE6 or IE6SP1
 
 '**********************************************************************************
 'Check for Current ServicePack for Windows and Internet Explorer
 '**********************************************************************************
 If strOS = "WXP" Then
     If strSP = CHECKXPSP1 Then checkOS = True
     If strSP = CHECKXPSP2 Then checkOS = True
     If checkOS = False Then spMsg = "Windows XP " & CHECKXPSP1 & " or " & CHECKXPSP2
 ElseIf strOS = "W2K" Then 
     If strSP = CHECK2KSP Then checkOS = True
     If checkOS = False Then spMsg = "Windows 2000 " & CHECK2KSP
 End If
 
 If strIE = CHECKIESP1 Then checkIE = True
 If strIE = CHECKIESP2 Then checkIE = True
 
 If checkIE = False Then
     If spMsg = "" Then
         spMsg = "Internet Explorer " & CHECKIESP1 & " or " & CHECKIESP2
     Else
         spIEMsg = " and Internet Explorer " & CHECKIESP1 & " or " & CHECKIESP2
     End If
 End If
 
 If WScript.Arguments.Count = 0 Then
     If spMsg <> "" Then 
         Msgbox "This script requires: [" & spMsg & spIEmsg & "] to run." & vbcr _
         & "Please update to the latest Service Pack and / or IE Version (in that order) and re-run the Patches Script" & vbcr _
         & vbcr & "If you wish to run some of the patches, re-run this script with the switch \Patch"
         wscript.quit
     End If
 End If
 
 '**********************************************************************************
 'Begin Patches install
 '**********************************************************************************
 Call LoadXML(Doc, strPathToXml)
 'Get version of XML file.  Taken from <info>
 Call GetNode(Doc,thepatchscriptVer,"/info")
 patchScriptVer = GetValue(thepatchscriptVer,"patchscriptver")
 
 If strOS = "WXP" Then Call WriteToLog("Installing patches as needed for Windows XP " & strSP)
 If strOS = "W2K" Then Call WriteToLog("Installing patches as needed for Windows 2000 " & strSP)
 
 call GetNodes(Doc, patchList, "/info/patch")
 For Each patchNode in patchList
     patchVer = GetValue(patchNode, "patchver")
     
     Call GetNodes(patchNode, criterionList, "criterion")
 
     For Each criterion in criterionList'Processes Criterions
         patchPath = GetValue(criterion, "patchpath")
         cmd = GetValue(criterion, "cmd")
         msg = GetValue(criterion, "msg")
 
         Call GetNodes(criterion, criteriaList, "criteria")
     
         criteriaOk = False
         set checks = CreateObject("Scripting.Dictionary")
         For Each criteria in criteriaList'Processes Criteria's
             osname = LCase(GetValue(criteria, "osname"))
             osvalue = LCase(GetValue(criteria, "osvalue"))
             Select Case osname
                 case "osver_or": 
                     testvalue = "0" & checks(osname) 
                     curvalue = IsValue(strOS & strSP, osvalue)
                     curval = CInt(curvalue) + CInt(testvalue)
                     checks(osname) = Mid("011", curval+1,1): ' 0 - False, 1-True, oring conditions
                 case "iever_or": ' Code/function to test ieversiion
                     testvalue = "0" & checks(osname) 
                     curvalue = IsValue(strIE, osvalue)
                     curval = CInt(curvalue) + CInt(testvalue)
                     checks(osname) = Mid("011", curval+1,1): ' 0 - False, 1-True, oring conditions
             End Select
         Next
         checkList = checks.Items()
         criteriaOk = True
         For T=0 To UBound(checkList)
             If checkList(T)<>"1" Then
                 criteriaOk = false
                 Exit For
             End If
         Next
 
         If criteriaOk Then
           If FileCheckOK(criterion) OR RegCheckOK(criterion) Then
 '            Call WriteToLog("Checking patch " & patchVer)
             ' Run Patch
             'Check patchpath to verify that it has a starting and trailing \
             If NOT Left(patchpath,1) = "\" Then PatchPath = "\" & patchPath
             'Make sure that the full path does not contain \\ unless it is the left 2 chars
             If Left(strPatchPath,2) = "\\" Then
             'Make sure that the only \\ is at the start of the UNC path.
                 strPathToPatch = "\\" & Replace(MID(strPatchPath & patchpath,3,Len(strPatchPath & patchpath & installfile)),"\\","\")
               Else
                 strPathToPatch = Replace(MID(strPatchPath & patchpath,3,Len(strPatchPath & patchpath & installfile)),"\\","\")
             End If
             'DoInstall
                If Fso.FileExists(strPathToPatch) Then
                   WriteToLog(msg)
                   WshShell.Run """" & strPathToPatch & """ " & cmd,1,true
                   doPatch = True
                Else
                   WriteToLog("Exe not found for " & patchVer & "(" & strPathToPatch & ")")
                End If
           End If
         End If
 
     Next
 Next
 '************************************************************************************************
 ' Create tag file on C: drive to indicate that this script has completed and Set version variable
 '************************************************************************************************
 If doPatch = True Then
     WshSysEnv("CurrentPatchBuild") = patchScriptVer & " " & Date
 Else
     Call WriteToLog("No approved patches were needed.")    
 End if
 
 Call WriteToLog("Completed Patches.vbs")
 
 If WScript.Arguments.Count = 0 Then
     If spMsg <> "" Then 
         Msgbox "Some patches may not have been installed as this script requires: [" & spMsg & spIEmsg & "]." & vbcr _
         & "Please update to the latest Service Pack / Version and re-run the Patches Script"
     Else
         If doPatch = True Then
             Ret = Msgbox("Completed installing patches" & Vbcr & "Please reboot PC for changes to be applied",vbYesNo)
             If Ret = vbYes Then
                 On Error Resume Next
                 Set svcRestart = GetObject("WinMgmts:{impersonationLevel=impersonate,(Shutdown)}//./root/cimv2")
                 For Each Os in svcRestart.ExecQuery("select * from Win32_OperatingSystem where Primary=true")
                     Os.Reboot
                 Next
                 On Error GoTo 0
             End If
         Else
             Msgbox "No approved patches required."
         End if
     End If
 ElseIf LCase(Wscript.Arguments(0)) = "/nomsg" Then
   Set PatchDone = Fso.CreateTextFile("c:\patchesdone.txt", True)
 End If
 
 Wscript.Quit
 
 '**********************************************************
 'Procedures
 '**********************************************************
 Function IsValue(myValue, value)
   If lcase(myValue) = lcase(value) Then
         IsValue = "1"
     Else
       IsValue = "0"
   End If
 End Function
 
 Function RegistryKeyExists(LNGHKEY, strKey, strSubkey)
     RegistryKeyExists = False
     Dim reg, aSubkeys, s
     Set reg = GetObject("WinMgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
     reg.EnumKey LNGHKEY, strKey, aSubkeys
     If Not IsNull(aSubkeys) Then
         For Each s In aSubkeys
             If lcase(s)=lcase(strSubkey) Then
                 RegistryKeyExists = True
                 Exit Function
             End If
         Next
     End If
 End Function
 
 Function RegCheckOK(criterion)
     Call GetNodes(criterion, RegCheckList, "registrycheck")'Processes filechecks
     RegCheckOK = False
     For Each registrycheck in regcheckList
         reghive=LCASE(GetValue(registrycheck, "reghive"))'"HKLM" 
         regkey=LCASE(GetValue(registrycheck, "regkey"))'"SOFTWARE\Microsoft\Updates\Windows XP\SP2\KB833987" 
         regcheck=LCASE(GetValue(registrycheck, "regcheck"))'"FileList" 
         regchecktype=LCASE(GetValue(registrycheck, "regchecktype"))'"key" or Value
 
         If reghive = "hklm" Then reghive = HKLM 'Which Tree
         If regchecktype = "key" Then
             If RegistryKeyExists(reghive, regkey, regcheck) = False Then
                 RegCheckOK = True'Patch needs to be installed
                 Exit Function
             End if
         End If
     Next
 End Function
             
 Function FileCheckOK(criterion)
     Const WindowsFolder = 0
     Const SystemFolder = 1
     Dim TheFile
     Call GetNodes(criterion, FileCheckList, "filecheck")'Processes filechecks
     FileCheckOK = False
     For Each filecheck in filecheckList
         folderpath = LCASE(GetValue(filecheck, "folderpath"))
         fileName = LCASE(GetValue(filecheck, "filename"))
         filever = GetValue(filecheck, "filever")
 
             Select Case folderpath
                 Case "systemfolder" strFolder = Fso.GetSpecialFolder(SystemFolder) & "\"
                 Case "windowsfolder" strFolder = Fso.GetSpecialFolder(WindowsFolder) & "\"
                 Case Else strFolder = folderpath & "\"
             End Select
 
             'Check for double \\ 
             TheFile = Replace(strFolder & filename,"\\", "\")
             If fso.fileexists(TheFile) Then
                 If CompareVersion(Fso.GetFileVersion(TheFile), FileVer) = -1 Then
                     FileCheckOK = True'Patch needs to be installed
                     Exit Function
                End If
            Else 
             Call Writetolog(patchVer & " File " & filename & "not present")
            End If
     Next
 End Function
 
 Sub LoadXML(Doc, fileName)
   Dim fso, fo, xml, errDesc, errNum
   Set Doc = CreateObject("Msxml.DOMDocument")
   Set fso = CreateObject("Scripting.FileSystemObject")
   If fso.FileExists(fileName) Then
     Set fo = fso.OpenTextFile(fileName)
     xml = fo.ReadAll()
     fo.Close
     Doc.Async = False
     If Not Doc.LoadXML(xml) Then
       Exit Sub
     End If
   Else
         Exit Sub
   End If
 End Sub
 
 Sub GetNode(Doc, Node, NodePath)
   Set Node = Doc.selectSingleNode(NodePath)
 End Sub
 
 Sub GetNodes(Doc, Node, NodePath)
     Set Node = Doc.selectNodes(NodePath)
 End Sub
 
 Function GetValue(Node, ByVal Key)
   GetValue = "" & Node.getAttribute(LCase(Key))
 End Function
 
 Function CompareVersion(ByVal Version1, ByVal Version2)
     Dim V1, V2, T1, T2
     ' Function returns -1 if Version1 < Version2
     ' Function returns 1 if Version1 > Version2
     ' Function returns 0 if Version1 = Version2
     CompareVersion = 0
     If Version1="" Or Version2="" Then
         If Version1<Version2 Then
             CompareVersion = -1
             Exit Function
         Else
             If V1>V2 Then
                 CompareVersion = 1
                 Exit Function
             Else
                 CompareVersion = 0
                 Exit Function
             End If
         End If
     End If
     T1 = Instr(Version1, ".")
     If T1 = 0 Then T1 = Len(Version1)+1
     T2 = Instr(Version2, ".")
     If T2 = 0 Then T2 = Len(Version2)+1
     Do While True
         V1 = CInt(Left(Version1,T1-1))
         V2 = CInt(Left(Version2,T2-1))
         If V1<V2 Then
             CompareVersion = -1
             Exit Function
         Else
             If V1>V2 Then
                 CompareVersion = 1
                 Exit Function
             End If
         End iF
         Version1 = Mid(Version1,T1+1)
         Version2 = Mid(Version2,T2+1)
         If Version1="" Or Version2="" Then
             If Version1<Version2 Then
                 CompareVersion = -1
                 Exit Function
             Else
                 If V1>V2 Then
                     CompareVersion = 1
                     Exit Function
                 Else
                     CompareVersion = 0
                     Exit Function
                 End If
             End If
         End iF
         T1 = Instr(Version1, ".")
         If T1 = 0 Then T1 = Len(Version1)+1
         T2 = Instr(Version2, ".")
         If T2 = 0 Then T2 = Len(Version2)+1
     Loop
 End Function
 
 Sub WriteToLog(Message) ' For writing description of installation to Software Configuration.log
 Const FORREADING = 1
 Const FORWRITING = 2
 Const FORAPPENDING = 8
     Dim fLog, TheLogFile
     TheLogFile = "c:\program files\software configuration.log"
     ' Create the log file if it does not exist
     If not Fso.FileExists(TheLogFile) Then
         Set fLog = Fso.CreateTextFile(TheLogFile, True)
         fLog.WriteLine("Software Configuration Log")
         fLog.Close
     End If
     ' Append to the log file
     Set fLog = Fso.OpenTextFile(TheLogFile, FORAPPENDING)
     If Message = "" Then
         fLog.WriteLine("")
         flog.Close
     Else
         fLog.WriteLine(Now & "  " & Message)
         fLog.Close
     End If
 End Sub
 
 Function GetTheOS()
 ' Will work with most versions of WSH.
     Dim sResults, fFile
     Dim WshShell : Set WshShell = CreateObject("WScript.Shell")
     Dim FSO : Set FSO = CreateObject("Scripting.FileSystemObject")
     Dim sTemp : sTemp = WshShell.ExpandEnvironmentStrings("%TEMP%")
     Dim sTempFile : sTempFile = "c:\runresult.tmp"
     WshShell.Run "%comspec% /c ver >" & sTempFile, 0, True
 '  wscript.sleep 1000
 '  On error Resume Next
     Set fFile = FSO.OpenTextFile(sTempFile, FORREADING)
     sResults = fFile.ReadAll
     fFile.Close
     Fso.DeleteFile(sTempFile)
 
     Select Case True
         Case InStr(sResults, "Windows NT") > 1 : GetTheOS = "NT4"
         Case InStr(sResults, "Windows 2000") > 1 : GetTheOS = "W2K"
         Case InStr(sResults, "Windows XP") > 1 : GetTheOS = "WXP"
         Case Else : GetTheOS = "Unknown"
     End Select
 End Function
 
 Function GetIEVersion
     Dim sKey, sPath, tPack
     sKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\IEXPLORE.EXE\"
     sPath = Wshshell.regread(sKey)
     tPack = Fso.getfileversion(sPath)
     If CompareVersion(Fso.getfileversion(sPath), "6.00.2900.2180") = 0 Then
         GetIEVersion = "IE6SP2"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "6.00.2800.1106") = 0 Then
         GetIEVersion = "IE6SP1"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "6.00.2600.0000") = 0 Then
         GetIEVersion = "IE6"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.50.4807.2300") = 0 Then
         GetIEVersion = "IE55SP2"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.50.4522.1800") = 0 Then
         GetIEVersion = "IE55SP1"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.00.3700.1000") = 0 Then
         GetIEVersion = "IE51SP4"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.00.3502.1000") = 0 Then
         GetIEVersion = "IE51SP3"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.00.3315.1000") = 0 Then
         GetIEVersion = "IE51SP2"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.00.3103.1000") = 0 Then
         GetIEVersion = "IE51SP1"
     ElseIf CompareVersion(Fso.getfileversion(sPath), "5.00.2920.0000") = 0 Then
         GetIEVersion = "IE51"
     Else
         GetIEVersion = "UNKNOWN"
     End If
 End Function
 
 Function GetServicePack
 Dim Os
     For Each Os in GetObject("WinMgmts://").ExecQuery("select CSDVersion from Win32_OperatingSystem where Primary=true")
         Select Case Os.CSDVersion
             Case "Service Pack 1" : GetServicePack = "SP1"
             Case "Service Pack 2" : GetServicePack = "SP2"
             Case "Service Pack 3" : GetServicePack = "SP3"
              Case "Service Pack 4" : GetServicePack = "SP4"
             Case Else GetServicePack = "None"
         End Select
     Next
 End Function

< Message edited by mbouchard -- 9/15/2005 11:19:18 PM >

_____________________________

Mike

For useful Scripting links see the Read Me First stickey!

Always remember Search is your friend.

(in reply to mbouchard)

Post #: 2

RE: Install Patches using XML source - 8/10/2005 3:48:47 AM

mbouchard

Posts: 1804
Score: 12
Joined: 5/15/2003
From: USA
Status: online

Patches.XML
The way this is setup.
<info patchscriptver=P-xx> is used to set what version of the patch script ran when the patches were installed to an environment variable. This is only used for reporting.
<patch patchver=""> is used to store what version is being installed, call it want you want, I normally use the MS0 number, but you will notice a difference with the roll up's
<criterion patchpath="" cmd="" msg="">
    PatchPath = this line is used to tell where the patch is located (reference the first post to see what the path would look like
    cmd = the command line used to install patches. Taken from the MS security bulletin
    msg = what is written to the log file.
<criteria osname="osver_or" osvalue=""/>
    osname = Used by the script to see what needs to be checked, ie OS or IE versions
    osvalue = See Script for what is being checked here, can be found in the constants at the top (IE) or in the getOS function (OS)
<registrycheck reghive="" regkey="" regcheck="" regchecktype=""/>
     reghive = which hive to check HKLM, HKCU etc. For the most part HKLM is used
     regkey = Which key is being checked
     regcheck = What the value should be (can be key or value of a key)
     regchecktype = What is being checked, Key, Vlaue. ATM I have only checked KEYs.

I have supplied some examples below.
-----------------------------------------------------------------------------------

<info patchscriptver="P-012">
         
     
     <patch patchver="2000 Security Roll Up 1">
         <criterion patchpath="\Win2KSp4RollUp1\Media\Win2000\Windows2000-KB891861-x86-ENU.EXE" cmd="/passive /norestart /overwriteoem" msg="Installing Windows 2000 Security Roll Up 1 (891861)">
             <criteria osname="osver_or" osvalue="w2ksp4"/>
             <registrycheck reghive="HKLM" regkey="SOFTWARE\Microsoft\Updates\Windows 2000\SP5\Update Rollup 1" regcheck="FileList" regchecktype="key"/>
         </criterion>
     </patch>
 
     <patch patchver="MS05-037">
         <criterion patchpath="\MS05-037\Media\IE6sp2\WindowsXP-KB903235-x86-ENU.exe" cmd="/passive /norestart /overwriteoem" msg="Installing Security Update MS05-037 (903235)">
             <criteria osname="iever_or" osvalue="is6sp2"/>
             <registrycheck reghive="HKLM" regkey="SOFTWARE\Microsoft\Internet Explorer\ActiveX Compatibility" regcheck="{03D9F3F2-B0E3-11D2-B081-006008039BF0}" regchecktype="key"/>
         </criterion>
         <criterion patchpath="\MS05-037\Media\IE6sp1\IE-KB903235-x86-ENU.exe" cmd="/Q:U" msg="Installing Security Update MS05-037 (903235)">
             <criteria osname="iever_or" osvalue="ie6sp1"/>
             <registrycheck reghive="HKLM" regkey="SOFTWARE\Microsoft\Internet Explorer\ActiveX Compatibility" regcheck="{03D9F3F2-B0E3-11D2-B081-006008039BF0}" regchecktype="key"/>
         </criterion>
         <criterion patchpath="\MS05-037\Media\IE501\IE-KB903235-x86-ENU.exe" cmd="/passive /norestart /overwriteoem" msg="Installing Security Update MS05-037 (903235)">
             <criteria osname="iever_or" osvalue="ie501"/>
             <registrycheck reghive="HKLM" regkey="SOFTWARE\Microsoft\Internet Explorer\ActiveX Compatibility" regcheck="{03D9F3F2-B0E3-11D2-B081-006008039BF0}" regchecktype="key"/>
         </criterion>
     </patch>
 
     <patch patchver="MS05-036">
         <criterion patchpath="\MS05-036\WinXP\WindowsXP-KB901214-x86-ENU.exe" cmd="/passive /norestart /overwriteoem" msg="Installing Security Update MS05-036 (901214)">
             <criteria osname="osver_or" osvalue="wxpsp2"/>
             <filecheck folderpath="systemfolder" filename="icm32.dll" filever="5.1.2600.2709"/>
         </criterion>
         <criterion patchpath="\MS05-036\WinXP\WindowsXP-KB901214-x86-ENU.exe" cmd="/passive /norestart /overwriteoem" msg="Installing Security Update MS05-036 (901214)">
             <criteria osname="osver_or" osvalue="wxpsp1"/>
             <filecheck folderpath="systemfolder" filename="icm32.dll" filever="5.1.2600.1710"/>
         </criterion>
         <criterion patchpath="\MS05-036\Win2000\Windows2000-KB901214-x86-ENU.EXE" cmd="/passive /norestart /overwriteoem" msg="Installing Security Update MS05-036 (901214)">
             <criteria osname="osver_or" osvalue="w2ksp4"/>
             <filecheck folderpath="systemfolder" filename="icm32.dll" filever="5.0.0.3"/>
         </criterion>
     </patch>
 
     
     
     <patch patchver="MS04-034">
         <criterion patchpath="\MS04-034\Media\WinXP\WindowsXP-KB873376-x86-enu.exe" cmd="/passive /norestart /o" msg="Installing Security Update MS04-034 (873376)">
             <criteria osname="osver_or" osvalue="wxpsp1"/>
             <filecheck folderpath="SystemFolder" filename="zipfldr.dll" filever="6.0.2800.1584"/>
         </criterion>
     </patch>
 
     <patch patchver="MS04-032">
         <criterion patchpath="\MS04-032\Media\WinXP\WindowsXP-KB840987-x86-enu.exe" cmd="/passive /norestart /o" msg="Installing Security Update MS04-032 (840987)">
             <criteria osname="osver_or" osvalue="wxpsp1"/>
             <filecheck folderpath="SystemFolder" filename="Kernel32.dll" filever="5.1.2600.1560"/>
         </criterion>
     
     
     <patch patchver="XP Security Roll Up 1">
         <criterion patchpath="\WinXPSp1RollUp1\Media\WinXP\KB826939.exe" cmd="/u /o /n /z" msg="Installing Windows XP Security Rollup 1 (826939)">
             <criteria osname="osver_or" osvalue="wxpsp1"/>
             <registrycheck reghive="HKLM" regkey="SOFTWARE\Microsoft\Updates\Windows XP\SP2\KB826939" regcheck="FileList" regchecktype="key"/>
         </criterion>
     </patch>
 
     <patch patchver="MS03-043">
         <criterion patchpath="\MS03-043\media\winxp\windowsxp-kb828035-x86-enu.exe" cmd="/passive /norestart /o" msg="Installing Security Update MS03-043 (828035)">
             <criteria osname="osver_or" osvalue="wxpsp1"/>
             <filecheck folderpath="SystemFolder" filename="msgsvc.dll" filever="5.1.2600.1309"/>
         </criterion>
     </patch>
     
     
 
 </info>

< Message edited by mbouchard -- 9/15/2005 11:20:05 PM >

_____________________________

Mike

For useful Scripting links see the Read Me First stickey!

Always remember Search is your friend.

(in reply to mbouchard)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> Install Patches using XML source

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts