File comparison

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

File comparison

Logged in as: Guest

arrSession:exec spGetSession 2,2,31402

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> File comparison
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

File comparison - 2/21/2006 11:58:41 PM

Yukon2005

Posts: 0
Score: 0
Joined: 2/21/2006
Status: offline

Hey all,

I have a question regarding file comparison or string matching... I have a directory full of files that I would like to copy to a "working" folder else move to a "corrupted" folder.

All of the file names have the following structure:

{Username}_{Date}_{Section Type}.txt

JoeSoap_28032006_SectionOne.txt and JoeSoap_28032006_SectionThere.txt or
PietS_13052006_SectionOne.txt and PietSnot_13052006_SectionThere.txt

In theory there should always be two files, "SectionOne.txt" and "SectionThere.txt"

Each filename is unique, i.e. there will always only be one of eah file. Now... I would like to return all the files ending with "Section1.txt" and then find all the "Section2.txt" files associated with the "Section1.txt" file.

Section1 FileName                            |    Section2 FileName                                     |    Action
JoeSoap_28032006_SectionOne.txt    |    JoeSoap_28032006_SectionThere.txt    |    Move to "Working" folder.
PietSnot_13052006_SectionOne.txt    |                                                                   |    Move to "Corrupted" folder.
                                                             |    PietSnot_13052006_SectionThere.txt    |    Move to "Corrupted" folder.
etc.....

Could anybody please point me in the right direction on this. It's pretty urgent I haven't been able to figure it out.

Post #: 1

RE: File comparison - 2/22/2006 2:46:02 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

Here is how I would go about it. Note that this presumes that all the files in the folder are named along the guidelines you presented. If this may not be the case, then you will need to add code to skip files that do not:

Option Explicit
Dim oNameDic
Dim oTempDic
Dim oFSO : Set oFSO = CreateObject("Scripting.FileSystemObject")
Dim oFile
Dim oFolder
Dim arrNameParts
Dim strName
Dim strSection

Set oFolder = oFSO.GetFolder("C:\Temp")
Set oNameDic = CreateObject("Scripting.Dictionary")
For Each oFile In oFolder.Files
   arrNameParts = Split(LCase(oFile.Name), "_")
   strName = arrNameParts(0) & "_" & arrNameParts(1)
   strSection = arrNameParts(2)
   If oNameDic.Exists(strName) Then
       oNameDic(strName)(strSection) = oFile.Name
   Else
       Set oTempDic = CreateObject("Scripting.Dictionary")
       oTempDic.Add "sectionone.txt", ""
       oTempDic.Add "sectionthere.txt", ""
       oNameDic.Add strName, oTempDic
       oNameDic(strName)(strSection) = oFile.Name
   End If
Next
'Now we have a dictionary of all the name-date combinations in the folder along with knowing if they
'have both files. We need to move files based on this info:
For Each strName In oNameDic.Keys()
   If oNameDic(strName)("sectionone.txt") = "" Or oNameDic(strName)("sectionthere.txt") = "" Then
       'One of the files is missing. Copy the other one to corrupted
       For Each strSection In oNameDic(strName).Keys()
           If oNameDic(strName)(strSection) <> "" Then
               WScript.Echo "Copying " & oNameDic(strName)(strSection) & " To Corrupted"
               'PUT COPY COMMAND HERE
           End If
       Next
   Else
       'Both files are present so copy them to working
       For Each strSection In oNameDic(strName).Keys()
           WScript.Echo "Copying " & oNameDic(strName)(strSection) & " To working"
           'PUT COPY COMMAND HERE
       Next
   End If
Next

One more note is that the example data you gave:

Section1 FileName                            |    Section2 FileName                                     |    Action
JoeSoap_28032006_SectionOne.txt    |    JoeSoap_28032006_SectionThere.txt    |    Move to "Working" folder.
PietSnot_13052006_SectionOne.txt    |                                                                   |    Move to "Corrupted" folder.
                                                             |    PietSnot_13052006_SectionThere.txt    |    Move to "Corrupted" folder.

Does not look the way I think you meant it to. In your data, both sections are present for both users so I think they should all be moved to working.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Yukon2005)