.HTA Help

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

.HTA Help

Logged in as: Guest

arrSession:exec spGetSession 2,2,31513

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> .HTA Help
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

.HTA Help - 2/24/2006 7:54:29 AM

DiGiTAL.SkReAM

Posts: 1183
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

Hey folks!
I'm in the beginning stages of putting together a "progress bar" for use in some of my scripts. Eventually, it will probably be a class, but for right now, is a standalone script.
My problem is that while everything else works, I can NOT get the stupid thing to exit the script when I close the .HTA window. For example, there is a cancel button, but when clicked, it does some commands, and I can even end the window at that point, but the vbscript itself continues on. Also, I can close it by using Self.Close(), but then that pops up another dialogue "The window is trying to close itself, blah blah."

As a beginner to .HTA stuff, I copied most of this code from another script where I work, just to get a feelf or it, but the result is that I am lost on this last issue.
Can anyone help?

Const conBarSpeed = 80
StartIE "Progress Bar"
fSetLine1 "Doing Stuff..."
WScript.Sleep(1000)
fSetLine1 "1"
WScript.Sleep(1000)
fSetLine1 "2"
WScript.Sleep(1000)
fSetLine1 "3"
WScript.Sleep(1000)
fSetLine1 "4"
WScript.Sleep(1000)
fSetLine1 "5"
WScript.Sleep(1000)
fSetLine1 "6"
WScript.Sleep(1000)
fSetLine1 "7"
WScript.Sleep(1000)
fSetLine1 "8"
WScript.Sleep(1000)
fSetLine1 "9"
WScript.Sleep(1000)
fSetLine1 "10"
WScript.Sleep(1000)
fSetLine1 "Complete"
WScript.Sleep (3000)
CloseIE
'************************************************************************************************
Function StartIE(strTitle)
   Dim objDocument
   Dim objoShell
   Set objIE = CreateObject("InternetExplorer.Application")
   objIE.height = 230
   objIE.width = 400
   objIE.menubar = False
   objIE.toolbar = false
   objIE.statusbar = false
   objIE.addressbar = false
   'objIE.resizable = False
objIE.Navigate ("about:blank")
   ' wait till ie is loaded
   While (objIE.busy)
   wend
   set objDocument = objIE.document 
WriteHtmlToDialog objDocument,strTitle
   ' with ie/html loaded, define assorted objects...
   set objTextLine1 = objIE.document.all("txtMilestone")
   set objTextLine2 = objIE.document.all("txtRemarks")
   Set objProgressBar = objIE.document.all("pbText")
   set objQuitFlag = objIE.document.Secret.pubFlag
   objTextLine1.innerTEXT = ""
   objTextLine2.innerTEXT = ""
   objIE.visible = True
   ' set focus to ie 
   oShell.AppActivate("Microsoft Internet Explorer")
