problem with script

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

problem with script

Logged in as: Guest

arrSession:exec spGetSession 2,2,3612

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> problem with script
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

problem with script - 7/1/2005 11:15:35 PM

Bezerk

Posts: 22
Score: 0
Joined: 6/20/2005
From: Netherlands
Status: offline

I have problem with my script, the last section where the users will be made member of a group. The first users goes ok, But the rest will fail.

Who has an good idea?

Thanks in advance

' NAME addusers.vbs
' PURPOSE create users from excel sheet
' This script is created in sections for ease of use
' All that needs to be done is edit the path to the excel sheet
'
' Here is the list of sections:
' SECTION A DECLARE VARIABLES
' SECTION B CONNECT TO ACTIVE DIRECTORY
' SECTION C OPEN AND READ THE SPREADSHEET
' SECTION D DO LOOP UNTIL EMPTY CELL IN SPREADSHEET
' SECTION E CHECK TO SEE IF USER OU EXISTS
' SECTION F CREATE THE USER
' SECTION G - ECHO CONFIRMATION MESSAGE
' SECTION H - TIDY UP RESET OBJECTS TO NOTHING

' SECTION A DECLARE VARIABLES

Option Explicit
' Objects declared :
Dim objRootDSE, objFSO, objShell
Dim objUser, objGroup, objContainer
Dim objExcel, objSheet

Dim objExcelFile
Dim objWSHShell

' Strings declared :
Dim strCN, strNTSam, strPWD, strOUContainer, strUPN
Dim strGroupDN, strLast, strFirst, strDescription, strGroup

Dim strHomeFolder, strHomeDrive
Dim strNetBIOSDomain, strDomain
Dim strProfileDir

' Integers declared :
Dim intNumusers, intRunError, intRow, intCol

'Declare Constants:
'path to excelsheet
objExcelFile = "C:\scripts\addusers.xls"
'First password for the users
strPWD = "Welkom01"
'start at row 2 first row is for headlines
intRow = 3
' Groups start in column 11
intCol = 11

Dim ReplaceACL

'SECTION B CONNECT TO ACTIVE DIRECTORY
' Get Domain name from RootDSE object.
Set objRootDSE = GetObject("LDAP://RootDSE")
strDomain = objRootDSE.Get("DefaultNamingContext")

'Section C OPEN AND READ THE SPREADSHEET
' Connect to spreadsheet where users are stored
Set objExcel = CreateObject("Excel.Application")

' Open the Speadsheet (Error Handling Section).
On Error Resume Next
Err.Clear
objExcel.Workbooks.Open objExcelFile
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Kan de file niet vinden!" & Space(2) & objExcelFile
Wscript.Quit
End If
On Error GoTo 0
Set objSheet = objExcel.ActiveWorkbook.Worksheets(1)

' SECTION D DO LOOP UNTIL EMPTY CELL IN SPREADSHEET

Do
' Read values from spreadsheet for this user.
strCN = Trim(objSheet.Cells(intRow, 1).Value)
strNTSam = Trim(objSheet.Cells(intRow, 2).Value)
strOUContainer = Trim(objSheet.Cells(intRow, 3).Value)
strFirst = Trim(objSheet.Cells(intRow, 4).Value)
strLast = Trim(objSheet.Cells(intRow, 5).Value)
strUPN = Trim(objSheet.Cells(intRow, 6).Value)
strHomeFolder = Trim(objSheet.Cells(intRow, 7).Value)
strHomeDrive = Trim(objSheet.Cells(intRow, 8).Value)
strProfileDir = Trim(objSheet.Cells(intRow, 9).Value)
strDescription = Trim(objSheet.Cells(intRow, 10).Value)
strGroup = Trim(objSheet.Cells(intRow, 11).Value)

' SECTION E CHECK TO SEE IF USER OU EXISTS
'extra section for error handling
' Connect to OU where users to be created.
On Error Resume Next
Err.Clear
Set objContainer = GetObject("LDAP://" & strOUContainer)

If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Edit the LDAP path to your OU " & strOUContainer
Wscript.Quit
End If
On Error GoTo 0

