Registry Search (through export)

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Registry Search (through export)

Logged in as: Guest

arrSession:exec spGetSession 2,16,37092

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Registry Search (through export)
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Registry Search (through export) - 8/18/2006 2:15:52 AM

Snipah

Posts: 1343
Score: 6
Joined: 11/1/2004
From: Netherlands
Status: offline

This code is officially not mine, but it was optimized for use with 2k and XP machines....

It is commented throughout the use of it... Copy/Save and Run it...it will ask you for a specific search term (case sensisitve) and it will dump the registry in a tempfile and output the search results in another tempfile...

As example i searched for a term that was spread throughout the registry, it found 79 items in ~29 seconds...in a registry of 35MB...

Good luck...

Option Explicit
Dim oWS : Set oWS = CreateObject("WScript.Shell")
Dim oFSO : Set oFSO = CreateObject("Scripting.FileSystemObject")
Dim sSearchFor

sSearchFor = InputBox("This script will search your Registry and find all " & _
            "instances of the search string you input."  & vbcrlf & vbcrlf & _
            "This search could take several minutes, so please be patient." & _
            vbcrlf & vbcrlf & "Enter search string (case insensitive) and " & _
            "click OK...")

If sSearchFor = "" Then Cleanup()

Dim StartTime : StartTime = Timer
Dim sRegTmp, sOutTmp, eRegLine, iCnt, sRegKey, aRegFileLines
sRegTmp = oWS.Environment("Process")("Temp") & "\RegTmp.tmp "
sOutTmp = oWS.Environment("Process")("Temp") & "\sOutTmp" & _
         Hour(Now) & Minute(Now) & Second(Now) & ".tmp "
oWS.Run "regedit /e /a " & sRegTmp, , True '/a enables export as Ansi for WinXP

With oFSO.OpenTextFile(sOutTmp, 8, True)
 .WriteLine("REGEDIT4" & vbcrlf & vbcrlf & "; Registry search " & _
   "results for string " & Chr(34) & sSearchFor & Chr(34) & " " & Now & _
   vbcrlf & vbcrlf & "; NOTE: This file will be deleted when you close " & _
   "WordPad." & vbcrlf & "; You must manually save this file to a new " & _
   "location if you want to refer to it again later." & vbcrlf & "; (If " & _
   "you save the file with a .reg extension, you can use it to restore " & _
   "any Registry changes you make to these values.)" & vbcrlf)

With oFSO.GetFile(sRegTmp)
   aRegFileLines = Split(.OpenAsTextStream(1, 0).Read(.Size), vbcrlf)
 End With

oFSO.DeleteFile(sRegTmp)
 For Each eRegLine in aRegFileLines
   If InStr(1, eRegLine, "[", 1) > 0 Then sRegKey = eRegLine
   If InStr(1, eRegLine, sSearchFor, 1) >  0 Then
     If sRegKey <> eRegLine Then
       .WriteLine(vbcrlf & sRegKey) & vbcrlf & eRegLine
     Else
       .WriteLine(vbcrlf & sRegKey)
     End If
     iCnt = iCnt + 1
   End If
 Next
 Erase aRegFileLines
 If iCnt < 1 Then
   oWS.Popup "Search completed in " & FormatNumber(Timer - StartTime, 0) & " seconds." & _
             vbcrlf & vbcrlf & "No instances of " & chr(34) & sSearchFor & chr(34) & _
             " found.",,, 4096
   .Close
   oFSO.DeleteFile(sOutTmp)
   Cleanup()
 End If
 .Close
End With

oWS.Popup "Search completed in " & FormatNumber(Timer - StartTime, 0) & " seconds." & _
         vbcrlf & vbcrlf & iCnt & " instances of " & chr(34) & sSearchFor & chr(34) & _
         " found." & vbcrlf & vbcrlf & "Click OK to open Results in WordPad.",,, 4096
oWS.Run "WordPad " & sOutTmp, 3, True
oFSO.DeleteFile(sOutTmp)

Cleanup()

Sub Cleanup()
 Set oWS = Nothing
 Set oFSO = Nothing
 WScript.Quit
End Sub

_____________________________

For more information, please see the "Read me First" topic.

http://www.visualbasicscript.com

Post #: 1

RE: Registry Search (through export) - 8/18/2006 2:59:07 AM

DiGiTAL.SkReAM

Posts: 1183
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

http://www.visualbasicscript.com/m_35588/mpage_1/key_search%2cregistry/tm.htm#35598

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to Snipah)