Regular expression tester [Updated]

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Regular expression tester [Updated]

Logged in as: Guest

arrSession:exec spGetSession 2,16,35894

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Regular expression tester [Updated]
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1] 2 next > >>

Message

<< Older Topic Newer Topic >>

Regular expression tester [Updated] - 6/29/2006 6:44:59 AM

mikeock

Posts: 124
Score: 1
Joined: 6/8/2006
Status: offline

At work i am limited to VBS due to the project.

I wrote this lil app for regular expressions through VBS.
A fellow employee did do a lil bit of fixing for the submatch and the global search.

Let me know what you think.
Original

<html>
<head>
 <title>Regex Tester</title>
<HTA:APPLICATION
 icon = "c:\icons\hate.ico"
 Caption = "yes"
 Version = "1.1(a)"
/>
<script language="VBScript">
'#################### Start VBScript Section ####################
'Sub to Run when Test RegEx button is pressed
sub cmdTextBox
 dim string1, Re,s,colMatches,Test,ResultArr()
 
 'Configure Regular Expression
 set Re = new RegExp
 Re.Pattern = ExprStrin.TextBox.value
 
 ' Error if pattern is blank
 if Re.Pattern = "" then 
     DataAr1.InnerHTML = "<font color=red>Please enter a Regular Expression</font>"
     ClearSubs
 
 'Move on pattern is not blank
 else
     If ExprStrin.GlobalCheckBox.checked Then    'Set Global attribute according to checkbox
         Re.Global = true
     Else
         Re.Global = false
     End If
     
     If ExprStrin.caseCheckbox.checked Then    'Set IgnoreCase attribute according to checkbox
         Re.IgnoreCase = True
     Else
         Re.IgnoreCase = False
     End If
     s = ExprStrin.StringBox.value
     
     'Error if string to search is blank
     if s = "" then 
         DataAr1.InnerHTML = "<font color=red>Search String cannot be left blank</font>"
         ClearSubs
         
     ' Test regex if string is not blank
     else
     
         'If a match is found...
         if Re.Test(s) then 
             'Collect and Output Matches
             Set colMatches = Re.Execute(s)
             counter = 0
             numMatches = colMatches.count
             for each Test in colMatches
                 ReDim Preserve ResultArr(counter + 1)
                 ResultArr(counter) = Test.value
                 counter = counter + 1
             next
             dim tempstring
             for count2 = 0 to counter - 1
                 tempstring = tempstring & "<b>Match " & count2+1 & ": </b>" & ResultArr(count2) & "<br>"
             next
             DataAr1.InnerHTML = "<b>The following matches were found:</b><br>" & tempstring
             
             'Collect SubMatches and Store them in a String
             subMatchesString = ""
             For i=0 to numMatches-1    'Loop through each match
                 Set myMatch = colMatches(i)
                 numSubMatches = myMatch.submatches.count
                 If numSubMatches > 0 Then    'Loop through each submatch in current match
                     subMatchesString = subMatchesString & "<b>Submatches for Match " & i+1 & "</b><br>"
                     For j=0 to numSubMatches-1
                         subMatchesString = subMatchesString & myMatch.SubMatches(j) & "<br>"
                     Next
                 End If
             Next
             
             'Output submatches to correct field
             SubAr1.InnerHTML = subMatchesString
                 
         'If no match is found output error and sub strings
         else 
             DataAr1.InnerHTML = "No match was found for the regular expression."
             ClearSubs
         end if
     end if
 end if
 
 'Clear things up
 Set Re = Nothing
 Set colMatches = nothing
end sub

'Sub to Run when Clear Results button is pressed
sub ClearDataAr1
 DataAr1.InnerHTML = ""
 ClearSubs
end sub

'Sub to clear submatches
sub ClearSubs
 SubAr1.InnerHTML = ""
End sub
'#################### End VBScript Section ####################
</script>
</head>

