Terminal Server Maintenance

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Terminal Server Maintenance

Logged in as: Guest

arrSession:exec spGetSession 2,16,31330

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Terminal Server Maintenance
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Terminal Server Maintenance - 2/21/2006 1:09:21 AM

turranx

Posts: 38
Score: 0
Joined: 2/7/2006
Status: offline

This code was designed to perform a number of behind the scenes tasks to keep our Terminal Server healthy. At the time this was written, all profiles had a 25,000K storage size limit. Many users were running past that limit. One purpose of this script is to empty certian directores within a user's profile of all files and subfolders older than 3 days. Instructions on how to configure this are below. The second purpose of this script is to
unload user registry hives from HKEY_USERS (HKU). Our Terminal Server suffers from a common but hard to diagnose problem where it is unable to unload a users's hive after that user logs off. Perhaps a process is still using that hive when the OS wants to unload it.

This code relies upon some custom made VBS libraries and one custom made console executable. I'll be happy to provide both to you if you send me an email at G.Forums@oraucoc.org.

When you put this code into a text file, give it a .WSF extension.

G.

<?xml version="1.0" ?>
<package>
   <comment>
   PrimalCode wizard generated file.
   </comment>
   <job id="Profile_Folder_Maintenance" prompt="no">
       <?job error="false" debug="false" ?>
       <script id="Standard_Functions.vbs" language="VBScript" src="..\Libraries\Standard_Functions.vbs"/>
       <script id="Search_Through_Profile_Folders" language="VBScript">
