change proxy server from browser

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

change proxy server from browser

Logged in as: Guest

arrSession:exec spGetSession 2,16,26837

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> change proxy server from browser
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

change proxy server from browser - 10/9/2005 11:00:20 AM

Sgt. Wilco

Posts: 8
Score: 0
Joined: 9/24/2005
From: BC, Canada
Status: offline

The following is a script used to change IE's proxy server through a browser, although not entirely as it sounds. It was created to work in conjunction with PHP to create a dynamic script to change IE's proxy server right out of the browser (by going "run" rather than "save as"). Eg, select the server, generate the script, download the script. You can see what I mean here.

The script itself closes all instances of IE, changes the registry settings, and re-opens IE again. It is also backwards compatable to the earliest days of Win95.

' *  VBScript to change the IE Proxy Server, by directly editing the registry
 ' *  Version:  2.1
 ' *  
 ' *  Enjoy!
 
 Option Explicit
 
 ' *  Proxy Server
 
 Dim proxy
 proxy = "203.162.29.90:80"
 
 ' *  Application Title
 
 Dim Title
 Title = "Los Proxy Changer"
 
 ' *  Welcome Message
 
 Dim Welcome_Text
 Welcome_Text = "Do you really want to change the Proxy Server to " & proxy & "?"
 
 Call Welcome()
 
 Sub Welcome()
     Dim GO
     GO = MsgBox(Welcome_Text, 36, Title)
     If GO = 7 Then
         WScript.Quit
     End If
 End Sub
 
 ' *  Warning Message
 
 Dim Warning_Text
 Warning_Text = "Warning:  All current Internet Explorer and Windows Explorer windows will be closed." & Chr(10) _
                 & Chr(10) _
                 & "Do you still wish to continue?"
 
 Call Warning()
 
 Sub Warning()
     Dim GO
     GO = MsgBox(Warning_Text, 36, Title)
     If GO = 7 Then
         WScript.Quit
     End If
 End Sub
 
 ' *  WSHShell
 
 Dim WSHShell
 Set WSHShell = WScript.CreateObject("WScript.Shell")
 
 ' *  Kill IE (and consequently WE as well)
 
 Call Kill_IE()
 
 Sub Kill_IE()
     While WSHShell.AppActivate("Internet Explorer")
         WSHShell.SendKeys "%{F4}"
         WScript.Sleep 500    ' Impedes a traffic jam
     WEnd
 End Sub
 
 ' *  Regedits
 
 WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyEnable", 1, "REG_DWORD"
 WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyServer", proxy
 WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ProxyOverride", ""
 WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\DisablePasswordCaching", 1, "REG_DWORD"
 
 ' *  Confirmation
 
 Dim confirm
 confirm = MsgBox("Proxy Server has been changed to " & proxy & ".  Enjoy.", 64, Title)
 
 ' *  Open IE
 
 WSHShell.run "iexplore.exe http://www.google.ca"

_____________________________

Software is like sex. It's better when it's free...
-Linus Torvalds