Output results in a text file instead of display on screen

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Output results in a text file instead of display on screen

Logged in as: Guest

arrSession:exec spGetSession 2,2,31951

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Output results in a text file instead of display on screen
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Output results in a text file instead of display on screen - 3/7/2006 4:23:50 AM

NewBee

Posts: 32
Score: 0
Joined: 2/10/2006
Status: offline

hello

just wanted to find out how can i make the script below to out put the information to a text file instead of displaying it on the screen

thanks in advance,

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colOSes = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
For Each objOS in colOSes
Wscript.Echo "Computer Name: " & objOS.CSName
Wscript.Echo "Caption: " & objOS.Caption 'Name
Wscript.Echo "Version: " & objOS.Version 'Version & build
Wscript.Echo "Build Number: " & objOS.BuildNumber 'Build
Wscript.Echo "Build Type: " & objOS.BuildType
Wscript.Echo "OS Type: " & objOS.OSType
Wscript.Echo "Other Type Description: " & objOS.OtherTypeDescription
WScript.Echo "Service Pack: " & objOS.ServicePackMajorVersion & "." & _
objOS.ServicePackMinorVersion
Next

Post #: 1

RE: Output results in a text file instead of display on... - 3/7/2006 4:40:06 AM

led203

Posts: 1
Score: 0
Joined: 3/7/2006
Status: offline

The following is code that I tested on my system and it works great - thanks for giving me the Idea!

LarryD

===========================================
On Error Resume Next
Dim objFileSystem, objOutputFile
Dim strOutputFile

Const OPEN_FILE_FOR_APPENDING = 8

' Specify the File Name
strOutputFile = "\\server\directory\PC_Stats.log"

Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objFileSystem = CreateObject("Scripting.fileSystemObject")

'Open the File
Set objOutputFile = objFileSystem.OpenTextFile(strOutputFile, OPEN_FILE_FOR_APPENDING)

'If the file does NOT exist - then create it
If err.number = 53 then Set objOutputFile = objFileSystem.CreateTextFile(strOutputFile, TRUE)

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOSes = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")

For Each objOS in colOSes
    objOutputFile.WriteLine("Computer Name: " & objOS.CSName )
    objOutputFile.WriteLine("Caption: " & objOS.Caption) 'Name
    objOutputFile.WriteLine("Version: " & objOS.Version) 'Version & build
    objOutputFile.WriteLine("Build Number: " & objOS.BuildNumber) 'Build
    objOutputFile.WriteLine("Build Type: " & objOS.BuildType )
    objOutputFile.WriteLine("OS Type: " & objOS.OSType )
    objOutputFile.WriteLine("Other Type Description: " & objOS.OtherTypeDescription )
    objOutputFile.WriteLine("Service Pack: " & objOS.ServicePackMajorVersion & "." & objOS.ServicePackMinorVersion )
    objOutputFile.WriteLine(vbcrlf) 'Just for Readability
Next

'Close the file
objOutputFile.Close

(in reply to NewBee)

Post #: 2

RE: Output results in a text file instead of display on... - 3/7/2006 7:07:01 AM

hamboy

Posts: 94
Score: 6
Joined: 7/11/2005
Status: offline

This should work..

(in reply to led203)

Post #: 3

RE: Output results in a text file instead of display on... - 3/7/2006 8:43:38 AM

NewBee

Posts: 32
Score: 0
Joined: 2/10/2006
Status: offline

thanks for your inputs, i have taken the script and added manufacture, model, physical memory and CPU info. this is very handy script for system admins that need to collect info about their servers

On Error Resume Next
Dim objFileSystem, objOutputFile
Dim strOutputFile
Const OPEN_FILE_FOR_APPENDING = 8
' Specify the File Name
strOutputFile = "\\server name\share\PC_Stats.log"
Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objFileSystem = CreateObject("Scripting.fileSystemObject")
'Open the File
Set objOutputFile = objFileSystem.OpenTextFile(strOutputFile, OPEN_FILE_FOR_APPENDING)
'If the file does NOT exist - then create it
If err.number = 53 then Set objOutputFile = objFileSystem.CreateTextFile(strOutputFile, TRUE)
strComputer = "computer name"
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem")
Set colOSes = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
Set colCSItems = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem")
For Each objItem In colItems
    objOutputFile.WriteLine"Computer Name: " & objItem.Name
    objOutputFile.WriteLine"Manufacturer: " & objItem.Manufacturer
    objOutputFile.WriteLine"Model: " & objItem.Model