<![CDATA[
Option Explicit
On Error Resume Next
'On Error Goto 0
'*********************************************************************************
'Description:   This code was designed to perform a number of behind the scenes
'               tasks to keep our Terminal Server healthy.  At the time this was
'               written, all profiles had a 25,000K storage size limit.  Many
'               users were running past that limit.  One purpose of this script is
'               to empty certian directores within a user's profile of all files
'               and subfolders older than 3 days.  Instructions on how to
'               configure this are below.  The second purpose of this script is to 
'               unload user registry hives from HKEY_USERS (HKU).  Our Terminal
'               Server suffers from a common but hard to diagnose problem where it
'               is unable to unload a users's hive after that user logs off.
'               Perhaps a process is still using that hive when the OS wants to
'               unload it.  
'*********************************************************************************
'Revisions:
'(Feb 21st 2006) - v1.2.1 - Added code to run at 9PM in addition to 6AM
'                           Removed SQL_Classes.vbs dependancy
'(Feb 20th 2006) - v1.2   - Added code to unload unused registry hives from HKU
'(Feb 20th 2006) - v1.1.4 - Moved GetUserSessionID to Standard_Functions.vbs 
'                           Library.  New function is GetUserSessionIDEx.
'(Feb 02nd 2006) - v1.1.3 - Removed Send Email Code
'                           Added documentation to Search Subfolder function
'                           Removed folder creation code from main body of script
'(Jan 31st 2006) - v1.1.2 - Added code to remove documents With certian extentions
'(Jan 25th 2006) - v1.0   - Writing Script
'*********************************************************************************
'Written For: A Windows 2000 Advanced Server
'*********************************************************************************
'NOTE: * This code should be installed in C:\Running_Scripts\<Script_Directory>
'      * This code relies upon standard libararies which should be located in 
'        C:\Running_Scripts\Libraries
'      * If you cannot find the code for a Function/Subroutine that is used here,
'        check Standard_Functions.vbs as it Is probably in there.
'      * This code uses the SIDTranslator function which sets On Error Resume Next
'        So be aware of this when debugging and trying to trap errors.
'      * Reg.exe and HiveEnum.exe are required for this code to run properly.
'        Reg.exe is a part of Windows 2000 Support Tools
'            http://support.microsoft.com/kb/301423/
'        Reg.exe might not be located in c:\Program Files\Resource Kit\ on your 
'        server, so you might have to change the path in the code.
'      * HiveEnum.exe is a custom built console application designed by an 
'        in-house Delphi programmer.  If you choose not to use this application,
'        you need to install http://support.microsoft.com/kb/817478 and change
'        the code below.
'*********************************************************************************
'Define Variants
Dim strProfile_Folder           'Contains a UNC Path to the User Profile folder
Dim objProfile_Folder           'Will be an object representing the User Profile folder
Dim colProfiles                 'A collection of Profile folders
Dim objProfile                  'Will be an object representing an individual User Profile folder
Dim colFiles                    'A collection of files within a folder
Dim objFile                     'Will be an object representing an individual file
Dim objLogFile            'To keep track of what was removed or added
Dim strLogFile            'Path to Log File
Dim boolDebug                   'Turns on or off debugging.  If turned on, wscript.echo commands
                               'will be used.  Don't run this as a service or Scheduled Task
                               'while debugging is turned on.
Dim arrFolderList               'Array of folders to search through
Dim arrFileList                 'Array of file extensions to search for
Dim arrDeleteSubFolders         'Array of boolean values indicating whether or not to delete subfolders
Dim arrLogThisActivity          'Array of boolean values indicating whether or not to write deletions
                               'to a log file
Dim i                           'Counter used in a For Loop
Dim strSID                      'SID for a userID
Dim objExec                     'A Shell used to run an executable
Dim strRunMe                    'Command line utility
Dim strRunMeOutput              'Command line utility StdOut
Dim strHKUHives                 'A List of User Hives loaded in HKEY_USERS
Dim strDomain                   'Used when translating userIDs into SIDs
'*********************************************************************************
'Populate Variants
boolDebug = False
strProfile_Folder = "D:\Documents and Settings"

'arrFolderList contains a list of subfolders to inspect.
'strProfile_Folder & <User Name> & arrFolderList(i) creates a path like
'D:\Documents and Settings\jdoe\Local Settings\Temp
arrFolderList = Array("\Local Settings\Temp", _
                     "\Local Settings\Temporary Internet Files", _
                     "\Local Settings\Application Data\Microsoft\Terminal Server Client\Cache", _
                     "\Application Data\Microsoft\Excel")

'arrFileList tells the script what file extentions TO DELETE
'arrFileList(i) corresponds to arrFolderList(i)
'To have multiple file extensions for one folder, separate them like this: "xar/zip/yyz"
'This will remove files of type xar AND zip AND yyz
'To remove files with extensions xar, zip, yyz, and no extension: "xar/zip/yyz/Null"
arrFileList = Array("*","*","*","xar")

'arrDeleteSubFolders tells the script whether or not to delete subfolders
'that have a created date older than 3 days
'arrDeleteSubFolders(i) corresponds to arrFolderList(i)
'For more information, read the documentation in the Search_Subfolder subroutine
arrDeleteSubFolders = Array(True,True,True,False)

'arrLogThisActivity tells the script whether or not to log the deletion of
'files and folders
'arrLogThisActivity(i) corresponds to arrFolderList(i)
arrLogThisActivity = Array(False,False,False,True)

'When translating user IDs into SIDs, query this domain
strDomain = "Contoso"     'Put your domain name here
'*********************************************************************************
'Run Code
Do While True
Initilize_Standard_Variables

'Gather a list of User Hives that are loaded on this computer
strHKUHives = ""
strRunMe = "C:\Running_Scripts\Profile_Folder_Maintenance\HiveEnum.exe"
On Error Goto 0
Set objExec = WshShell.Exec(strRunMe)
Do While Not objExec.StdOut.AtEndOfStream
 strHKUHives = strHKUHives & objExec.StdOut.ReadLine() & "/"
Loop
Set objExec = Nothing

'Open Log File
strLogFile = strRunningPath & "\Log_File.txt"
If Not objFSO.FileExists(strLogFile) Then
   Set objLogFile = objFSO.CreateTextFile(strLogFile)
Else
   Set objLogFile = objFSO.OpenTextFile(strLogFile,8)
End If

'Start with the primary Profile folder
Set objProfile_Folder = objFSO.GetFolder(strProfile_Folder)

'Obtain a list of individual user's profiles
Set colProfiles = objProfile_Folder.Subfolders

'Go through each profile folder one at a Time
For Each objProfile in colProfiles
 'Pull the userID out of objProfile.Path And see if this person is logged in
 'If they are NOT logged in, then run through their profile looking for files to delete
 If GetUserSessionIDEx(Mid(objProfile.Path,Len(strProfile_Folder)+2),Nothing) = -1 Then
  'Run through each specific folder In arrFolderList and search it for items to delete
  For i = 0 to UBound(arrFolderList)
   If objFSO.FolderExists(objProfile.Path & arrFolderList(i)) Then
    Search_Subfolder objProfile.Path & arrFolderList(i), _
                     arrFileList(i), _
                     arrDeleteSubFolders(i), _
                     arrLogThisActivity(i), _
                     0
   End If
  Next
  'Now check to see if this user's registry hive is still loaded in HKEY_USERS (HKU).  
  'Try to unload it if it is.
  strSID = SIDTranslator(Mid(objProfile.Path,Len(strProfile_Folder)+2),strDomain,"")
  'For Debugging, remember SIDTranslator sets On Error Resume Next
  'The SID should be in the string that contains a list of HKEY_USERS Hives
  If (InStr(strHKUHives,strSID) > 0) and (Left(strSID,2) = "S-") Then
       strRunMeOutput = ""
       strRunMe = "c:\Program Files\Resource Kit\reg.exe Unload HKU\" & Trim(strSID)
       Set objExec = wshShell.Exec(strRunMe)
       Do While Not objExec.StdOut.AtEndOfStream
               'Collect all the output.  Use it later for debugging.
               strRunMeOutput = strRunMeOutput & objExec.StdOut.ReadLine() & VbCrLf
       Loop
       'Wscript.echo strRunMe & vbcrlf & strRunMeOutput & "." & VbCrLf
       Set objExec = Nothing
       strRunMe = "c:\Program Files\Resource Kit\reg.exe Unload HKU\" & Trim(strSID) & "_Classes"
       Set objExec = wshShell.Exec(strRunMe)
       Do While Not objExec.StdOut.AtEndOfStream
               'Collect all the output.  Use it later for debugging.
               strRunMeOutput = strRunMeOutput & objExec.StdOut.ReadLine() & VbCrLf
       Loop
       'Wscript.echo strRunMe & vbcrlf & strRunMeOutput & "." & VbCrLf
       Set objExec = Nothing
  End If
 End If
Next

objLogFile.Close

'Break down Global Variables...
Set objLogFile = Nothing
Set objProfile_Folder = Nothing
Set colProfiles = Nothing
Set objProfile = Nothing
Set colFiles = Nothing
Set objFile = Nothing

Denitilize_Standard_Variables  'I know this is spelled wrong.  
                               'It's spelled wrong in A LOT of my code 
                               'and I'm too lazy to change it.

'In production, this timeout will be set for 6AM and 9PM every Day
If Hour(Now) >= 6 Then
       Wscript.Sleep Sleep_Until("21:00:00",cstDaily)
Else
       Wscript.Sleep Sleep_Until("06:00:00",cstDaily)
End If
Loop

Wscript.Quit

'============================
'Search_Subfolder
'============================
Sub Search_Subfolder(strDirectory,strFileExtensions,boolDeleteSubFolders,boolLogThisActivity,intDir_Level)
'Description: This subroutine searches the base folder and all
'             subfolders for files that are have a modified date 
'             at least 3 days old AND whose file extensions are in
'             the string contained within the variable strFileExtensions
'Parameters:
'INPUT: strDirectory - The directory to recursively search
'INPUT: strFileExtentions - A string of file extentions to inspect for deletion
'                    "*" -> inspect ALL files
'                    "xar" -> inspect only files with extension 'xar'
'                    "NULL" -> inspect only files without extensions
'                    "zip/jpg/NULL" -> inspect files with the extensions
'                                      'zip' and 'jpg' and files without
'                                      any extension at all
'                    NOTE: Use '/' to separate the file extensions
'INPUT: boolDeleteSubFolders - True = Yes, delete folders with a created date older than 3 days
'                       False = No, don't delete any folders
'INPUT: boolLogThisActivity - True = Yes, write to the log file all deletes made for this call of Search_Subfolder
'                      False = No, don't write anything to the log file for this call of Search_Subfolder
'INPUT: intDir_Level - When you first call this subroutine, pass in the value zero
'OUTPUT: NONE
On Error Resume Next
Dim objFolder
Dim colSubFolders
Dim objSubFolder
Dim colFiles
Dim objFile
Dim strFullPath

'Start with this directory 'strDirectory'
Set objFolder = objFSO.GetFolder(strDirectory)

'Obtain a list of subfolders
Set colSubFolders = objFolder.SubFolders

'Check the number of subfolders
If colSubFolders.Count > 0 Then
 For Each objSubFolder In colSubFolders
  'As long as there are subfolders,
  'this recursion keeps going until we hit the deepest subfolder that 
  'contains only files, not additional subfolders
  Search_Subfolder objSubFolder.Path,strFileExtensions,boolDeleteSubFolders,boolLogThisActivity,intDir_Level+1
 Next
End If

'If you've reached this part of the code, there are
'either no more subfolders (on your way deeper into the 
'folder structure) OR you've hit bottom and are on your
'way back up (getting closer to root)

'Start looking at the files in this folder
'Obtain a list of files in this folder
Set colFiles = objFolder.Files

'Inspect Each file one at a Time
For Each objFile In colFiles
 'Inspect the file's modified date
 'delete it If it's older than 3 days AND the extension is in the list of extensions to delete.
 If (objFile.DateLastModified < (Now - 3)) AND _
    (  (strFileExtensions = "*") OR _
       ( _
               (Instr(lcase(strFileExtensions),lcase(objFSO.GetExtensionName(objFile))) > 0) AND _
               (Len(objFSO.GetExtensionName(objFile)) > 0) _
        ) OR _
       ( _   
               (Instr(lcase(strFileExtensions),lcase("NULL")) > 0) AND _
               (Len(objFSO.GetExtensionName(objFile)) = 0) _
        ) _
     ) Then
  'Yes? Delete it. (Force Delete = True)
  If boolLogThisActivity Then objLogFile.WriteLine(Now & " - Deleted " & objFile.Path)
  objFSO.DeleteFile objFile,True
 End If
Next
 
If (colFiles.Count = 0) AND (intDir_Level > 0) And boolDeleteSubFolders Then
 'If you've made it into this If Statement, Then...
 'Files don't exist in this folder
 'Inspect the folder's creation date
 'delete it If it's older than 3 days
  'Is the folder's Created Date older than 3 days?
 If objFolder.DateCreated < (Now - 3) Then
   'Yes? Delete it. (Force deletion = True)
   If boolLogThisActivity Then objLogFile.WriteLine(Now & " - Deleted " & objFolder.Path)
   objFSO.DeleteFolder objFolder
 End If
End If

'Clean up local objects
Set objFile = Nothing
Set colFiles = Nothing
Set objFolder = Nothing
Set colSubFolders = Nothing
Set objSubFolder = Nothing
End Sub
]]>
       </script>
   </job>
</package>

_____________________________

Microsoft Windows 2000 Scripting Guide - The best book for newbie scripters
http://www.myspace.com/Evil__Overlord

Post #: 1

RE: Terminal Server Maintenance - 2/21/2006 2:46:32 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

I am the TS server administrator at my job as well,

I am curious why you developed an in house solution (hiveenum.exe) when there was a MS KB fix for the same thing?

Also, I have yet to run into this problem with the user specific hive not unloading, what happens to the server when this happens and how do you fix it? (other than your script)

Would you please send me your libraries and that console app to the email account listed on my forum account?

Thanks!

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to turranx)

Post #: 2

RE: Terminal Server Maintenance - 2/21/2006 2:51:59 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

I have a few comments.
1) I think some more indentation would make the code more legible.
2) It is well commented.
3) It appears to be using some library functions which you have not posted. That makes this code very hard to be adapted to someone else's environment.(Disregard)
4) It looks like you use several arrays to keep track of the folders to search and information on how to process those folders. I would lean toward a dictionary to do this.
5) Do While True Loop constructs are dangerous IMO and run the risk of wasting resources.
6) I think the use of a global On Error Resume Next statement is dangerous in that it would mask errors that you really should correct.

As always, these comments are purely my opinion and since you have a script that does what you need, then by definition it is written correctly.

