home directory permissions script folder exception

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

home directory permissions script folder exception

Logged in as: Guest

arrSession:exec spGetSession 2,2,2831

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> home directory permissions script folder exception
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

home directory permissions script folder exception - 4/28/2005 6:50:26 AM

neocipher

Posts: 4
Score: 0
Joined: 4/28/2005
From:
Status: offline

I've found a script that changes permissions based on the directory name. Currently it asks for the location of the home directories and also allow you to select a specific folder or prefix of folders to run the script upon. I need a way to keep the script from running on certain folders, kind of an exection either specified by a prompt or manually placed in the file to keep the script from bothering with certain directories.

'SPECIAL THANKS TO ERNIE COLDWELL (Ernest.Coldwell@us.mahle.com)
'FOR SUGGESTING THE ADDITION OF FILTERING CAPABILITIES

'INTRO
'I'M NOT YELLING, I FIND THE CAPS MAKE IT EASIER TO PICK THE COMMENTS OUT OF THE GIBBERISH.
'YOU MAY DO ANYTHING YOU WANT WITH THIS SCRIPT.  SELL IT, CHANGE IT, STEAL IT, WHATEVER, I DON'T CARE.

'OVERVIEW
'WHAT THE DAMN THING DOES...
'RESETS THE SECURITY ON A COLLECTION OF HOME FOLDERS BY
'ASSIGNING ALLOW FULL CONTROL TO ADMINISTRATORS
'AND ALLOW MODIFY TO THE ACCOUNT WHOSE HOME FOLDER IT IS.
'YES, WHEN YOU CREATE HOME FOLDERS VIA AD THEY SHOULD BE
'SECURED CORRECTLY HOWEVER THE LAST NETWORK I ENCOUNTERED HAD
'2,000+ HOME FOLDERS SET TO EVERYONE, ALLOW FULL CONTROL
'(HENCE THE REASON FOR THIS SCRIPT).
'THIS SCRIPT REQUIRES THAT SOME PORTION OF THE HOME FOLDER NAMES
'CONTAIN THEIR ASSOCIATED ACCOUNT NAME.  FOR EXAMPLE:
'$$JOHNH OR JOHNH$$$ OR EVEN #T^JOHNH!?%*.
'WHATEVER THE HOME FOLDER NAMING CONVENTION,
'HOPEFULLY IT'S BEEN USED CONSISTENTLY.

'QUICK STEP BY STEP
'-NOTIFIES YOU THAT XCACLS.VBS IS REQUIRED
'-OPTION TO DOWNLOAD XCACLS.VBS FROM MS, CONTINUE, OR CANCEL
'-SPECIFY THE PARENT DIRECTORY CONTAINING XCACLS.VBS
'-SPECIFY THE PARENT DIRECTORY CONTAINING YOUR HOME FOLDERS (PLEASE MAP A DRIVE IF NOT LOCAL)
'-SPECIFY THE DOWNLEVEL DOMAIN NAME THESE ACCOUNTS ARE IN
'-SPECIFY HOW MANY (IF ANY) CHARACTERS IN THE FOLDER NAME TO IGNORE STARTING ON THE LEFT
'-EXAMPLE:  IF NAMED $$JOHNH YOU WOULD SKIP 2 CHARACTERS
'-SPECIFY HOW MANY (IF ANY) CHARACTERS IN THE FOLDER NAME TO IGNORE FROM THE RIGHT
'-EXAMPLE:  IF NAMED JOHNH$%*$ YOU WOULD SPECIFY 4 CHARACTERS
'-WARNS YOU TO CLOSE ANY OPEN WINDOWS - THIS IS QUITE IMPORTANT
'-NOTE THAT OUTPUT LOGS TO c:\xcacls.txt
'-750,000 FILES WILL GIVE YOU A 50 MEG LOG EASY
'-AWAY IT GOES