'SECTION F CREATE THE USER
On Error Resume Next
Err.Clear
Set objUser = objContainer.Create("user", "cn=" & strCN)
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Cannot create user with cn: " & strCN
Else
On Error GoTo 0
' Assign mandatory attributes cn and sAMAccountName.
If strNTSam = "" Then
strNTSam = strCN
End If
objUser.sAMAccountName = strNTSam
On Error Resume Next
Err.Clear
objUser.SetInfo
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Unable to create user with NT SAM name: " & strNTSam
Else
' Set password for user.
objUser.SetPassword strPWD
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Unable to set password for user " & strNTSam
End If
On Error GoTo 0
' Enable the user account.
objUser.AccountDisabled = False
If strFirst <> "" Then
objUser.givenName = strFirst
End If

' Assign values to remaining attributes.
If strLast <> "" Then
objUser.sn = strLast
End If
If strUPN <> "" Then
objUser.userPrincipalName = strUPN
End If
If strHomeDrive <> "" Then
objUser.homeDrive = strHomeDrive
End If
If strHomeFolder <> "" Then
objUser.homeDirectory = (strHomeFolder & strNTSam)
End If
If strProfileDir <> "" Then
objUser.profilepath = (strProfileDir & strNTSam)
End If

'Set user DisplayName
If strDescription <> "" Then
objUser.displayName = strDescription
End If

' Set password expired. Must be changed on next logon.
objUser.pwdLastSet = 0
' Save changes.
On Error Resume Next
Err.Clear
objUser.SetInfo
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Unable to set attributes for user with NT name: " _
& strNTSam
End If
On Error GoTo 0

'Section Create the home and profile directory and set permissions
Set objFSO = CreateObject("Scripting.FileSystemObject")

'check to see if the homedrive is available otherwise create one
If objfso.FolderExists(objUser.homeDirectory) = False Then
objfso.CreateFolder(objUser.homeDirectory)
End If
If objfso.FolderExists(objUser.profilepath) = False Then
objfso.CreateFolder(objUser.profilepath)
End If

'set the permissions
Set objWSHShell = CreateObject("Wscript.Shell")
objWSHShell.Run ("C:\scripts\SetACL.exe -on """ & objUser.homeDirectory & """ -ot file -actn ace " & "-ace ""n:msscript.org\" & strNTSam & ";p:full""")
objWSHShell.Run ("C:\scripts\SetACL.exe -on """ & objUser.profilepath & """ -ot file -actn ace " & "-ace ""n:msscript.org\" & strNTSam & ";p:full""")

wscript.sleep 1000

' Section H - Group Membership
'Loop Until empty cell.
Do
strGroupDN = Trim(objSheet.Cells(intRow, intCol).Value)
On Error Resume Next
Err.Clear
Set objGroup = GetObject("LDAP://" & strGroupDN)
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Unable to bind to group " & strGroupDN
Else
objGroup.Add objUser.AdsPath
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
Wscript.Echo "Unable to add user " & strNTSam _
& " to group " & strGroupDN
End If
End If
On Error GoTo 0
' Increment to next group DN.
intCol = intCol + 1
Loop Until objSheet.Cells(intRow, intCol).Value = ""
End If
End If

wscript.sleep 3000

' Increment to next user.
intRow = intRow + 1
intNumusers = intNumusers + 1
Loop Until objSheet.Cells(intRow, 1).Value = ""

' Section G - Echo confirmation Message
Wscript.Echo intNumusers & " Users created in " & strOUContainer

' Section H - Tidy up Reset objects to nothing

objExcel.ActiveWorkbook.Close
objExcel.Application.Quit
Set objUser = Nothing
Set objGroup = Nothing
Set objContainer = Nothing
Set objSheet = Nothing
Set objExcel = Nothing
Set objFSO = Nothing
Set objShell = Nothing
Set objRootDSE = Nothing
Set strProfileDir = Nothing
Set ReplaceACL = Nothing
Set objWSHShell = Nothing

Post #: 1

Re: problem with script - 7/2/2005 2:29:16 AM

didorno

Posts: 361
Score: 0
Joined: 2/12/2005
From:
Status: offline

Can you tell at which line(s) the process went wrong ?
What is the difference between the "first users" and the "rest", you mentioned. ?

Regards.

(in reply to Bezerk)

Post #: 2

Re: problem with script - 7/2/2005 10:40:55 AM