< Message edited by ebgreen -- 2/21/2006 3:40:15 AM >

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to turranx)

Revisions: 1 | Post #: 3

RE: Terminal Server Maintenance - 2/21/2006 3:36:26 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

quote:

ORIGINAL: ebgreen
3) It appears to be using some library functions which you have not posted. That makes this code very hard to be adapted to someone else's environment.

Their original post stated that they would send the libraries and the custom console app via email if required. I have requested them since I'd like to take a look at them.

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to ebgreen)

Post #: 4

RE: Terminal Server Maintenance - 2/21/2006 3:38:31 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

Ehh...reading comrehension is overated.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to kirrilian)

Post #: 5

RE: Terminal Server Maintenance - 2/21/2006 5:10:04 AM

turranx

Posts: 38
Score: 0
Joined: 2/7/2006
Status: offline

HiveEnum.exe is a safer way of obtaining a list of user registry hives than installing the hotfix. This particular hotfix wasn't regression tested. It's not likely to become an official patch, nor find it's way into Win2000 SP5 (if there ever is such a thing). Our development/test TS doesn't suffer from this inability to unload user registry hives, so I couldn't test the hotfix there. Stability of our TS is a major concern of ours and I hesitate to install an untested hotfix on our production TS.

Description of Terminal Server behavior pre-script
The production TS would occasionally display "Out of Registry Space" errors, then inform us it was automatically increasing our registry size. After a week of uptime (from a reboot), the TS became unstable. Users would attempt to log in but would receive one of two results: either the login attempt would "freeze" before the user was presented with a desktop, or they would be presented with a generic Guest desktop and receive a message that their registry hive could not be loaded.

Furthermore, attempts to map to \\Terminal_Server\c$ would fail. The Terminal Services Manager utility I keep on my desktop couldn't connect to our TS.

I had started to think there was a memory leak, so I installed poolmon.exe on our TS and began watching TS like a hawk. Below are some outputs from poolmon.exe.

-------------------------------------------------------------------------------------------------------

Memory: 7601392K Avail: 6611496K PageFlts: 6629   InRam Krnl: 3292K P:109316K
Commit:1072056K Limit:19690960K Peak:2092960K            Pool N:44512K P:109508
Tag Type     Allocs            Frees            Diff   Bytes      Per Alloc

CM   Paged    175897 ( 15)    164321 ( 14)    11576 51532512 (    32)   4451
MmSt Paged    348435 ( 47)    339941 ( 92)     8494 14709856 (-127744)   1731
SavE Nonp    5224418 ( 901)   5223987 ( 901)      431 13320160 (     0) 30905

---------------------------------------------------------------------------------------------------------
System Up Time: 13D 20H
Problem: Zero available System Page

Memory: 7601392K Avail: 6009760K PageFlts: 4538   InRam Krnl: 3192K P:170636K
Commit:1731088K Limit:19690960K Peak:3100648K            Pool N:30240K P:170920
Tag Type     Allocs            Frees            Diff   Bytes      Per Alloc

CM   Paged   1704824 (   4)   1680881 (   4)    23943 107688384 (     0)   4497
RadS Paged 317650747 (1453) 317647866 (1453)     2881 28105376 (     0)   9755
MmSt Paged 11506291 ( 73) 11502628 ( 63)     3663 6899872 ( 25920)   1883

It wasn't until I installed the 'Debugging Tools for Windows' and read C:\Program Files\Debugging Tools for Windows\triage\pooltag.txt that I found out CM = Configuration Manager (registry). I thought CM = Cache Manager from all the reading I did on Microsoft.com. Once I learned the CM process handled the registry, I inspected HKEY_USERS and found many registry hives were loaded for users that weren't currently using the TS. The 'RadS' tag is for the Symantec Antivirus Corporate Edition service.

How I handled the problem without the script
I translated the name of each hive into a userID using GetSID.exe from www.sysinternals.com and made sure that user wansn't logged on. If they weren't logged on to the TS, I'd unload their hive using regedt32.exe. This was a long and drawn out task perfect for automating. As I did this, the Paged Kernel Memory (as is visible in the Performance Tab of Windows Task Manager) would drop from 170000 down to 120000 and responsiveness, connectivity, and user's ablity to log into TS would return to normal.

Alternate Solution
There is a 3rd party utility you can download from Microsoft called UPHClean: http://www.microsoft.com/downloads/details.aspx?FamilyID=1b286e6d-8912-4e18-b570-42470e2f3582&displaylang=en&Hash=SY534SC . Our resident TS expert installed UPHClean on our Test TS, but was unable to make it work properly. It was for this reason I automated the task.

Response to EBGreen
Arrays I tend to use a lot. You're probably right about Dictionaries; I should use them. I just haven't taken the time to learn them. :)

My indentation habbits sometimes swing between tabbing (8 spaces) or just 1 space. It depends on the kind of mood I'm in when I write the script.

I made sure that any objects I instantiated were also destroyed at the end of the loop. Of course, if you find one that I've missed, I'll correct my code.

I've become so used to writing code with On Error Resume Next and writing my own error handling routines, that I usually only enable On Error Goto 0 when I'm debugging. It might seem backwards, but it works for me. :)

The only reason I won't post the libraries is because I want to know who's reading/running/using my code. I'm interested in who's interested in my vbs babble.

G.

_____________________________

Microsoft Windows 2000 Scripting Guide - The best book for newbie scripters
http://www.myspace.com/Evil__Overlord

(in reply to kirrilian)

Post #: 6

RE: Terminal Server Maintenance - 2/21/2006 5:47:12 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

quote:

I made sure that any objects I instantiated were also destroyed at the end of the loop. Of course, if you find one that I've missed, I'll correct my code.

I wasn't concerned with object clean up. Garbage collection has become much better in recent releases of WSH. I was more concerned with the general implications of running an infinite loop. This script looks like it will essentially run constantly forever. I would tink that would be a processor ineficient implementation that's all.

EDIT: Spelling.

< Message edited by ebgreen -- 2/23/2006 1:00:20 AM >

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to turranx)

Revisions: 1 | Post #: 7

RE: Terminal Server Maintenance - 2/22/2006 3:52:30 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

thank you so much for your history and information on why you wrote this script. we are running 2003 on our TS server and have yet to run across this problem, so perhaps they fixed this problem in TS for 2003 but who knows. Our next step as our user base grows is to run a TS server farm with multiple nodes using the built in load balancing for TS, that should be interesting!