Generate a list of IP ranges for your Domain

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Generate a list of IP ranges for your Domain

Logged in as: Guest

arrSession:exec spGetSession 2,16,26614

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Generate a list of IP ranges for your Domain
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Generate a list of IP ranges for your Domain - 10/1/2005 6:49:59 AM

skione

Posts: 40
Score: 0
Joined: 10/1/2005
Status: offline

I manage a network that has a lot of subnets. 64 to be exact and unfortunately they seem to change more often than you would think.

I also use an device monitoring and asset management tool which discovers devices based on an IP range sweep method.

So I need to be able to generate a text file of IP ranges and subnet masks for each range and import that into my application.

This script will read all computer agains for a specified domain.

It will then ask for a username and password (this should be a Domain Admin account)

It will then generate a text file called output.txt in the current folder.

The output will be similar to: [192.168.1.1],[192.168.1.254],[255.255.255.0]

It will only add a range if it does not already exist.

It will also display a progress bar which I got from a post in this forum(http://www.visualbasicscript.com/m_24746/tm.htm)

'�2005 Michael Sole for Xerox Corp. 
'You may use this script or modify it for any purpose so long as you keep the original 
'Copyright posted. The script is distributed without and warranty or garantee of any kind. 
'USE AT YOUR OWN RISK! 
Option Explicit 
Dim objFSO, objFolder, objShell, objReadTextFile, objFile, objFSO1, objTextFile, objaTextFile, ErrorComp 
Dim strCurrentDir, strFile, strText, strReadText, arrComputers, ArrIP, newIP, IPRange 
Dim objWMIService, objItem, colItems, strComputer, colNicConfigs, objNicConfig, StrIPAddresses, strIPSubnet 
Dim objReadIP, objFSO2, strCheckFileText, containername, strDomain, strCpuList, container, computer 
Dim isMatched, ArrayIP, ip, arrayReadIP, strNamespace 
Dim strUser, strPassword, objwbemLocator 
Dim fso, snum, progress, wshshell
Const wbemFlagReturnImmediately = &h10 
Const wbemFlagForwardOnly = &h20 
Const ForReading = 1 
Const ForAppending = 8 
Const ForWriting = 2 
Const WbemAuthenticationLevelPktPrivacy = 6 
strFile = "output.txt" 
strNamespace = "root\cimv2" 
strCurrentDir = Left(WScript.ScriptFullName,InstrRev(WScript.ScriptFullName,"\")) 
ContainerName = inputBox("Please enter the domain name you want to generate a host file", "Input") 
strUser = inputbox("Please enter the username", "Input") 
strUser = containerName & "\" & strUser 
strPassword = inputbox("Please enter the password", "Input") 
EnumClients strDomain,strCpuList 
arrComputers = split(strcpulist, vbCr) 
snum = 0
for each strComputer in arrcomputers
sNum = snum +1
next
Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objaTextFile = objFSO.OpenTextFile _ 
( strCurrentDir & strFile, ForWriting, True) 
objatextfile.writeline("Host File Generated") 
objaTextFile.Close 
Set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject") 
Set Progress = fso.OpenTextFile _
( "ProgressBar.log", forWriting, True)
Progress.WriteLine "sNum = " & sNum 
Progress.WriteLine "Done = 0 _" 
Progress.Write "+0" 
WshShell.Run "ProgressBarFast.vbs" 
WScript.Sleep 250 
For Each strComputer In arrComputers 
On Error Resume Next 
Progress.Write "+1"
Set objWbemLocator = CreateObject("WbemScripting.SWbemLocator") 
Set objWMIService = objwbemLocator.ConnectServer _ 
   (strComputer, strNamespace, strUser, strPassword) 
objWMIService.Security_.authenticationLevel = WbemAuthenticationLevelPktPrivacy 
Set colNicConfigs = objWMIService.ExecQuery _ 
("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True") 
For Each objNicConfig In colNicConfigs 
  If Not IsNull(objNicConfig.IPAddress) Then 
    strIPAddresses = Join(objNicConfig.IPAddress) 
  Else 
    strIPAddresses = "" 
  End If 
  If Not IsNull(objNicConfig.IPSubnet) Then 
    strIPSubnet = Join(objNicConfig.IPSubnet) 
  Else 
    strIPSubnet = "" 
  End If 
  If Err.Number <> 0 Then 
    ErroComp = strComputer & ": No IP received" 
     Set objaTextFile = objFSO.OpenTextFile _ 
     ( strCurrentDir & strFile, ForAppending, True) 
     objaTextFile.WriteLine(strComputer & ": No IP received") 
     objaTextFile.Close 
  Else 
    arrIp = Split(strIPAddresses, ".") 
    newIP = arrIp(0) & "." & arrIp(1) & "." & arrIp(2) 
    IPRange = "[" & newIp & ".1],[" & newIp & ".254],[" & strIPSubnet & "]" 
  Set objFSO2 = CreateObject("Scripting.FileSystemObject") 
  Set objReadIP = objFSO2.OpenTextFile _ 
      (strCurrentDir & "output.txt", ForReading) 
  strCheckFileText = objReadIP.ReadAll 
  objReadIP.Close 
  isMatched = 0 
     arrayReadIP = split(strCheckFileText, vbCrLf) 
     for each ip in arrayReadIP 
     If ip = IPRange Then 
'      msgbox "match" 
        isMatched = 1 
     End If 
  next 
  if isMatched = 0 then 
     Set objaTextFile = objFSO.OpenTextFile _ 
     ( strCurrentDir & strFile, ForAppending, True)  
     objaTextFile.WriteLine(IPRange) 
     objaTextFile.Close 
  end if 
 End If 
 Next 
Next 
Function EnumClients(strDomain,strCpuList) 
Set Container = GetObject("WinNT://" & ContainerName) 
Container.Filter = Array("Computer") 
'msgbox Container.count 
For Each Computer in Container 
    strCpuList= strCpuList + Computer.Name + vbCr 
Next 
End Function 
Progress.Close 
Wscript.Echo("Finished") 
WScript.Quit

This file needs to be named ProgressBarFast.vbs

'--------set constants-------- 
Const ForReading = 1, ForWriting = 2, ForAppending = 3 
Const TristateUseDefault = -2, TristateTrue = -1, TristateFalse = 0 
Const OPEN_FILE_FOR_APPENDING = 8 
Set fso = CreateObject("Scripting.fileSystemObject") 
Set WshShell = WScript.CreateObject("WScript.Shell") 
Title = "Progress" 
'--------read from file----------- 
Set f = fso.GetFile("ProgressBar.log") 
Set ts = f.OpenAsTextStream(ForReading, Tristatefalse) 
Execute ts.ReadAll 
ts.Close 
d = FormatNumber( Done / (sNum/100) +1 ,0,0,0,0) 
Msg1 = String(d, "]") & String(100 - d, ".") 
Msg2 = Done & "/" & sNum 
Msg3 = "To stop the progressbar clic ""Cancel""" & VbCrlf & "Attention: This will not stop the process." 
Do Until Done >= sNum 
BtnCode = WshShell.Popup(Msg1 & VbCrlf & Msg2 & VbCrlf & Msg3, 1, Title, 1) '------to change the refresh speed: change the number after "Msg3," 
Select Case BtnCode 
case 1 MsgBox "The progress bar will be back in one minutes.",,Title '------ok 
WScript.Sleep 60000 
case 2 MsgBox " " & _ 
VbCrlf & "Attention: The progressbar will disapear but the script process will continue." & _ 
VbCrlf & _ 
VbCrlf & "To stop the script process:" & _ 
VbCrlf & VbTab & "-Clic here on ""Ok"", then..." & _ 
VbCrlf & VbTab & "-Type Ctrl+Alt+Del." & _ 
VbCrlf & VbTab & "-Select ""Wscript"" in the task list. If several you will need to stop them all." & _ 
VbCrlf & VbTab & "-Clic ""End Task""." & _ 
VbCrlf & VbTab & "-Clic ""End Task"" one more time" & _ 
VbCrlf & VbTab & "-Repeat this operation until all the ""Wscript"" tasks have been terminated. ",,Title 
wscript.quit 
End Select 
Set ts = f.OpenAsTextStream(ForReading, Tristatefalse) 
Execute ts.ReadAll 
ts.Close 
d = FormatNumber( Done / (sNum/100) +1 ,0,0,0,0) 
If d <= 100 Then 
Msg1 = String(d, "]") & String(100 - d, ".") 
End If 
Msg2 = Done & "/" & sNum 
'-----------check if progressing-------- 
Done1 = Done2 
Done2 = Done 
If Done2 > Done1 Then 
Idletime = 0 
Else 
Idletime = Idletime +1 
If Idletime = 45 Then 
WshShell.Popup "Program not responding!",, Title, 0 + 16 
End If 
End If 
Loop