Modify Boot INI

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Modify Boot INI

Logged in as: Guest

arrSession:exec spGetSession 2,16,33091

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Modify Boot INI
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Modify Boot INI - 4/4/2006 1:29:52 PM

SteveWilliams

Posts: 1
Score: 0
Joined: 4/4/2006
Status: offline

This is a script I wrote for extra credit in a scripting class I was taking. it's not all that groundbreaking, and I am sure there are probably other ways to accomplish what it does, but I did comment it extensively to explain what is happening and why, so it may be a good script for someone who is learning how to script or for someone who is teaching scripting to use with their students. Functionally, it will modify the boot.ini file to reduce the timeout value by one second each time it's run. Because it was written to modify a "fake" boot.ini file, the path to the file is stored in a variable. In reality, this would, of course, almost always be c:\. It also goes through the process of removing the read only attribute from the boot.ini, creating a backup, and restoring the read-only flag when it's done.

' Boot File Updater
' Steve Williams

' Objective:     Edit the boot.ini file to decrease the timeout value by one second

Option Explicit

dim strFileLocation    ' The location of files used in the script.
dim strBootFile        ' The name of the boot file
dim strBootBackup    ' The name of the backup boot.ini file
dim strCurrentLine    ' The Current Line from the boot.ini file
dim intTimeOut        ' The Timeout Value
dim intTimePos        ' Position of the word Timeout

dim objFSO        ' Object to hold the File System Object
dim objBootFile        ' Object to hold the boot.ini file
dim objBootBackup    ' Object to hold the backup boot.ini file

const ForReading = 1
const ForWriting = 2
const ForAppending = 8

strFileLocation = "C:\" 
strBootFile    = strFileLocation & "\boot.ini"
strBootBackup     = strFileLocation & "\boot.old"

wscript.echo " **************************************** "
wscript.echo " *           Boot File Updater          * "
wscript.echo " *       Written By Steve Williams      * "
wscript.echo " **************************************** "
wscript.echo " "

Set objFSO = CreateObject("Scripting.FileSystemObject")

if objFSO.FileExists (strBootFile) then 
   
  ' Since the boot.ini file is a critical system file, we want to back it up before 
  ' we begin working with it.

if objFSO.FileExists (strBootBackup) then
     wscript.echo "Removing old BOOT.INI backup file..."
     set objBootBackup = objFSO.GetFile (strBootBackup)
     ' If the Backup File is ReadOnly, we need to remove the ReadOnly attribute
     if (objBootBackup.attributes AND 1) then 
        objBootBackup.attributes = (objBootBackup.attributes XOR 1)
     end if
     ' Now we can get rid of the old backup file
     objFSO.DeleteFile (strBootBackup)
  end if

' We now know there is no existing backup file and can copy the new one in

wscript.echo "Backing up existing BOOT.INI file to " & strBootBackup & "..."
  objFSO.CopyFile strBootFile, strBootBackup

' To be safe, we'll now set the read only attribute on the backup file to prevent 
  ' accidentally causing damage to the sytem.

Set objBootBackup = objFSO.GetFile (strBootBackup)
  if NOT (objBootBackup.attributes AND 1) then 
     objBootBackup.attributes = (objBootBackup.attributes XOR 1)
  end if

' Now that we're ready to work with the boot.ini file, we need to make sure we 
  ' are able to by turning off its Read Only attribute

set objBootFile = objFSO.GetFile (strBootFile)
  if (objBootFile.attributes AND 1) then 
     objBootFile.attributes = (objBootFile.attributes XOR 1)
  end if

' Now we can open our backup for reading and our boot.ini for writing.

set objBootBackup     = objFSO.OpenTextFile(strBootBackup, ForReading)
  set objBootFile    = objFSO.OpenTextFile(strBootFile, ForWriting)

Do Until objBootBackup.AtEndOfStream
     strCurrentLine = objBootBackup.ReadLine
     if InStr(strCurrentLine, "timeout") <> 0 then
        intTimePos = Instr(strCurrentLine, "=") + 1
        intTimeOut = Mid( strCurrentLine, intTimePos)
    wscript.echo "Current timeout value is " & intTimeout
    intTimeout = intTimeout - 1
        wscript.echo "Setting New Timeout Value to " & intTimeout
        objBootFile.WriteLine "timeout=" & intTimeout
     else
    objBootFile.WriteLine strCurrentLine
     end if
  Loop

wscript.echo "Finished Updating Boot.ini...Closing Files"
  objBootFile.close
  objBootBackup.close

' Let's set the boot.ini file back to read only now.

set objBootFile = objFSO.Getfile (strBootFile)
  if NOT (objBootFile.attributes AND 1) then 
     objBootFile.attributes = (objBootFile.attributes XOR 1)
  end if
else
  wscript.echo "Specified Boot File Does Not Exist.  Script can not continue."
end if