EMWProf caller login script

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

EMWProf caller login script

Logged in as: Guest

arrSession:exec spGetSession 2,16,35506

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> EMWProf caller login script
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

EMWProf caller login script - 6/16/2006 9:49:30 AM

SteveHarper

Posts: 2
Score: 0
Joined: 6/16/2006
From: Maryland
Status: offline

'**************************************************************************
'
' This script was written by Stephen Harper for the 
' Federal Transit Administration
' Date: 3/13/2006
' Purpose:
'  To call the EMWProf batch file for users whose mailboxes have 
'  been migrated. This script will only call EMWProf at login if 
'  the following conditions are true:
'   1) The user account in in the active directory group at 
'   the time of login
'   2) The registry keys that this script creates are not present.
'   
' Usage:
'  You must be performing a Quest migration using the Quest products. 
'  Please visit [link=http://www.quest.com]www.quest.com[/link] if you don't know what this means.
'  This is a login script and must be run at login because it calls the 
'  program that modifies the users' outlook profile.
'  Change the string "strGroupDN = 
'  ""CN=EMW-Run-Script-Group,OU=Distribution Lists,... etc" to 
'  reflect any group you choose to use. I created a distribution 
'  group and did not assign it an email address. This is fine to do
'  because it does not need an email address nor does it need to be 
'  used for assigning permissions to resources. Add the users to that 
'  group whose mailboxes have been migrated using Quest EMW or QMM.
'  When the user logs in the script will check that the user is a 
'  member of that group and it will check to see if a registry key 
'  exists. If the key does not exist and the user is a member of the 
'  group, then the EMWProf.bat file is called. The EMWProf.bat file is 
'  provided by Quest when you purchase their product. You will also 
'  need to change the line at the bottom that reads 
'  "wn.MapNetworkDrive "Y:", "\\server\share"" to point to your 
'  server where you have placed the EMWProf.bat file and the various other 
'  files provided by Quest. Anyone who is using this script should 
'  understand computers enough to be able to use it. No warranties, 
'  no guarentees. Use at your risk (but hey, it works).
'**************************************************************************
On Error Resume Next
Set WshShell=WScript.CreateObject("WScript.Shell")
Set wn=WScript.CreateObject("WScript.Network")
Dim objRegistry, RegKey, strHasBeenRun
Const debugging = false
strUser=""
While strUser=""
  strUser=wn.UserName
Wend
Set objSysInfo = CreateObject("ADSystemInfo")
UserADsPath = objSysInfo.UserName
If debugging Then
  wscript.echo "Welcome to the EMWProf caller script written by Stephen Harper for FTA!" & vbcrlf & _
  "This script will call EMWProf.bat if your mailbox has been moved. If you get an error message stating that your profile could " & _
  "not be updated please call the help desk at (xxx) xxx-xxxx. Have a good day!" & vbcrlf & VbCrLf
End if
'Set up the string to determine group membership. Modify this group to reflect the group in which you added your users.
strGroupDN = "CN=EMW-Run-Script-Group,OU=Distribution Lists, OU=Resources,OU=FTA,OU=Agencies,DC=ad,DC=dot,DC=gov"
Set objGroupName = GetObject("LDAP://" & strGroupDN)
Set objUser = GetObject("LDAP://" & UserADsPath)
If Not isnull(objUser) Then
  If objGroupName.IsMember(objUser.AdsPath) Then
      RegKey = "HKEY_CURRENT_USER\Software\EMWProf\"
      strHasBeenRun = WSHShell.RegRead (regkey & "HasBeenRun")
      If Err.Number <> 0 Then
          if debugging Then
              wscript.echo "EMWProf has never been run!"
          end If
          strHasBeenRun = "NO"
      End If
          
      If strHasBeenRun = "YES" Then
          if debugging Then
              wscript.echo "Quitting" 
          end If
          wscript.quit
      Else
          WSHShell.RegWrite regkey & "HasBeenRun", "YES"
          WSHShell.RegWrite regkey & "Script Programmer", "Stephen Harper"
          WSHShell.RegWrite regkey & "For Help Call", "FTA Help Desk: (xxx) 555-1234"
          if debugging Then
              wscript.echo "Setting Key to YES"
          end If
          wn.RemoveNetworkDrive("Y:")
          wn.MapNetworkDrive "Y:", "\\server\share"
          Run "Y:\EMWProf.bat"
          wn.RemoveNetworkDrive("Y:")
          End If 
      End If
End If

Function Run (ByVal cmd)
  Dim sh, wsx
  Set sh = CreateObject("Wscript.Shell")
  Set wsx = sh.Exec(cmd)
  Do
      Dim Status
      Status = wsx.Status
      WScript.StdOut.Write wsx.StdOut.ReadAll()
      WScript.StdErr.Write wsx.StdErr.ReadAll()
      If Status <> 0 Then Exit Do
      Wscript.Sleep 10
  Loop
  Run = wsx.ExitCode
End Function
Function RunCmd (ByVal cmd)
  If debugging Then
      wscript.echo "Running command: " & cmd
  End If
  RunCmd = Run("ComSpec% /c " & cmd)
End Function

EDIT(EBGREEN): Added code tags, changed indentation, and removed personal contact information.

< Message edited by ebgreen -- 6/19/2006 12:21:12 AM >

Revisions: 2 | Post #: 1

RE: EMWProf caller login script - 6/19/2006 12:14:11 AM 1 votes

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Thanks for sharing your script. The comment block at the top with the explanation of purpose and what a user would need to tweak in the script is great. I did put it into a code block to make it a little more browser friendly. There are some things that I would change if I were writing this script:

1) Global On Error Resume Next - I avoid using this if at all possible. It tends to mask errors that I need to know about to know when there is a problem with a script and what the problem is. I use it to specifically cover a single statement that I expect to have errors, but as I said I avoid using it globally.
2) This construct:
While strUser=""
strUser=wn.UserName
Wend
Has the potential to produce an infinite loop. Have there been specific situations where the WScript.Network object was unable to get the username but did get it if you tried repeatedly? I have never seen behavior like that.
3) Constant Names - By convention, constants are generally named with all caps to distinguish them as constants. It is not a hard and fas rule but most people follow the convention.
4) Function Names - While 'Run' is not a reserved keyword, it is a method of a WSH builtin object so that using it as a function name could be considered a little ambiguous.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to SteveHarper)

Post #: 2

RE: EMWProf caller login script - 7/6/2006 2:44:07 AM

SteveHarper

Posts: 2
Score: 0
Joined: 6/16/2006
From: Maryland
Status: offline

Thank you for the great comments and suggestions.
In regard to the

While strUser=""
strUser=wn.UserName
Wend

comment, I have never seen it not get the username on the first try. There is a reason that I did that though, but I don't remember what it was. Probably could do an If statement instead of a while loop or even a direct asignment without the check would be fine.

strUser = wn.UserName

Thanks for the great comments.
steve

(in reply to ebgreen)