linux du vbscript

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

linux du vbscript

Logged in as: Guest

arrSession:exec spGetSession 2,16,27178

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> linux du vbscript
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

linux du vbscript - 10/21/2005 6:24:04 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

' COMMENT: This script emulates the linux du command which gives a recursive
'           listing of directories and the size the use. It is useful in helping
'           to find large directories.
'           Check the usage sub for usage information.

'==========================================================================
 '
 ' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 4.0
 '
 ' NAME: du.vbs
 '
 ' AUTHOR: Kirrilian
 ' DATE  : 10/21/2005
 '
 ' COMMENT:  This script emulates the linux du command which gives a recursive
 '            listing of directories and the size the use. It is useful in helping
 '            to find large directories.
 '            Check the usage sub for usage information.
 '
 '==========================================================================
 Option Explicit
 Dim humanReadable, recurse, summaryOnly, objArgs, fso, summary
 Set FSO = CreateObject("Scripting.FileSystemObject")
 Set objArgs = WScript.Arguments
 'start with all booleans = FALSE
 recurse = False
 humanReadable = False
 summaryOnly = False
 summary = False
 
 argNum objArgs.Count
 Sub argNum(num)
     'we test for our arguments
     Select Case num 
         Case 1
             'only one arg, therefore it must be a directory
             recurse = True
             getData objArgs.Item(0)
         Case 2
             argTest objArgs.Item(0)
             getData objArgs.Item(1)
             'check for -all or -c switch
             If summary = True Then doSummary objArgs.Item(1) End If
         Case 3
             argTest objArgs.Item(0)
             argTest objArgs.Item(1)
             getData objArgs.Item(2)
             'check for -all or -c switch
             If summary = True Then doSummary objArgs.Item(2) End If
         Case 4
             argTest objArgs.Item(0)
             argTest objArgs.Item(1)
             argTest objArgs.Item(2)
             getData objArgs.Item(3)
             'check for -all or -c switch
             If summary = True Then doSummary objArgs.Item(3) End If
         Case Else
             usage()
     End Select
 End Sub 'argNum
 
 Sub argTest(arg)
     Select Case  arg
         Case "-c"
             summary = True
         Case "-h"
             humanReadable = True
         Case "-s"
             summaryOnly = True
         Case "-all"
             humanReadable = True
             summary = True
         Case Else
             usage()
     End Select
 End Sub 'argTest
 
 Sub usage()
     WScript.Echo "Usage: cscript " & WScript.ScriptName & " [option] directory"
     WScript.Echo vbTab & "Where [option] is:"
     WScript.Echo vbTab & "-c is for including the total size,"
     WScript.Echo vbTab & "-h is for human readable sizes,"
     WScript.Echo vbTab & "-s is for the total space only (-r is implied),"
     WScript.Echo vbTab & "-all is to use all of the options. [-c -h]."
     WScript.Quit 1
 End Sub 'usage
 
 
 Sub getData(path)
     Dim spaceUsedout, folder, subfolder, spaceUsed, padding
     
     if fso.FolderExists(path) Then 
         set Folder = FSO.GetFolder(path)
         'check for not summary only
         If Not summaryOnly = true Then
             For Each Subfolder in Folder.SubFolders
                 'check for output size
                 If humanReadable = True then
                     spaceUsed = Round(((subfolder.size/1024)/1024), 2)
                     padding = 15 - Len(spaceUsed)
                     spaceUsedout = spaceUsed & "M " & space(padding)
                     WScript.Echo spaceUsedout & Subfolder.Path
                 Else
                     spaceUsed = Round((subfolder.size/1024), 2)
                     padding = 15 - Len(spaceUsed)
                     spaceUsedout = spaceUsed & "K " & space(padding)
                     WScript.Echo spaceUsedout & Subfolder.Path
                 End If
                 'call the getData sub over and over to recurse subdirectories
                 getData subfolder    
             Next
 
         Else
             'total size only
             doSummary path
         End If
             
     Else 
         WScript.Echo path & " doesn't exist, try again"
         usage()
     End If
 End Sub 'getData
 
 Sub doSummary(path)
     'its easier just to get a folder.size on the root dir rather than tallying the subdirs
     dim size, folder
     
     if fso.FolderExists(path) Then 
         set Folder = FSO.GetFolder(path)
         size = folder.size
     Else 
         WScript.Echo path & " doesn't exist, try again"
         usage()
     End If
     If humanReadable = True Then 
         WScript.echo
         WScript.Echo "The total space used is: " & Round(((size/1024)/1024), 2) & "M"
     Else
         WScript.echo
         WScript.Echo "The total space used is: " & Round((size/1024), 2) & "K"
     End If
 End Sub 'doSummary

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site