End Function
'************************************************************************************************
Function CloseIE()
On Error Resume Next
objIE.quit
End Function 
'************************************************************************************************
Function fSetLine1(sNewText)
On Error Resume Next
objTextLine1.innerTEXT = sNewText
End Function 
'************************************************************************************************
Function fSetLine2(sNewText)
On Error Resume Next
objTextLine2.innerTEXT = sNewText
End Function
'************************************************************************************************
Function WriteHtmlToDialog(objDocument, strTitle)
   objDocument.Open
   objDocument.Writeln "<title>" & strTitle & "</title> "
   objDocument.Writeln "<style>"
   objDocument.Writeln " BODY {background: Silver} BODY { overflow:hidden }"
   objDocument.Writeln " P.txtStyle {color: Navy; font-family: Verdana; font-size: 10pt; font-weight: bold; margin-left: 10px } "
   objDocument.Writeln " input.pbStyle {color: navy; font-family: Wingdings; font-size: 10pt; background: Silver; height: 20px; width: 340px } " 
   objDocument.Writeln "</style>"
   objDocument.Writeln "<div id=""objProgress"" class=""Outer""></div>"
   ' write out text lines... 
   objDocument.Writeln "<P id=txtMilestone class='txtStyle' style='margin-left: 10px'> </P>"
   objDocument.Writeln "<P id=txtRemarks class='txtStyle' style='margin-left: 10px' ></P>"
   objDocument.Writeln "<CENTER>"
   ' write progbar
   objDocument.Writeln "<input type='text' id='pbText' class='pbStyle' value='' >" 
   objDocument.Writeln "<br><br>" ' space down a little
   ' write cancel button...
   objDocument.Writeln "<input type='button' value='Cancel' " _
               & " onclick='SetReturnFlag(""quit"")' >"
   objDocument.Writeln "</CENTER>" 
   ' write hidden object...
   objDocument.Writeln "<form name='secret' ><input type='hidden' name='pubFlag' value='run' ></form>" 
   objDocument.Writeln "<SCRIPT LANGUAGE='VBScript' >" 
   ' write "local script" to handle cmdCancel_Click event...
   objDocument.Writeln "Sub SetReturnFlag(sFlag)"
   objDocument.Writeln " secret.pubFlag.Value = sFlag"
   objDocument.Writeln " txtMileStone.style.color = ""Red"" "
   objDocument.Writeln " txtRemarks.style.color = ""Red"" "
   objDocument.Writeln " Self.Close()"
   objDocument.Writeln "End Sub" 
   ' progress bar
   objDocument.Writeln "Function PctComplete(nPct)"
   objDocument.Writeln "pbText.Value = String(nPct,"" "") & String(4,""n"")"
   objDocument.Writeln "End Function"
   ' calc progress bar and direction
   objDocument.Writeln "Sub UpdateProgress()"
   objDocument.Writeln "Dim intStep"
   objDocument.Writeln "Dim intDirection"
   objDocument.Writeln "If (IsNull(objProgress.getAttribute(""Step"")) = True) Then"
   objDocument.Writeln "intStep = 0"
   objDocument.Writeln "Else"
   objDocument.Writeln "intStep = objProgress.Step"
   objDocument.Writeln "End If"
   objDocument.Writeln "if (IsNull(objProgress.GetAttribute(""Direction""))=True) Then"
   objDocument.Writeln "intDirection = 0"
   objDocument.Writeln "Else"
   objDocument.Writeln "intDirection = objProgress.Direction"
   objDocument.Writeln "End If"
   objDocument.Writeln "if intDirection=0 then"
   objDocument.Writeln "intStep = intStep + 1"
   objDocument.Writeln "else"
   objDocument.Writeln "intStep = intStep - 1"
   objDocument.Writeln "end if"
   objDocument.Writeln "Call PctComplete(intStep)"
   objDocument.Writeln "if intStep>=23 then"
   objDocument.Writeln "intDirection=1"
   objDocument.Writeln "end if"
   objDocument.Writeln "if intStep<=0 then"
   objDocument.Writeln "intDirection=0"
   objDocument.Writeln "end if"
   objDocument.Writeln "objProgress.SetAttribute ""Step"", intStep"
   objDocument.Writeln "objProgress.SetAttribute ""Direction"", intDirection"
   objDocument.Writeln "Window.setTimeout GetRef(""UpdateProgress""), " & conBarSpeed
   objDocument.Writeln "End Sub"
   objDocument.Writeln "Sub Window_OnLoad()"
   objDocument.Writeln "theleft = (screen.availWidth - document.body.clientWidth) / 2"
   objDocument.Writeln "thetop = (screen.availHeight - document.body.clientHeight) / 2"
   objDocument.Writeln "window.moveTo theleft,thetop"
   objDocument.Writeln "Window.setTimeout GetRef(""UpdateProgress""), " & conBarSpeed
   objDocument.Writeln "End Sub"
   objDocument.Writeln "</SCRIPT>"
   objDocument.Close 
End Function

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

Post #: 1

RE: .HTA Help - 2/26/2006 9:17:16 AM

Fredledingue

Posts: 383
Score: 0
Joined: 5/9/2005
From:
Status: offline

It doesn't close because the progressbar is launched via IE as html, NOT as hta.

I tested the progressbar page as an hta and it close immediately without warning message. It's just that it's not resizing. Maybe hta doesn't support resizing. (if someone has info about resizing hta, please post)

