Script Template

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Script Template

Logged in as: Guest

arrSession:exec spGetSession 2,16,26947

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Script Template
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Script Template - 10/14/2005 1:34:18 AM

Country73

Posts: 716
Score: 8
Joined: 8/25/2004
From: USA
Status: offline

I created this "Script Template" for all of my scripts that are ran against multiple machines. You can still use this against one machine via the InputBox, but was created to run off of a "pclist.txt" which contains multiple machine names. Each machine should be on it's own line in this text file.

1. Forces the script to run in CScript mode. (For countdown purposes. CTRL + C can be used to kill the script)
2. Checks the date of the "pclist.txt" and asks if you still want to use it or not. (Helps to make sure you are using a current list of machines)
3. Verifies the machine is online before proceeding
4. Writes all offline machines to a csv file.

This script is ready to run, just supply your pclist.txt.
Currently you will just get an echo of "call function required", replace that with your function call.
If you have any questions / comments about this script, please contact me through the email function here at VBScript Forum.

'On Error Resume Next
'========================================================================================
' TITLE:     Script Template    
' Description:  Used for creating any script that will be ran against multiple machines so
'    that a countdown will display the number of machines remaining (can be used
'    against single machines, but was mainly created for multiple machines), 
'    pings the machine to make sure it is online before proceeding, logs the 
'    machines that are offline.
'
' Requirements: pclist.txt for multiple machines (each machine listed on their own line)
'
' Created by:   Chris Hatt
'========================================================================================
Set oFS = CreateObject("Scripting.FileSystemObject")
Set oShell = WScript.CreateObject("WScript.Shell")
Const strScript = "Script Template" 'Title for the InputBox
Const PCL = "pclist.txt"   'List containing multiple machines to run script against
Const OFF = "offline.csv"   'Let me know if the machines are offline
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'             Force script to run in "CScript" mode                
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
If Instr(1, WScript.FullName, "CScript", vbTextCompare) = 0 Then    
   oShell.Run "cscript """ & WScript.ScriptFullName & """", 1, False
   WScript.Quit                                                    
End If                                                              
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'-----------------------------------------------------------------------------
' User input to determine if script is ran against single or multiple machines. 
'------------------------------------------------------------------------------
strComputer = InputBox("Which machine do you wish to run this script against?" & vbcrlf _
& vbcrlf & "Leave blank to run against " & chr(34) & PCL & chr(34),strScript,"")
If strComputer = "" Then
'--------------------------------------------------------------------------------------
'Check the date that pclist.txt was created to verify if we still want to use it or not.
'Select NO if you want to update the "pclist.txt"
'---------------------------------------------------------------------------------------
   If oFS.FileExists(PCL)Then
    Set file = oFS.GetFile(PCL)
  myDate = file.DateLastModified
  myOpt = MsgBox(PCL & " was created on " & myDate & vbcrlf & vbcrlf & "Would you still like to use it?",4,PCL & " check")
  If myOpt = 7 Then
   MsgBox "Script will now close.",0,"EXIT"
   wscript.quit
  End If
       '-------------------------------------------------------------------------
       'Grab the pclist and get a total count we are running the script against.
       'This will give us our countdown in the Command Window as the script runs.
       '-------------------------------------------------------------------------
       Set file = oFS.GetFile(PCL)
       Set pc = file.OpenAsTextStream(1,TristateUseDefault)
       Do While pc.AtEndOfStream <> True
           strComputer = Trim(pc.ReadLine)
           strCount = strCount + 1
       Loop
       Set pc = file.OpenAsTextStream(1,TristateUseDefault)
       Do While pc.AtEndOfStream <> True
           strComputer = Trim(pc.ReadLine)
           strCount = strCount - 1
           wscript.echo strCount & "  " & strComputer
           Call PingMe(strComputer,strCount)
       Loop
   Else
       '-----------------------------------------------------------
       'No pclist.txt found and no machine name entered in InputBox
       '-----------------------------------------------------------
       wscript.echo "No " & PCL & " found!" & vbcr & "Script will now close."
       wscript.quit
   End If
Else
   strCount = ""
   Call PingMe(strComputer,strCount)
End If    
wscript.echo "Finished"
'Functions
'------------------------------------------------------------------------------
Function PingMe(strComputer,strCount)
'-----------------------------------------------------------------------
'Verify that the machine is online before running the rest of the script
'-----------------------------------------------------------------------
Set cPingResults = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2").ExecQuery("SELECT * FROM Win32_PingStatus WHERE Address = '" + strComputer + "'")
   For Each oPingResult In cPingResults
       If oPingResult.StatusCode = 0 Then
  wscript.echo "call function required"
       Else
           call LogEvent(strComputer,"Offline")
       End If
   Next
End Function
'+++++++++++++++++++++++++++++++++++++++++++++++++
Function LogEvent(pc,msg)
'--------------------------------
'Machine is OFFLINE, create a log
'--------------------------------
Set strLogFile = oFS.OpenTextFile(OFF,8,True)
   strLogFile.WriteLine pc & "," & msg
   strLogFile.Close
End Function
'+++++++++++++++++++++++++++++++++++++++++++++++++