next
For Each objCSItem In colCSItems
    objOutputFile.WriteLine"Total Physical Memory: " & objCSItem.TotalPhysicalMemory
Next
For Each objOS in colOSes
    objOutputFile.WriteLine"Caption: " & objOS.Caption 'Name
    objOutputFile.WriteLine"Version: " & objOS.Version 'Version & build
    objOutputFile.WriteLine"Build Number: " & objOS.BuildNumber 'Build
    objOutputFile.WriteLine"Build Type: " & objOS.BuildType
    objOutputFile.WriteLine"OS Type: " & objOS.OSType
    objOutputFile.WriteLine"Other Type Description: " & objOS.OtherTypeDescription
    objOutputFile.WriteLine"Service Pack: " & objOS.ServicePackMajorVersion & "." & objOS.ServicePackMinorVersion
    objOutputFile.WriteLine"Computer Name: " & objCS.Name
    objOutputFile.WriteLine"System Type: " & objCS.SystemType
    objOutputFile.WriteLine"Number Of Processors: " & objCS.NumberOfProcessors
Next
Set colProcessors = objWMIService.ExecQuery("Select * from Win32_Processor")
For Each objProcessor in colProcessors
    objOutputFile.WriteLine"Manufacturer: " & objProcessor.Manufacturer
    objOutputFile.WriteLine"Name: " & objProcessor.Name
    objOutputFile.WriteLine"Description: " & objProcessor.Description
    objOutputFile.WriteLine"Processor ID: " & objProcessor.ProcessorID
    objOutputFile.WriteLine"Address Width: " & objProcessor.AddressWidth
    objOutputFile.WriteLine"Data Width: " & objProcessor.DataWidth
    objOutputFile.WriteLine"Family: " & objProcessor.Family
    objOutputFile.WriteLine"Maximum Clock Speed: " & objProcessor.MaxClockSpeed
    objOutputFile.WriteLine(vbcrlf) 'Just for Readability

Next
'Close the file
objOutputFile.Close

(in reply to NewBee)

Post #: 4

RE: Output results in a text file instead of display on... - 3/7/2006 9:29:29 AM

vbsnovice

Posts: 21
Score: 0
Joined: 11/1/2005
Status: offline

Hi all,

Here is another way of getting a Network Computer Inventory info in your domain, I found this script very handy when the need arises. There are 2 seperate scripts involved in this procedure:
1. Create-IP-Table.vbs and
2. SMS-PC-Inventory.vbs
Enjoy...

Script 1. Create-IP-Table

Script 2. SMS-PC-Inventory.vbs