I tested the script but it does nothing except showing 4 blocks going left and right until I click "cancel". Looks like the data are not transmited from the vbs to the progressbar.

While you may want not to use that method for some reasons, it's much easier to use intermediary file to wirte datas on one side, read these datas on the other side as I do with my progressbar
http://visualbasicscript.com/m_24746/mpage_1/key_progress/tm.htm#24746
Maybe I will do a version of my progressbar in hta...when I have time.

There are also tons of script simplications that can be done in your sample, but that's less important for the moment.

_____________________________

Fred

(in reply to DiGiTAL.SkReAM)

Post #: 2

RE: .HTA Help - 2/26/2006 6:59:51 PM

crazymatt

Posts: 296
Score: 0
Joined: 3/4/2005
From:
Status: offline

I use this on my .hta�s to resize em.

Sub bodyLoaded()
window.ResizeTo 176,140 ' WIDTH, HEIGHT
End Sub

Check my proxyswitcher script under the "Post a VBScript " forum.

Hope it helps.

/CM

_____________________________

-There is only 10 sorts of people, those who understand binary and those who dont.

(in reply to Fredledingue)

Post #: 3

RE: .HTA Help - 2/27/2006 4:08:04 AM

DiGiTAL.SkReAM

Posts: 1183
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

Thanks for the comments, folks.
My direction ont his has changed a little, and I am developing it as a class for use in our includes file.
There is one thing that is bugging me though... when I open the html windows via obj.IE object, the title bar shows
"http://" on the left, then the Title that I assign the window, and then "Microsoft Internet Explorer".
Is there a way, other than running it as an .hta, that i can get this behavior to stop?

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to crazymatt)

Post #: 4

RE: .HTA Help - 3/1/2006 11:06:18 PM

rOOs

Posts: 63
Score: 0
Joined: 2/28/2006
From: Switzerland
Status: offline

This here is my version of showing the User that somethings is going on:

<html>
<head>
<title id="title">StatusDemo</title>
<HTA:APPLICATION 
    ID="StatusDemo"
    APPLICATIONNAME="StatusDemo"
    SCROLL="no"
    SINGLEINSTANCE="yes"
    caption="yes"
    BORDER="yes"
    BORDERSTYLE="normal"
    MAXIMIZEBUTTON="no"
    MINIMIZEBUTTON="yes"
    SYSMENU="no"
    CONTEXTMENU="NO"
    WINDOWSTATE="normal"
    />
<SCRIPT Language="VBScript">
' -------------------------------------------------------------------------------
' ::: StatusDemo :::
' 
' Shows a way of a StatusBar in pure VBScript/HTA where somethings moving While
' operations are in progress ...
'
' Copy it, Use it, Distribute it, Change it, Virus it.....
' 
' -------------------------------------------------------------------------------
' CHANGE-LOG:
' 02.03.06 JOS 1.0 DemoScript
' 
strVer = "1.0"
' -------------------------------------------------------------------------------
' Developers Mail: [email=scripting@stageweb.net]scripting@stageweb.net[/email]
' -------------------------------------------------------------------------------
Set objShell = CreateObject("Wscript.Shell")
Dim strTimer, strTimerCnt
 Sub Window_Onload
 window.resizeTo 320,250
 
 Stats "Init"
 document.title = document.title & " | Version: "&strVer
 ' Subroutines Call here...
 
 Return = objShell.Run("cmd /c pause",,True)
 
 Stats "End"
 
 window.Close
 End Sub
 Sub Stats(strStatus)
 If strStatus = "Init" Then
   strTimer = window.setInterval("Stats('Run')", 50) ' <- ---------------- Change the Value 50 here for the delay in Milliseconds, lower is faster....
 Elseif strStatus = "Run" Then
   If strTimerCnt = "" Then
      strTimerCnt ="�"
   Elseif strTimerCnt = "�" Then
     strTimerCnt =  "\"
   Elseif strTimerCnt = "\" Then
     strTimerCnt = "|"
   Elseif strTimerCnt = "|" Then
     strTimerCnt = "/"
   Elseif strTimerCnt = "/" Then
     strTimerCnt = "�"
   End If
   document.getElementById("Stats").innerHTML = strTimerCnt
 Elseif strStatus = "End" Then
   window.clearInterval(strTimer)
   document.getElementById("Stats").innerHTML = ""
 End If
 End Sub