<body>
 <form action="some_form_handler.asp" method="post" id="ExprStrin" name="ExprStrin" target="_self">
     <table align="center">
         <tr>
             <td>Enter an expression</td>
             <td><input type="text" id="TextBox" name="TextEntry" value="" tabindex=1 size=66></td>
         </tr>
         <tr>
             <td>Enter a String</td>
             <td><textarea cols=50 rows=4 name="StringBox" tabindex=2></textarea>
             </td>
         </tr>
     </table>
     <table align="center" cellpadding=5>
         <tr>
             <td><input type=checkbox name="IgnoreCase" ID="CaseCheckBox" tabindex=-1>Ignore Case</td>
             <td><input type=checkbox name="Global" id="GlobalCheckBox" tabindex=-1>Global Search</td>
             <td><input type="button" value="Clear Results" onClick="ClearDataAr1" size=30 tabindex=3><td>
             <td><input type="button" value="Test RegEx" onClick="cmdTextBox" tabindex=4</td>
         </tr>
     </table>

<table align="center">
         <tr>
             <td><br><font color=blue size=+1><b>Error or Result display</b></font></td>
         </tr>
     </table>
     <table align="center" frame="border" >
         <tr>
             <td><span id=DataAr1>Result will display here</span></td>
         </tr>
     </table>
     <table align="center" ID="Table1">
         <br>
         <tr><td><font color=blue size=+1><b>Substring Matches Display</b></font></td></tr>
     </table>
     <table align=center frame="border">
         <tr>
             <td><span id=SubAr1>Substrings will display here</span></td>
         </tr>
 
     </table>
 </form>
</body>
</html>

Edit: 2006/07/27
And now with all fixes. File loading, GUI enhancements.
App now features tool tips on almost all items.
Added a lot of coloring.
Cleaned out code where possible.
Try it and let me know

<html>
<head>
 <title>Regex Tester</title>
<HTA:APPLICATION
 icon = "c:\icons\hate.ico"
 Caption = "yes"
 Version = "2.5"
/>

<script language="VBScript">
'#################### Start VBScript Section ####################

''= refreshes the HTA page, which includes re-running any Windows_Onload code
'' ============================================================================
Sub reloadHTA()
 location.reload( True )
End Sub

'Sub to Run when Test RegEx button is pressed
sub cmdTextBox
 dim string1, Re,s,colMatches,Test,ResultArr()

'Configure Regular Expression
 set Re = new RegExp
 Re.Pattern = ExprStrin.TextBox.value

' Error if pattern is blank
 if Re.Pattern = "" Then
       strError = "<font color=red>Please enter a Regular Expression!</font>"
   DataAr1.InnerHTML = strError
   SubAr1.InnerHTML = strError
   strError = ""

'Move on pattern is not blank
 else
   If ExprStrin.GlobalCheckBox.checked Then    'Set Global attribute according to checkbox
       Re.Global = true
   Else
       Re.Global = false
   End If
  
   If ExprStrin.caseCheckbox.checked Then    'Set IgnoreCase attribute according to checkbox
       Re.IgnoreCase = True
   Else
       Re.IgnoreCase = False
   End If

If ExprStrin.MultilineCheckBox.checked Then    'Set Multiline attribute according to checkbox
         Re.Multiline = True
     Else
         Re.Multiline = False
     End If

s = ExprStrin.StringBox.value
  
   'Error if string to search is blank
   if s = "" Then
           strError = "<font color=red>Search String cannot be left blank!</font>"
       DataAr1.InnerHTML = strError
       SubAr1.InnerHTML = strError
       strError = ""
      
   ' Test regex if string is not blank
   else
  
       'If a match is found...
       if Re.Test(s) then
           'Collect and Output Matches
           Set colMatches = Re.Execute(s)
           counter = 0
           numMatches = colMatches.count
           for each Test in colMatches
               ReDim Preserve ResultArr(counter + 1)
               ResultArr(counter) = Test.value
               counter = counter + 1
           next
           dim tempstring
           for count2 = 0 to counter - 1
               tempstring = tempstring & "<b>Match " & count2+1 & ": </b>" & ResultArr(count2) & "<br>"
           next
           DataAr1.InnerHTML = "<b>The following matches were found:</b><br>" & tempstring
          
           'Collect SubMatches and Store them in a String
           subMatchesString = ""
           For i=0 to numMatches-1    'Loop through each match
               Set myMatch = colMatches(i)
               numSubMatches = myMatch.submatches.count
               If numSubMatches > 0 Then    'Loop through each submatch in current match
                   subMatchesString = subMatchesString & "<b>Submatches for Match " & i+1 & "</b><br>"
                   For j=0 to numSubMatches-1
                       subMatchesString = subMatchesString & myMatch.SubMatches(j) & "<br>"
                   Next
               End If
           Next
          
           'Output submatches to correct field
           SubAr1.InnerHTML = subMatchesString
              
       'If no match is found output error and sub strings
       else
           DataAr1.InnerHTML = "No match was found for the regular expression."
           ClearSubs
       end if
   end if
 end if

