DNS Clean Up

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

DNS Clean Up

Logged in as: Guest

arrSession:exec spGetSession 2,16,34266

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> DNS Clean Up
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

DNS Clean Up - 5/8/2006 3:52:36 AM 1 votes

mcds99

Posts: 407
Score: 4
Joined: 2/28/2006
Status: offline

I work as the DNS and DHCP Administrator for a large corporation that has 100`s of thousands of DNS entries, and about 17,000 DHCP scopes.
One of my tasks when I took the job in January is to clean up DNS, OMG!
This is a MS shop no BIND.
The one catch is I have to know the machine has not pinged for 30 days and I have to keep records to that end.

It took me a while to devise a way to accomplish this task so, I though I would share it to save anyone else the time of having to do this.

I first export all the domains where NON - DHCP subnets exist.
I then run a script that I call wmiPing.vbs
It simply reads the host names from a text file, does a wmiPing and writes the results to a tab delimited text file.
I open the file in EXCEL and eliminated the live hosts we have a lot of servers UNIX, Windows, Linux, Mainframe.

I ended up with several spreadsheets containing host names for the various domains. I need to keep all the host/domains straight.
I can then wmiPing them using the spreadsheets and eliminate the hosts that come back on line over time.

It may be convoluted or it may be nuts but it works (most likly NUTS) ;-D

Option Explicit 'use only dimensioned variables and constructs
'### Dimension Variables
Dim objPing, objRetStatus, Ping
Dim strHost
Dim strFile
Dim strCn1, strCn2, strCn3
Dim intRow
Dim objExcel, strPathExcel, objSheet
Dim strPath
'### Dimension File System Object
Dim iFile
Dim oFile
Dim fSo1
Dim fSo2
Dim rdFile
Dim wrFile
'### Constructs for File System Objects
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8
'### Load Variables
iFile = "ifile.txt"  'list of Excel spreadsheet names
oFile = "ofile.txt"  'output of the script
strPath = "C:\_Script\DNS\wmiPING\"  'path to the spreadsheets
'### Initialize File System Object 1
Set fSo1 = CreateObject("Scripting.FileSystemObject")
Set rdFile = fSo1.OpenTextFile(iFile, ForReading)
'### Initialize File System Object 2
Set fSo2 = CreateObject("Scripting.FileSystemObject")
Set wrFile = fSo2.OpenTextFile(oFile, ForAppending)
'### Read File System Object 1
do while rdFile.AtEndofStream=false
  strFile = strPath & rdFile.readline()
'### Read a Row
  Set objExcel = CreateObject("Excel.Application")
    strPathExcel = strFile
    objExcel.Workbooks.open strPathExcel
  Set objSheet = objExcel.ActiveWorkbook.Worksheets(1)
    wscript.echo strPathExcel  'helps to have a status of the progress
    wrfile.WriteLine strPathExcel  'keeps the host/domain straight
'### Ping the Host, Write FSO2
  intRow = 2
    Do while objSheet.Cells(intRow, 1).Value <> ""
       strCn1 = Trim(objSheet.Cells(intRow, 1).Value) 'host name
       strHost = strCn1
       set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery _
         ("select * from Win32_PingStatus where address = '" & strHost & "'")
       For each objRetStatus in objPing
         if IsNull(objRetStatus.StatusCode) or objRetStatus.StatusCode<>0 then
           Ping = False
           wrfile.WriteLine strHost & vbTab & "Host did NOT Ping" & vbTab & now & vbTab & objRetStatus.StatusCode
         else
           Ping = True
           wrfile.WriteLine strHost & vbTab & "Host Pinged" & vbTab & now & vbTab & objRetStatus.StatusCode
         end if
       next
        intRow = intRow + 1
    Loop
'### Close Workbooks and Quit Excel
  objExcel.Workbooks.close
  objExcel.Application.Quit
  intRow = 2
loop
'###  Close Text files, Notify completion, Exit the script
rdFile.close
wrFile.close
wscript.echo "wmiPing Script Complete"
wscript.quit

< Message edited by ebgreen -- 5/8/2006 11:50:16 PM >

_____________________________

Sam

Keep it Simple Make it Fun KiSMiF

Post #: 1

RE: DNS Clean Up - 5/8/2006 11:49:41 PM

ebgreen

Posts: 4595
Score: 29
Joined: 7/12/2005
Status: offline

Thank you for sharing your code. I have a couple of comments that are primarily procedural.

1) The tags for a code block here are [ code] and [ /code] (without the spaces).
2) There is no need for 2 FileSystemObjects. You could just use one to open both TextStream.
3) There is no need for WScript.Quit on the last line.

Thanks again for sharing with the community. As I have always maintained, if the script does what you want the way you want then by definition it is written correctly.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to mcds99)