ManagePC Tool HTA

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

ManagePC Tool HTA

Logged in as: Guest

arrSession:exec spGetSession 2,16,24728

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> ManagePC Tool HTA
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

ManagePC Tool HTA - 8/11/2005 1:05:27 AM 1 votes

ginolard

Posts: 1005
Score: 21
Joined: 8/10/2005
Status: offline

Save the following code as an HTA. It is a tool that will allow you to manage any PC in the forest. The buttons won't show up properly as you need the images they use

<html>
  
  
  
  <title>Manage PC Tool v1.3</title>
  <head>
  
  <HTA:APPLICATION 
       APPLICATIONNAME="Manage PC Tool"
       SCROLL="yes"
       SINGLEINSTANCE="yes"
       WINDOWSTATE="normal"
       
  >
  </head>
  
      <style> 
      .tab
  {
           color: navy;
           background-color: white;
           border: thin solid navy;
           position: absolute;
           top: 10;
           width: 40;
           text-align: center;
           font: 9pt Verdana,sans-serif;
           
           z-index: 2;
           padding: 3;
           cursor: pointer;
           cursor: hand;
  }
  .panel
  {
           position: absolute;
           top: 32;
           left: 10;
           width: 95%;
           z-index: 1;
           height: 85%;
           visibility: hidden;
           font: 12pt Verdana,sans-serif;
            
           color: navy;
           border: thin solid navy;
           padding: 10;
           overflow: auto;
  }
  BODY
  {
  background-color: buttonface;
    
     font-size: 10pt;
     margin-top: 10px;
     margin-left: 20px;
     margin-right: 20px;
     margin-bottom: 10px;
  }
  .button
  {
     font-size: 8pt;
     width: 92px;
  }
  td
  {
     font-family: arial;
     font-size: 10pt;
  }
  
  </style>
  
  <script language="VBScript">
  'Declare variables and create objects to be used during the script.  
  'The FirstRun variable is used to determine if this is the first time the HTA has been opened.  If so, it used in the
  'ImportMachines Sub to force the script to import machines from the default domain.
      'On Error Resume Next
  
      Dim strSeconds,strWaitMsg,objExplorer,varIP,i,strForest,TotalRes,strDefaultDomain,FirstRun,strSoftInfo
     DimstrcompManufacturer,strcompModel,strcompName,strcompSystemType,strHostNameRole,strChassisType,strOS,varMachineOnline
     DimstrBIOSver,strPFSize,StrCompRAM,strFloppyPresent,strHDD,StrShares,strCD,strSvcPack,strBIOS,strIP,varShowDisabledServices
      
      Const ForWriting = 2
      Const ADS_SCOPE_SUBTREE = 2
      
      varShowDisabledServices=False
      varMachineOnline=False
  
      Set objShell = CreateObject("WScript.Shell")
      myCur = objShell.CurrentDirectory
      
      Set objFSO = CreateObject("Scripting.FileSystemObject")
      Set Logfile = objFSO.OpenTextFile(myCur & "\" & "managepc.log",ForWriting,True)
      LogFile.Writeline "This logfile was created on " & Date & " at " & Time & VbCrLf 
      
      Set objRootGC = GetObject("GC://RootDSE")
      strForest = objRootGC.Get("RootDomainNamingContext")
      strDefaultDomain=objRootGC.Get("DefaultNamingContext")
      
      strWaitMsg="<center>Importing machines from Active Directory.  Please wait....</center>"
  
  'Determine the user's resolution so that we can put the "Please wait" message in the middle of the screen.
      Set objWMIService = GetObject("Winmgmts:\\.\root\cimv2")
      Set colItems = objWMIService.ExecQuery("Select * From Win32_DesktopMonitor")
      For Each objItem in colItems
          intHorizontal = objItem.ScreenWidth
          intVertical = objItem.ScreenHeight
      Next
          TotalRes=Int(intHorizontal + intVertical)
  
      Set objWMIService=Nothing
      Set colItems=Nothing
      
      FirstRun=True
      varIP=""
  
  Sub Window_OnLoad
  'Prepare user interface and load users.  Dynamically create the HTML textareas depending on the user's resolution
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Running On_Load Routine"
      Refresh_button.Disabled=True
      
      If TotalRes >= 2304 Then
        SoftInfoSetting.InnerHTML="<textarea rows=""20"" name=""SoftInfo""cols=""72""align=""right""></textarea>"      
         MachineInfoSetting.InnerHTML="<textarea rows=""20"" name=""PCInfo"" cols=""72""align=""right""></textarea>"
        UserInfoSetting.InnerHTML="<textarea rows=""20""name=""UserInfo"" cols=""30"" align=""right""></textarea>"
        SvcInfoSetting.InnerHTML="<textarea rows=""20"" name=""SVCInfo""cols=""30"" align=""right""></textarea>"
        PCInfoSetting.InnerHTML="<select size=""23"" width=""25""name=""PCList"" onChange=""RunScript""></select>"
      End If
  
      If TotalRes = 1792 Then
        SoftInfoSetting.InnerHTML="<textarea rows=""15"" name=""SoftInfo""cols=""57""align=""right""></textarea>"      
         MachineInfoSetting.InnerHTML="<textarea rows=""15"" name=""PCInfo"" cols=""57""align=""right""></textarea>"
        UserInfoSetting.InnerHTML="<textarea rows=""15""name=""UserInfo"" cols=""27"" align=""right""></textarea>"
        SvcInfoSetting.InnerHTML="<textarea rows=""15"" name=""SvcInfo""cols=""27"" align=""right""></textarea>"
        PCInfoSetting.InnerHTML="<select size=""16"" width=""25""name=""PCList"" onChange=""RunScript""></select>"
          
      End If
  
      Call DisplayWaitWindow
      Call ImportDomains
      Call ImportMachines
      Call DisableButtons
      PCInfo.ReadOnly=True
      SoftInfo.ReadOnly=True
      UserInfo.ReadOnly=True
  
      objExplorer.Quit
  
  End Sub
  
  Sub DisplayWaitWindow
  'Display "Please wait" window
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Display 'Please wait' window"
      Set objExplorer = CreateObject ("InternetExplorer.Application")
          objExplorer.Navigate "about:blank"   
          objExplorer.ToolBar = 0
          objExplorer.Resizable = 0
          objExplorer.StatusBar = 0
          objExplorer.Left = (intHorizontal - 400) / 2
          objExplorer.Top = (intVertical - 200) / 2
          objExplorer.Width = 400
          objExplorer.Height = 100 
          objExplorer.Visible = 1   
          objExplorer.Document.Body.Style.Cursor = "wait"
          objExplorer.Document.Title = "ManagePC"
          objExplorer.Document.Body.InnerHTML = strWaitMsg
  
  End Sub
  
  Sub ImportMachines
  'Import list of users from Active Directory
      On Error Resume Next
  
      Call ClearPCList
  
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Importing Machines"
      Set objConnection = CreateObject("ADODB.Connection")
      Set objCommand =   CreateObject("ADODB.Command")
      objConnection.Provider = "ADsDSOObject"
      objConnection.Open "Active Directory Provider"
      objConnection.Cursorlocation=3
  
      Set objCommand.ActiveConnection = objConnection
      If FirstRun=True Then
         objCommand.CommandText = "SelectName from 'GC://" & strDefaultDomain & "' " & "WhereobjectClass='computer'"  
      Else
         objCommand.CommandText = "SelectName from 'GC://" & DomainList.Value & "' " & "WhereobjectClass='computer'"  
      End If
      objCommand.Properties("Page Size") = 1000
      objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
      
      Set objRecordSet = objCommand.Execute
      If FilterCompInput.Value = "" Then 
          objRecordSet.Filter=""
      Else
          objRecordSet.Filter="Name LIKE '" & FilterCompInput.Value & "*'"
      End If
      If objRecordSet.RecordCount = 0 Then
          MsgBox "No machines found matching the current filter"
          Exit Sub
      End If
  
      objRecordSet.MoveFirst
      objRecordSet.Sort="Name"
  
      Do Until objRecordSet.EOF
            Set objOption = Document.createElement("Option")
          objOption.Text = objRecordSet.Fields("Name")
          objOption.Value = objRecordSet.Fields("Name")
          PCList.Add objOption
            objRecordSet.MoveNext
      Loop 
      
      objRecordSet.Close
      objConnection.Close
      FirstRun=False    
  
  End Sub
  
  Sub RunScript
  
  On Error Resume Next
  'If the machine is online, get all WMI info and the currently logged on user and update all fields with values
  'If the machine is offline, display error messages.
      
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Running OnlineCheck/IsConnectible on " & PCList.Value
      Refresh_button.Disabled=False
  
      If IsConnectible = True Then
          MachineStatus.InnerHTML= PCList.Value & " is ONLINE"
          varMachineOnline=True
          Call EnableButtons
  
         Set objWMIService =GetObject("winmgmts:"  & "{impersonationLevel=impersonate}!\\"& PcList.Value & "\root\cimv2")
          If Err.Number = -2147217405 Then
              PCInfo.Value = "Unable to make WMI connection"
              UserInfo.Value = "Unable to make WMI connection"
              SoftInfo.Value = "Unable to make WMI connection"
              SVCInfo.Value = "Unable to make WMI connection"
              CurrentUser.Value = "N/A"
              Exit Sub
          End If
  
      Set colComputer = objWMIService.ExecQuery  ("Select UserName from Win32_ComputerSystem")
  
      For Each objComputer in colComputer
          If Not IsNull(objComputer.UserName) Then
              CurrentUser.Value = objComputer.UserName
          Else
              CurrentUser.Value = "No user logged on."
          End If
      Next
  
      Call GetPCInfo
  
      Else
          MachineStatus.InnerHTML= PCList.Value & " is OFFLINE!!"
          PCInfo.Value="Machine is offline.  Could not obtain WMI data."
          SoftInfo.Value="Machine is offline.  Could not obtain installed software."
         UserInfo.Value="Machine isoffline." & VbCrLf & VbCrLf & "Could not obtain local userinformation."
        SVCInfo.Value="Machine is offline." & VbCrLf & VbCrLf &"Could not obtain services information."
          CurrentUser.Value = "No user logged on."
          varMachineOnline=False
          Call DisableButtons
      End If
  
      Set objWMIService=Nothing
      Set colComputer=Nothing
     LogFile.Writeline Time & vbTab & "-" &vbTab & "OnlineCheck/IsConnectible completed On "& PCList.Value
      
  End Sub
  
  Function IsConnectible()
  'Check if the remote machine is online. 
      Dim objPing,objStatus
  
      Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._
         ExecQuery("select Replysizefrom Win32_PingStatus where address = '" & PCList.Value & "'")
  
      For Each objStatus in objPing
          If  IsNull(objStatus.ReplySize) Then 
              IsConnectible=False
           Else 
              IsConnectible = True
            End If
      Next
      Set objPing=Nothing
      Set objStatus=Nothing
      
  
  End Function
  
  Sub GetPCInfo
  'Get the various WMI data and update it the HTML elements accordingly
      On Error Resume Next
  
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Getting WMI data For " & PCList.Value
      PCInfo.Value=""
      SoftInfo.Value=""
  
      Set objWMIService = GetObject("winmgmts:\\" & PCList.Value & "\root\CIMV2")
     Set compItems = objWMIService.ExecQuery("SELECTManufacturer, Model, Name, SystemType, TotalPhysicalMemory, DomainRoleFROM Win32_ComputerSystem")
      Set CDItems = objWMIService.ExecQuery("SELECT Name FROM Win32_CDROMDrive")
      Set cpuItems = objWMIService.ExecQuery("SELECT Name FROM Win32_Processor")
      Set BIOSItems = objWMIService.ExecQuery("SELECT Manufacturer, SMBIOSBIOSVersion FROM Win32_BIOS")
      Set ChassisItems = objWMIService.ExecQuery("Select ChassisTypes from Win32_SystemEnclosure")
      Set OSItems = objWMIService.ExecQuery("SELECT Caption, CSDVersion FROM Win32_OperatingSystem")
      Set PFItems = objWMIService.ExecQuery("SELECT FileSize FROM Win32_PageFile")
     Set HDDItems =  objWmiService.ExecQuery("SELECT Caption, DeviceID FROM Win32_DiskDrive")    
     Set IPItems = objWMIService.ExecQuery ("SelectIPAddress from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
      Set Shareitems = objWMIService.ExecQuery("Select Name, Path from Win32_Share")    
         Set FloppyItems = objWMIService.ExecQuery("SELECT * FROM Win32_FloppyDrive")
      Set PrinterItems =  objWMIService.ExecQuery ("Select * from Win32_Printer")
  
  'Checks if floppy is present
         If FloppyItems.Count > 0 Then
             strFloppyPresent="Yes"
         Else
             strFloppyPresent="No"
         End If
  
  'Gets basic machine info
     For Each objItem IncompItems                                     
          strcompManufacturer=Trim(objItem.Manufacturer)
          strcompModel=Trim(objItem.Model)
          strcompName=Trim(objItem.Name)
          strcompSystemType= Trim(objItem.SystemType)
          strcompRAM=Trim(Int((objItem.TotalPhysicalMemory/1024)/1024)) & " MB"
  
          Select Case objitem.DomainRole
              Case 0
                strHostNameRole = "Standalone Workstation"
              Case 1
                  strHostNameRole = "Member Workstation"
              Case 2
                  strHostNameRole = "Standalone Server"
              Case 3
                  strHostNameRole = "Member Server"
              Case 4
                strHostNameRole = "Backup Domain Controller"
              Case 5
                strHostNameRole = "Primary Domain Controller"
          End Select
  
      Next
      
  'Gets CD/DVD info
      For Each objItem In cDItems
          strCD=strCD & objItem.Name & VbCrLf & vbTab & vbTab
      Next
  
  'Gets CPU info
      For Each objItem In cpuItems
          strCPU=Trim(objItem.Name)
      Next
      
      'Gets machine type
      For Each objItem In ChassisItems
          For j = Lbound(objItem.ChassisTypes) To UBound(objItem.ChassisTypes)
              nChassisType = objItem.ChassisTypes(j)
          Next
          
          Select Case nChassisType
              Case 1       
                  strChassisType = "Other"
              Case 2
                  strChassisType = "Unknown"
              Case 3
                  strChassisType = "Desktop"
              Case 4
                   strChassisType = "Low-profiledesktop"
              Case 5
                  strChassisType = "Pizza box"
              Case 6
                  strChassisType = "Mini tower"
              Case 7
                  strChassisType = "Tower"
              Case 8
                   strChassisType = "Portable"
              Case 9
                  strChassisType = "Laptop"
              Case 10
                  strChassisType = "Notebook"
              Case 11
                  strChassisType = "Hand-held"
              Case 12
                  strChassisType = "Docking station"
              Case 13
                  strChassisType = "All-in-one"
              Case 14
                  strChassisType = "Subnotebook"
              Case 15
                  strChassisType = "Space-saving"
              Case 16
                  strChassisType = "Lunch box"
              Case 17
                  strChassisType = "Main system chassis"
              Case 18
                  strChassisType = "Expansion chassis"
              Case 19
                  strChassisType = "Subchassis"
              Case 20
                  strChassisType = "Bus-expansion chassis"
              Case 21
                  strChassisType = "Peripheral chassis"
              Case 22
                  strChassisType = "Storage chassis"
              Case 23
                  strChassisType = "Rack-mounted chassis"
              Case 24
                  strChassisType = "Sealed-case computer"
           End Select
       Next
  
     strcompInfo="Name:" & vbTab & vbTab &strcompName & VbCrLf  & "Make:" & vbTab & vbTab& strcompManufacturer & VbCrLf & _
                "Model:" &vbTab & vbTab & strcompModel &  VbCrLf &"Architecture:" & vbTab & strcompSystemType & VbCrLf &_
                "Type:" & vbTab & vbTab & strChassisType& VbCrLf & "CPU:" & vbTab & vbTab &  strCPU& VbCrLf & _
                  "CD/DVD:" & vbTab & vbTab & strCD
                  
  
  'Gets Operating System info
      For Each objItem In OSItems
          strOS= Trim(objItem.Caption) 
          strSvcPack=Trim(objItem.CSDVersion)
      Next
      
     strOSInfo="OS Name:" & vbTab & StrOS &VbCrLf & "Service Pack:" & vbTab & strSvcPack & VbCrLf
  
  'Gets BIOS info
      For Each objItem In BIOSItems
          strBIOS=Trim(objItem.Manufacturer)
          strBIOSver=Trim(objItem.SMBIOSBIOSVersion)
      Next
      
     strBIOSInfo= "BIOS Name:" & vbTab & strBIOS& VbCrLf & "BIOS Version:" & vbTab &  strBIOSver& VbCrLf & VbCrLf & _
                "Domain Role:"& vbTab & strHostNameRole & VbCrLf
  
  'Gets pagefile info
      For Each objItem In PFItems
          strPFSize=Int((objItem.FileSize/1024)/1024) & " MB"
      Next
      
      strcompRAM=Trim(Int((objItem.TotalPhysicalMemory/1024)/1024)) & " MB"
  
     strMemInfo="Total RAM:" & vbTab & StrCompRAM& VbCrLf & "Pagefile:" & vbTab & strPFSize
  
  'Gets hard drive info and associated drive letter.
      For Each objItem In HDDItems
          strEscapedDeviceID = Replace(objItem.DeviceID, "\", "\\", 1, -1, vbTextCompare)
         Set wmiDiskPartitions =objWmiService.ExecQuery ("ASSOCIATORS OF {Win32_DiskDrive.DeviceID="""& _
          strEscapedDeviceID & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
              
              For Each wmiDiskPartition In wmiDiskPartitions
                    Set wmiLogicalDisks = objWmiService.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & _
                    wmiDiskPartition.DeviceID & """} WHEREAssocClass = Win32_LogicalDiskToPartition")
                  
                  For Each wmiLogicalDisk In wmiLogicalDisks
                    strHDD=strHDD &objItem.Caption & vbTab & "(" & wmiLogicalDisk.DeviceID& ")" & VbCrLf
                  Next
              Next
      Next
      
     strdrivesInfo="Floppy drive:" & vbTab &strFloppyPresent & VbCrLf & "HDDs:" & vbTab & vbTab& strHDD 
  
  'Gets all IP addresses.  Ignores NICs that are enabled but don't have an IP address.
  'Assign the primary IP address to the variable varIP (can be used to connect to the machines if DNS does not work)
      For Each IPConfig In IPItems
          If Not IsNull(IPConfig.IPAddress) Then
                For i=LBound(IPConfig.IPAddress) to UBound(IPConfig.IPAddress)
                    If varIP="" Then
                      varIP=IPConfig.IPAddress(0)
                    End If
                  If Not IPConfig.IPAddress(i)="0.0.0.0" Then
                       strIP=strIP &IPConfig.IPAddress(0) & VbCrLf & vbTab & vbTab
                     End If
                Next
           End If
      Next
      strIPInfo="IP Address(es):" & vbTab & strIP
  
  'Get Printer info
          For Each objPrinter In PrinterItems
          If objPrinter.Default = True Then
              strDefault="(Default)"
          Else
              strDefault=""
          End If
         strPrinters=strPrinters &objPrinter.Name & " " & strDefault & VbCrLf & vbTab& vbtab
      Next
      'strPrinterInfo="Printers:" & vbTab & strPrinters 
  
  'Gets shares info
      For Each objItem In ShareItems
         strShares=strShares &objItem.Name & " (" & objitem.Path & ")" & VbCrLf &vbTab & vbTab
      Next
      
      strSharesInfo="Shares:" & vbTab & vbTab & StrShares
  
  'Update the Machine Summary box
     strFullPCInfo = strcompInfo & VbCrLf &strdrivesInfo & VbCrLf & strOSInfo & VbCrLf &strBIOSInfo & VbCrLf & strMemInfo & _
                    VbCrLf & VbCrLf &strIPInfo & VbCrLf & strPrinterInfo & VbCrLf &strSharesInfo 
  
      PCInfo.Value=strFullPCInfo
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Finished getting WMI data for " & PCList.Value
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Getting software data for " & PCList.Value
  
  'Sort the list of installed software.
      AppsArray = Split(InstalledApplications(PCList.Value),vbtab)
  
      For i = 0 To Ubound(AppsArray) - 1
            If AppsArray(i+1) < AppsArray(i) Then
              temp = AppsArray(i)
              AppsArray(i) = AppsArray(i+1)
              AppsArray(i+1) = temp
              i = -1
            End If
      Next
      
      SoftInfo.Value=Join(AppsArray,VbCrLf)
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Finished getting software data for " & PCList.Value
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Getting user data for " & PCList.Value
  
  'Gets local user info
      Set colGroups = GetObject("WinNT://" & PCList.Value & "")
      colGroups.Filter = Array("group")
  
      For Each objGroup In colGroups
          strUserNames=""
          StrGroup=Ucase(ObjGroup.Name) & vbcrlf
  
              For Each objUser in objGroup.Members
                strUserNames=strUsernames & objUser.Name&vbcrlf
              Next
          strLocalUsers=strLocalUsers & strGroup & strUsernames & VbCrLf 
  
      Next
      UserInfo.Value=strLocalUsers
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Finished getting user data for " & PCList.Value
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Finished getting all data for " & PCList.Value
      
      Call GetServices
  
  End Sub
  
  Sub GetServices    
  'Gets services info
      strsvclist=""
      Set objWMIService = GetObject("winmgmts:\\" & PCList.Value & "\root\CIMV2")
      If varShowDisabledServices=True Then
          Set Svcitems = objWMIService.ExecQuery("Select Name from Win32_Service")
      Else
         Set Svcitems =objWMIService.ExecQuery("Select Name from Win32_Service WHERE StartMode<> 'DISABLED'")
      End If
  
       For Each objItem In svcItems
           strsvcList = strsvcList & objitem.name & VbCrLf
      Next
      
      SVCInfo.Value=strsvclist
      
      Set objWMIService=Nothing
      Set svcItems=Nothing
  End Sub
  
  Sub OpenC
  
  'Open C: drive of remote machine.
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Opening C$ on " & PCList.Value
      
      If IPBox.Checked Then
          objShell.Run("explorer.exe \\" & varIP & "\C$")
      Else
          objShell.Run("explorer.exe \\" & PCList.Value & "\C$")
      End If
  
  End Sub
  
  Sub RemoteMMC
  
  'Remotely manage the PC via MMC
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Running RemoteMMC On " & PCList.Value
      If IPBox.Checked Then
          objShell.Run "compmgmt.msc /computer=" & varIP
      Else
          objShell.Run "compmgmt.msc /computer=" & PCList.Value
      End If
  
  End Sub
  
  Sub RemoteDesktop
  
  'Connect to remote machine via Remote Desktop
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Running RemoteDesktop On " & PCList.Value
      If IPBox.Checked Then
          objShell.Run "mstsc /v: " & varIP        
      Else
          objShell.Run "mstsc /v: " & PCList.Value        
      End If
  
  End Sub
  
  Sub RemoteReg
  
  'Connect to registry of remote machine
  
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Running RemoteReg On " & PCList.Value
      objShell.Run "c:\windows\regedit.exe"
      Sleep(5)
      objShell.SendKeys "%F"
      objShell.SendKeys "C"
      Sleep(5)
      If IPBox.Checked Then
          objShell.SendKeys varIP
      Else
          objShell.SendKeys PCList.Value    
      End If
      objShell.SendKeys "{ENTER}"
  
  End Sub
  
  Sub RemoteAssistance
  
  'Launch Remote Assistance page
  
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Running RemoteAssistance On " & PCList.Value
     objShell.Run "cmd /c starthcp://CN=Microsoft%20Corporation,L=Redmond,S=Washington,C=US/Remote%20Assistance/Escalation/unsolicited/unsolicitedrcui.htm",0
      Sleep (5)
      If IPBox.Checked Then
          objShell.SendKeys varIP
      Else
          objShell.SendKeys PCList.Value
      End If
      objShell.SendKeys "%C"
      objShell.SendKeys "%S"
      
  End Sub
  
  Sub Reboot
  'Reboot the machine
      Dim varConfirm
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Running Reboot On " & PCList.Value
      varConfirm=MsgBox ("Are you sure you wish to reboot " & PCList.Value & "?",36,"Confirm action")
      If varConfirm = 6 Then
         Set objWMIService =GetObject("winmgmts:"  &"{impersonationLevel=impersonate,(Shutdown)}!\\" & PCList.Value& "\root\cimv2")
         Set colOperatingSystems = objWMIService.ExecQuery ("Select * fromWin32_OperatingSystem")
          For Each objOperatingSystem in colOperatingSystems
              ObjOperatingSystem.Reboot() 
            Next
       End If
  
  End Sub
  
  Sub Sleep(strSeconds)
  'A sleep routine because we have to use the crappy Sendkeys method
      Dim strCmd
     LogFile.Writeline Time & vbTab & "-" &vbTab & "Running Sleep for " & strSeconds & " seconds"
      strCmd = "%COMSPEC% /c ping -n " & strSeconds & " 127.0.0.1>nul"
      objShell.Run strCmd,0,1
  
  End Sub
  
  Function InstalledApplications(node)
  
  'Gets list of installed software
      Const HKLM = &H80000002 'HKEY_LOCAL_MACHINE
      Set oRegistry = GetObject("winmgmts://" & node & "/root/default:StdRegProv")
      sBaseKey = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\"
      iRC = oRegistry.EnumKey(HKLM, sBaseKey, arSubKeys)
  
        For Each sKey In arSubKeys
          iRC = oRegistry.GetStringValue(HKLM, sBaseKey & sKey, "DisplayName", sValue)
          If iRC <> 0 Then
            oRegistry.GetStringValue HKLM, sBaseKey & sKey, "QuietDisplayName",sValue
          End If
  
      If Trim(sValue) <> "" Then
        InstalledApplications = InstalledApplications & sValue & vbTab
      End If
  
      Next
  
  End Function 
  
  Sub ClearPCList
  
  'Remove all entries from the Machine List
      For Each objOption in PCList.Options
          objOption.RemoveNode
      Next
           
  End Sub
  
  Sub DisableButtons
  
  'Disables all the buttons (if the machine is offline)
      OpenC_button.Disabled=True
      RemoteMMC_button.Disabled=True
      RemoteReg_button.Disabled=True
      RemoteAssistance_button.Disabled=True
      RemoteDesktop_button.Disabled=True
      Reboot_button.Disabled=True
      Export_Button.Disabled=True
      OpenC_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=1)"
      RemoteMMC_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=1)"
      RemoteReg_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=1)"
      RemoteAssistance_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=1)"
      RemoteDesktop_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=1)"
      Reboot_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=1)"
      
  End Sub
  
  Sub EnableButtons
  
  'Enables all the buttons
      OpenC_button.Disabled=False
      RemoteMMC_button.Disabled=False
      RemoteReg_button.Disabled=False
      RemoteAssistance_button.Disabled=False
      RemoteDesktop_button.Disabled=False
      Reboot_button.Disabled=False
      Export_Button.Disabled=False
      OpenC_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=0)"
      RemoteMMC_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=0)"
      RemoteReg_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=0)"
      RemoteAssistance_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=0)"
      RemoteDesktop_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=0)"
      Reboot_button.Style.Filter="progid:DXImageTransform.Microsoft.BasicImage(grayscale=0)"
      
  End Sub
  
  Sub ImportDomains
  
  'Import a list of the domains in the forest and add them to a drop-down box
      Set objConnection = CreateObject("ADODB.Connection")
      Set objCommand =   CreateObject("ADODB.Command")
      objConnection.Provider = "ADsDSOObject"
      objConnection.Open "Active Directory Provider"
      Set objCommand.ActiveConnection = objConnection
  
      objCommand.Properties("Page Size") = 1000
      objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
  
     objCommand.CommandText = "Select distinguishednameFROM 'GC://" & strForest & "' " & "WHEREobjectCategory='domain'"  
      Set objRecordSet = objCommand.Execute
  
      objRecordSet.MoveFirst
      Do Until objRecordSet.EOF
            strDomain=objRecordSet.Fields("distinguishedname")
             Set objOption = Document.createElement("Option")
          objOption.Text = strDomain
          objOption.Value = strDomain
          DomainList.Add objOption
          objRecordSet.MoveNext
      Loop
      objRecordSet.Close
      objConnection.Close
      DomainList.Value=objRootGC.Get("DefaultNamingContext")
  
  End Sub
  
  Sub DomainChange
  
  'If the user selects a domain, clear the filter value and import the machines 
      filterCompInput.Value=""
      Call ImportMachines
  End Sub
  
  Sub ExportToExcel
      On Error Resume Next
      Set objExcel = CreateObject("Excel.Application")
      If objExcel=Nothing Then
         MsgBox "Excel object could not becreated.  Please check that Excel is installed!",48
          Exit Sub
      End If    
      
      Set objWorkBook=objExcel.WorkBooks.Add
      Set objWorksheetPCInfo = objWorkbook.Worksheets(1)
      objWorksheetPCInfo.Name="Machine Summary"
      Set objWorksheetSoftInfo = objWorkbook.Worksheets(2)
      objWorksheetSoftInfo.Name="Installed Software"
      Set objWorksheetUserInfo = objWorkbook.Worksheets(3)
      objWorksheetUserInfo.Name="Local Users"
      Set objWorksheetSvcInfo = objWorkbook.Worksheets.Add
      objWorkSheetsvcInfo.Name="Services"
  
      SoftInfoArray=Split(SoftInfo.Value,VbCrLf)
      UserInfoArray=Split(UserInfo.Value,VbCrLf)
      SvcInfoArray=Split(SvcInfo.Value,VbCrLf)
      varStartRow=3    
      
      objWorkSheetPCinfo.Cells(1,1)="Make"
      objWorkSheetPCinfo.Cells(3,1)=strcompManufacturer
      
      objWorkSheetPCinfo.Cells(1,2)="Model"
      objWorkSheetPCinfo.Cells(3,2)=strcompModel
      
      objWorkSheetPCinfo.Cells(1,3)="Architecture"
      objWorkSheetPCinfo.Cells(3,3)=strcompSystemType
      
      objWorkSheetPCinfo.Cells(1,4)="Type"
      objWorkSheetPCinfo.Cells(3,4)=strChassisType
      
      objWorkSheetPCinfo.Cells(1,5)="CD & DVD"
      ArrayCDExcel=Split(Replace(strCD,vbTab,""),VbCrLf)
      
      For i = 0 To UBound(ArrayCDExcel)
          objWorkSheetPCinfo.Cells(varStartRow,5)=ArrayCDExcel(i)
          varStartRow=varStartRow+1
      Next
      varStartRow=3
      
      objWorkSheetPCinfo.Cells(1,6)="Floppy Drive present"
      objWorkSheetPCinfo.Cells(3,6)=strFloppyPresent
      
      objWorkSheetPCinfo.Cells(1,7)="Hard drives"
      ArrayHDDExcel=Split(Replace(strHDD,vbTab,""),VbCrLf)
      
      For i = 0 To UBound(ArrayHDDExcel)
          objWorkSheetPCinfo.Cells(varStartRow,17)=ArrayHDDExcel(i)
          varStartRow=varStartRow+1
      Next
      varStartRow=3
      
      objWorkSheetPCinfo.Cells(1,8)="Operating System"
      objWorkSheetPCinfo.Cells(3,8)=strOS
      
      objWorkSheetPCinfo.Cells(1,9)="Service Pack"
      objWorkSheetPCinfo.Cells(3,9)=strSvcPack
      
      objWorkSheetPCinfo.Cells(1,10)="BIOS make"
      objWorkSheetPCinfo.Cells(3,10)=strBIOS
  
      objWorkSheetPCinfo.Cells(1,11)="BIOS version"
      objWorkSheetPCinfo.Cells(3,11)=strBIOSver    
      
      objWorkSheetPCinfo.Cells(1,12)="BIOS version"
      objWorkSheetPCinfo.Cells(3,12)=strBIOSver    
      
      objWorkSheetPCinfo.Cells(1,13)="Domain Role"
      objWorkSheetPCinfo.Cells(3,13)=strHostNameRole    
      
      objWorkSheetPCinfo.Cells(1,14)="Total RAM"
      objWorkSheetPCinfo.Cells(3,14)=StrCompRAM    
      
      objWorkSheetPCinfo.Cells(1,15)="Pagefile"
      objWorkSheetPCinfo.Cells(3,15)=strPFSize
      
      objWorkSheetPCinfo.Cells(1,16)="IP Addresses"
      ArrayIPExcel=Split(Replace(strIP,vbTab,""),VbCrLf)
      
      For i = 0 To UBound(ArrayIPExcel)
          objWorkSheetPCinfo.Cells(varStartRow,16)=ArrayIPExcel(i)
          varStartRow=varStartRow+1
      Next
      varStartRow=3
      
      objWorkSheetPCinfo.Cells(1,17)="Shares"
      ArraySharesExcel=Split(Replace(StrShares,vbTab,""),VbCrLf)
      
      For i = 0 To UBound(ArraySharesExcel)
          objWorkSheetPCinfo.Cells(varStartRow,17)=ArraySharesExcel(i)
          varStartRow=varStartRow+1
      Next
      varStartRow=3
      
      For i = 1 To UBound(SoftInfoArray)
       objWorkSheetSoftInfo.Cells(i,1)=SoftInfoArray(i)
      Next    
      
      UserColumn=1
      Set colGroups = GetObject("WinNT://" & PCList.Value & "")
      colGroups.Filter = Array("group")
  
      For Each objGroup In colGroups
          UserRow=3
          objWorkSheetUserInfo.Cells(1,UserColumn)=ObjGroup.Name
              
              For Each objUser in objGroup.Members
               objWorkSheetUserInfo.Cells(UserRow,UserColumn)=ObjUser.Name
                  UserRow=UserRow+1
              Next
              
          UserColumn=UserColumn+1
      Next
  
      For i = 1 To UBound(SVCInfoArray)
          objWorkSheetSvcInfo.Cells(i,1)=SvcInfoArray(i)
      Next
  
      Set objRange=objWorkSheetPCInfo.Range("A1:Z1")
      objRange.Font.Bold = True
      Set objRange=objWorkSheetUserInfo.Range("A1:Z1")
      objRange.Font.Bold = True
      objWorkSheetPCInfo.Columns("A:ZZ").EntireColumn.AutoFit
      objWorkSheetUserInfo.Columns("A:ZZ").EntireColumn.AutoFit
      'objExcel.Visible=True
  
      objWorkBook.SaveAs (myCur & "\" & PCList.Value & ".xls")
      MsgBox "Workbook has been saved as " & myCur & "\" & PCList.Value & ".xls"
      objExcel.Quit
  
  End Sub
  
  Sub ShowDisabledServices
  
      If ShowDisabledServicesBox.Checked Then
          varShowDisabledServices=True
      Else
          varShowDisabledServices=False
      End If
  
      Call GetServices
  
  End Sub
  
  Sub Window_OnUnload
  'Clear objects & variables
      LogFile.Writeline Time & vbTab & "-" & vbTab & "Running Unload"
  
      Set objConnection=Nothing
      Set objCommand=Nothing
      Set objOption=Nothing
      Set objShell=Nothing
      Set objRootGC=Nothing
      LogFile.Close
      
  End Sub
  
  </script>
  
  <script id=clientEventHandlersJS language=javascript>
  
  </script>
  
  
  <body>
  <TABLE WIDTH="100%" BORDER="1" CELLSPACING="0" CELLPADDING="0" ID="MainTable">
   
  <TR>
 <TD id='tab1' language=javascript onclick="return tab1_onclick()"style="CURSOR: hand; BACKGROUND-COLOR: #c0c0c0" align=centerwidth="25%"><b>Manage machines</b></TD>
 <TDid='tab2' language=javascript onclick="return tab2_onclick()"style="CURSOR: hand" align=centerwidth="25%"><b>Tab2</b></TD>
 <TD id='tab3'language=javascript onclick="return tab3_onclick()" style="CURSOR:hand" align=center width="25%"><b>Tab3</b></TD>
 <TD id='tab4' language=javascript onclick="return tab4_onclick()"style="CURSOR: hand" align=centerwidth="25%"><b>About</b></TD>
  </TR>
   
  </TABLE>
  
 <DIV id='divTab1' style="BORDER-RIGHT: black 1px solid; BORDER-TOP:black 1px solid; DISPLAY: inline; BORDER-LEFT: black 1px solid; WIDTH:100%; BORDER-BOTTOM: black 1px solid; HEIGHT: 97%; BACKGROUND-COLOR:#c0c0c0">
  
      <table width="100%" height="95%">
              
      <div style="position:absolute;top:5%;left:3%;">
      Only show machines beginning with&nbsp
     <input type ="text" name="filterCompInput"align="absmiddle" size="25" type="text" maxlength="16" id="filterComp" 
      style="filter:alpha(opacity=60);height:20px;">&nbsp&nbsp    
     <input type="button" value="Apply filter"align="absmiddle" name="UpdatePCList_button" onClick="ImportMachines">
      </div>
      
      <div style="position:absolute;top:5%;left:52%;">
      &nbsp&nbsp&nbspSelect a domain&nbsp&nbsp
      <select size="1" name="DomainList" onChange="DomainChange"></select>
      </div>
      
      <td width = "15%" valign="top">
       
      <div style="position:absolute;top:9%;left:3%;">
      <b>Select a machine</b>
      </div>
       
      <div style="position:absolute;top:11%;left:3%;"> 
      <span id="PCInfoSetting"></span>
      </div>
             
      <div style="position:absolute;top:52%;left:3%;">
     <input type="checkbox" name="IPBox" title="Usemachine's IP address to connect"> Use IP address to connect
      </div>
      
      <div style="position:absolute;top:57%;left:3%;">
      <button onClick="OpenC" alt="Browse C: drive" name="OpenC_button">
      <img src=".\images\directory.gif">
      </button> 
      </div>
      
      <div style="position:absolute;top:58%;left:8.5%;">
      Browse C: drive
      </div>
      
      <div style="position:absolute;top:63%;left:3%;">
      <button onClick="RemoteMMC" alt="Launch remote MMC" name="RemoteMMC_button" >
      <img src=".\images\MMC.gif">
      </button>
      </div>
      
      <div style="position:absolute;top:64%;left:8.5%;">
      Remote MMC
      </div>
      
      <div style="position:absolute;top:69%;left:3%;">
      <button onClick="RemoteDesktop" alt="Launch Remote Desktop" name="RemoteDesktop_button" >
      <img src=".\images\Desktop.gif">
      </button>
      </div>
      
      <div style="position:absolute;top:70%;left:8.5%;">
      Remote Desktop
      </div>
  
      <div style="position:absolute;top:75%;left:3%;">
      <button onClick="RemoteReg" alt="Launch Remote Registry" name="RemoteReg_button" >
      <img src=".\images\regedit.gif">
      </button> 
      </div>
      
      <div style="position:absolute;top:76%;left:8.5%;">
      Remote Registry
      </div>
      
      <div style="position:absolute;top:81%;left:3%;">
     <button onClick="RemoteAssistance" alt="Launch Remote Assistance" name="RemoteAssistance_button" >
      <img src=".\images\RemoteAssistance.gif">
      </button>
      </div>
      
      <div style="position:absolute;top:82%;left:8.5%;">
      Remote Assistance
      </div>
  
      <div style="position:absolute;top:87%;left:3%;">
      <button onClick="Reboot" alt="Reboot machine" name="Reboot_button" >
      <img src=".\images\Reboot.gif">    
      </button> 
      </div>
  
      <div style="position:absolute;top:88%;left:8.5%;">
      Reboot machine
      </div>
          
      <div style="position:absolute;top:94%;left:3%;">
      <input type="button" value="Update machine status" name="Refresh_button"  onClick="RunScript">
      </div>
      
      <div style="position:absolute;top:94%;left:25%;">
      <input type="button" value="Export data to Excel" name="Export_button"  onClick="ExportToExcel">
      </div>
      
      <td width = "5%" valign="top">
      <td width = "25%" valign="top">    
      
      <div style="position:absolute;top:9%;left:22%;">
      <b>Machine summary</b>
      </div>
      
      <div style="position:absolute;top:11%;left:22%;">
      <span id="MachineInfoSetting"></span>
      </div>    
         
         <div style="position:absolute;top:47%;left:22%;">
         <b>Installed software</b>
         </div>
         
         <div style="position:absolute;top:49%;left:22%;">
         <span id="SoftInfoSetting"></span>
         </div>
         
         <div style="position:absolute;top:86.5%;left:22%;">
         <b>Currently logged-on user</b>
         </div>
         
         <div style="position:absolute;top:86%;left:39%;">
         <textarea rows="1" name="CurrentUser" cols="25"></textarea>
         </div>
               
      <div style="position:absolute;top:90%;left:22%;">
      <font color="red"><b><span ID="MachineStatus"></b></font></span>
      </div>
      
         <td width = "2%" valign="top">    
         <td width = "20%" valign="top">    
         
         <div style="position:absolute;top:9%;left:72%;">
      <b>Local&nbspusers</b>
      </div>
      
      <div style="position:absolute;top:11%;left:72%;">
      <span id="UserInfoSetting"></span>
      </div>
         
         <div style="position:absolute;top:47%;left:72%;">
      <b>Installed&nbspservices&nbsp</b>
      </div>
      
      <div style="position:absolute;top:49%;left:72%;">
      <span id="SvcInfoSetting"></span>
      </div>
      
      <div style="position:absolute;top:86%;left:72%;">
     <input type="checkbox"name="ShowDisabledServicesBox" title="Show disabled services"onclick="ShowDisabledServices">&nbspAlso&nbspshow&nbspdisabled&nbspservices
      </div>
      
      </table>
      </DIV>    
      
     <DIV id='divTab2' style="BORDER-RIGHT: black 1pxsolid; BORDER-TOP: black 1px solid; DISPLAY: none; BORDER-LEFT: black1px solid; WIDTH: 100%; BORDER-BOTTOM: black 1px solid; HEIGHT: 100%;BACKGROUND-COLOR: #c0c0c0">
      This TAB 2
      </DIV>
   
     <DIV id='divTab3' style="BORDER-RIGHT: black 1pxsolid; BORDER-TOP: black 1px solid; DISPLAY: none ; BORDER-LEFT: black1px solid; WIDTH: 100%; BORDER-BOTTOM: black 1px solid; HEIGHT: 100%;BACKGROUND-COLOR: #c0c0c0">
      This TAB 3
      </DIV>
   
     <DIV id='divTab4' style="BORDER-RIGHT: black 1pxsolid; BORDER-TOP: black 1px solid; DISPLAY: none; BORDER-LEFT: black1px solid; WIDTH: 100%; BORDER-BOTTOM: black 1px solid; HEIGHT: 100%;BACKGROUND-COLOR: #c0c0c0">
      <div style="position:absolute;top:5%;left:3%;">
      <fieldset>
      <pre>
      Name:        ManagePC Tool
      Author:        Matt Williams
      Created:    August 2005
      Modified:    16/8/2005 - added Export to Excel feature
              17/8/2005 - added tabs (thanks to Barry Hendricks for the code!)
                  
      Version:    1.3
      
     Description:    ManagePC is anapplication that will allow you to manage any PC in a forest.  
              It uses WMI to retrieve various data on the selected machine.
      
      Dependencies:    1) You must run the tool on a WMI enabled computer
              2) It is only for Active Directory environments
             3) You need tohave Administrative rights to perform the WMI queries on the machines
              4) Will not display correctly in anything under 1024x768 resolution
      
      This application and all its code is distributed as open-source/freeware.
      
     Thanks to everyone on the <AHREF="http://groups.msn.com/windowsscript/home.msnw">MSN ScriptingGroup</A> for their support and ideas.
      
     Please report all bugs/errors/suggestions to me at<AHREF="mailto:matthew.williams@pandora.be?subject=Re:%20Manage%20PC%20Tool">matthew.williams@pandora.be</font></A>
      </fieldset>
      </pre>
      </div>
      </DIV>
      
      
  </body>

< Message edited by Snipah -- 9/16/2005 6:10:54 AM >

Post #: 1

RE: ManagePC Tool HTA - 8/11/2005 10:01:33 PM 1 votes

ginolard

Posts: 1005
Score: 21
Joined: 8/10/2005
Status: offline

New BETA version posted in message above.

Changes
-----------

TABS! I was given a nifty piece of code that lets me "emulate" tabbed browsing. I plan to add different modules to the HTA in the future.
Ability to export data to Excel
Option to show disabled services
General streamlining of code.

< Message edited by ginolard -- 8/16/2005 11:50:56 PM >

(in reply to ginolard)

Post #: 2

RE: ManagePC Tool HTA - 8/17/2005 1:07:39 AM

tnoonan

Posts: 364
Score: 0
Joined: 12/14/2004
From:
Status: offline

\\edit by Snipah: post moved to: http://www.visualbasicscript.com/m_24965/mpage_1/key_/tm.htm

Please read the Topic guidelines: Please read before posting.

lame rule Kinda getting a little edit happy at this forum.

< Message edited by tnoonan -- 8/17/2005 8:59:17 AM >

(in reply to ginolard)

Post #: 3

RE: ManagePC Tool HTA - 8/18/2005 9:06:20 PM

ginolard

Posts: 1005
Score: 21
Joined: 8/10/2005
Status: offline

Sorry to post the code again but this version is nowhere near complete and I need some assistance with some HTML code.