Quirky Script

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Quirky Script

Logged in as: Guest

arrSession:exec spGetSession 2,2,36762

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Quirky Script
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Quirky Script - 8/7/2006 4:06:45 AM

Mindmesh

Posts: 78
Score: 0
Joined: 11/23/2004
From:
Status: offline

Ok so I wrote a script to decrypt all files and folders on a system provided it doesn't have a specfic application on the system. The scripts checks to see if the system is a laptop and if so it checks for the application. If the application is installed it will decrypt the system, otherwise it will encrypt the specified files and folders. Now when I run the script on a system that doesn't belong to our laptop users group it bombards the system with wscript.exe and cmd.exe processes. The error appears to happen in the FolderEncryption() sub where it runs the cipher command. I was wondering if anyone could determine what was causing this issue? Thanks for the help.

Dim wshNetwork, wshSysInfo, wshShell, wshProcEnv
Dim strUserProfile, strUserAdsPath
Dim strWinDir, strProcEnv, strEncrypted
Dim objFSO, objComputer, objGroupList
Dim i, arrProcEnv

Set wshNetwork = CreateObject("Wscript.Network")
Set wshSysInfo = CreateObject("ADSystemInfo")
Set wshShell = WScript.CreateObject("Wscript.shell") 'Creates Shell Script Object
Set objFSO = CreateObject("Scripting.FileSystemObject")
strUserAdsPath = wshSysInfo.ComputerName
Set objComputer = GetObject("LDAP://" & strUserAdsPath)

'Get User TMP and TEMP
Set wshProcEnv = WshShell.Environment("PROCESS")

i = 0
strUserProfile=wshProcEnv("UserProfile")
strWinDir = wshProcEnv("WinDir")

wshProcEnv("Encrypted") = "C:\Encrypted"
wshProcEnv("Spooler") = strWinDir & "\system32\spool\PRINTERS"
wshProcEnv("Outlook") = strUserProfile & "\Local Settings\Application Data\Microsoft\Outlook"
wshProcEnv("MyDocs") = strUserProfile & "\My Documents"
wshProcEnv("UserTemp") = strUserProfile & "\Local Settings\Temp"

strEncrypted = wshProcEnv("Encrypted")
arrProcEnv = Array(wshProcEnv("Spooler"), wshProcEnv("Outlook"), wshProcEnv("MyDocs"), wshProcEnv("UserTemp"))

' If member of the Laptop Users Group move on else encrypt\decrypt folders.
If IsMember(objComputer, "Laptop_Users") Then
   'If pointsec is installed decrypt files and folders 
   'then create the flag file for the encryption check
   If objFSO.FileExists(strPointSec) Then
       FolderDeCryption() 'calls decryption sub routine
       CreateFlagFile(strPointFlag)'calls create flag subroutine while passing flag name
       WScript.Echo strPointSec & " exists."
   Else
       'Encrypts files and folders if pointsec isn't installed
       For i = 0 To UBound(arrProcEnv)
           FolderEncryption(arrProcEnv(i)) ' calls encryption script and passes folders to encrypt.
       Next
   End If
Else
   For i = 0 To UBound(arrProcEnv)
       FolderEncryption(arrProcEnv(i))  'calls encryption script and passes folders to encrypt.
   Next
   FolderEncryption(strEncrypted)
   CreateFlagFile(strEFSFlag)
End If

WScript.Echo "Complete!"