</SCRIPT>
<style>
body,td,a {font-family:Arial;font-size:12px;text-decoration:none;color:black;}
body {filter:progid:DXImageTransform.Microsoft.Gradient(GradientType=0, StartColorStr='#9999FF', EndColorStr='#FFFFFF')}
.pix {width: 1px; height 1px;}
</style>
</head>
<body>
<center>
<table width="275">
 <tr><td>
   <fieldset><legend align="center"><b> : : : Status : : : </b></legend>
     <br><center>
       <span id=Stats style="font-weight: bold;font-size:20px;"></span>
     </center><br><br>
   </fieldset>
 </td></tr>
</table>
</center>
</body>
</html>

Save it as .hta and let it run. Move the DOS Box away to see what the .hta window shows....

Its like a progress bar. But with no end (you can't always know how long an operation will take, so progressbars are difficult to program)

(in reply to DiGiTAL.SkReAM)

Post #: 5

RE: .HTA Help - 3/3/2006 6:08:22 AM

Country73

Posts: 732
Score: 10
Joined: 8/25/2004
From: USA
Status: offline

Nice little bit of code!

I changed one line in there so that the DOS window wouldn't get in the way.

Return = objShell.Run("cmd /c ping -n 5 " strPC,0,True)

strPC = Machine name

(in reply to rOOs)

Post #: 6

RE: .HTA Help - 3/8/2006 1:21:38 AM

rOOs

Posts: 63
Score: 0
Joined: 2/28/2006
From: Switzerland
Status: offline

thanks ...

i got a new way to do status. If you know how long a script will run, or how much operations you do, then you can make a progressbar that shows the exact progress.

below some lines of code i used. (the object declarations you have to add)

Function StatusBar(actstat)
Dim strHTML

If actstat = "Start" Then

Set FSTAT = fso.GetFile(FSource)
Set ts = FSTAT.OpenAsTextStream(1)
ts.Skip(FSTAT.Size)

FSize = ts.Line
ts.Close
set ts = Nothing

'Explorer Open! yeahh!
strHTML = "<html><body><p><object classid='clsid:35053A22-8589-11D1-B16A-00C0F0283628' id='ProgressBar1' height='20' width='800'><param name='Min' value='0'><param name='Max' value='100'><param name='Orientation' value='0'><param name='Scrolling' value='1'></object></p></body></html>"
Set objExplorer = CreateObject("InternetExplorer.Application")
objExplorer.Navigate "about:blank"
objExplorer.Document.title = "Bitte warten . . ."
objExplorer.Document.body.bgcolor = "buttonface"
objExplorer.Document.body.Innerhtml = strHTML
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Width = 850
objExplorer.Height = 90
objExplorer.Left = 50
objExplorer.Top = 50
objExplorer.Visible = 1

Do While (objExplorer.Busy)
     Wscript.Sleep 200
Loop

intIncrement = 5000/FSize

Elseif actstat = "Inc" Then
objExplorer.Document.Body.All.ProgressBar1.Value = objExplorer.Document.Body.All.ProgressBar1.Value + intIncrement

   Elseif actstat = "Stop" Then
objExplorer.Quit
   End If
End Function

Call StatusBar("Start")
Call StatusBar("Inc")
Call StatusBar("Stop")

The Function reads a textfile and counts how much rows it has, then the script part which i didnt post here executes a subroutine for each line in the textfile, every 50 lines it increases the statusbar with the increase value, and finally if the line number ist equal to the maximum line number, it stops the statusbar...

the statusbar increase value is calculated by the count of lines. then 5000 was divided by number of rows to get the exact increase value...

first i increased the statusbar every line, but then it takes tooooo long to execute, 10 times longer... every 50 line is a good value...

(in reply to Country73)