'-OH YEAH AND...
'WORKS ON XP OR 2003, WOULD NEED CHANGES TO WORK ON 2000 (BUT CAN BE RUN FROM
'AN XP WORKSTATION) AGAINST A NETWORK SHARE SO SHOULDN'T BE AN ISSUE.
'INHERRITANCE IS REMOVED
'DEFAULT SECURITY GIVES THE USER FULL CONTROL OF THEIR HOME FOLDER BUT
'THIS SCRIPT GIVES THEM MODIFY INSTEAD BECAUSE I DON'T PARTICULARILY WANT THEM
'TO BE ABLE TO CHANGE PERMISSIONS OR DELETE THEIR HOME FOLDER.
'YOU CAN CHANGE THIS IN THE SCRIPT (TOWARDS THE BOTTON, WHEN XCACLS.VBS IS CALLED).
'IF ANYTHING IN THIS SCRIPT IS WEIRD OR CONFUSING IT'S PROBABLY ME NOT YOU.
'I HAVE NO FORMAL PROGRAMMING KNOWLEDGE SO THIS IS ME FIGGURING IT OUT -
'NOTHING IN HERE SHOULD BE TAKEN AS 'THE RIGHT WAY' TO DO SOMETHING.
'QUESTIONS ARE ALWAYS WELCOME - NICK.STAFF@COMCAST.NET

on error resume next

Const MY_COMPUTER = &H11&
Const SYSTEM32 = &H25&
Const WINDOW_HANDLE = 0
Const NO_OPTIONS = 0
Const FILES_YES = &H4000&

Set WSHShell = WScript.CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Shell.Application")
strComputer = "."

'INFORM THE USER THEY NEED XCACLS.VBS AND GIVE THEM THE OPTION TO DOWNLOAD IT

xcacQuest = "This script requires xcacls.vbs from Microsoft.  If you need to download it click yes.  If you don't, click no.  And if you feel safer getting the file from Microsoft yourself click cancel and rerun this script after you have."
xcacTitle = "Home Groan - Got xcacls?"
HomeGTitle = "Home Groan"
HomeGDomTitle = "Home Groan - Downlevel Domain"

xcacChoice = msgbox(xcacQuest, vbQuestion + vbYesNoCancel + vbDefaultButton6, xcacTitle)

xcacLoc = "http://download.microsoft.com/download/f/7/8/f786aaf3-a37b-45ab-b0a2-8c8c18bbf483/XCacls_Installer.exe"

'IF THEY WANT US TO DOWNLOAD IT FOR THEM WE WILL PAUSE THE SCRIPT
'WE PAUSE BY CREATING A LOOP THAT WAITS FOR THE XCACLS INSTALER PROCESS TO TERMINATE

IF xcacChoice = 6 then

Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colMonitoredProcesses = objWMIService. _
ExecNotificationQuery("select * from __instancedeletionevent " _
& "within 1 where TargetInstance isa 'Win32_Process'")

xcacDLWait = msgbox ("When the download finishes run XCacls_Installer.exe which will extract xcacls.vbs to the directory of your choice.  This script should automatically continue when the xcacls_installer exits.", vbokonly, xcactitle)

'BELOW WE LAUNCH AN IE PROCESS TO BEGIN THE FILE DOWNLOAD

set ie = CreateObject("InternetExplorer.Application")
ie.visible = true
ie.navigate xcacLoc

i = 0

'THE NEXT LINE IS WHERE WE SPECIFY THE PROCESS TO MONITOR FOR TERMINATION

Do While i <> "XCacls_Installer.exe"
Set objLatestProcess = colMonitoredProcesses.NextEvent
i = objLatestProcess.TargetInstance.Name
loop

ELSEIF xcacChoice = vbcancel then

xcacCancel = msgbox ("You can download xcacls.vbs by searching for it at http://www.microsoft.com/downloads", vbokonly, xcactitle)
wscript.quit()

END IF

'GET THE PATH OF THE SYSTEM32 FOLDER so we can launch cscript
'JUST IN CASE THE PATH SYSTEM VARIABLE IS HORRIBLY WRONG
'OR BECAUSE WE'RE OBSESIVE COMPULIVE AND CAN'T LEAVE IT ALONE

Set objSYSDR = objShell.Namespace(SYSTEM32)
Set objSYSDRItem = objsysDR.Self
Sys32 = objsysDRItem.Path

'GET THE PATH - ERR CLSID OF MY COMPUTER SO IT CAN BE USED AS THE ROOT
'WHEN WE BROWSE FOR FILES/FOLDERS

Set objMyComp = objShell.Namespace(MY_COMPUTER)
Set objMyCompItem = objMyComp.Self
BrowseRoot = objMyCompItem.Path

'OPEN BROWSE WINDOW SO USER CAN SPECIFY LOCATION OF XCACLS.VBS
'APPEND THE LOCATION WITH \XCACLS.VBS AND SET IT TO A VARIABLE

Do Until objFSO.FileExists(xcacls)

Set xcaclspath = objShell.BrowseForFolder _
(WINDOW_HANDLE, "Select the location of the xcacls.vbs file:", NO_OPTIONS, BrowseRoot)

IF xcaclspath = Empty then
wscript.quit()

ELSEIF xcaclspath = "" then
wscript.quit()
END IF

Set xcaclspathItem = xcaclspath.Self
xcaclsPath = xcaclspathItem.Path

xcacls = xcaclspath & "\xcacls.vbs"

If not objFSO.FileExists(xcacls) then

oUserError = Msgbox ("xcacls.vbs does not exist in the folder you specified.  Please verify it's location and select the appropriate folder.", vbExclamation + vbokonly, HomeGTitle)
end if
loop

'OPEN BROWSE WINDOW SO USER CAN SPECIFY LOCATION OF HOME FOLDERS (PARENT DIRECTORY)

Set objpath = objShell.BrowseForFolder _
(WINDOW_HANDLE, "Select the drive or folder containing the Home Directories to secure:", NO_OPTIONS, BrowseRoot)
Set objpathItem = objpath.Self
objPath = objpathItem.Path

'PROMPT USER FOR THE DOWNLEVEL DOMAIN NAME

do until thisdom <> empty
ThisDom = Inputbox("Type the downlevel name of the domain the accounts associated with these home folders are in (ie no .com)", HomeGDomTitle)

IF (ThisDom = empty) then

oUserError = Msgbox ("The domain name is required and can not be blank.  Script will now exit.", vbExclamation + vbokonly, HomeGTitle)
wscript.quit()
End IF
loop

'PROMPT USER FOR NUMBER OF CHARACTERS TO IGNORE FROM THE LEFT

iCHleft = Inputbox("In determining the account name, how many (if any) characters should be cropped from the left of the folder name?  For example if your naming convention is $$username then enter 2 here.  If the folder names begin with the account names enter 0.", HomeGTitle)

IF (iCHleft = empty) then
lUserError = Msgbox ("Script will now exit.  If you meant to specify not to skip any characters, run the script again and enter 0 next time", vbInformation + vbokonly, HomeGTitle)
wscript.quit()
END IF

'PROMPT USER FOR NUMBER OF CHARACTERS TO IGNORE FROM THE RIGHT

iCHright = Inputbox("In determining the account name, how many (if any) characters should be cropped from the right of the folder name?  For example if your naming convention is username$$ then enter 2 here.  If the folder names end with the account names enter 0.", HomeGTitle)

IF (iCHright = empty) then
rUserError = Msgbox ("Script will now exit.  If you meant to specify not to skip any characters, run the script again and enter 0 next time", vbInformation + vbokonly,  HomeGTitle)
wscript.quit()
END IF

'PROMPT USER FOR STRING TO MATCH

strFilter = Inputbox("If you want to filter by folder name enter the string to match below.  Only folders whose names begin with the string will be changed.  For example if you enter the letter ""A"" (do not use quotes) then the folder named asmith would be changed but not the folder named janedoe. Leave blank to change all.", HomeGTitle)

IF strFilter <> EMPTY then
rFormatFilter = LCase(strFilter)
filterAlive = 1
END IF

'CREATE A COLLECTION OFF ALL SUB FOLDERS IN THE DIRECTORY SPECIFIED BY USER

Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSubfolders = objWMIService.ExecQuery _
("Associators of {Win32_Directory.Name='" & objPath & "'} " _
& "Where AssocClass = Win32_Subdirectory " _
& "ResultRole = PartComponent")

'SINCE WE USE APPACTIVATE TO TIGHTEN PERFORMANCE IT IS VERY IMPORTANT TO HAVE NO OTHER WINDOWS OPEN WHEN THIS RUNS
'THIS IS WHERE WE TELL THE USER THAT

xcacDLWait = msgbox ("Please make sure all other windows are closed - especially any folders you have open.  This is very important if you'd like this to work.  Please click ok when that's done and you're ready to continue.", vbInformation + vbokonly, xcactitle)

'HERE IS WHERE WE CHANGE FOLDER PERMISSIONS
'EVERYTHING BETWEEN THE FOR AND THE NEXT STATEMENT_
'WILL BE RUN ON EACH FOLDER IN THE COLLECTION ABOVE

For Each objFolder in colSubfolders

Set objFolders = objFSO.GetFolder(objFolder.name)

FID = objFolders.name
HomeFolder = objFolder.name