Function IsMember(objADObject, strGroup)
' Function to test for group membership.
' objADObject is a user or computer object.
' strGroup is the NT name (sAMAccountName) of the group to test.
' objGroupList is a dictionary object, with global scope.
' Returns True if the user or computer is a member of the group.
' Subroutine LoadGroups is called once for each different objADObject.
 
 If IsEmpty(objGroupList) Then
   Set objGroupList = CreateObject("Scripting.Dictionary")
 End If
 If Not objGroupList.Exists(objADObject.sAMAccountName & "\") Then
   Call LoadGroups(objADObject, objADObject)
   objGroupList(objADObject.sAMAccountName & "\") = True
 End If
 If err.number <> 0 Then
     err.Clear
     err.number = 0
     IsMember = False
 Else
     IsMember = objGroupList.Exists(objADObject.sAMAccountName & "\" & strGroup)
 End If
End Function

Sub LoadGroups(objPriADObject ,objSubADObject)
' Recursive subroutine to populate dictionary object with group
' memberships. When this subroutine is first called by Function
' IsMember, both objPriADObject and objSubADObject are the user or
' computer object. On recursive calls objPriADObject still refers to the
' user or computer object being tested, but objSubADObject will be a
' group object. The dictionary object objGroupList keeps track of group
' memberships for each user or computer separately.
' For each group in the MemberOf collection, first check to see if
' the group is already in the dictionary object. If it is not, add the
' group to the dictionary object and recursively call this subroutine
' again to enumerate any groups the group might be a member of (nested
' groups). It is necessary to first check if the group is already in the
' dictionary object to prevent an infinite loop if the group nesting is
' "circular".

'On Error Resume Next

Dim colstrGroups, objGroup, j
 objGroupList.CompareMode = vbTextCompare
 colstrGroups = objSubADObject.memberOf
 If IsEmpty(colstrGroups) Then
   Exit Sub
 End If
 If TypeName(colstrGroups) = "String" Then
   Set objGroup = GetObject("LDAP://" & colstrGroups)
   If Not objGroupList.Exists(objPriADObject.sAMAccountName & "\" _
       & objGroup.sAMAccountName) Then
     objGroupList(objPriADObject.sAMAccountName & "\" _
       & objGroup.sAMAccountName) = True
     Call LoadGroups(objPriADObject, objGroup)
   End If
   Set objGroup = Nothing
   Exit Sub
 End If
 For j = 0 To UBound(colstrGroups)
   Set objGroup = GetObject("LDAP://" & colstrGroups(j))
   If Not objGroupList.Exists(objPriADObject.sAMAccountName & "\" _
       & objGroup.sAMAccountName) Then
     objGroupList(objPriADObject.sAMAccountName & "\" _
       & objGroup.sAMAccountName) = True
     Call LoadGroups(objPriADObject, objGroup)
   End If
 Next
 Set objGroup = Nothing
End Sub

Sub FolderEncryption(strDestFolder)
   Dim strCipher
   'Creates the command for encryption
   strCipher = "Cipher /E /S:""" & strDestFolder & """" 
   
   'Runs the encryption command 
   wshShell.Run  "%ComSpec% /c" & strCipher & " /A /F", 0
   
End Sub

Sub FolderDeCryption()
   Dim FileSet
   Dim objFile
   Dim strCipher
   
   'Pulls all the folders located on the local C:\ that are encrypted
   Set DirectorySet=GetObject("winmgmts:").ExecQuery("SELECT * FROM Win32_Directory WHERE Encrypted = True AND Drive = 'C:'") 
   'Decrypts all folders that are encrypted
   For Each objDir In DirectorySet
       strCipher = "Cipher /D /S:""" & objDir.Name & """"
       wshShell.Run "%ComSpec% /c" & strCipher & " /A", 0
       WScript.Echo objDir.name
   Next    
   Set DirectorySet = Nothing 'Releases variable
   
   'Pulls all files located on the local C:\ that are encrypted
   Set FileSet = GetObject("winmgmts:").ExecQuery("SELECT * FROM CIM_DataFile WHERE Encrypted = True AND Drive = 'C:'")

' Decrypt All Encrypted Files.
   For Each objFile In FileSet
       strCipher = "Cipher /D /S:""" & objFile.Name & """"
       wshShell.Run "%ComSpec% /c" & strCipher & " /A", 0
       'WScript.Echo objFile.name
   Next
   Set FileSet = Nothing

End Sub

'Creates the flag file
Sub CreateFlagFile(strFlagDir)
   Dim strFlag
   Dim strFlagName
   
   strFlagName = strFlagDir & wshNetwork.ComputerName
   WScript.Echo strFlagName
   Set strFlag = objFSO.CreateTextFile(strFlagName, True)
   
   strFlag.Close
End Sub

Post #: 1

RE: Quirky Script - 8/7/2006 5:35:14 AM

Mindmesh

Posts: 78
Score: 0
Joined: 11/23/2004
From:
Status: offline

Just an FYI. It works fine if the script is run under CScript. But if it's run under WScript then it goes nuts.

(in reply to Mindmesh)

Post #: 2

RE: Quirky Script - 8/7/2006 5:50:49 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

I haven't read the script itself, but you should be aware that WScript.Echo acts like MsgBox when the script is run with WScript. So anywhere in your script that you have WScript.Echo, the script will pop open a message box on the screen.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Mindmesh)

Post #: 3

RE: Quirky Script - 8/7/2006 5:55:02 AM

Mindmesh

Posts: 78
Score: 0
Joined: 11/23/2004
From:
Status: offline

Yeah that wouldn't be so bad. I only use the wscript.echo for troubleshooting, but this is different. It's not a message box that's popping up it's like 300 cmd.exe boxes. Also, in task manager there are about 150 wscript.exe's. Not sure what would cause such a significant differnece between the two shells (Proper term???).

(in reply to ebgreen)

Post #: 4

RE: Quirky Script - 8/7/2006 7:13:11 AM

DiGiTAL.SkReAM

Posts: 1194
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

Well, I have found that if you use a Shell.Run command, and don't specify that you want it to wait until the command if compelte before moving on to the next line, it won't.
I modified your shell.run statements to wait for the process to close, so give this a try.

'Option Explicit
'On Error Resume Next
Const strPointSec = "C:\Program Files\Pointsec\P95TRAY.exe"
Const strPointFlag = "\\W2KIT02\Everyone_LT\Perm\Scripts\Encrypted\Pointsec_Encrypted\"
Const strEFSFlag = "\\W2KIT02\Everyone_LT\Perm\Scripts\Encrypted\EFS_Encrypted\"
Dim wshNetwork, wshSysInfo, wshShell, wshProcEnv
Dim strUserProfile, strUserAdsPath
Dim strWinDir, strProcEnv, strEncrypted
Dim objFSO, objComputer, objGroupList
Dim i, arrProcEnv
Set wshNetwork = CreateObject("Wscript.Network")
Set wshSysInfo = CreateObject("ADSystemInfo")
Set wshShell = WScript.CreateObject("Wscript.shell") 'Creates Shell Script Object
Set objFSO = CreateObject("Scripting.FileSystemObject")
strUserAdsPath = wshSysInfo.ComputerName
Set objComputer = GetObject("LDAP://" & strUserAdsPath)
'Get User TMP and TEMP
Set wshProcEnv = WshShell.Environment("PROCESS")
i = 0
strUserProfile=wshProcEnv("UserProfile")
strWinDir = wshProcEnv("WinDir")
wshProcEnv("Encrypted") = "C:\Encrypted"
wshProcEnv("Spooler") = strWinDir & "\system32\spool\PRINTERS"
wshProcEnv("Outlook") = strUserProfile & "\Local Settings\Application Data\Microsoft\Outlook"
wshProcEnv("MyDocs") = strUserProfile & "\My Documents"
wshProcEnv("UserTemp") = strUserProfile & "\Local Settings\Temp"
strEncrypted = wshProcEnv("Encrypted")
arrProcEnv = Array(wshProcEnv("Spooler"), wshProcEnv("Outlook"), wshProcEnv("MyDocs"), wshProcEnv("UserTemp"))

' If member of the Laptop Users Group move on else encrypt\decrypt folders.
If IsMember(objComputer, "Laptop_Users") Then
  'If pointsec is installed decrypt files and folders 
  'then create the flag file for the encryption check
  If objFSO.FileExists(strPointSec) Then
      FolderDeCryption() 'calls decryption sub routine
      CreateFlagFile(strPointFlag)'calls create flag subroutine while passing flag name
      WScript.Echo strPointSec & " exists."
  Else
      'Encrypts files and folders if pointsec isn't installed
      For i = 0 To UBound(arrProcEnv)
          FolderEncryption(arrProcEnv(i)) ' calls encryption script and passes folders to encrypt.
      Next
  End If
Else
  For i = 0 To UBound(arrProcEnv)
      FolderEncryption(arrProcEnv(i))  'calls encryption script and passes folders to encrypt.
  Next
  FolderEncryption(strEncrypted)
  CreateFlagFile(strEFSFlag)
End If
WScript.Echo "Complete!"
  
Function IsMember(objADObject, strGroup)
' Function to test for group membership.
' objADObject is a user or computer object.
' strGroup is the NT name (sAMAccountName) of the group to test.
' objGroupList is a dictionary object, with global scope.
' Returns True if the user or computer is a member of the group.
' Subroutine LoadGroups is called once for each different objADObject.

If IsEmpty(objGroupList) Then
  Set objGroupList = CreateObject("Scripting.Dictionary")
End If
If Not objGroupList.Exists(objADObject.sAMAccountName & "\") Then
  Call LoadGroups(objADObject, objADObject)
  objGroupList(objADObject.sAMAccountName & "\") = True
End If
If err.number <> 0 Then
    err.Clear
    err.number = 0
    IsMember = False
Else
    IsMember = objGroupList.Exists(objADObject.sAMAccountName & "\" & strGroup)
End If
End Function
Sub LoadGroups(objPriADObject ,objSubADObject)
' Recursive subroutine to populate dictionary object with group
' memberships. When this subroutine is first called by Function
' IsMember, both objPriADObject and objSubADObject are the user or
' computer object. On recursive calls objPriADObject still refers to the
' user or computer object being tested, but objSubADObject will be a
' group object. The dictionary object objGroupList keeps track of group
' memberships for each user or computer separately.
' For each group in the MemberOf collection, first check to see if
' the group is already in the dictionary object. If it is not, add the
' group to the dictionary object and recursively call this subroutine
' again to enumerate any groups the group might be a member of (nested
' groups). It is necessary to first check if the group is already in the
' dictionary object to prevent an infinite loop if the group nesting is
' "circular".
'On Error Resume Next
Dim colstrGroups, objGroup, j
objGroupList.CompareMode = vbTextCompare
colstrGroups = objSubADObject.memberOf
If IsEmpty(colstrGroups) Then
  Exit Sub
End If
If TypeName(colstrGroups) = "String" Then
  Set objGroup = GetObject("LDAP://" & colstrGroups)
  If Not objGroupList.Exists(objPriADObject.sAMAccountName & "\" _
      & objGroup.sAMAccountName) Then
    objGroupList(objPriADObject.sAMAccountName & "\" _
      & objGroup.sAMAccountName) = True
    Call LoadGroups(objPriADObject, objGroup)
  End If
  Set objGroup = Nothing
  Exit Sub
End If
For j = 0 To UBound(colstrGroups)
  Set objGroup = GetObject("LDAP://" & colstrGroups(j))
  If Not objGroupList.Exists(objPriADObject.sAMAccountName & "\" _
      & objGroup.sAMAccountName) Then
    objGroupList(objPriADObject.sAMAccountName & "\" _
      & objGroup.sAMAccountName) = True
    Call LoadGroups(objPriADObject, objGroup)
  End If
Next
Set objGroup = Nothing
End Sub
Sub FolderEncryption(strDestFolder)
  Dim strCipher
  'Creates the command for encryption
  strCipher = "Cipher /E /S:""" & strDestFolder & """" 
  
  'Runs the encryption command 
  wshShell.Run  "%ComSpec% /c" & strCipher & " /A /F", 0, True 
  
End Sub
Sub FolderDeCryption()
  Dim FileSet
  Dim objFile
  Dim strCipher
  
  'Pulls all the folders located on the local C:\ that are encrypted
  Set DirectorySet=GetObject("winmgmts:").ExecQuery("SELECT * FROM Win32_Directory WHERE Encrypted = True AND Drive = 'C:'") 
  'Decrypts all folders that are encrypted
  For Each objDir In DirectorySet
      strCipher = "Cipher /D /S:""" & objDir.Name & """"
      wshShell.Run "%ComSpec% /c" & strCipher & " /A", 0, True
      WScript.Echo objDir.name
  Next    
  Set DirectorySet = Nothing 'Releases variable
  
  'Pulls all files located on the local C:\ that are encrypted
  Set FileSet = GetObject("winmgmts:").ExecQuery("SELECT * FROM CIM_DataFile WHERE Encrypted = True AND Drive = 'C:'")
  ' Decrypt All Encrypted Files.
  For Each objFile In FileSet
      strCipher = "Cipher /D /S:""" & objFile.Name & """"
      wshShell.Run "%ComSpec% /c" & strCipher & " /A", 0, True
      'WScript.Echo objFile.name
  Next
  Set FileSet = Nothing
  
End Sub
'Creates the flag file
Sub CreateFlagFile(strFlagDir)
  Dim strFlag
  Dim strFlagName
  
  strFlagName = strFlagDir & wshNetwork.ComputerName
  WScript.Echo strFlagName
  Set strFlag = objFSO.CreateTextFile(strFlagName, True)
  
  strFlag.Close
End Sub

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to Mindmesh)

Post #: 5

RE: Quirky Script - 8/8/2006 1:26:27 AM

mcds99

Posts: 441
Score: 4
Joined: 2/28/2006
Status: offline

Run the script in a wrapper.

In a .cmd file put cscript scriptname.vbs
Create a short cut that runs minimized calling the .cmd file.

No more popup command prompts.

_____________________________

Sam

Keep it Simple Make it Fun KiSMiF

(in reply to Mindmesh)

Post #: 6

RE: Quirky Script - 8/8/2006 4:26:50 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

its much easier to just set cscript as your default script host

Tue 08/08/2006 @ 12:25:14.67 | kirrilian@workstation
C:\Documents and Settings\grhea.dis.000
=)cscript //H:cscript
Microsoft (R) Windows Script Host Version 5.6
Copyright (C) Microsoft Corporation 1996-2001. All rights reserved.

The default script host is now set to "cscript.exe".

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to mcds99)