Bezerk

Posts: 22
Score: 0
Joined: 6/20/2005
From: Netherlands
Status: offline

Problem solved, it wasn't looking right.
Everything works like a charm, i even managed to add the mailboxes to the users as well.
So till now the script is doing what is suppose to do, now i am looking for logging capacabilities and maybe create a version that can read a .csv file instead of using excel.

(in reply to Bezerk)

Post #: 3

Re: problem with script - 7/3/2005 1:36:04 AM

ehvbs

Posts: 2171
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

ad .CSV

if you are familiar with the FileSystemObject and his cousins, you can
use OpenTextStream, AtEndOfStream, and Readline to move thru your x.csv,
splitting lines with Split() or RegExp. Expect problems with delimiters
and data fields containing delimiters.

if you are familiar with SQL/ADO and would make your work easy by using SQL features
like sorting, filtering, etc. you can use ADO/JET to get at your csv data.
' You can also open an Excel Spreadsheet using the JET OLE DB Provider ' oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _ ' "Data Source=c:\somepath\mySpreadsheet.xls;" & _ ' "Extended Properties=""Excel 8.0;HDR=Yes""" ' Where "HDR=Yes" means that there is a header row in the cell range ' (or named range), so the provider will not include the first row of the ' selection into the recordset. If "HDR=No", then the provider will include ' the first row of the cell range (or named ranged) into the recordset. ' For more information, see: Q278973

Expect some trouble with (security) settings and/or having to install
(a new version) of this or that.

(in reply to Bezerk)

Post #: 4

Re: problem with script - 7/3/2005 6:54:04 AM

Bezerk

Posts: 22
Score: 0
Joined: 6/20/2005
From: Netherlands
Status: offline

I preffer to stick with excel, becaseu of problem sorting the data with textfiles etc.

Database connections seems also a good point especially when doing migrations of huge enviroments, then userinformation is put into a database.

(in reply to Bezerk)

Post #: 5

Re: problem with script - 7/3/2005 7:55:28 AM

ehvbs

Posts: 2171
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

I don't doubt your decision. But because I maintained that
sorting would be easy:

Dim sFSpec
Dim nRecs
Dim nRows

sFSpec = ".\tosort.txt"
nRecs  = 100
nRows  =  10

ReDim aData( (nRecs - 1) )
Dim   nIdx
Dim   oFS

For nIdx = 0 To (nRecs - 1)
aData( nIdx ) = CStr( Rnd() )
Next

Set oFS = CreateObject( "Scripting.FileSystemObject" )
sFSpec  = oFS.GetAbsolutePathName( sFSpec )
oFS.CreateTextFile( sFSpec ).Write Join( aData, vbCrlf )

Dim sTmp
Dim oCnct
Dim oRS
Dim aRows

sTmp      =   "[tosort.txt]"        + vbCrLf _
+ "Format=Delimited(;)" + vbCrLf _
+ "Col1=dblN DOUBLE"    + vbCrLf

oFS.CreateTextFile( oFS.GetParentFolderName( sFSpec  ) + "\" + "schema.ini" ) _
.Write sTmp

sTmp      = "ADODB.Connection"
Set oCnct = CreateObject( sTmp )

sTmp      =   "Provider=MSDASQL;" _
+ "Driver={Microsoft Text Driver (*.txt; *.csv)};" _
+ "DBQ=" + oFS.GetParentFolderName( sFSpec  ) + ";"
oCnct.Open sTmp

sTmp    = "ADODB.Recordset"
Set oRS = CreateObject( sTmp )

sTmp    = "Select dblN From " + oFS.GetFileName( sFSpec ) + " ORDER BY dblN DESC"
oRS.Open sTmp, oCnct

aRows = oRS.GetRows( nRows )
For nIdx = 0 To (nRows - 1)
WScript.Echo aRows( 0, nIdx )
Next

oCnct.Close
Set oCnct = Nothing

output:

=== SortText: Sorting Text Files via ADO =
0,9994146
0,9860932
0,9800032
0,9798294
0,9790779
0,9619532
0,9495566
0,9485711
0,9193771
0,916164
=== SortText: 0 done (00:00:00) ==========

(in reply to Bezerk)

Post #: 6

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> problem with script

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts