List Domain Controllers

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

List Domain Controllers

Logged in as: Guest

arrSession:exec spGetSession 2,16,33275

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> List Domain Controllers
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

List Domain Controllers - 4/8/2006 3:23:26 PM

DiGiTAL.SkReAM

Posts: 1146
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

I was writing a script for a client, and discovered that I needed a way to list all of the domain controllers in a domain, no matter if they had been moved out of the default OU or not.
I did some searching on Google, and came across the Scripting Guys way of listing them, modified it a bit, and came up with this function that you can just plug into your code:

Function fGetDCList()
' AUTHOR: DiGiTAL SkReAM
' CONTACT: digital.skream@gmail.com
' DATE  : 4/8/2006
' COMMENT: Will return a list of all of the Domain Controllers in an
'        Active Directory domain.
Dim oRoot, sConfigNamingContext, oADOConnection, oADOCommand, sADOQuery
Dim oRecordSet, oDC, oSite, oCat, iErr
fGetDCList = "N/A"
On Error Resume Next 
Set oRoot = GetObject("LDAP://RootDSE")
iErr = Err.Number
On Error GoTo 0 
If iErr = 0 Then 
 sConfigNamingContext = oRoot.Get("configurationNamingContext")
 Set oADOCommand = CreateObject("ADODB.Command")
 Set oADOConnection = CreateObject("ADODB.Connection")
 oADOConnection.Provider = "ADsDSOObject"
 oADOConnection.Open "Active Directory Provider"
 oADOCommand.ActiveConnection = oADOConnection
 sADOQuery = "<LDAP://" & sConfigNamingContext & ">;(ObjectClass=nTDSDSA);AdsPath;subtree"
 oADOCommand.CommandText = sADOQuery
 oADOCommand.Properties("Page Size") = 100
 oADOCommand.Properties("Timeout") = 30
 oADOCommand.Properties("Cache Results") = False
 Set oRecordSet = oADOCommand.Execute
 Set oCat = New StringCat
  Do Until oRecordSet.EOF
    Set oDC = GetObject(GetObject(oRecordSet.Fields("AdsPath")).Parent)
    oCat "Netbios_Name : " & oDC.cn
    '"FQDN : " & oDC.DNSHostName & VbCrLf 
    oRecordSet.MoveNext
  Loop
 oADOConnection.Close
 fGetDCList = oCat.Flush
End If 
End Function

EDIT: Added some error checking for times when a DC is not available. The function will then return "N/A", which you can change to suit your own warped and twisted little worlds.

< Message edited by DiGiTAL.SkReAM -- 4/8/2006 3:46:38 PM >

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

Revisions: 2 | Post #: 1

RE: List Domain Controllers - 4/10/2006 1:44:28 AM

hopsbarleyman

Posts: 9
Score: 0
Joined: 1/17/2006
Status: offline

That is a great piece of code to enumerate DC's. I wrote a quick script about a year ago that uses the nTDSDSA object you demonstrated in enumerating DC's within the forest,queries them for specific attributes, and sends the output to a formatted Excel spreadsheet. Thought I'd offer it up as a good starting example that can be easily modified to include/omiit other attributes as needed for reporting on different AD environments.

'==========================================================================
' VBScript Source File 
'
' NAME: DC_Info
'
' AUTHOR: hopsbarleyman
' DATE  : 11/2/2004
'
' COMMENT: Queries all DC's in the forest and enumerates specific info by
'   domain into Excel.
'==========================================================================
'<-- BEGIN Excel Check -->
' Ensure Excel is installed locally
'On Error Resume Next
Set objExcel = CreateObject("Excel.Application")
If Err.Number <> 0 Then
 On Error GoTo 0
 WScript.Echo "Excel application not found."
 WScript.Quit
End If
On Error GoTo 0
'<-- END Excel Check -->
'<-- BEGIN Domain Enumeration -->
' Enumerate all domains in the current forest
On Error Resume Next
Set objShell = WScript.CreateObject("Wscript.Shell")
Set objRootDSE = GetObject("LDAP://RootDSE")
strADsPath =  "<GC://" & objRootDSE.Get("rootDomainNamingContext") & ">;"
strFilter  = "(objectcategory=domainDNS);"
strAttrs   = "distinguishedname;"
strScope   = "SubTree"
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
objName = objFSO.GetTempName
objTempFile = objName
Set outfile = objFSO.OpenTextFile(objTempFile, 2, True)
Set objConn = CreateObject("ADODB.Connection")
objConn.Provider = "ADsDSOObject"
objConn.Open "Active Directory Provider"
Set objRS = objConn.Execute(strADsPath & strFilter & strAttrs & strScope)
objRS.MoveFirst
While Not objRS.EOF
   outfile.writeline objRS.Fields(0).Value
   objRS.MoveNext
Wend
outfile.close
' Read domains into an Array
Set infile = objFSO.OpenTextFile(objTempFile)
str = infile.ReadAll()
SvrArray = Split(str, VbCrLf)
s=1
objTextFile.Close
objFSO.DeleteFile(objTempFile)
'<-- END Domain Enumeration -->
'<-- BEGIN Main Script Processes -->
For Each strDom In SvrArray
' Regular expressions to format domain names
Set regex = CreateObject("VBScript.RegExp")
regex.Pattern = "DC=" 
regex.Global = True 
regex.IgnoreCase = True
ReplacedString = regex.Replace(strDom, "")
regex.Pattern = ","
ReplacedString = regex.Replace(ReplacedString, ".")
regex.Pattern = "DC="
strExcelPath = "c:\Scripts\DC_Info.xls"
strDomain = ReplacedString
' Create Excel workbook
If s = 1 Then
 objExcel.Workbooks.Add
 objExcel.ActiveWorkbook.Worksheets.Add
 objExcel.ActiveWorkbook.Worksheets.Add
End If
Set objSheet = objExcel.ActiveWorkbook.Worksheets(s)
objSheet.Name = UCase(strDomain)
objSheet.Range("A1:F75").Font.Size = 8
objSheet.Range("A1:F1").Font.Bold = True
objSheet.Range("B2:B75").HorizontalAlignment = -4108
objSheet.Range("F2:F75").HorizontalAlignment = -4108
ObjSheet.Columns(1).Columnwidth = 24
ObjSheet.Columns(2).Columnwidth = 12
ObjSheet.Columns(3).Columnwidth = 16
ObjSheet.Columns(4).Columnwidth = 11
ObjSheet.Columns(5).Columnwidth = 30
ObjSheet.Columns(6).Columnwidth = 11
i = 1
intRow = 2
intCola = 2
intColb = 3
intColc = 4
intCold = 5
intCole = 6
objSheet.Cells(1, 1).Value = "DC Name"
objSheet.Cells(1, 2).Value = "Global Catalog"
objSheet.Cells(1, 3).Value = "Site Name"
objSheet.Cells(1, 4).Value = "IP Address"
objSheet.Cells(1, 5).Value = "OS Version"
objSheet.Cells(1, 6).Value = "Service Pack"
'Domain Controller Name
Set objRootDSE = GetObject("LDAP://" & strDomain & "/RootDSE")
Set objDomain = GetObject("LDAP://" & objRootDSE.Get("defaultNamingContext"))
strMasteredBy = objDomain.GetEx("masteredBy")
For Each strNTDSDN In strMasteredBy
    Set objNTDS = GetObject("LDAP://" & strNTDSDN)
    regex.Pattern = "gs,CN=(\w+),CN=Se" 'Obtain server RDN
    Set objMatches = regex.Execute(strNTDSDN)
    Set objServer = GetObject(objNTDS.Parent)
    objSheet.Cells(intRow, 1).Value = objServer.Get("dnsHostName")
    For Each objMatch In objMatches
  
    '<-- BEGIN GC Check -->
    ' Determine if server is a GC
     strLen = Len(objMatch.Value)-12
     strRight = Mid(ObjMatch.Value, 7, strLen)
     Set objRoot = GetObject("LDAP://" & strRight & "/RootDSE")
        objDSServiceDN = objRoot.Get("dsServiceName")
     Set objDSRoot = GetObject("LDAP://" & strRight & "/" & objDSServiceDN )
     blnCurrentOptions = objDSRoot.Get("options")
      If blnCurrentOptions Then
       objSheet.Cells(intRow, intCola).Value = "YES"
       Else objSheet.Cells(intRow, intCola).Value = "NO"
      End If
    '<-- END GC Check -->
    
   '<-- BEGIN SITE NAME -->
   ' Enumerate site name of DC
     Set objNTDSsite = GetObject("LDAP://" & objRoot.Get("dsServiceName"))
     Set objSite = GetObject(GetObject(GetObject(objNTDS.Parent).Parent).Parent)
  objSheet.Cells(intRow, intColb).Value = objSite.Get("cn")
 '<-- END SITE NAME -->
  
 '<-- BEGIN IP ADDRESS -->
 ' Obtain remote IP address
  Set objFSO = Wscript.CreateObject("Scripting.FileSystemObject")
  Set objShell = WScript.CreateObject("Wscript.Shell")
  objName = objFSO.GetTempName
  objTempFile = objName
  objShell.Run "cmd /c ping -n 3 -w 1000 " & strRight & " >" & objTempFile, 0, True
  Set objTextFile = objFSO.OpenTextFile(objTempFile)
  regex.Pattern = "\b\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}\b" 'RegEx for remote IP address
  strContents = objTextFile.ReadAll()
  PingArray = Split(strContents, VbCrLf)
  For Each strPing In PingArray
      Set objMatchesA = regex.Execute(strPing)
      For Each objMatchA In ObjMatchesA
       If i = 1 Then
        objSheet.Cells(intRow, intColc).Value = objMatchA.Value
       End If
      i = i+1
            Next
        Next
        i=1
     Next
     '<-- END IP ADDRESS -->
    objTextFile.Close
  objFSO.DeleteFile(objTempFile)
 
    '<-- BEGIN OS and Service Pack -->
    ' Enumerate current OS Version and Service Packs
    Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strRight & "\root\cimv2")
 Set colOperatingSystems = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")
    For Each objOperatingSystem in colOperatingSystems
     objSheet.Cells(intRow, intCold).Value = objOperatingSystem.Caption & " " & _
        objOperatingSystem.Version
 Next
 For Each objOperatingSystem in colOperatingSystems
        objSheet.Cells(intRow, intCole).Value = objOperatingSystem.ServicePackMajorVersion  _
        & "." & objOperatingSystem.ServicePackMinorVersion
 Next
 '<-- END OS and Service Pack -->
 
 intRow = intRow+1 
Next
Set regex = Nothing
s=s+1
Next
MsgBox "Script Completed"
'<-- Clean up -->
objExcel.ActiveWorkbook.SaveAs strExcelPath
objExcel.ActiveWorkbook.Close
objExcel.Application.Quit
objTextFile.Close
objFSO.DeleteFile(objTempFile)
WScript.Quit

(in reply to DiGiTAL.SkReAM)

Post #: 2

RE: List Domain Controllers - 4/10/2006 1:48:49 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

It is just a pet peeve of mine and has no functional effect at all, but there is no point to putting WScript.Quit at the end of the script. As I said it is a personal thing and I have always maintained that if the script does what you want then it is by definition written correctly.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to hopsbarleyman)

Post #: 3

RE: List Domain Controllers - 4/10/2006 2:20:37 AM

DiGiTAL.SkReAM

Posts: 1146
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

I just realized that my code requires my StringCat class. So here it is:

Class StringCat
' This class allows the creation of an Object for use in
' concatenating strings MUCH faster than "string = string & newstring" method.
' Usage: first, create a new instance of the object.
' set oMyNewStringObject = New StringCat
' Then, simply add strings to that object until you are ready to read them back out.
' oMyNewStringObject "A new String to add."
' When ready to read the concatenated strings back, simply flush the object.
' sNewString = oMyNewStringObject.Flush
' or 
' WScript.Echo oMyNewStringObject.Flush
'
' When done with the object, you can clear it by performing:
' oMyNewStringObject = Nothing
Dim StringCat_iElement, StringCat_aString
Private Sub Class_Initialize()
 StringCat_iElement = 0
 ReDim StringCat_aString(StringCat_iElement)
End Sub

Public Default Sub AddString(Value)
 StringCat_aString(StringCat_iElement) = Value
 StringCat_iElement = StringCat_iElement + 1
 ReDim Preserve StringCat_aString(StringCat_iElement)
End Sub

Public Function Flush
 StringCat_iElement = StringCat_iElement - 1
 Redim Preserve StringCat_aString(StringCat_iElement)
 Flush = Join(StringCat_aString,VbCrLf)
End Function
Private Sub Class_Terminate()
 Erase StringCat_aString
End Sub
End Class

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to ebgreen)

Post #: 4

RE: List Domain Controllers - 4/11/2006 4:51:19 AM

hopsbarleyman

Posts: 9
Score: 0
Joined: 1/17/2006
Status: offline

Yep, I agree. It's also not really necessary to release the instantiated objects from memory either. This was an old script I wrote a while back and this particular version was one I used in helping another admin who was new to scripting learn proper form and demonstrate releasing objects from memory. It is some extra fluff that's unnecessary, I just didn't take it out before posting.

(in reply to ebgreen)

Post #: 5

RE: List Domain Controllers - 4/13/2006 12:55:33 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

I thought I'd throw in my (modified scripting guy script as well!) domain controller role script as well

'==========================================================================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 4.0
'
' NAME: getadroles.vbs
'
' AUTHOR: Kirrilian
' DATE : 11/3/2005
'
' COMMENT: just run it, preferably with cscript :)
'            code liberally hacked/borrowed from the script repository
'==========================================================================
'put your domains in below
domains = Array("domain1", "domain2", "domain3", "domain4")

For Each domain In domains
   WScript.Echo "*********** Querying: " & domain & " *************"
   getdomaininfo domain
   WScript.echo
Next

Sub getdomaininfo(domain)
   'needed for the gc queries
   On Error Resume Next

   Set objRootDSE = GetObject("LDAP://" & domain & "/rootDSE")

   'ugly code follows...
   Set objSchema = GetObject _
       ("LDAP://" & objRootDSE.Get("schemaNamingContext"))
   strSchemaMaster = objSchema.Get("fSMORoleOwner")
   Set objNtds = GetObject("LDAP://" & strSchemaMaster)
   Set objComputer = GetObject(objNtds.Parent)
   WScript.Echo "Forest-wide Schema Master FSMO: " & objComputer.Name

   Set objNtds = Nothing
   Set objComputer = Nothing

   Set objPartitions = GetObject("LDAP://CN=Partitions," & _
       objRootDSE.Get("configurationNamingContext"))
   strDomainNamingMaster = objPartitions.Get("fSMORoleOwner")
   Set objNtds = GetObject("LDAP://" & strDomainNamingMaster)
   Set objComputer = GetObject(objNtds.Parent)
   WScript.Echo "Forest-wide Domain Naming Master FSMO: " & objComputer.Name

   Set objDomain = GetObject _
       ("LDAP://" & objRootDSE.Get("defaultNamingContext"))
   strPdcEmulator = objDomain.Get("fSMORoleOwner")
   Set objNtds = GetObject("LDAP://" & strPdcEmulator)
   Set objComputer = GetObject(objNtds.Parent)
   WScript.Echo "Domain's PDC Emulator FSMO: " & objComputer.Name

   Set objRidManager = GetObject("LDAP://CN=RID Manager$,CN=System," & _
       objRootDSE.Get("defaultNamingContext"))
   strRidMaster = objRidManager.Get("fSMORoleOwner")
   Set objNtds = GetObject("LDAP://" & strRidMaster)
   Set objComputer = GetObject(objNtds.Parent)
   WScript.Echo "Domain's RID Master FSMO: " & objComputer.Name

   Set objInfrastructure = GetObject("LDAP://CN=Infrastructure," & _
       objRootDSE.Get("defaultNamingContext"))
   strInfrastructureMaster = objInfrastructure.Get("fSMORoleOwner")
   Set objNtds = GetObject("LDAP://" & strInfrastructureMaster)
   Set objComputer = GetObject(objNtds.Parent)
   WScript.Echo "Domain's Infrastructure Master FSMO: " & objComputer.Name

   'check for global catalogs
   Const NTDSDSA_OPT_IS_GC = 1
   Set objGC = GetObject("LDAP://OU=Domain Controllers," & _
       objRootDSE.Get("defaultNamingContext"))
   For Each gc In objGC
       'clean up the ldap response
       gc = Replace(gc.name, "CN=", "")
       Set objRootDSE = GetObject("LDAP://" & gc & "/rootDSE")
       strDsServiceDN = objRootDSE.Get("dsServiceName")
       Set objDsRoot = GetObject("LDAP://" & gc & "/" & strDsServiceDN)
       'this doesnt always exist therefore we have to use on error resume next
       intOptions = objDsRoot.Get("options")
       'check to see if the previous command failed with the err.number function
       If intOptions And NTDSDSA_OPT_IS_GC and err.Number = 0 Then
           WScript.Echo gc & " is a global catalog server."
       Else
           WScript.Echo gc & " isnt up or isnt a global catalog server."
           Err.Clear
       End If
   next

End Sub 'getdomaininfo


_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to hopsbarleyman)

Post #: 6

RE: List Domain Controllers - 4/17/2006 6:58:59 AM

johnrod

Posts: 9
Score: 0
Joined: 9/19/2005
Status: online

Hello--

Thanks for posting your script-- I was trying to use it however, it did not work correctly.

When I removed "On Error Resume Next", it states that it cannot find the object objTextFile in line 51. When I tried to resolve this, it kept coming up with more errors down the line.

Can you offer any assistance?

Thanks!
John

(in reply to hopsbarleyman)

Post #: 7

RE: List Domain Controllers - 4/17/2006 7:04:41 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

You'll probably need to post the actual code that you are running since quite a bit has been posted in this thread.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to johnrod)