=================================================================
'Author: Clark Caldwell
'
'Description:
'Network computer inventory in a Excel spreadsheet.
'
'****** Script 2 of 2 ******
'Script 2 of 2
'Start 2 of 2
'**********************************************
'Date: 03/26/2005
'Title: SMS-PC-Inventory.vbs
'Version: 1.06
'Authors: Alex Angelopoulos/Torgeir Bakken/Clark Caldwell
'Use: Create network computer inventory in an Excel Spreadsheet.
'Comments:
'Must have ADSI and WMI installed on PC running script.
'
'Must have Excel!
'
'Must have Admin rights on machines you connect to.
'
'If a computer cannot be contacted then it will write that IP to
'PC_Inv_NA.txt outputfile.
'
'Windows XP SP 2 firewall will block this script, turn it off
'manualy or through a GPO.
'
'Must create the PC_Inv_IP.txt file with the provided script or
'manualy with IP addresses.
'
'Email ccaldwell@dblair.com with problems/sugestions.
'
'***********************************************
'***** DECLARATIONS*****************************
CONST ForReading = 1 
CONST ForWriting = 2 
CONST DEV_ID = 0 
CONST FSYS = 1 
CONST DSIZE = 2 
CONST FSPACE = 3 
CONST USPACE = 4 
CONST TITLE = "SMS-PC-Inventory" 
Dim fso, f, fsox, fx, objXL, wmiPath, strNoPing, strMBProduct
Dim computerIndex, wscr, adsi, intbutton, strStart, Cshell, strNoConnect
Dim inputFile, outputFile, objKill, strAction, strComplete, strManufact
Dim strPC, intRow, strFilter, RowNum, strCompName, strVideo, strFSB
Dim strDEV_ID, strFSYS, strDSIZE, strFSPACE, strUSPACE, strSD 
Dim strRAM, strVir, strPage, strOS, strSP, strProdID, strStatic, strUser 
Dim strNIC, strIP, strMask, strGate, strMAC, strProc, strSpeed, strHostName
Set objExplorer = WScript.CreateObject("InternetExplorer.Application")
objExplorer.Navigate "Scanning..."
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Width = 200
objExplorer.Height = 80 
objExplorer.Left = 200
objExplorer.Top = 200
set adsi = CreateObject("ADSystemInfo") 
set wscr = CreateObject("WScript.Network") 
inputFile = "PC_Inv_IP.txt" 
outputFile = "PC_Inv_NA.txt" 
Call KillFile()
set fso = CreateObject("Scripting.FileSystemObject") 
set f = fso.OpenTextFile(inputFile, ForReading, True) 
set fsox = CreateObject("Scripting.FileSystemObject") 
set fx = fsox.OpenTextFile(outputFile, ForWriting, True)
Set Cshell = CreateObject("WScript.Shell")
computerIndex = 1 
'*****[ FUNCTIONS ]******************************* 
Function Ask(strAction) 
intButton = MsgBox(strAction, vbQuestion + vbYesNo, TITLE) 
Ask = intButton = vbNo 
End Function 
'*****[ MAIN SCRIPT ]*****************************
If Ask("Run Network Inventory?") Then 
Wscript.Quit 
Else 
strStart = "Inventory run started: " & Date & " at " & time
End If 
Call BuildXLS() 
Call Connect() 
Call Footer()
objExplorer.Quit
objXL.ActiveWorkbook.SaveAs "SMS-Network-Inventory.xls" 
MsgBox "Your inventory run has completed!", vbInformation + vbOKOnly, TITLE
'*****[ SUB ROUTINES ]****************************
'*** Subroutine Connect *** 
Sub Connect()
  Do While f.AtEndOfLine <> True
      strPC = f.ReadLine
      If strPC <> "" Then
          If Not IsConnectible(strpc, "", "") Then
              strNoPing = "Couldn't ping " & strPC
              Call MsgNoPing()
              Call Error()
          Else
              On Error Resume Next
              set oWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!//" & strPC & "/root/cimv2")
              If Err.Number <> 0 Then
              strNoConnect = "Couldn't connect to " & strPC
              Call MsgNoConnect()
              Call Error()
          Else
                  strCompName = UCase(strPC)
                  set SDSet = oWMI.ExecQuery("select SocketDesignation from Win32_Processor")
                  for each SD in SDSet
                      strSD = SD.SocketDesignation
                  Next
                  set MemorySet = oWMI.ExecQuery("select TotalPhysicalMemory, " & "TotalVirtualMemory, TotalPageFileSpace from " & "Win32_LogicalMemoryConfiguration")
                  for each Memory in MemorySet
                      strRAM = FormatNumber(Memory.TotalPhysicalMemory/1024,1) & " Mb"
                      strVir = FormatNumber(Memory.TotalVirtualMemory/1024,1) & " Mb"
                      strPage = FormatNumber(Memory.TotalPageFileSpace/1024,1) & " Mb"
                  Next
                  set OSSet = oWMI.ExecQuery("select Caption, CSDVersion, SerialNumber " & "from Win32_OperatingSystem")
                  for each OS in OSSet
                      strOS = OS.Caption
                      strSP = OS.CSDVersion
                      strProdID = OS.SerialNumber
                  Next
                  set IPConfigSet = oWMI.ExecQuery("select ServiceName, IPAddress, " & "IPSubnet, DefaultIPGateway, MACAddress from " & "Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
                  Count = 0
                  for each IPConfig in IPConfigSet
                   Count = Count + 1
                  Next
                  ReDim sName(Count - 1)
                  ReDim sIP(Count - 1)
                  ReDim sMask(Count - 1)
                  ReDim sGate(Count - 1)
                  ReDim sMAC(Count - 1)
                  Count = 0
                  for each IPConfig in IPConfigSet
                      sName(Count) = IPConfig.ServiceName(0)
                      strNIC = sName(Count)
                      sIP(Count) = IPConfig.IPAddress(0)
                   strIP = sIP(Count)
                   sMask(Count) = IPConfig.IPSubnet(0)
                   strMask = sMask(Count)
                   sGate(Count) = IPConfig.DefaultIPGateway(0)
                   strGate = sGate(Count)
                   sMAC(Count) = IPConfig.MACAddress(0)
                   strMAC = sMAC(Count)
                      Count = Count + 1
                  Next
                  set ProSet = oWMI.ExecQuery("select Name, MaxClockSpeed from Win32_Processor")
                  for each Pro in ProSet
                      strProc = Pro.Name
                      strSpeed = Pro.MaxClockSpeed & " Hz"
                  Next
                  set HostName = oWMI.ExecQuery("select DNSHostName from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
                  for each Host in HostName
                      strHostName = Host.DNSHostName
                  Next
                  set VideoMem = oWMI.ExecQuery("select AdapterRAM from Win32_VideoController")
                  for each Video in VideoMem
                      strVideo = FormatNumber(Video.AdapterRAM/2^20,1) & " Mb"
                  Next
                  
                  set loggeduser = oWMI.ExecQuery("select UserName from Win32_ComputerSystem")
                  for each logged in loggeduser
                      struser = logged.UserName
                  Next
                  set FSBSpeed = oWMI.ExecQuery("select ExtClock from Win32_Processor")
                  for each FSB in FSBSpeed
                      strFSB = FSB.ExtClock & " Mhz"
                  Next
                  set Manufact = oWMI.ExecQuery("select Manufacturer from Win32_BaseBoard")
                  for each Man in Manufact
                      strManufact = Man.Manufacturer
                  Next
                  set MBProduct = oWMI.ExecQuery("select Product from Win32_BaseBoard")
                  for each MBP in MBProduct
                      strMBProduct = MBP.Product

Next
                  set DiskSet = oWMI.ExecQuery("select DeviceID, FileSystem, Size, FreeSpace " & "from Win32_LogicalDisk where DriveType = '3'")
                  ReDim strDisk(RowNum,4)
                  for each Disk in DiskSet
                      strDisk(RowNum,DEV_ID)= Disk.DeviceID
                      strDisk(RowNum,FSYS)= Disk.FileSystem
                      strDisk(RowNum,DSIZE)= FormatNumber(Disk.Size/2^30,1) & " Gb"
                      strDisk(RowNum,FSPACE)= FormatNumber(Disk.FreeSpace/2^30,1) & " Gb"
                      strDisk(RowNum,USPACE)= FormatNumber((Disk.Size-Disk.FreeSpace)/2^30,1) & " Gb"
                      Call AddLineToXLS(strCompName, strHostName, strOS, strSP, strProdID, strProc, strSpeed, strSD, strFSB, strManufact, strMBProduct, strDisk(RowNum,DEV_ID), strDisk(RowNum,FSYS), strDisk(RowNum,DSIZE), strDisk(RowNum,FSPACE), strDisk(RowNum,USPACE), strVideo, strRAM, strVir, strPage, strUser, strNIC, strMask, strGate)    
                  Next
              End If
          End If
      End If
  Loop
End Sub

'*** Subroutine Build XLS ***
Sub BuildXLS() 
intRow = 1 
Set objXL = Wscript.CreateObject("Excel.Application") 
objXL.Visible = True 
objXL.WorkBooks.Add
objXL.Sheets("Sheet1").Select()
objXL.Sheets("Sheet1").Name = "Network Inventory"

'** Set Row Height 
objXL.Rows(1).RowHeight = 25 
'** Set Column widths 
objXL.Columns(1).ColumnWidth = 11
objXL.Columns(2).ColumnWidth = 10 
objXL.Columns(3).ColumnWidth = 32
objXL.Columns(4).ColumnWidth = 12
objXL.Columns(5).ColumnWidth = 20
objXL.Columns(6).ColumnWidth = 23
objXL.Columns(7).ColumnWidth = 7
objXL.Columns(8).ColumnWidth = 7
objXL.Columns(9).ColumnWidth = 7 
objXL.Columns(10).ColumnWidth = 29 
objXL.Columns(11).ColumnWidth = 10
objXL.Columns(12).ColumnWidth = 6 
objXL.Columns(13).ColumnWidth = 7 
objXL.Columns(14).ColumnWidth = 7 
objXL.Columns(15).ColumnWidth = 7 
objXL.Columns(16).ColumnWidth = 7 
objXL.Columns(17).ColumnWidth = 7
objXL.Columns(18).ColumnWidth = 9
objXL.Columns(19).ColumnWidth = 9
objXL.Columns(20).ColumnWidth = 9
objXL.Columns(21).ColumnWidth = 14 
objXL.Columns(22).ColumnWidth = 7
objXL.Columns(23).ColumnWidth = 10
objXL.Columns(24).ColumnWidth = 10
'*** Set Cell Format for Column Titles ***
objXL.Range("A1:X1").Select 
objXL.Selection.Font.Bold = True
objXL.Selection.Font.Size = 8 
objXL.Selection.Interior.ColorIndex = 11 
objXL.Selection.Interior.Pattern = 1 'xlSolid 
objXL.Selection.Font.ColorIndex = 2 
objXL.Selection.WrapText = True 
objXL.Columns("A:X").Select 
objXL.Selection.HorizontalAlignment = 3 'xlCenter 
'*** Set Column Titles ***
Call AddLineToXLS("Scanned IP","HostName","Operating System","Service Pack","Product ID","Processor Type","CPU Speed","Socket Type","Bus Speed","MotherBoard Manufacture","MB Product","Device ID","File System","Disk Size","Free Space","Used Space","Video Memory","Physical Memory","Virtual Memory","Page File","Logged on User"," Network Card","Subnet Mask","Default Gateway") 
objExplorer.Visible = 1 
objExplorer.Document.Body.InnerHTML = "..."
End Sub 
'*** Subroutine Add Lines to XLS *** 
objXL.Columns("A:X").Select 
objXL.Selection.HorizontalAlignment = 3 'xlCenter
objXL.Selection.Font.Size = 8
Sub AddLineToXLS(strCompName, strHostName, strOS, strSP, strProdID, strProc, strSpeed, strSD, strFSB, strManufact, strMBProduct, strDEV_ID, strFSYS, strDSIZE, strFSPACE, strUSPACE, strVideo, strRAM, strVir, strPage, strUser, strNIC, strMask, strGate) 
  objXL.Cells(intRow, 1).Value = strCompName
  objXL.Cells(intRow, 2).Value = strHostName 
  objXL.Cells(intRow, 3).Value = strOS
  objXL.Cells(intRow, 4).Value = strSP 
  objXL.Cells(intRow, 5).Value = strProdID 
  objXL.Cells(intRow, 6).Value = strProc 
  objXL.Cells(intRow, 7).Value = strSpeed 
  objXL.Cells(intRow, 8).Value = strSD
  objXL.Cells(intRow, 9).Value = strFSB
  objXL.Cells(intRow, 10).Value = strManufact
  objXL.Cells(intRow, 11).Value = strMBProduct
  objXL.Cells(intRow, 12).Value = strDEV_ID
  objXL.Cells(intRow, 13).Value = strFSYS
  objXL.Cells(intRow, 14).Value = strDSIZE
  objXL.Cells(intRow, 15).Value = strFSPACE
  objXL.Cells(intRow, 16).Value = strUSPACE 
  objXL.Cells(intRow, 17).Value = strVideo
  objXL.Cells(intRow, 18).Value = strRAM 
  objXL.Cells(intRow, 19).Value = strVir 
  objXL.Cells(intRow, 20).Value = strPage
  objXL.Cells(intRow, 21).Value = strUser
  objXL.Cells(intRow, 22).Value = strNic
  objXL.Cells(intRow, 23).Value = strMask
  objXL.Cells(intRow, 24).Value = strGate
  intRow = intRow + 1 
  objXL.Cells(1, 1).Select 
End Sub 
'*** Subroutine Add Lines to XLS for Disk Info. ***
objXL.Columns("A:W").Select 
objXL.Selection.HorizontalAlignment = 3 'xlCenter
objXL.Selection.Font.Size = 8 
Sub AddLineToDisk(strDEV_ID, strFSYS, strDSIZE, strFSPACE, strUSPACE) 
  objXL.Cells(intRow, 11).Value = strDEV_ID 
  objXL.Cells(intRow, 12).Value = strFSYS 
  objXL.Cells(intRow, 13).Value = strDSIZE 
  objXL.Cells(intRow, 14).Value = strFSPACE 
  objXL.Cells(intRow, 15).Value = strUSPACE 
  intRow = intRow + 1 
  objXL.Cells(1, 1).Select 
End Sub

'*** Delete file if exists *** 
Sub KillFile() 
  Set objKill = CreateObject("Scripting.FileSystemObject") 
  If (objKill.FileExists("PC_Inv_NA.txt")) Then 
  objKill.DeleteFile("PC_Inv_NA.txt") 
End If 
  Set objKill = Nothing 
End Sub 
'*** Sub to add footer when speadsheet is complete *** 
Sub Footer() 
strFooter1 = "DBlair Ltd. Computer Services"
strFooter2 = "Script Modified by Clark Caldwell for Hardware Inventory"
strComplete = "Inventory run completed at: " & Date & " at " & time 
intRow = intRow + 2 
'** Set Cell Format for Row
objXL.Cells(intRow, 2).Select 
objXL.Selection.Font.ColorIndex = 1 
objXL.Selection.Font.Size = 8 
objXL.Selection.Font.Bold = False 
objXL.Selection.HorizontalAlignment = 2 'xlRight
objXL.Cells(intRow, 2).Value = strFooter1 
intRow = intRow + 1 
'** Set Cell Format for Row 
objXL.Cells(intRow, 2).Select 
objXL.Selection.Font.ColorIndex = 1 
objXL.Selection.Font.Size = 8 
objXL.Selection.Font.Bold = False 
objXL.Selection.HorizontalAlignment = 2 'xlRight 
objXL.Cells(intRow, 2).Value = strFooter2 
intRow = intRow + 1 
'** Set Cell Format for Row 
objXL.Cells(intRow, 2).Select 
objXL.Selection.Font.ColorIndex = 1 
objXL.Selection.Font.Size = 8 
objXL.Selection.Font.Bold = False 
objXL.Selection.HorizontalAlignment = 2 'xlRight 
objXL.Cells(intRow, 2).Value = strStart 
intRow = intRow + 1 
'** Set Cell Format for Row 
objXL.Cells(intRow, 2).Select 
objXL.Selection.Font.ColorIndex = 1 
objXL.Selection.Font.Size = 8 
objXL.Selection.Font.Bold = False 
objXL.Selection.HorizontalAlignment = 2 'xlRight 
objXL.Cells(intRow, 2).Value = strComplete 
intRow = intRow + 1 
End Sub 
'*** ErrorHandler *** 
Sub Error() 
fx.WriteLine(strPC)
End Sub 
'*** Ping Host Timeout *** 
Function IsConnectible(sHost, iPings, iTO) 
' Returns True or False based on the output from ping.exe 
' 
' Author: Alex Angelopoulos/Torgeir Bakken 
' Works an "all" WSH versions 
' sHost is a hostname or IP 
' iPings is number of ping attempts 
' iTO is timeout in milliseconds 
' if values are set to "", then defaults below used

Const OpenAsASCII = 0 
Const FailIfNotExist = 0 
Const ForReading = 1 
Dim oShell, oFSO, sTempFile, fFile
If iPings = "" Then iPings = 2 
If iTO = "" Then iTO = 750 
Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject") 
sTempFile = oFSO.GetSpecialFolder(2).ShortPath & "\" & oFSO.GetTempName
oShell.Run "%comspec% /c ping.exe -n " & iPings & " -w " & iTO & " " & sHost & ">" & sTempFile, 0 , True 
Set fFile = oFSO.OpenTextFile(sTempFile, ForReading, FailIfNotExist, OpenAsASCII) 
Select Case InStr(fFile.ReadAll, "TTL=")
Case 0 IsConnectible = False 
Case Else IsConnectible = True 
End Select 
fFile.Close
oFSO.DeleteFile(sTempFile) 
End Function
Sub MsgNoPing()
Set objIE = WScript.CreateObject("InternetExplorer.Application")
objIE.Navigate("about:blank")
objIE.ToolBar = 0
objIE.StatusBar = 0
objIE.Width= 200
objIE.Height = 100 
objIE.Left = 400
objIE.Top = 400
Set objDoc = objIE.Document.Body
strHTML = strNoPing
objDoc.InnerHTML = strHTML
objIE.Visible = True
WScript.Sleep 2500
objIE.Quit
End Sub
Sub MsgNoConnect()
Set objIE2 = WScript.CreateObject("InternetExplorer.Application")
objIE2.Navigate("about:blank")
objIE2.ToolBar = 0
objIE2.StatusBar = 0
objIE2.Width= 200
objIE2.Height = 100 
objIE2.Left = 400
objIE2.Top = 400
Set objDoc = objIE2.Document.Body
strHTML = strNoConnect
objDoc.InnerHTML = strHTML
objIE2.Visible = True
WScript.Sleep 2500
objIE2.Quit
End Sub
=================================================================

< Message edited by vbsnovice -- 3/7/2006 9:51:20 AM >

_____________________________

Cheers,
VBSnovice

(in reply to NewBee)

Post #: 5

RE: Output results in a text file instead of display on... - 3/7/2006 9:37:02 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Please, please, please edit your post and put your code into a [code][/code] block or simply highlight all of your code and click the <% button just above the edit box.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to vbsnovice)

Post #: 6

RE: Output results in a text file instead of display on... - 3/7/2006 9:52:22 AM

vbsnovice

Posts: 21
Score: 0
Joined: 11/1/2005
Status: offline

Oops, sorry dude! please dont get mad at me as I'm just a novice

_____________________________

Cheers,
VBSnovice

(in reply to ebgreen)

Post #: 7

RE: Output results in a text file instead of display on... - 3/7/2006 9:54:13 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Not mad, just need to buy a new scroll wheel for my mouse now.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to vbsnovice)

Post #: 8

RE: Output results in a text file instead of display on... - 3/7/2006 9:59:48 AM

vbsnovice

Posts: 21
Score: 0
Joined: 11/1/2005
Status: offline

ebgreen, I got a spare MS InteliMouse would you like me to email you?

_____________________________

Cheers,
VBSnovice

(in reply to ebgreen)

Post #: 9

RE: Output results in a text file instead of display on... - 3/7/2006 10:02:32 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

I think I should be able to muddle through, thanks though.

(in reply to vbsnovice)

Post #: 10

RE: Output results in a text file instead of display on... - 3/7/2006 10:04:41 AM

vbsnovice

Posts: 21
Score: 0
Joined: 11/1/2005
Status: offline

No thank You

, I've learned a lot of tricks from you guys, thanks everyone in this super forum.

_____________________________

Cheers,
VBSnovice

(in reply to ebgreen)

Post #: 11

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Output results in a text file instead of display on screen

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts