SystemDocumenter :: Document Server and Workstation configuration

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

SystemDocumenter :: Document Server and Workstation configuration

Logged in as: Guest

arrSession:exec spGetSession 2,16,27389

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> SystemDocumenter :: Document Server and Workstation configuration
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

SystemDocumenter :: Document Server and Workstation con... - 10/27/2005 12:04:35 AM

jluis

Posts: 5
Score: 0
Joined: 10/26/2005
Status: offline

YOU ABSOLUTELY MUST TRY THIS SCRIPT!!!
I recommend it VERY highly.
I have been using it on my own site for several moths.
The author has done a wonderful job with the gui and the script works as advertised out of the box.

quote:

This script was created while doing an SMS architecture design project! During the initial design stage, we wanted server documentation, eg. configuration.
The customer did not have proper system configuration documents to determine if new server hardware was required or if we could use existing systems.
It has obviously expanded! Our customers got a report of their configuration and requested, if posssible to convert it in a web format so that can use the reports in their intranet.
The script will generate an html page index of the selected systems that displays whether or not the selected systems were alive on the network and if they are, creates an hyperlink to the generated a web report for each of the selected systems.
The index page will automatically open at the completion of the script.

Options: To set the default reporting sections, go to this section of the script: Enable/Disable Report Sections To enable the default report, set the value of the report to True. To disable the default report, set the value of the report to False.
To add Windows Server System Applications, go to this section: fctBuildSystemRoles

The Script:

=====================
' Name: SystemDocumenter.vbs
' Version: 3.2.3
' Author: Rene Lariviere , Zentzu Inc.
' Date: 11/30/03
' Updates: http://www.zentzu.com (not available yet)
' Bug Reports & Enhancement Req: rene.lariviere@zentzu.com
'
' Main Function:    Document Server and Workstation configuration
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 3.0
'=====================
Option Explicit

Const ADS_SCOPE_SUBTREE = 2
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Const TristateUseDefault = -2 'format system default
Const TristateTrue = -1 'format UNICODE
Const TristateFalse = 0 'format ASCII
Const SEC_IN_DAY = 86400
Const MIN_IN_DAY = 1440
Const SEC_IN_MIN = 60
Const ONE_HUNDRED_NANOSECOND = .000000100 ' .000000100 is equal to 10^-7
Const dictKey = 1
Const dictItem = 2
Const adVarChar = 200
Const MaxCharacters = 255
Const BEGIN_TABLE = " <table width='664' border='0' cellspacing='1' cellpadding='2'>"
Const END_TABLE = " </table>"

'* Initialize variables
Dim objShell, objProcessEnv, objSystemEnv, objNet, objFso, objSwitches
Dim objWMILocator, objService, objWMIInstance
Dim strDomainToEnumerate, strSystemsToEnumerate, strSystemsToEnumerateName, strSystemName, strReportName
Dim strSystemsWildcardToEnumerate, WindowsVersion
Dim dictComputerArray, dictExcludedComputerArray, arrayComputerList, dictServiceRole
Dim colKeys, strKey, colParsedKeys, strParsedKey
Dim IE, objDIV, objDBG, strMyDocPath, strSubFolder, strTempFile, f1, ts, File2Load, objFlash
Dim blnProgressMode, blnDebugMode, blnVerboseMode, dbgTitle, strTempFolder, strReportOption
Dim dbgToolBar, dbgStatusBar, dbgResizable
Dim dbgWidth, dbgHeight, dbgLeft, dbgTop, dbgVisible
Dim strScriptVer, strCustomerName, strCurrentDate, strUserName, strUserPassword
Dim ErrNum, ErrText, strReportFile
Dim BeginRow: BeginRow = 1
Dim EndRow: EndRow = 2
Dim i, query, item, acounter, strOS, blnExtendedWMI
Dim dlgBarWidth, dlgBarHeight, dlgBarTop, dlgBarLeft, dlgProgBarWidth, dlgProgBarHeight, dlgProgBarTop, dlgProgBarLeft
Dim dlgBar, dlgProgBar, wdBar, objPBar, objBar
Dim blnSearchWildcard, blnRequireDCFilter, blnPingProcess, blnProcessAll, blnPromptforInfo, strLDAP, strExcludeLDAP
Dim strScriptPath, strScriptName, strScriptFolder
Dim blnReportHeader, blnGeneralInfo, blnSystemInfo, blnReportProcessorsInfo, blnReportSysMemoryInfo
Dim blnReportPhysicalDisksInfo, blnReportNetAdaptersInfo, blnReportQFEInfo, blnReportSharesInfo
Dim blnReportServicesInfo, blnReportProcessesInfo, blnReportEventInfo, blnReportARPInfo, blnReportSystemRoles
Dim strDebugFile, fdbg, tsdbg

'* Initialize objects
Set objShell = WScript.CreateObject("WScript.Shell")
Set objProcessEnv = objShell.Environment("Process")
Set objSystemEnv = objShell.Environment("System")
Set objNet = CreateObject("Wscript.Network")
Set objFso = CreateObject("Scripting.FileSystemObject")
Set dictComputerArray = CreateObject("Scripting.Dictionary")
Set dictExcludedComputerArray = CreateObject("Scripting.Dictionary")
Set objSwitches = CreateObject("Scripting.Dictionary")

'* Set global variables
strScriptVer = " v3.2.3"
strSystemName = objProcessEnv("Computername")
strCurrentDate = fctGetDate()
blnProgressMode = True
blnVerboseMode = True
blnDebugMode = True
blnSearchWildcard = False
blnPingProcess = False
blnProcessAll = False
strScriptPath = Wscript.ScriptFullName
strScriptName = Wscript.ScriptName
strScriptFolder = Left(strScriptPath, Len(strScriptPath) - Len(strScriptName))

objSwitches.CompareMode = vbTextcompare

strTempFolder = fctGetTempFolder()

WindowsVersion = fctGetWindowsVersion()
If WindowsVersion >= "5.1" Then
   blnPingProcess = True
End If

Set IE = CreateObject("InternetExplorer.Application")

'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    Customize the script Sections
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    strDomainToEnumerate: Used to set the context of the search.
'%    strCustomerName: Used to create a folder where the reports will be saved.
'%    strSystemsToEnumerate: Used for the type of systems to report on.
'%    blnPromptforInfo: Used to disable/enable selection screens.
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    If you do not want to be prompted when running the script, set the variable
'% blnPromptforInfo to False, and set the other 3 variables to your requirements.
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
blnPromptforInfo = True
strDomainToEnumerate = "OU=Workstations,DC=int,DC=zentzu,DC=com"
strCustomerName = "Zentzu"
strSystemsToEnumerate = 5
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    strSystemsToEnumerate: 
'%            1 = All
'%            2 = Domain Controllers
'%            3 = Servers
'%            4 = Workstations
'%            5 = DCs-Servers
'%            6 = Servers-Workstations
'%            7 = Wildcard
'%            8 = Single computer
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    Examples: 
'% When strSystemsToEnumerate is set to (1 thru 6), strDomainToEnumerate must
'% be the LDAP path.
'% When strSystemsToEnumerate is set to 7, strSystemsWildcardToEnumerate must be a
'% string like NB*CAL or CAL* or ZEN*D*M*
'% When strSystemsToEnumerate is set to 8, strDomainToEnumerate must be a
'% single computer name
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    Enable/Disable Report Sections
'%    True: enable the reporting section
'%    False: disable the reporting section
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
blnReportHeader = True
blnGeneralInfo = True
blnReportSystemRoles = True
blnSystemInfo = True
blnReportProcessorsInfo = True
blnReportSysMemoryInfo = True
blnReportPhysicalDisksInfo = True
blnReportNetAdaptersInfo = True
blnReportQFEInfo = True
blnReportSharesInfo = True
blnReportServicesInfo = True
blnReportProcessesInfo = True
blnReportEventInfo = False
blnReportARPInfo = False