'WE ARE PARSING EACH FOLDER NAME TO FIND IT'S
'ASSOCIATED USER ACCOUNT.  WE MUST ALSO IGNORE
'THE NUMBER OF CHARACTERS SPECIFIED BY USER (IF ANY)

'*******************************************
'THANKS TO Kenneth Bryant (kbryant@checksinthemail.com) AND
'Richard Stephen Reese (rsreese@ifas.ufl.edu)
'FOR HELPING TO RESOLVE AND ERROR IN THIS NEXT SECTION
'*******************************************

If iCHright > 0 Then

uidR = RTrim(Left(FID,Len(FID)-iCHright))
cRightnum = 1
END IF

IF cRightnum = 1 then

UID = LTrim(Right(uidR,Len(uIDR)-iCHleft))

ELSE

UID = LTrim(Right(FID,Len(FID)-iCHleft))

END IF

'WE COMPARE FOLDER NAMES TO OUR FILTER STRING (IF ANY)

noMatch = 0
IF filterAlive = 1 then
checkFilter = Left(uid,LEN(rFormatFilter))

IF lcase(checkFilter) <> rFormatFilter then
noMatch = 1
END IF
END IF

'THIS IS THE COMMAND THAT RUNS THE XCACLS.VBS SCRIPT.
'THIS IS WHERE YOU CAN CHANGE WHAT PERMISSIONS ARE SET
'AND WHAT GROUPS THEY'RE SET FOR
'NOTE THAT OUTPUT LOGS TO c:\xcacls.txt
'750,000 FILES WILL GIVE YOU A 50 MEG LOG EASY

IF noMatch = 0 then

WSHShell.run ("""" & sys32 & "\cscript.exe"" """ & xcacls & """ """ & homefolder & """ /f /s /t /g administrators:F /g " & ThisDom & "\" & UID & ":M /I remove /l c:\xcacls.txt /Q")

wscript.sleep 200
WshShell.AppActivate "C:\"

Do while WshShell.AppActivate("C:\") = TRUE
wscript.sleep 200
loop
END IF

'THIS IS THE LAST LINE

Post #: 1

Re: home directory permissions script folder exception - 4/28/2005 1:23:21 PM

token

Posts: 1917
Score: 0
Joined: 1/14/2005
From:
Status: offline

If you can tell me EXACTLY what permission do you want to change and for what resource (files, directories and/or sub-directories), I might be more of help. and If you can give examples, that will be good too (eg: c:\folder, everyone:R administrators:F/c)

(in reply to neocipher)

Post #: 2

Re: home directory permissions script folder exception - 4/29/2005 2:16:04 AM

neocipher

Posts: 4
Score: 0
Joined: 4/28/2005
From:
Status: offline

Well currently the script parses the name of a folder and add's user permissions according to the folder name and administrator permissions.

This prompts the user for stuff they want to change. I need to be able to exclude certain folders not specify which one's I need to change.

(in reply to neocipher)

Post #: 3

Re: home directory permissions script folder exception - 4/30/2005 7:59:35 AM

token

Posts: 1917
Score: 0
Joined: 1/14/2005
From:
Status: offline

I believe you can do it without this script. However, I need to know EXACTLY what is changed (what was the permission before and what is the permission after) for an object. As far as I can see, it will change the ACL for a directory to allow local admins F/C, adds a user with Modify permission and turns of inheritance for the folder, and process all files/sub-directories within the folder.

Do you want to exclude one or multiple folders ? and how do you intend to specify the filtering "string" ? (eg: any folders that start with A, or the complete folder name such as "AppFolder")

(in reply to neocipher)

Post #: 4

Re: home directory permissions script folder exception - 5/2/2005 12:50:54 AM

neocipher

Posts: 4
Score: 0
Joined: 4/28/2005
From:
Status: offline

You are correct about the permissions. It removes any previously existing permissions and adds the administrator and the user according to the folder name.

I would like to exclude directories based on a list of folder names. A prompt would also work but it would need to prompt multiple time so it might be easier to just write them out.

(in reply to neocipher)

Post #: 5

Re: home directory permissions script folder exception - 5/3/2005 8:31:00 AM

esnmb

Posts: 448
Score: 0
Joined: 1/11/2005
From: USA
Status: offline

I have a script that does this already.

I search folders that are named after user accounts, then a match the folder names to user names, move the folders to a new server and ACL them with MS' SubInACL tool. I also supply a security group to the script so I can pick and choose what users are to be moved.

If this doesn't help, I also have a script to read an Excel spreadsheet for user names and copy folders and ACL them. That particular script will allow you to move users based on their first initial.

Any way, here is the first one I talked about:

Start = Now

' **************************************
' * Prompt user for Group to search in *
' **************************************
strGroup = InputBox("Please enter the Group to search through.", "Active Directory Group Search")
'strGroup = "Ctxusr Midd01fs"

Const ForWriting = 2
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("\\DOMAIN-share\users\TimeReport-" & strGroup & ".log", ForWriting)

' *********************************
' * Error handling for user input *
' *********************************
Const TIMEOUT = 10
Const POPUP_TITLE = "Input Error"

Set objScript = Wscript.CreateObject("Wscript.Shell")

If strGroup = "" Then
iRetVal = objScript.Popup( "You must enter a Group name to search through." & _
vbCrLf & "Would you like to enter it now?",TIMEOUT,POPUP_TITLE,vbQuestion + vbYesNo)
End If

Select Case iRetVal
Case vbYes
strGroup = InputBox("Please enter the Group you wish to search through.", "Active Directory Group Search")
Case vbNo
Wscript.Quit
Case -1
MsgBox "** POPUP TIMED OUT **" & vbCrLf & vbCrLf & "No files have been copied.",, "Notification Message"
wscript.Quit
End Select

' ***************
' * Script Main *
' ***************
Set objFSO = CreateObject("Scripting.FileSystemObject")

Set objGroup = GetObject _
("LDAP://CN=" & strGroup & ",OU=General,OU=Security Groups,DC=DOMAIN,DC=com")
objGroup.GetInfo

' Retrieves members of specified Group
arrMember = objGroup.GetEx("member")

' Defines the different OU's that contain user accounts
Set objOU = GetObject("LDAP://OU=Users,OU=All Users,DC=DOMAIN,DC=com")
objOU.GetInfo
Set objOU1 = GetObject("LDAP://OU=Admins,OU=All Users,DC=DOMAIN,DC=com")
objOU1.GetInfo
Set objOU2 = GetObject("LDAP://OU=Executives,OU=All Users,DC=DOMAIN,DC=com")
objOU2.GetInfo
Set objOU3 = GetObject("LDAP://OU=Emax Recipients,OU=Users,OU=All Users,DC=DOMAIN,DC=com")
objOU3.GetInfo
Set objOU4 = GetObject("LDAP://OU=MLN Recipients,OU=Users,OU=All Users,DC=DOMAIN,DC=com")
objOU4.GetInfo

arrLDAP = Array(objOU, objOU1, objOU2, objOU3, objOU4)

' Defines the paths to user folders
objPath = "\\midd01fs\vol3\Oakbrook\Users\"
objPath1 = "\\midd01fs\vol3\Atlanta\Users\"
objPath2 = "\\midd01fs\vol3\Horsham\Users\"
objPath3 = "\\midd01fs\vol1\Users\"
objPath4 = "\\Midd01bs\vol1\Delaware\Users\"
objPath5 = "\\Midd01bs\vol1\Phoenix\Users\"
objPath6 = "\\Midd01bs\vol1\Retail\Users\"
objPath7 = "\\Midd01bs\vol1\Referral\Users\"

arrPath = Array(objPath, objPath1, objPath2, objPath3, objPath4, objPath5, objPath6, objPath7)

' Loops from 0 to as many item as there are in the Array
For i = 0 To UBound(arrLDAP)

For Each objItem In arrLDAP(i)

objMembers = LCase(Join(arrMember))
strName = LCase(objItem.DistinguishedName)

If InStr(objMembers, strName) Then

' Copying files and folders
For Each Path In arrPath
strFolder = Path & objItem.SamAccountName
strDest = "\\DOMAIN-share\users\" & objItem.SamAccountName
If objFSO.FolderExists(strFolder) Then
' When disabling display of "Percent Complete" with switch, Robocopy hangs on large files.
objScript.Run ("robocopy.exe " & strFolder & " " _
& strDest & " /MIR /R:5 /NC /LOG+:CopyReport.log /TEE"), 1, True
objFile.WriteLine "Copied: " & objItem.SamAccountName
End If
Next

' Setting permissions on only the folders copied in this batch
If objFSO.FolderExists(strDest) Then
objScript.Exec ("SubInACL.exe /subdirectories " & strDest _
& " /grant=DOMAIN\" & objItem.SamAccountName & "=C")
End If

End If

Next

Next

If DateDiff("n", Start, Now) = 0 Then
objFile.WriteBlankLines 1
objFile.WriteLine "The script took less than 0 minutes to complete." & vbCrLf
objFile.WriteLine "There may have been a problem or the group that was entered does not exist."
objFile.Close
Else
objFile.WriteBlankLines 1
objFile.WriteLine "======================"
objFile.WriteLine "======================"
objFile.Write DateDiff("n", Start, Now) & " minutes to complete"
objFile.Close
End If

< Message edited by esnmb -- 1/2/2007 5:38:05 AM >

(in reply to neocipher)

Post #: 6

Re: home directory permissions script folder exception - 5/3/2005 8:32:26 AM

esnmb

Posts: 448
Score: 0
Joined: 1/11/2005
From: USA
Status: offline

Here is the other one to get user/folder names from an Excel Spreadsheet and move and ACL them.

' ********************************************************
' * Prompt to get the first initial of the users to copy *
' ********************************************************
strInitial = InputBox(vbCrLf & vbCrLf & vbCrLf & _
"Please enter the first initial of the users you wish to copy.","Folder Copy")

'strInitial = "a"

If strInitial = "" Then

Wscript.Echo "You must enter an initial to begin the copy." & vbCrLf & "Script is exiting."
Wscript.Quit

End If

' *********************
' * Script start time *
' *********************
Start = Now

' ***************
' * Script Main *
' ***************
Const ForWriting = 2

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("\\DOMAIN-share\TestShare\TimeReport_Midd01fs - " & Left(UCase(strInitial), 1) _
& ".log", ForWriting)
Set objScript = Wscript.CreateObject("Wscript.Shell")

objPath = "\\midd01fs\vol1\Users\"

Set objExcel = CreateObject("Excel.Application")
strPathExcel = "c:\temp\midd01fsusers.xls"
objExcel.Workbooks.Open strPathExcel

NumofSheet = objExcel.ActiveWorkbook.Sheets.Count

For s = 1 To NumofSheet
objExcel.ActiveWorkbook.Sheets(s).Select
Set objSheet = objExcel.ActiveWorkbook.Activesheet

For intRow = 1 To objSheet.UsedRange.Rows.Count
strData= LCase(Trim(objSheet.Cells(intRow,1).Value))

If Left(strData, 1) = Left(LCase(strInitial), 1) Then

strFolder = objPath & strData
strDest = "\\DOMAIN-share\TestShare\" & strData

If objFSO.FolderExists(strFolder) Then
objScript.Run ("robocopy.exe " & strFolder & " " _
& strDest & " /Create /E /R:5 /NC /LOG+:CopyReport.log /TEE"), 1, True
objFile.WriteLine "Copied: " & strData
End If

If objFSO.FolderExists(strDest) Then
objScript.Exec ("SubInACL.exe /subdirectories " & strDest _
& " /grant=DOMAIN\" & strData & "=C")
End If

End If

Next

Next

' *************************************************************************
' * Updates log with time to complete as well as a form of error handling *
' *************************************************************************
If DateDiff("n", Start, Now) = 0 Then
objFile.WriteBlankLines 1
objFile.WriteLine "The script took less than 0 minutes to complete." & vbCrLf
objFile.WriteLine "There may have been a problem or the initial that was entered, " & Chr(34) _
& strInitial & Chr(34) & " does not exists."
objFile.Close
Else
objFile.WriteBlankLines 1
objFile.WriteLine "======================"
objFile.WriteLine "======================"
objFile.Write DateDiff("n", Start, Now) & " minute(s) to complete"
objFile.Close
End If

objExcel.Quit

< Message edited by esnmb -- 1/2/2007 5:38:19 AM >

(in reply to neocipher)

Post #: 7

Re: home directory permissions script folder exception - 5/4/2005 2:08:23 AM

neocipher

Posts: 4
Score: 0
Joined: 4/28/2005
From:
Status: offline

I like the first script that you have posted. But I don't need all of the copying functions. Just lookup the OU check that the users exists and then assign right's to the folder. Problem is that there is still the same issue with the first script I was using. I need a way for the script to skip certain users that I specify that are in the same OU and their home directory is in the same area that the rest of the users' folder's reside in or a better method would be when listing the directory don't include folders that have a folder size greater then some amount.

Here's a little bit of code that I think might work the first script I posted.

but i'm not sure how to incorporate to skip a user's folder if the size is greater then some number

(in reply to neocipher)

Post #: 8

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> home directory permissions script folder exception

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts