Detach and re-attach floppy drive to all virtual servers

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Detach and re-attach floppy drive to all virtual servers

Logged in as: Guest

arrSession:exec spGetSession 2,16,34405

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Detach and re-attach floppy drive to all virtual servers
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Detach and re-attach floppy drive to all virtual servers - 5/11/2006 6:59:49 PM

jovius98

Posts: 17
Score: 0
Joined: 4/19/2005
From:
Status: offline

I use MS Virtual Server R2 at the moment, but copying files between the host and from the virtual machines is difficult when you configure the servers to use their own private network (invaluablle when tinkering with DNS setups).

One way to copy small files is to link the server's floppy drive to the one on the host PC. I don't have a floppy drive on my laptop, but I use Ken Kato's Virtual Floppy Drive for Windows 2.1 which works really well. However, once you've accessed the files on the virtual machine, the host can no longer access the drive. I don't know if this only happens with VFD or with physical drives too, but I've written a VBScript program to detach and re-attach the drive on all the installed virtual servers. There's bound to be a better way of doing this, but I thought I'd share it anyway.

It also demonstrates how to re-invoke your script with a specific engine.

' VFloppy.vbs - detach and re-attach host
  ' floppy drive on all installed Virtual Servers.
  Option Explicit
  UseEngine "cscript.exe"

Dim objVS, colVMs, objVM, colFloppyDrives, objDrive
  Set objVS = CreateObject ("VirtualServer.Application")
  Set colVMs = objVS.VirtualMachines
  For Each objVM in colVMS
     WScript.Echo
     WScript.Echo "VIRTUAL MACHINE: "  & objVM.Name
     WScript.Echo
     Set colFloppyDrives = objVM.FloppyDrives
     For Each objDrive in colFloppyDrives
        If objDrive.Attachment <> 0 Then
           If objDrive.HostDriveLetter = "A" Then
              ShowDriveInfo (objDrive)
              WScript.Echo "    Releasing drive A: ..."
              ShowError (objDrive.ReleaseHostDrive () )
              WScript.Echo "    Re-attaching floppy drive A: ..."
              ShowError (objDrive.AttachHostDrive ("A"))
           End If
        End If
        ShowDriveInfo objDrive
     Next
  Next

Sub ShowDriveInfo (objDriveA)
  With objDriveA
     WScript.Echo "    Floppy drive A: found"
     WScript.Echo "        Attachment = " & .Attachment & ", Drive number = " & .DriveNumber
     If .Attachment = 1 Then ' Image file attached
        WScript.Echo "        Image file= "  & .ImageFile
     End If
  End With
End Sub

Sub ShowError (intReturnCode)
  If intReturnCode = 0 Then
     WScript.Echo "        Done."
  Else
     WScript.Echo "        ERROR " & intReturnCode
  End If
End Sub

Sub UseEngine (ByVal strEngine)
  ' Re-invoke current script with the correct engine if required
  If LCase (Right (WScript.FullName, len (strEngine)+1)) = "\" & strEngine Then Exit Sub
  Dim i, objArgs, strCmd, objWSH
  Set objWSH = CreateObject ("WScript.Shell")
  Set objArgs = WScript.Arguments
  strCmd = strEngine & " //nologo " & Chr (34) & WScript.ScriptFullName & Chr (34)
  For i = 0 To objArgs.Count-1
     strCmd = strCmd & " " & Chr (34) & objArgs (i) & Chr (34)
  Next
  ' If invoking cscript, do so within a persistent command shell so script output is not lost.
  If LCase (Left (strEngine, 8)) = "cscript." Then strCmd = objWSH.ExpandEnvironmentStrings ("%COMSPEC%") & " /k " & strCmd
  WScript.Quit (objWSH.Run (strCmd, 10, true))
End Sub