'Clear things up
 Set Re = Nothing
 Set colMatches = nothing
end sub

'Sub to Run when Clear Results and submatches when button is pressed 
sub ClearDataAr1
 DataAr1.InnerHTML = "Results Cleared!"
 SubAr1.InnerHTML = "Results Cleared!"
end sub

sub loadfiles
 retVal = "<input type=file name=xmlname> <br> <input type=button value=Assimilate onclick=fileLoader Title=""Click to load settings into App"">"
 Loader.InnerHTML = retVal
 ExprStrin.Saver.disabled = True
 ExprStrin.Templ2.Disabled = True
 exprstrin.xmlname.style.backgroundcolor = "C0C0C0"
end sub

sub CloseFile
 Loader.InnerHTML = ""
 Loader2.InnerHTML = ""
 ExprStrin.Loader.Disabled = False
 ExprStrin.Saver.disabled = False
 ExprStrin.Templ2.Disabled = false
end sub

sub fileLoader
 set fileObj = CreateObject("Scripting.FileSystemObject")
 if ExprStrin.xmlname.value = "" then
     Loader2.InnerHTML= "<font color=red>Enter a filename</font>"
 else
     file = ExprStrin.xmlname.value
 end if 
 if fileObj.FileExists(file) then 
     set objStream = fileObj.OpenTextFile (file, _
         1,false,0)
     opened = true 
 else 
     Loader2.InnerHTML= "<font color=red size=+1>File not found</font>"
     opened = false
 end if
 if opened then
     Loader2.InnerHTML= ""
     contents = ObjStream.Readall
     contents2 = split(contents,"-------")
     expr = Replace(contents2(0),VbnewLine,"")
     if instr(len(contents2(1))-1,contents2(1),vbnewline) then
         stringer = Left(cstr(contents2(1)),len(cstr(contents2(1)))-2)
         stringer = right(stringer,len(stringer) -2 )
     else
         Stringer = contents2(1)
     end if
     ig = Replace(contents2(2),vbnewline,"")
     gs = Replace(contents2(3),vbnewline,"")
     ml = Replace(contents2(4),vbnewline,"")
     'Set hta vars back to loaded values
     ExprStrin.TextBox.value = expr
     ExprStrin.StringBox.value = Stringer
     if ig then 
         ExprStrin.caseCheckbox.checked = True
     else 
         ExprStrin.caseCheckbox.checked = False
     end if 
     if gs then 
         ExprStrin.GlobalCheckBox.Checked = True
     else 
         ExprStrin.GlobalCheckBox.Checked = false
     end if 
     if ml then 
         ExprStrin.MultilineCheckBox.checked = true
     else
         ExprStrin.MultilineCheckBox.checked = False
     end if
 else 
     expr =""
     stringer = ""
     ig = ""
     gs = ""
     ml = ""
 end if 
set fileObj = Nothing
End sub

sub TmpInner
 Loader2.InnerHTML = ""
 Loader.InnerHTML= "Enter a filename for template<br>" & _
                   "<input type=""Text"" ""id=Templ"" name=""Templ"" value="""">" & _
                   "<input type=""Button"" value=""Save"" onClick=""SaveTmpl"" Title=""Click after entering filename for template to be created"">"
 ExprStrin.Loader.Disabled = true
 ExprStrin.Saver.disabled = true
 ExprStrin.Templ.style.backgroundcolor = "C0C0C0"
 
end sub

sub SaveTmpl
 set fileObj = CreateObject("Scripting.FileSystemObject")
 file = ExprStrin.Templ.value 
 if file = "" then 
     Loader2.InnerHTML = "<font color=red size=+1>Enter a FileName</font>"

else
     if not (fileObj.FileExists(file)) then
         Loader2.InnerHTML = "File not found. Creating now"
         set file2 = fileObj.CreateTextFile(file)
     else 
         Loader2.InnerHTML = "File existed. Over-writing now!"
         set file2 = fileObj.CreateTextFile(file,True)
     end if 
     file2.writeline ("'Remove this line and put expr here")
     file2.WriteLine ("-------")
     file2.WriteLine ("'Remove this line and enter in string.. Can be multi line")
     file2.WriteLine ("-------")
     file2.WriteLine ("'Remove this line. Enter boolean of Ignore case value")
     file2.WriteLine ("-------")
     file2.WriteLine ("'Remove this line. Enter boolean of Global Search value ")
     file2.WriteLine ("-------")
     file2.WriteLine ("'Remove this line. Enter boolean of MultiLine value")
     file2.close
 end if
 set fileObj = nothing
end sub

sub SaveSets
 Loader2.InnerHTML = ""
 'load txtbox for save value 
 Loader.InnerHTML= "Enter a filename to save<br>" & _
                   "<input type=""Text"" ""id=Templ"" name=""Templ"" value="""">"  & _
                   "<input type=""button"" value=""Save"" onclick=""SaveSets2"" Title=""Click after entering a filename to save"">"
 ExprStrin.Loader.Disabled = True    
 ExprStrin.Templ2.Disabled = True
 ExprStrin.Templ.style.backgroundcolor = "C0C0C0"
end sub

sub SaveSets2
 set fileObj = CreateObject("Scripting.FileSystemObject")
 file = ExprStrin.Templ.value 
 'open file for writing
 if file = "" then 
     Loader2.InnerHTML = "<font color=red size=+1>Enter a FileName</font>"
 else
     if not (fileObj.FileExists(file)) then 
         Loader2.InnerHTML = "File not found. Creating now"
         set file2 = fileObj.CreateTextFile(file)
     else 
         Loader2.InnerHTML = "File existed. Over-writing now!"
         set file2 = fileObj.CreateTextFile(file,True)
     end if 
     delim = "-------"
     file2.writeline(ExprStrin.TextBox.value)
     file2.writeline(delim)
     file2.writeline(ExprStrin.StringBox.value)
     file2.writeline(delim)
     file2.writeline( ExprStrin.caseCheckbox.checked)
     file2.writeline(delim)
     file2.writeline(ExprStrin.GlobalCheckBox.Checked)
     file2.writeline(delim)
     file2.writeline(ExprStrin.MultilineCheckBox.checked)
     file2.close
 End if 
     set fileObj = nothing
end sub

sub Window_onload
 ExprStrin.TextBox.style.backgroundcolor = "C0C0C0"
 ExprStrin.StringBox.style.backgroundcolor = "c2c2c2"
end sub
'#################### End VBScript Section ####################
</script>
</head>

<body STYLE="filter:progid:DXImageTransform.Microsoft.Gradient(GradientType=0, StartColorStr='#c2c2c2', EndColorStr='#00CCFF')">
 <form action="some_form_handler.asp" method="post" id="ExprStrin" name="ExprStrin" target="_self">
 <center><h1>Regex Tester</font></h1></center>
   <table align="center">
   
       <tr>
           <td>Enter an expression</td>
           <td><input type="text" id="TextBox" name="TextEntry" value="" tabindex=1 size=66 title="Enter a valid regular expression here"></td>
       </tr>
       <tr>
           <td>Enter a string</td>
           <td><textarea cols=50 rows=4 name="StringBox" tabindex=2 Title="Enter in a string to test Regular expression against"></textarea>
           </td>
       </tr>
   </table>
     
   <table align="center" cellpadding="5">
       <tr>
           <td><input type=checkbox name="IgnoreCase" ID="CaseCheckBox" tabindex=3 title="Allows the ability to ignore case sensitivity">Ignore Case</td>
           <td><input type=checkbox name="Global" id="GlobalCheckBox" tabindex=4 checked="true" Title="Allows the ability to search the whole string">Global Search</td>
           <td><input type=checkbox name="Multiline" id="MultilineCheckBox" tabindex=5 title="Allows the ability to search multiple line strings">Multiline</td>
           </tr>
           <tr>
           <td><input type="button" value="Clear Results" onClick="ClearDataAr1" size=30 tabindex=6 Title="Clear the results area"></td>
           <td><input type="button" value="Test RegEx" onClick="cmdTextBox" tabindex=7 title="Test regular expression"></td>
           <td><input type = "BUTTON" value = "Reload" onclick = "reloadHTA()"tabindex=8 title="Reload App with default values" ></td>
       </tr>
   </table>

<table align="center" cellpadding="5">
       <tr>
           <td><br><font color=blue size=+1><b>Error or Result display</b></font></td>
       </tr>
   </table>
   <table align="center" >
       <tr>
           <td><span id=DataAr1>Result will display here</span></td>
       </tr>
   </table>
   <table align="center" ID="Table1" cellpadding="5">
       <br>
       <tr><td><font color=blue size=+1><b>Substring Matches Display</b></font></td></tr>
   </table>
   <table align=center >
       <tr>
           <td><span id=SubAr1>Substrings will display here</span></td>
       </tr>
   </table>
   <table align=center cellpadding="5"><br><br>
     <tr>
         <td><font color=blue size=+1>Import/Export data from file</font><br><input type="button" value="Load" onClick="loadfiles" id="loader" Title="Select to enable loading options">
             <input type="button" value="Template" onClick="TmpInner" id="Templ2" Title="Allows the creation of a default template">
             <input type="button" value="Save" onclick="SaveSets" id="Saver" Title="Allows you to save current settings to a file">
             <input type="button" Value="Hide" onClick="CloseFile" Title="Hides save/template options"></td>
   </tr>
     <tr>
     <td><span id=Loader></span></td>
     </tr>
     <tr><td><span id=Loader2></span></td></tr>
 </table>
 </form>
</body>
</html>

< Message edited by mikeock -- 7/27/2006 1:29:32 AM >

_____________________________

My sig sucks!

Revisions: 4 | Post #: 1

RE: Regular expression tester - 6/29/2006 9:16:08 AM 1 votes

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Hi mikeok,

thanks for your useful script. I had real fun studying it. Perhaps you
are interested in two additions:

(1) I like to test my .HTAs immediately while I'm tinkering with the
    code; .HTMLs can be reloaded using the browser's button, for .HTAs
    I usually add a button and this reloadHTA() Sub.

(2) There is another RegExps property that was undocumented for a long
    time and frequently misunderstood: Multiline. The new VBScript Docs
    mention it for JScript only - so perhaps you'll learn something
    new.

Additions:

9:    />
 10:    <script language="VBScript">
 11:    '#################### Start VBScript Section ####################
 12:    
 ----------------------------- (1) ------------------------------------------------
 13:    ''= refreshes the HTA page, which includes re-running any Windows_Onload code
 14:    ' ============================================================================
 15:    Sub reloadHTA()
 16:      location.reload( True )
 17:    End Sub
 ----------------------------------------------------------------------------------
 18:    
 12:    'Sub to Run when Test RegEx button is pressed
 13:    sub cmdTextBox
 14:       dim string1, Re,s,colMatches,Test,ResultArr()
 
 35:           Else
 36:               Re.IgnoreCase = False
 37:           End If
 45:    
 ----------------------------- (2) ------------------------------------------------
 46:           If ExprStrin.MultilineCheckBox.checked Then    'Set Multiline attribute according to checkbox
 47:               Re.Multiline = True
 48:           Else
 49:               Re.Multiline = False
 50:           End If
 ----------------------------------------------------------------------------------
 51:    
 38:           s = ExprStrin.StringBox.value
 39:    
 40:           'Error if string to search is blank
 
 109:       <form action="some_form_handler.asp" method="post" id="ExprStrin" name="ExprStrin" target="_self">
 110:           <table align="center">
 ----------------------------- (1) ------------------------------------------------
 111:               <tr>
 126:                 <input type = "BUTTON" value = "reload" onclick = "reloadHTA()">
 127:               </tr>
 ----------------------------------------------------------------------------------
 128:    
 129:               <tr>
 112:                   <td>Enter an expression</td>
 113:                   <td><input type="text" id="TextBox" name="TextEntry" value="" tabindex=1 size=66></td>
 114:               </tr>
 
 122:               <tr>
 123:                   <td><input type=checkbox name="IgnoreCase" ID="CaseCheckBox" tabindex=-1>Ignore Case</td>
 124:                   <td><input type=checkbox name="Global" id="GlobalCheckBox" tabindex=-1>Global Search</td>
 ----------------------------- (2) ------------------------------------------------
 143:                   <td><input type=checkbox name="Multiline" id="MultilineCheckBox" tabindex=-1>Multiline</td>
 ----------------------------------------------------------------------------------
 125:                   <td><input type="button" value="Clear Results" onClick="ClearDataAr1" size=30 tabindex=3><td>
 126:                   <td><input type="button" value="Test RegEx" onClick="cmdTextBox" tabindex=4</td>
 127:               </tr>

I think it shows the quality of your code that another programmer could
understand and add to your script in such a painless way. I hope you will
like my additions as much as I liked your "Regular expression tester"

ehvbs

(in reply to mikeock)

Post #: 2

RE: Regular expression tester - 6/30/2006 1:44:27 AM

ebgreen

Posts: 4595
Score: 29
Joined: 7/12/2005
Status: offline

Not to diminish the contribution of very well written and useful code, but there is a regular expression testing extension for Firefox that I use all the time when I need to come up with a weird pattern.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ehvbs)

Post #: 3

RE: Regular expression tester - 6/30/2006 2:13:23 AM

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Hi ebgreen,

you are right and I thank you for the pointer to Sebastian Zartner's Regular Expressions Tester.
But after using this (or any other non VBScript based tool), you'll still have to check with mikeok's
script, whether the results in your VBScript will be the same! Just use the MultiLine feature as
a test case, you'll be surprised!

ehvbs

(in reply to ebgreen)

Post #: 4

RE: Regular expression tester - 6/30/2006 3:59:24 AM

mikeock

Posts: 124
Score: 1
Joined: 6/8/2006
Status: offline

Thanks for the input!
I will look at rolling the those other options into this.

_____________________________

My sig sucks!

(in reply to ebgreen)

Post #: 5

RE: Regular expression tester - 7/6/2006 5:35:02 AM 1 votes

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

Thanks for this regex tester, it's much easier to use than some of the others I've tried and it is vbs specific for some stuff.

I have already merged it and cleaned it up a little bit, the code is below.

also ehvbs, it is difficult to copy and paste your stuff with the line numbers included ;)

Suggestions:
Check for "preceding" symbols such as the * symbol, it created an error when I searched for *test in testing
Add in functionality for the replace method, this would be nice to have.

'Sub to Run when Test RegEx button is pressed
sub cmdTextBox
  dim string1, Re,s,colMatches,Test,ResultArr()
 
  'Configure Regular Expression
  set Re = new RegExp
  Re.Pattern = ExprStrin.TextBox.value
 
  ' Error if pattern is blank
  if Re.Pattern = "" Then
          strError = "<font color=red>Please enter a Regular Expression!</font>"
      DataAr1.InnerHTML = strError
      SubAr1.InnerHTML = strError
      strError = ""
 
  'Move on pattern is not blank
  else
      If ExprStrin.GlobalCheckBox.checked Then    'Set Global attribute according to checkbox
          Re.Global = true
      Else
          Re.Global = false
      End If
     
      If ExprStrin.caseCheckbox.checked Then    'Set IgnoreCase attribute according to checkbox
          Re.IgnoreCase = True
      Else
          Re.IgnoreCase = False
      End If

If ExprStrin.MultilineCheckBox.checked Then    'Set Multiline attribute according to checkbox
            Re.Multiline = True
        Else
            Re.Multiline = False
        End If

s = ExprStrin.StringBox.value

'Error if string to search is blank
      if s = "" Then
              strError = "<font color=red>Search String cannot be left blank!</font>"
          DataAr1.InnerHTML = strError
          SubAr1.InnerHTML = strError
          strError = ""
         
      ' Test regex if string is not blank
      else
     
          'If a match is found...
          if Re.Test(s) then
              'Collect and Output Matches
              Set colMatches = Re.Execute(s)
              counter = 0
              numMatches = colMatches.count
              for each Test in colMatches
                  ReDim Preserve ResultArr(counter + 1)
                  ResultArr(counter) = Test.value
                  counter = counter + 1
              next
              dim tempstring
              for count2 = 0 to counter - 1
                  tempstring = tempstring & "<b>Match " & count2+1 & ": </b>" & ResultArr(count2) & "<br>"
              next
              DataAr1.InnerHTML = "<b>The following matches were found:</b><br>" & tempstring
             
              'Collect SubMatches and Store them in a String
              subMatchesString = ""
              For i=0 to numMatches-1    'Loop through each match
                  Set myMatch = colMatches(i)
                  numSubMatches = myMatch.submatches.count
                  If numSubMatches > 0 Then    'Loop through each submatch in current match
                      subMatchesString = subMatchesString & "<b>Submatches for Match " & i+1 & "</b><br>"
                      For j=0 to numSubMatches-1
                          subMatchesString = subMatchesString & myMatch.SubMatches(j) & "<br>"
                      Next
                  End If
              Next
             
              'Output submatches to correct field
              SubAr1.InnerHTML = subMatchesString
                 
          'If no match is found output error and sub strings
          else
              DataAr1.InnerHTML = "No match was found for the regular expression."
              ClearSubs
          end if
      end if
  end if
 
  'Clear things up
  Set Re = Nothing
  Set colMatches = nothing
end sub

'Sub to Run when Clear Results button is pressed
sub ClearDataAr1
  DataAr1.InnerHTML = "Results Cleared!"
  ClearSubs
end sub

'Sub to clear submatches
sub ClearSubs
  SubAr1.InnerHTML = "Results Cleared!"
End sub
'#################### End VBScript Section ####################
</script>
</head>

<body>
  <form action="some_form_handler.asp" method="post" id="ExprStrin" name="ExprStrin" target="_self">
  <center><h1>Regex Tester</h1></center>
      <table align="center">
      
          <tr>
              <td>Enter an expression</td>
              <td><input type="text" id="TextBox" name="TextEntry" value="" tabindex=1 size=66></td>
          </tr>
          <tr>
              <td>Enter a string</td>
              <td><textarea cols=50 rows=4 name="StringBox" tabindex=2></textarea>
              </td>
          </tr>
      </table>
      <table align="center" cellpadding="5">
          <tr>
              <td><input type=checkbox name="IgnoreCase" ID="CaseCheckBox" tabindex=-1>Ignore Case</td>
              <td><input type=checkbox name="Global" id="GlobalCheckBox" tabindex=-1>Global Search</td>
              <td><input type=checkbox name="Multiline" id="MultilineCheckBox" tabindex=-1>Multiline</td>
              </tr>
              <tr>
              <td><input type="button" value="Clear Results" onClick="ClearDataAr1" size=30 tabindex=3></td>
              <td><input type="button" value="Test RegEx" onClick="cmdTextBox" tabindex=4></td>
              <td><input type = "BUTTON" value = "Restart" onclick = "reloadHTA()"tabindex=4></td>
          </tr>
      </table>

<table align="center">
          <tr>
              <td><br><font color=blue size=+1><b>Error or Result display</b></font></td>
          </tr>
      </table>
      <table align="center" >
          <tr>
              <td><span id=DataAr1>Result will display here</span></td>
          </tr>
      </table>
      <table align="center" ID="Table1">
          <br>
          <tr><td><font color=blue size=+1><b>Substring Matches Display</b></font></td></tr>
      </table>
      <table align=center >
          <tr>
              <td><span id=SubAr1>Substrings will display here</span></td>
          </tr>
 
      </table>
  </form>
</body>
</html>

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to mikeock)

Post #: 6

RE: Regular expression tester - 7/6/2006 5:57:24 AM

mikeock

Posts: 124
Score: 1
Joined: 6/8/2006
Status: offline

Nice. I was acutally in the process of rolling the new settings in when I saw your post.

Thanks! Saves me a bit of time.

What exactly does the Multiline funtion do?

I see that it can be enabled but do we need to call against or just enabl it to see the difference?

_____________________________

My sig sucks!

(in reply to kirrilian)

Post #: 7

RE: Regular expression tester - 7/6/2006 6:55:07 AM

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Hi mikeok,

Straight from the VBScript Docs:

If multiline is false, "^" matches the position at the beginning of a string, and "$" matches the position
at the end of a string. If multiline is true, "^" matches the position at the beginning of a string as well
as the position following a "\n" or "\r", and "$" matches the position at the end of a string and the position
preceding "\n" or "\r".

Hi kirrilian,

sorry about the inconvenient line numbers, but

   (1) I wanted to mark the positions in mikeok's code clearly where my proposed additions
         should be added

   (2) If your editor doesn't have a column mode, you can always use my (transfor)mator
         tool to add/remove line numbers painlessly.

ehvbs

(in reply to mikeock)

Post #: 8

RE: Regular expression tester - 7/6/2006 6:56:07 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

all you have to do is check the box,

      If ExprStrin.MultilineCheckBox.checked Then    'Set Multiline attribute according to checkbox
            Re.Multiline = True
        Else
            Re.Multiline = False
        End If

however, im not sure what the multiline flag does though.

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to mikeock)

Post #: 9

RE: Regular expression tester - 7/6/2006 7:14:09 AM

mikeock

Posts: 124
Score: 1
Joined: 6/8/2006
Status: offline

ehvbs,

Thanks for the explanation. It looks a lot like what you would see in other langauges and makes alot more sense now,

_____________________________

My sig sucks!

(in reply to kirrilian)

Post #: 10

RE: Regular expression tester - 7/6/2006 7:23:54 AM

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Hi mikeok,

your are welcome. By the way - what do you think about adding some persistency to your
Regular expression tester? It would be great, if you could save RegExps, options, test data,
and comments/explanations - perhaps even post samples here, that could be loaded
and studied.

ehvbs (just starting to dream)

(in reply to mikeock)

Revisions: 1 | Post #: 11

RE: Regular expression tester - 7/6/2006 7:26:23 AM

mikeock

Posts: 124
Score: 1
Joined: 6/8/2006
Status: offline

That is an intersting idea... I think that would be very cool and the tool would become that much more robust.....
Maybe you could use a txt file that has everything in a certain order, click load from hta and all of the fields are auto filled out?

Dunno just throwing out ideas seeing what others think!

_____________________________

My sig sucks!

(in reply to ehvbs)

Post #: 12

RE: Regular expression tester - 7/6/2006 8:04:58 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

could one of you share what the multiline flag does?

it seems to be poorly documented...

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to mikeock)

Post #: 13

RE: Regular expression tester - 7/6/2006 9:32:48 AM

ehvbs

Posts: 2012
Score: 48
Joined: 6/22/2005
From: Germany
Status: offline

Start a version of mikeok's .hta with the multiline code added. Enter RegExp
   ^a
(looking for an "a" at start) and the test data
   a
   b
   a
   b
Enable Global and Test: one match (the first "a", because the second one isn't at the
start). Activate Multiline and Test: two matches, because now the ^ means "at the
start of the whole string and at the start of each line (af