If blnDebugMode Then
   strDebugFile = strScriptFolder & "debuglog.txt"
   objFso.CreateTextFile (strDebugFile)
   Set fdbg = objFso.GetFile(strDebugFile)
   Set tsdbg = fdbg.OpenAsTextStream(2, True)
   tsdbg.WriteLine("System Documenter" & strScriptVer & "")
   tsdbg.WriteLine("" & Now & "")
   tsdbg.WriteLine("Running on: " & strSystemName & " - Windows " & WindowsVersion & "")
   tsdbg.WriteLine("Running from: " & strScriptFolder & "")
   tsdbg.WriteLine("Initial Settings:")
   tsdbg.WriteLine(" Progress Mode " & blnProgressMode & "")
   tsdbg.WriteLine(" Debug Mode " & blnDebugMode & "")
   tsdbg.WriteLine(" Search with Wildcard " & blnSearchWildcard & "")
   tsdbg.WriteLine(" Discover using Ping " & blnPingProcess & "")
   tsdbg.WriteLine(" Document all sections " & blnProcessAll & "")
   tsdbg.WriteLine(" Prompt for info " & blnPromptforInfo & "")
   tsdbg.WriteLine(" Create report header " & blnReportHeader & "")
   tsdbg.WriteLine(" General info section " & blnGeneralInfo & "")
   tsdbg.WriteLine(" System roles section " & blnReportSystemRoles & "")
   tsdbg.WriteLine(" System info section " & blnSystemInfo & "")
   tsdbg.WriteLine(" Processors section " & blnReportProcessorsInfo & "")
   tsdbg.WriteLine(" Memory section " & blnReportSysMemoryInfo & "")
   tsdbg.WriteLine(" Physical disks section " & blnReportPhysicalDisksInfo & "")
   tsdbg.WriteLine(" Network adapters section " & blnReportNetAdaptersInfo & "")
   tsdbg.WriteLine(" QFE section " & blnReportQFEInfo & "")
   tsdbg.WriteLine(" Shares section " & blnReportSharesInfo & "")
   tsdbg.WriteLine(" Services section " & blnReportServicesInfo & "")
   tsdbg.WriteLine(" Processes section " & blnReportProcessesInfo & "")
   tsdbg.WriteLine(" Event log section " & blnReportEventInfo & "")
   tsdbg.WriteLine(" Add/Remove Progams section " & blnReportARPInfo & "")
   tsdbg.WriteLine("Default Enumeration:")
   tsdbg.WriteLine(" Path: " & strDomainToEnumerate & "")
   tsdbg.WriteLine(" Folder: " & strCustomerName & "")
   tsdbg.WriteLine(" Systems Type: " & strSystemsToEnumerate & "")
   tsdbg.Close
End If

If blnPromptforInfo Then
   If blnDebugMode Then
       Call writeDebugLog("Report Options")
   End If
   GetInput "ReportOption", strTempFolder, strReportOption
   If blnDebugMode Then
       Set tsdbg = fdbg.OpenAsTextStream(8, True)
       tsdbg.WriteLine(" QFE section " & blnReportQFEInfo & "")
       tsdbg.WriteLine(" Shares section " & blnReportSharesInfo & "")
       tsdbg.WriteLine(" Services section " & blnReportServicesInfo & "")
       tsdbg.WriteLine(" Processes section " & blnReportProcessesInfo & "")
       tsdbg.WriteLine(" Event log section " & blnReportEventInfo & "")
       tsdbg.WriteLine(" Add/Remove Progams section " & blnReportARPInfo & "")
       tsdbg.Close
   End If
End If

'*    define debug window parameters
If blnProgressMode Then
   dbgTitle = "System Documenter"
   dbgToolBar = False
   dbgStatusBar = False
   If blnVerboseMode Then
       dbgResizable = True
   Else
       dbgResizable = False
   End If
   dbgWidth = 500
   dbgHeight = 160
   dbgLeft = 0
   dbgTop = 0
   dbgVisible = True
   dlgBarWidth = 380
   dlgBarHeight = 23 
   dlgBarTop = 80
   dlgBarLeft = 50
   dlgProgBarWidth = 0
   dlgProgBarHeight = 18 
   dlgProgBarTop = 82
   dlgProgBarLeft = 50
   dlgBar = "left: " & dlgBarLeft & "; top: " & dlgBarTop & "; width: " & dlgBarWidth & "; height: " & dlgBarHeight & ";"
   dlgProgBar = "left: " & dlgProgBarLeft & "; top: " & dlgProgBarTop & "; width: " & dlgProgBarWidth & "; height: " & dlgProgBarHeight & ";"
   wdBar = 1 * dlgBarWidth
End If

If blnPromptforInfo Then
   If blnDebugMode Then
       Call writeDebugLog("Customer Option")
   End If
   Do
       GetInput "CustomerName", strTempFolder, strCustomerName
   Loop Until strCustomerName <> ""
   If UCase(strCustomerName) = "QUIT" Then
       WScript.Sleep 3000
       If blnDebugMode Then
           Call writeDebugLog("Exiting on user request in Customer Option")
       End If
       WScript.Quit
   End If
   If blnDebugMode Then
       Set tsdbg = fdbg.OpenAsTextStream(8, True)
       tsdbg.WriteLine(" Folder: " & strCustomerName & "")
       tsdbg.Close
   End If
End If

'* Set progress information
If blnProgressMode Then
'    Set IE = CreateObject("InternetExplorer.Application")
   strMyDocPath = strScriptFolder
   If (objFso.FolderExists(strMyDocPath & strCustomerName)) Then
       strSubFolder = strMyDocPath & strCustomerName
   Else
       strSubFolder = objFso.CreateFolder(strMyDocPath & strCustomerName)
   End If
   If (objFso.FolderExists(strSubFolder & "\" & strCurrentDate)) Then
       strSubFolder = strSubFolder & "\" & strCurrentDate
   Else
       strSubFolder = objFso.CreateFolder(strSubFolder & "\" & strCurrentDate)
   End If
   strTempFile = strSubFolder & "\progress.html"
   objFso.CreateTextFile (strTempFile)
   Set f1 = objFso.GetFile(strTempFile)
   Set ts = f1.OpenAsTextStream(2, True)
   ts.WriteLine("<html><head><title>" & dbgTitle & strScriptVer & "</title>")
   ts.WriteLine("<style>.errortext {color:red}")
   ts.WriteLine(".hightext {color:blue}</style>")
   ts.WriteLine("</head>")
   If blnVerboseMode Then
       ts.WriteLine("<body scroll='yes' topmargin='0' leftmargin='0' style='font-family: Tahoma; font-size: 0.6em color: #000000; font-weight: bold; text-align: center'><center><font face='Tahoma'><font size='0.8em'> <hr color='blue'>")
   Else
       ts.WriteLine("<body scroll='no' topmargin='0' leftmargin='0' style='font-family: Tahoma; font-size: 0.6em color: #000000; font-weight: bold; text-align: center'><center><font face='Tahoma'><font size='0.8em'> <hr color='blue'>")
   End If
   ts.WriteLine("<div id='ProgObject' align='center'></div><hr color='blue'>")            
   If blnVerboseMode Then
       ts.WriteLine("<div id='ProgDebug' align='center'></div>")
   End If
   ts.WriteLine("<script LANGUAGE='JavaScript1.2'>")
   ts.WriteLine("")
   ts.WriteLine("</script>")
   ts.WriteLine("<div id='ProgBarId' align='center'></div>")
   ts.WriteLine("</font></center>")
   ts.WriteLine("</body></html>")
   ts.Close
   fctSetupIE(strTempFile)
   Set objDIV = IE.Document.All("ProgObject")
   If blnVerboseMode Then
       Set objDBG = IE.Document.All("ProgDebug")
   End If
   Set objFlash = IE.Document.All("ProgFlash")
   Set objPBar = IE.Document.All("ProgBarId")
   Set objBar = IE.Document
End If

'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    Script code
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'* Main Procedure
objDIV.InnerHTML = "Starting the documentation process!<br>Please be patient..."

fctBuildSystemRoles

If blnPromptforInfo Then
   If blnDebugMode Then
       Call writeDebugLog("Enumeration Option")
   End If
   Do
       GetInput "Enumeration", strTempFolder, strDomainToEnumerate
   Loop Until strDomainToEnumerate <> ""
   If UCase(strDomainToEnumerate) = "QUIT" Then
       WScript.Sleep 3000
       If blnDebugMode Then
           Call writeDebugLog("Exiting on user request in Enumeration Option")
       End If
       WScript.Quit
   End If
   If blnDebugMode Then
       Set tsdbg = fdbg.OpenAsTextStream(8, True)
       tsdbg.WriteLine(" Value: " & strDomainToEnumerate & "")
       tsdbg.Close
   End If
End If

If (InStr(UCase(strDomainToEnumerate), "DC=")) Or (InStr(UCase(strDomainToEnumerate), "O=")) Then
   If blnPromptforInfo Then
       If blnDebugMode Then
           Call writeDebugLog("System Enumeration Option")
       End If
       Do
           GetInput "SystemEnumeration", strTempFolder, strSystemsToEnumerate
       Loop Until strSystemsToEnumerate <> ""
       If strSystemsToEnumerate = "9" Then
           WScript.Sleep 3000
           If blnDebugMode Then
               Call writeDebugLog("Exiting on user request in System Enumeration Option")
           End If
           fctTerminateIE
           fctCleanup
           WScript.Quit
       End If
       If blnDebugMode Then
           Set tsdbg = fdbg.OpenAsTextStream(8, True)
           tsdbg.WriteLine(" Systems to enumerate: " & strSystemsToEnumerate & "")
           tsdbg.Close
       End If
   End If
   If blnVerboseMode Then
       objDBG.InnerHTML = "Generating enumeration criteria!<br>Please be patient..."
   End If
   Select Case strSystemsToEnumerate
       Case 1
           strSystemsToEnumerateName = "All"
           strReportName = strSystemsToEnumerateName
           strLDAP = "<LDAP://" & strDomainToEnumerate & ">;(objectCategory=computer);name,distinguishedName;subtree"
           blnProcessAll = True
           If blnDebugMode Then
               objDBG.InnerHTML = objDBG.InnerHTML & "<br>Criteria: " & strLDAP
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
       Case 2
           strSystemsToEnumerateName = "Domain Controllers"
           strReportName = strSystemsToEnumerateName
           strLDAP ="<LDAP://CN=Configuration," & strDomainToEnumerate & ">;(objectCategory=nTDSDSA);name,distinguishedName;subtree"
           If blnDebugMode Then
               objDBG.InnerHTML = objDBG.InnerHTML & "<br>Criteria: " & strLDAP
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
       Case 3
           strSystemsToEnumerateName = "Servers"
           strReportName = strSystemsToEnumerateName
           strLDAP = "<LDAP://" & strDomainToEnumerate & ">;(&(objectCategory=computer)(operatingSystem=*Server*));name,distinguishedName;subtree"
           blnRequireDCFilter = True
           strExcludeLDAP ="<LDAP://CN=Configuration," & strDomainToEnumerate & ">;(objectCategory=nTDSDSA);name,distinguishedName;subtree"
           If blnDebugMode Then
               objDBG.InnerHTML = objDBG.InnerHTML & "<br>Criteria: " & strLDAP & "<br>Filter: " & strExcludeLDAP
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
       Case 4
           strSystemsToEnumerateName = "Workstations"
           strReportName = strSystemsToEnumerateName
           strLDAP = "<LDAP://" & strDomainToEnumerate & ">;(&(objectCategory=computer)(operatingSystem=*Professional*));name,distinguishedName;subtree"
           If blnDebugMode Then
               objDBG.InnerHTML = objDBG.InnerHTML & "<br>Criteria: " & strLDAP
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
       Case 5
           strSystemsToEnumerateName = "DCs-Servers"
           strReportName = strSystemsToEnumerateName
           strLDAP = "<LDAP://" & strDomainToEnumerate & ">;(&(objectCategory=computer)(operatingSystem=*Server*));name,distinguishedName;subtree"
           If blnDebugMode Then
               objDBG.InnerHTML = objDBG.InnerHTML & "<br>Criteria: " & strLDAP
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
       Case 6
           strSystemsToEnumerateName = "Servers-Workstations"
           strReportName = strSystemsToEnumerateName
           strLDAP = "<LDAP://" & strDomainToEnumerate & ">;(&(objectCategory=computer)(|(operatingSystem=*Server*)(operatingSystem=*Professional*)));name,distinguishedName;subtree"
           blnRequireDCFilter = True
           strExcludeLDAP ="<LDAP://CN=Configuration," & strDomainToEnumerate & ">;(objectCategory=nTDSDSA);name,distinguishedName;subtree"
           If blnDebugMode Then
               objDBG.InnerHTML = objDBG.InnerHTML & "<br>Criteria: " & strLDAP & "<br>Filter: " & strExcludeLDAP
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
       Case 7
           blnSearchWildcard = True
           If blnDebugMode Then
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" LDAP query: " & strLDAP & "")
               tsdbg.WriteLine(" Process all?: " & blnProcessAll & "")
               tsdbg.WriteLine(" Search using wildcard?: " & blnSearchWildcard & "")
               tsdbg.WriteLine(" Require DC Filter?: " & blnRequireDCFilter & "")
               tsdbg.WriteLine(" LDAP exclusion: " & strExcludeLDAP & "")
               tsdbg.Close
           End If
           If blnPromptforInfo Then
               If blnDebugMode Then
                   Call writeDebugLog("Wildcard Enumeration Option")
               End If
               Do
                   GetInput "WildcardEnumeration", strTempFolder, strSystemsWildcardToEnumerate
               Loop Until strSystemsWildcardToEnumerate <> ""
               If UCase(strSystemsWildcardToEnumerate) = "QUIT" Then
                   WScript.Sleep 3000
                   If blnDebugMode Then
                       Call writeDebugLog("Exiting on user request in Wildcard Enumeration Option")
                   End If
                   WScript.Quit
               End If
           End If
           strSystemsToEnumerateName = strSystemsWildcardToEnumerate
           strReportName = "Index"
           If blnDebugMode Then
               Set tsdbg = fdbg.OpenAsTextStream(8, True)
               tsdbg.WriteLine(" Systems to enumerate: " & strSystemsWildcardToEnumerate & "")
               tsdbg.Close
           End If
   End Select
   If blnRequireDCFilter Then
       fctExcludeDCList()
   End If
   fctGetSystemsList()
   If blnRequireDCFilter Then
       subCleanList()
   End If
Else
   strSystemsToEnumerate = 8
   strSystemsToEnumerateName = strDomainToEnumerate
   strReportName = "Index"
   If blnDebugMode Then
       Set tsdbg = fdbg.OpenAsTextStream(8, True)
       tsdbg.WriteLine(" Systems to enumerate: " & strSystemsToEnumerate & "")
       tsdbg.Close
   End If
   dictComputerArray.Add strDomainToEnumerate, strDomainToEnumerate
End If

fctGenerateWebReport()
fctGenerateSystemsReport()

arrayComputerList = dictComputerArray.Items
For i = 0 To dictComputerArray.Count -1
   Err.Clear
   objDIV.InnerHTML = "Processing computer " & UCase(arrayComputerList(i)) & " ...!<br>Please be patient..."
   set strReportFile = objFso.createTextFile (strSubFolder & "\" & UCase(arrayComputerList(i)) & ".html")
   Call fWriteReportHTMLHeader(arrayComputerList(i))
   Set objWMILocator = GetObject("winmgmts:{impersonationLevel=impersonate,(Security)}!\\" & arrayComputerList(i) & "\root\cimv2")
   If Err <> 0 Then
       Call fWriteProgressErrMessage("ConnetServer", Err)
       strReportFile.WriteLine("" & UCase(arrayComputerList(i)) & "<br>")
       strReportFile.WriteLine("<font size='2'>Data collected On: " & Date & " " & Time() & "</font>")
       Call fWriteTable("Top", "Error", "sysError")
       strReportFile.WriteLine(BEGIN_TABLE)
       strReportFile.WriteLine(" <tr>")
       strReportFile.WriteLine("<td align='right' class='category' height='12'><span class='errortext'>Error:</span></td>")
       strReportFile.WriteLine("<td class='result' height='12'><span class='hightext'>" & Err.Number & "</span></td>")
       strReportFile.WriteLine("</tr>")
       strReportFile.WriteLine("<tr>")
       strReportFile.WriteLine("<td align='right' class='category' height='12'><span class='errortext'>Description:</span></td>")
       strReportFile.WriteLine("<td class='result' height='12'><span class='hightext'>" & Err.Description & "</span></td>")
       strReportFile.WriteLine("</tr>")
       fSpacer (10)
       If Err = -2147023174 Then 
           strReportFile.WriteLine("<tr><td colspan='6' bgcolor='#ff0000' class='result'>This error normally indicates that the server is either unavailable or does not have Windows Management Instrumentation installed.</td></tr>")
       End If
       strReportFile.WriteLine(END_TABLE)
       Call fWriteTable("Bottom", Empty, Empty)
   Else
       objDIV.InnerHTML = "Processing computer " & arrayComputerList(i)
       If blnReportHeader Then
           fWriteReportHeader(arrayComputerList(i))
       End If
       If blnGeneralInfo Then
           fWriteReportGeneralInfo(arrayComputerList(i))
       End If
       If blnSystemInfo Then
           fWriteReportSystemInfo(arrayComputerList(i))
       End If
       If blnReportSystemRoles Then
           fWriteReportSystemRolesInfo(arrayComputerList(i))
       End If
       If blnReportProcessorsInfo Then
           fWriteReportProcessorsInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("<Div class=page>")
       If blnReportSysMemoryInfo Then
           fWriteReportSysMemoryInfo(arrayComputerList(i))
       End If
       If blnReportPhysicalDisksInfo Then
           fWriteReportPhysicalDisksInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
       strReportFile.WriteLine("<Div class=page>")
       If blnReportNetAdaptersInfo Then
           fWriteReportNetAdaptersInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
       strReportFile.WriteLine("<Div class=page>")
       If blnReportQFEInfo Then
           fWriteReportQFEInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
       strReportFile.WriteLine("<Div class=page>")
       If blnReportSharesInfo Then
           fWriteReportSharesInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
       strReportFile.WriteLine("<Div class=page>")
       If blnReportServicesInfo Then
           fWriteReportServicesInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
       strReportFile.WriteLine("<Div class=page>")
       If blnReportProcessesInfo Then
           fWriteReportProcessesInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
       If blnReportEventInfo Then
           strReportFile.WriteLine("<Div class=page>")
           fWriteReportEventInfo(arrayComputerList(i))
           strReportFile.WriteLine("</Div>")
       End If
       strReportFile.WriteLine("<Div class=page>")
       If blnReportARPInfo Then
           fWriteReportARPInfo(arrayComputerList(i))
       End If
       strReportFile.WriteLine("</Div>")
   End If
   'call fGetProcessInfo(Request.QueryString("procHandle"))
   Err.Clear
Next

'*    If Progress mode, leave the progress window running for a while.
If blnProgressMode Then
   objDIV.InnerHTML = "Documentation Script Completed."
   If blnDebugMode Then
       objDBG.InnerHTML = ""
       WScript.Sleep 1000
   End If
   WScript.Sleep 1000
   fctTerminateIE
End If

objShell.Run Chr(34) & strSubFolder & "\" & LCase(strReportName) & "report.html" & Chr(34)
fctCleanup
WScript.Quit

'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    End script code
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'%    Start script subs to build the report sections 
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Sub fWriteReportHeader(sysName)
   If blnVerboseMode Then
       objDBG.InnerHTML = "Building Report Header ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   strReportFile.WriteLine("   " & UCase(sysName) & "<br>")
   strReportFile.WriteLine(" <font size='2'>  Data collected On: " & Date & " " & Time() & "</font>")
   Call fWriteTable("Top", "Tools", "sysTools")
   strReportFile.WriteLine(BEGIN_TABLE)
   fWriteTableTools(sysName)
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objFlash.InnerHTML = ""
End Sub

Sub fWriteReportGeneralInfo(sysName)
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering General Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Call fWriteTable("Top", "General", "sysGeneral")
   strReportFile.WriteLine(BEGIN_TABLE)
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_computersystem",,48)
   objFlash.InnerHTML = ""
   For Each item In objWMIInstance
       fWriteData "Name:", item.Caption, BeginRow
       fWriteData "Domain:", item.Domain, BeginRow
       fWriteData "Role:", fDomainRole(item.domainrole), EndRow
       fWriteData "Manufacturer:", fCheckValue(item.manufacturer, Empty, Empty), BeginRow
       fWriteData "Model:", fCheckValue(item.model, Empty, Empty), EndRow
       fWriteData "Type:", item.systemtype, BeginRow
       fWriteData "Processors:", item.numberofprocessors, EndRow
       fWriteData "Memory:", fFormatNum(item.totalphysicalmemory,True), BeginRow
   Next
   Set objWMIInstance = Nothing
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_operatingsystem",,48)
   For Each item In objWMIInstance
       If InStr(1, item.Caption, "2000") Then
           strOS = "2000"
           blnExtendedWMI = False
       Elseif InStr(1, item.caption, "XP") Then
           strOS = "XP"
           blnExtendedWMI = True
       Elseif InStr(1, item.caption, "2003") Then
           strOS = "2003"
           blnExtendedWMI = True
       Else
           strOS = "WinNT9x"
           blnExtendedWMI = False
       End If
       fWriteData "Up Since:", fDateDisplay(item.lastbootuptime), EndRow
       If strOS = "2003" Then
           fWriteData "OS:", Replace(item.Caption, "Microsoft(R) Windows(R)", ""), BeginRow
       Else
           fWriteData "OS:", Replace(item.Caption, "Microsoft Windows", ""), BeginRow
       End If
       fWriteData "Version:", item.Version, EndRow
       fWriteData "SP:", item.csdversion, BeginRow
       fWriteData "OS Lang:", fLangVers(Hex(item.oslanguage)), EndRow
       fWriteData "Serial #:", item.serialnumber, BeginRow
   Next
   Set objWMIInstance = Nothing
   fSpacer (10)
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
End Sub

Sub fWriteReportSystemInfo(sysName)
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering System Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Call fWriteTable("Top", "System", "sysSystem")
   strReportFile.WriteLine(BEGIN_TABLE)
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_BIOS",,48)
   objFlash.InnerHTML = ""
   For Each item In objWMIInstance
       fWriteData "BIOS Name:", item.Name, BeginRow
       fWriteData "BIOS Version:", item.SMBIOSBIOSVersion, BeginRow
       fWriteData "Serial #:", item.SerialNumber, BeginRow
   Next
   Set objWMIInstance = Nothing
   fSpacer (3)
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select caption from win32_timezone",,48)
   For Each item In objWMIInstance
       fWriteData "Timezone:", item.caption, BeginRow
   Next
   Set objWMIInstance = Nothing
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select buildversion from win32_wmisetting",,48)
   For Each item In objWMIInstance
       fWriteData "WMI Version:", item.buildversion, EndRow
   Next
   Set objWMIInstance = Nothing
   fSpacer (3)
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_computersystem",,48)
   For Each item In objWMIInstance
       fWriteData "Boot State:", item.BootupState, BeginRow
       fWriteData "Status:", item.Status, EndRow
       fWriteData "Boot ROM Support:", item.BootROMSupported, BeginRow
       fWriteData "Supply State:", fPowerSupplyState(item.PowerSupplyState), EndRow
   Next
   Set objWMIInstance = Nothing
   fSpacer (3)
   fWriteHeading ("Onboard Devices")
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select tag, description, devicetype, enabled from win32_onboarddevice")
   aCounter = 0
   For Each item In objWMIInstance
       fWriteData "Description:", item.description, BeginRow
       fWriteData "Enabled:", item.enabled, EndRow
       aCounter = aCounter + 1
       If aCounter < objWMIInstance.Count Then
           fSpacer (3)
       End If
   Next
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
End Sub

Sub fWriteReportSystemRolesInfo(sysName)
   Dim searchKey, searchItem, searchService, s
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering System Role Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   searchKey = dictServiceRole.Keys
   searchItem = dictServiceRole.Items
   Call fWriteTable("Top", "Windows Server Systems", "sysRoles")
   strReportFile.WriteLine(BEGIN_TABLE)
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select Name, State from win32_Service",,48)
   objFlash.InnerHTML = ""
   For Each searchService In objWMIInstance
       For s = 0 to dictServiceRole.Count -1
           If (LCase(searchService.Name) = LCase(searchKey(s))) And (searchService.State = "Running") Then
               fWriteSubHeading searchItem(s)
           End If
       Next
   Next
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
End Sub

Sub fWriteReportProcessorsInfo(sysName)
   On Error Resume Next
   Dim pcount, ttlProcessors, pctComplete, pxBar
   pcount = 0
   ttlProcessors = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering Processor Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_processor")
   ttlProcessors = objWMIInstance.Count
   If Err Then
       Call fWriteErrorDetails("Processor(s)", "sysProcessor", Err.Number)
       Err.Clear
   Else
       objFlash.InnerHTML = ""
       Call fWriteTable("Top", "Processor(s) - " & ttlProcessors, "sysProcessor")
       strReportFile.WriteLine(BEGIN_TABLE)
       aCounter = 0
       For Each item In objWMIInstance
           fWriteHeading (item.deviceID)
           fWriteData "Name:", item.Name, BeginRow
           fWriteData "", "", EndRow
           fWriteData "Type:", item.Description, BeginRow
           fWriteData "", "", EndRow
           fWriteData "Family:", fProcFamily(item.family), BeginRow
           fWriteData "", "", EndRow
           fWriteData "Speed:", item.currentclockspeed & " Mhz", BeginRow
           fWriteData "Cache Size:", fCheckValue(item.l2cachesize, Empty, " Kb"), Empty
           fWriteData "Cache Speed:", fCheckValue(item.l2cachespeed, Empty, " Mhz"), EndRow
           fWriteData "External Clock:", fCheckValue(item.extClock, Empty, " Mhz"), BeginRow
           fWriteData "Interface:", fProcUpgrademethod(item.upgrademethod), Empty
           fWriteData "CPU Load:", fCheckValue(item.loadpercentage, Empty, "%"), EndRow
           aCounter = aCounter + 1
           If aCounter < ttlProcessors Then
               fSpacer (5)
           End If
           pcount = pcount + 1
           pxBar = CLng((Pcount/ttlProcessors) * (wdBar-2))
           objBar.all.ProgBar.Style.width = CStr(pxBar)
           WScript.Sleep 10
       Next
   End If
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportSysMemoryInfo(sysName)
   On Error Resume Next
   Dim ttlPopulatedDevices, ttlDevices, acounter, i, bcounter
   Dim ttlPFCount
   Dim arrMemory()
   bcounter = 1
   acounter = 0
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering Memory Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Call fWriteTable("Top", "Physical Memory", "sysMemory")
   strReportFile.WriteLine(BEGIN_TABLE)
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("Select memorydevices from Win32_PhysicalMemoryArray",,48)
   For Each item In objWMIInstance
       ttlDevices = item.memorydevices
   Next
   ReDim arrMemory(5, ttlDevices)
   strReportFile.WriteLine(" <tr align='center' bgcolor='#b6b6b6'>")
   strReportFile.WriteLine(" <th colspan='2' class='category'>Bank #</th>")
   strReportFile.WriteLine(" <th class='category'>Label</th>")
   strReportFile.WriteLine(" <th class='category'>Capacity</th>")
   strReportFile.WriteLine(" <th class='category'>Form</th>")
   strReportFile.WriteLine(" <th class='category'>Type</th>")
   strReportFile.WriteLine(" </tr>")
   Set objWMIInstance = Nothing
   query = "select capacity, formfactor, memorytype, banklabel, devicelocator " _
           & "from win32_physicalmemory"
   Set objWMIInstance = objWMILocator.ExecQuery(query)
   ttlPopulatedDevices = objWMIInstance.Count
   objFlash.InnerHTML = ""
   For Each item In objWMIInstance
       arrMemory(0, acounter) = "Bank " & bcounter
       If item.BankLabel="" Then
           arrMemory(1, acounter) = item.DeviceLocator
       Else
           arrMemory(1, acounter) = item.BankLabel
       End If
       arrMemory(2, acounter) = fFormatNum(item.Capacity, True)
       arrMemory(3, acounter) = fMemoryForm(item.FormFactor)
       arrMemory(4, acounter) = fMemoryType(item.MemoryType)
       acounter = acounter + 1
       bcounter = bcounter + 1
   Next
   Do While acounter < ttlDevices
       arrMemory(0, acounter) = "Bank " & bcounter
       arrMemory(1, acounter) = "is Empty"
       arrMemory(2, acounter) = ""
       arrMemory(3, acounter) = ""
       arrMemory(4, acounter) = ""
       acounter = acounter + 1
       bcounter = bcounter + 1
   Loop
   fWriteTableMemoryDevice arrMemory
   strReportFile.WriteLine(END_TABLE)
   strReportFile.WriteLine(BEGIN_TABLE)
   Set objWMIInstance = Nothing
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select freephysicalmemory,totalvirtualmemorysize,freevirtualmemory,FreeSpaceInPagingFiles from win32_operatingsystem",,48)
   For Each item In objWMIInstance
       fWriteData "Free Mem:", fFormatNum(1000 * item.freephysicalmemory, True), BeginRow
       fWriteData "Virtual Mem:", fFormatNum(1000 * item.freephysicalmemory, True), EndRow
       fWriteData "Free Virt Mem:", fFormatNum(1000 * item.freevirtualmemory, True), BeginRow
       fWriteData "Free Page Space:", fFormatNum(1000 * item.FreeSpaceInPagingFiles, True), EndRow
   Next
   Set objWMIInstance = Nothing
   query = "select name, drive, initialsize, maximumsize " _
           & "from win32_PageFile"
   Set objWMIInstance = objWMILocator.ExecQuery(query)
   ttlPFCount = objWMIInstance.Count
   aCounter = 0
   For Each item In objWMIInstance
       fWriteData "PF Drive:", UCase(item.drive), BeginRow
       fWriteData "Initial Size:", fFormatNum(item.initialsize, False), Empty
       fWriteData "Maximum Size:", fFormatNum(item.maximumsize, False), EndRow
       aCounter = aCounter + 1
       If aCounter < ttlPFCount Then
           fSpacer (3)
       End If
   Next
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
End Sub

Sub fWriteReportPhysicalDisksInfo(sysName)
   On Error Resume Next
   Dim pcount, ttlDisks, pctComplete, pxBar
   pcount = 0
   ttlDisks = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering Disk Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   dim strDiskDescription
   dim objPartitionSet
   dim objPartition
   dim objDriveSet
   dim objDrive
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select manufacturer, description, caption, interfacetype, partitions, size, scsibus, scsitargetid, status from win32_diskdrive")
   ttlDisks = objWMIInstance.Count
   objFlash.InnerHTML = ""
   If Err Then
       Call fWriteErrorDetails("Physical Disk(s)", "sysDisk", Err.Number)
       Err.Clear
   Else
       Call fWriteTable("Top", "Physical Disk(s)", "sysDisk")
       strReportFile.WriteLine(BEGIN_TABLE)
       For Each item In objWMIInstance
           If strOS = "2000" Then
            strDiskDescription = item.Caption
           Elseif strOS = "2003" Then
            strDiskDescription = item.Caption    
           Elseif strOS = "XP" Then
            strDiskDescription = item.Caption    
           Else
            strDiskDescription = item.manufacturer & " " & item.Description
           End If
           fWriteHeading (Replace(item.deviceID, "\\.\", "") & " - " & strDiskDescription) & " - " & item.interfacetype
           fWriteData "Status:", item.Status, BeginRow
           fWriteData "Partitions:", item.partitions, Empty
           fWriteData "Type:", item.interfacetype, EndRow
           fWriteData "Size:", fFormatNum(item.Size, False), BeginRow
           If item.interfacetype = "IDE" Then
               fWriteData "IDE Bus#:", item.scsibus, Empty
               fWriteData "IDE ID:", item.scsitargetid, EndRow
           Else
               fWriteData "SCSI Bus#:", item.scsibus, Empty
               fWriteData "SCSI ID:", item.scsitargetid, EndRow
           End If
           fSpacer (5)
           Set objPartitionSet = item.Associators_("Win32_DiskDriveToDiskPartition", "Win32_DiskPartition")
           For Each objPartition In objPartitionSet
               Set objDriveSet = objPartition.Associators_("Win32_LogicalDiskToPartition", "Win32_LogicalDisk")
               aCounter = 0
               For Each objDrive In objDriveSet
                   If objPartition.bootpartition Then
                       fWriteData "Drive:", objDrive.Caption & " - Boot Partition", BeginRow
                   Else
                       fWriteData "Drive:", objDrive.Caption, BeginRow
                   End If
                   fWriteData "Label:", objDrive.VolumeName, Empty
                   fWriteData "File Sys:", objDrive.FileSystem, EndRow
                   fWriteData "Size:", fFormatNum(objDrive.Size, False), BeginRow
                   fWriteData "Free:", fFormatNum(objDrive.FreeSpace, False), Empty
                   fWriteData "S/N:", fCheckValue(objDrive.VolumeSerialNumber, Empty, Empty), EndRow
                   If aCounter < objPartitionSet.Count Then
                       fSpacer (5)
                   End If
                   aCounter = aCounter + 1
               Next
           Next
           fSpacer (10)
           pcount = pcount + 1
           pxBar = CLng((Pcount/ttlDisks) * (wdBar-2))
           objBar.all.ProgBar.Style.width = CStr(pxBar)
           WScript.Sleep 10
       Next
   End If
   Set objDriveSet = Nothing
   Set objPartitionSet = Nothing
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportNetAdaptersInfo(sysName)
   Dim pcount, ttlNet, pctComplete, pxBar, blnIPState
   pcount = 0
   ttlNet = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering Network Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Call fWriteTable("Top", "Network Adapter(s)", "sysNetwork")
   strReportFile.WriteLine(BEGIN_TABLE)
   If blnExtendedWMI Then
       Set objWMIInstance = objWMILocator.ExecQuery _
           ("Select * from Win32_IP4RouteTable",,48)
       strReportFile.WriteLine(" <tr>")
       strReportFile.WriteLine(" <td colspan='6' class='head' align='center' nowrap>")
       strReportFile.WriteLine(" <form name='RouteTable'>")
       strReportFile.WriteLine(" <input type='button' name='RouteTable' value='Routing Table' class='category' style='color: #ffffff' onclick=" & Chr(34) & "expandReportTable('RoutingTable')" & Chr(34) & ">")
       strReportFile.WriteLine(" </form>")
       strReportFile.WriteLine(" <div class='expando' id='RoutingTable' style='display:none;'>")
       strReportFile.WriteLine(" <table width='600' border='0' cellspacing='1' cellpadding='2'>")
       strReportFile.WriteLine(" <tr align=center bgcolor=#b6b6b6>")
       strReportFile.WriteLine(" <th class=category>Destination</th>")
       strReportFile.WriteLine(" <th class=category>Mask</th>")
       strReportFile.WriteLine(" <th class=category>Gateway</th>")
       strReportFile.WriteLine(" <th class=category>Interface</th>")
       strReportFile.WriteLine(" <th class=category>Metric</th>")
       strReportFile.WriteLine(" <tr>")
       For Each item In objWMIInstance
           strReportFile.WriteLine(" <tr>")
           strReportFile.WriteLine(" <td align='right' class='result'>" & item.destination & "</td>")
           strReportFile.WriteLine(" <td align='right' class='result'>" & item.mask & "</td>")
           strReportFile.WriteLine(" <td align='right' class='result'>" & item.nexthop & "</td>")
           strReportFile.WriteLine(" <td align='right' class='result'>" & item.interfaceindex & "</td>")
           strReportFile.WriteLine(" <td align='right' class='result'>" & item.metric1 & "</td>")
           strReportFile.WriteLine(" </tr>")
       Next
       Set objWMIInstance = Nothing
       strReportFile.WriteLine(" </table>")
       strReportFile.WriteLine(" </div>")
       strReportFile.WriteLine("     </td>")
       strReportFile.WriteLine(" </tr>")
       fSpacer (5)
       Set objWMIInstance = Nothing
   End If
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_networkadapterconfiguration WHERE IPEnabled='TRUE' AND ServiceName<>'AsyncMac' AND ServiceName<>'VMnetx' " _
       & "AND ServiceName<>'VMnetadapter' AND ServiceName<>'Rasl2tp' AND ServiceName<>'PptpMiniport' AND ServiceName<>'Raspti' " _
       & "AND ServiceName<>'NDISWan' AND ServiceName<>'RasPppoe' AND ServiceName<>'NdisIP' AND ServiceName<>''")
   aCounter = 0
   ttlNet = objWMIInstance.Count
   objFlash.InnerHTML = ""
   For Each item In objWMIInstance
       If UCase(item.ipenabled)="TRUE" Then
           blnIPState = "(Enabled)"
       Else
           blnIPState = "(Disabled)"
       End If
       fWriteHeading fCheckValue(item.Description & " - " & blnIPState, Empty, Empty)
fWriteSubHeading "GUID: " & item.settingid
       fWriteData "IP Address:", fBuildItemString(item.ipaddress), BeginRow
       fWriteData "Subnet:", fBuildItemString(item.ipsubnet), Empty
fWriteData "Gateways:", fBuildItemString(item.defaultipgateway), EndRow
fWriteData "DNS Srvs:", fBuildItemString(item.DNSServerSearchOrder), BeginRow
fWriteData "Wins Srvs:", fBuildItemString(Array(item.winsprimaryserver, item.winssecondaryserver)), Empty
fWriteData "MAC:", item.macaddress, EndRow
       fWriteData "Uses DHCP:", item.dhcpenabled, BeginRow
       fWriteData "", "", EndRow
       If item.dhcpenabled="True" Then
           fWriteData "Lease Obtained:", fDateDisplay(item.dhcpleaseobtained), BeginRow
           fWriteData "Expiration:", fDateDisplay(item.dhcpleaseexpires), Empty
           fWriteData "DHCP Server:", item.dhcpserver, EndRow
       End If
fWriteData "FQDN:", fCheckValue(item.dnshostname, Empty, Empty) & "." & fCheckValue(item.dnsdomain, Empty, Empty), BeginRow
fWriteData "DNS Domain:", fBuildItemString(item.DNSDomain), EndRow
fWriteData "DNS Suffix(es):", fBuildItemString(item.DNSDomainSuffixSearchOrder), BeginRow
fWriteData "DNS Reg:", item.DomainDNSRegistrationEnabled, Empty
fWriteData "DNS Full Reg:", item.fulldnsregistrationenabled, EndRow
fWriteData "Wins Scope:", item.winsscopeid, BeginRow
fWriteData "Wins Lookup:", item.winsenablelmhostslookup, EndRow
       aCounter = aCounter + 1
       If aCounter < objWMIInstance.Count Then
           fSpacer (5)
       End If
       pcount = pcount + 1
       pxBar = CLng((Pcount/ttlNet) * (wdBar-2))
       objBar.all.ProgBar.Style.width = CStr(pxBar)
       WScript.Sleep 10
   Next
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportQFEInfo(sysName)
   On Error Resume Next
   Dim pcount, ttlQFE, pctComplete, pxBar, arrQFE, aCounter
   pcount = 0
   ttlQFE = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering SP and Hotfixes ..."
   End If
   objFlash.InnerHTML = "Please wait..."
'    query = "select hotfixid, servicepackineffect, description, fixcomments, installedby " _
'     & "from win32_quickfixengineering"
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select * from win32_quickfixengineering")
   ttlQFE = objWMIInstance.Count
   objFlash.InnerHTML = ""
   If Err Then
       Call fWriteErrorDetails("Service Pack and Hotfix(es)", "sysHotfix", Err.Number)
       Err.Clear
   Else
       Call fWriteTable("Top", "Service Pack and Hotfix(es) - " & ttlQFE, "sysHotfix")
       strReportFile.WriteLine(BEGIN_TABLE)
       strReportFile.WriteLine(" <tr align=center bgcolor=#b6b6b6>")
       strReportFile.WriteLine(" <th class=category>Q Article</th>")
       strReportFile.WriteLine(" <th class=category>Installer</th>")
       strReportFile.WriteLine(" <th class=category>Description</th>")
       strReportFile.WriteLine(" </tr>")
       aCounter = 0
       For Each item In objWMIInstance
           If item.hotfixid="File 1" Then
               fWriteQFEData fRegExpQFE("\d{6}",item.servicepackineffect), true, BeginRow
           Else
               fWriteQFEData fRegExpQFE("\d{6}",item.hotfixid), true, BeginRow
           End If        
           fWriteQFEData item.installedby, false, Empty
           fWriteQFEData item.Description, false, EndRow
           aCounter = aCounter + 1
           If aCounter < objWMIInstance.Count Then
               fSpacer (3)
           End If
           pcount = pcount + 1
           pxBar = CLng((Pcount/ttlQFE) * (wdBar-2))
           objBar.all.ProgBar.Style.width = CStr(pxBar)
           WScript.Sleep 10
       Next
   End If
   Set objWMIInstance = Nothing
   fSpacer (10)
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportSharesInfo(sysName)
   On Error Resume Next
   Dim pcount, ttlShares, pctComplete, pxBar
   pcount = 0
   ttlShares = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering File Share Information ..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select name, caption, description, path from win32_share")
   ttlShares = objWMIInstance.Count
   objFlash.InnerHTML = ""
   If Err Then
       Call fWriteErrorDetails("Share(s)", "sysShare", Err.Number)
       Err.Clear
   Else
       Call fWriteTable("Top", "Share(s) - " & ttlShares, "sysShare")
       strReportFile.WriteLine(BEGIN_TABLE)
       strReportFile.WriteLine(" <tr align='center' bgcolor='#b6b6b6'>")
       strReportFile.WriteLine(" <th class='category'>Name</th>")
       strReportFile.WriteLine(" <th class='category'>Path</th>")
       strReportFile.WriteLine(" <th class='category'>Description</th>")
       strReportFile.WriteLine(" </tr>")
       aCounter = 0
       For Each item In objWMIInstance
           strReportFile.WriteLine(" <tr align='left'>")
           strReportFile.WriteLine(" <td align='left' class='result'><a target='_blank' href='\\" & sysName & "\" & item.name & "'>" & item.name & "</a></td>")
           strReportFile.WriteLine(" <td align='left' class='result'>" & item.path & "</td>")
           strReportFile.WriteLine(" <td align='left' class='result'>" & item.caption & "</td>")
           strReportFile.WriteLine(" </tr>")
           aCounter = aCounter + 1
           If aCounter < objWMIInstance.Count Then
               fSpacer (3)
           End If
           pcount = pcount + 1
           pxBar = CLng((Pcount/ttlShares) * (wdBar-2))
           objBar.all.ProgBar.Style.width = CStr(pxBar)
           WScript.Sleep 10
       Next
   End If
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportProcessesInfo(sysName)
   On Error Resume Next
   Dim pcount, ttlProcesses, pctComplete, pxBar, arrProcesses, aCounter
   pcount = 0
   ttlProcesses = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering Processes Information ..."
   End If
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select caption, processid, workingsetsize, priority, threadcount, creationdate, name from win32_process")
   ttlProcesses = objWMIInstance.Count
   objFlash.InnerHTML = ""
   If Err Then
       Call fWriteErrorDetails("Process(es)", "sysProcess", Err.Number)
       Err.Clear
   Else
       If (ttlProcesses - 1) > 1 Then
           ReDim arrProcesses(6, CInt(ttlProcesses - 1))
       Else
           ReDim arrProcesses(6, 1)
       End If
       Call fWriteTable("Top", "Process(es) - " & ttlProcesses, "sysProcess")
       strReportFile.WriteLine(BEGIN_TABLE)
       For Each item In objWMIInstance
           arrProcesses(0, aCounter) = item.Caption
           arrProcesses(1, aCounter) = fFormatNum(item.workingSetSize, False)
           arrProcesses(2, aCounter) = item.processID
           arrProcesses(3, aCounter) = fCheckValue(item.Priority, Empty, Empty)
           arrProcesses(4, aCounter) = fCheckValue(item.threadCount, Empty, Empty)
           arrProcesses(5, aCounter) = fCheckValue(fDateDisplay(item.creationDate), Empty, Empty)
           aCounter = aCounter + 1
           pcount = pcount + 1
           pxBar = CLng((Pcount/ttlProcesses) * (wdBar-2))
           objBar.all.ProgBar.Style.width = CStr(pxBar)
           WScript.Sleep 10
       Next
       Call fctSortArray(arrProcesses,0,"")
       Set objWMIInstance = Nothing
       strReportFile.WriteLine(" <tr align='center' bgcolor='#b6b6b6'>")
       strReportFile.WriteLine(" <th class='category'>Name</th>")
       strReportFile.WriteLine(" <th class='category'>Memory</th>")
       strReportFile.WriteLine(" <th class='category'>PID</th>")
       strReportFile.WriteLine(" <th class='category'>Priority</th>")
       strReportFile.WriteLine(" <th class='category'>Threads</th>")
       strReportFile.WriteLine(" <th class='category'>Started</th>")
       strReportFile.WriteLine(" </tr>")
       fWriteTableProcesses arrProcesses
   End If
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportServicesInfo(sysName)
   On Error Resume Next
   Dim pcount, ttlServices, pctComplete, pxBar, arrServices, acounter
   pcount = 0
   ttlServices = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.InnerHTML = "Gathering Services Information..."
   End If
   objFlash.InnerHTML = "Please wait..."
   Set objWMIInstance = objWMILocator.ExecQuery _
       ("select displayname, state, startmode, servicetype, status, startname, acceptpause, acceptstop, name from win32_service")
   ttlServices = objWMIInstance.Count
   objFlash.InnerHTML = ""
   If Err Then
       Call fWriteErrorDetails("Service(s)", "sysService", Err.Number)
       Err.Clear
   Else
       If (ttlServices - 1) > 1 Then
           ReDim arrServices(9, CInt(ttlServices - 1))
       Else
           ReDim arrServices(9, 1)
       End If
       Call fWriteTable("Top", "Service(s) - " & ttlServices, "sysService")
       strReportFile.WriteLine(BEGIN_TABLE)
       For Each item In objWMIInstance
           arrServices(0, aCounter) = item.DisplayName
           arrServices(1, aCounter) = item.State
           arrServices(2, aCounter) = item.StartMode
           arrServices(3, aCounter) = item.Status
           arrServices(4, aCounter) = item.startname
           arrServices(5, aCounter) = item.serviceType
           arrServices(6, aCounter) = item.acceptPause
           arrServices(7, aCounter) = item.acceptStop
           arrServices(8, aCounter) = item.Name
           aCounter = aCounter + 1
           pcount = pcount + 1
           pxBar = CLng((Pcount/ttlServices) * (wdBar-2))
           objBar.all.ProgBar.Style.width = CStr(pxBar)
           WScript.Sleep 10
       Next
       Call fctSortArray(arrServices,0,"")
       Set objWMIInstance = Nothing
       strReportFile.WriteLine(" <tr align='center' bgcolor='#b6b6b6'>")
       strReportFile.WriteLine(" <th class='category' nowrap>Name</th>")
       strReportFile.WriteLine(" <th class='category' nowrap>State</th>")
       strReportFile.WriteLine(" <th class='category' nowrap>Start Mode</th>")
       strReportFile.WriteLine(" <th class='category' nowrap>Status</th>")
       strReportFile.WriteLine(" <th class='category' nowrap>Start Name</th>")
       strReportFile.WriteLine(" </tr>")
       fWriteTableServices arrServices
   End If
   Set objWMIInstance = Nothing
   strReportFile.WriteLine(END_TABLE)
   Call fWriteTable("Bottom", Empty, Empty)
   objPBar.InnerHTML = ""
End Sub

Sub fWriteReportARPInfo(sysName)
   On Error Resume Next
   Dim intAppCounter
   Dim pcount, ttlARP, pctComplete, pxBar
   pcount = 0
   ttlARP = 0
   pctComplete = pcount
   objPBar.InnerHTML = "<input type=Text Name='pbFrame' style='background: silver; position: absolute; " & dlgBar & " z-index: -1;'><p ID='ProgBar' style='background: navy; color: black; position: absolute; " & dlgProgBar & " z-index: 0;'></p>"
   If blnVerboseMode Then
       objDBG.I