RE: Run Maintenance on a PC through Script.

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

RE: Run Maintenance on a PC through Script.

Logged in as: Guest

arrSession:exec spGetSession 2,2,37156

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> RE: Run Maintenance on a PC through Script.
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: << < prev 1 [2]

Message

<< Older Topic Newer Topic >>

RE: Run Maintenance on a PC through Script. - 9/6/2006 1:41:39 AM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

this may help. when I get time I'll try help further

'RUN CLEANUP MANAGER
wshshell.run c:\windows\system32\cleanmgr.exe /dc /sagerun: 1 'Will run cleanup Manager on drive C: and D:

'DEFRAG HARD DRIVE
On Error Resume Next
Dim WSHShell
Set WSHShell = CreateObject("WScript.Shell")
If Weekday(date) = 6 then 
WshShell.Run "defrag.exe c: /f ", 0, True
End If
Set WshShell = Nothing

'DELETE LOCAL USER ACCOUNT
strComputer = "MyComputer"
strUser = "Admin2"
Set objComputer = GetObject("WinNT://" & strComputer & "")
objComputer.Delete "user", strUser

' DISKCLEANER V. 1.1
' ------------------
' Deletes useless files on the disk and useless registry keys
' with no option : display a message when a file cannot be deleted because it is locked
' /v : verbose, display messages for every action
' /q : quiet, does not display the default messages. Supersedes /v
' /r : ask for confirmation before changing the registry
'
' (c) E. Marcon 2004
'     http://e.marcon.free.fr
'-----------------------------------------------------------------------------------------------------------------

Option Explicit

' Declare basic objects
dim wshFSO :    Set wshFSO = CreateObject("Scripting.FileSystemObject")
dim wshShell :  Set wshShell = CreateObject("WScript.Shell")
dim wshSysEnv : Set wshSysEnv = wshShell.Environment
dim wshUsrEnv : Set wshUsrEnv = wshShell.Environment("User")
dim wshPrcEnv : Set wshPrcEnv = wshShell.Environment("Process")
dim wshNet :    Set wshNet = WScript.CreateObject("WScript.Network")
dim wshArgs :   Set wshArgs = WScript.Arguments

' How to get paths whatever the configuration
'==================================================================================================================
'
' Available special folders: wshShell.SpecialFolders("Name")
'-----------------------------------------------------------
' AllUsersDesktop 
' AllUsersStartMenu 
' AllUsersPrograms 
' AllUsersStartup 
' Desktop 
' Favorites 
' Fonts 
' MyDocuments 
' NetHood 
' PrintHood 
' Programs 
' Recent 
' SendTo 
' StartMenu
' Startup 
' Templates 
'
' Available special folders: wshFSO.GetSpecialFolder(Value)
'----------------------------------------------------------
Const WindowsFolder   = 0
Const SystemFolder   = 1
Const TemporaryFolder = 2
'
' Available environment paths (System, User, Process): wshSysEnv("NAME"), wshUsrEnv("NAME") or wshPrcEnv("NAME")
'---------------------------------------------------------------------------------------------------------------
' Environment variables may be System, User or Process. The table gives the usual value in each environment array
' Values including other variables (%SystemRoot%) must be transformed before use (complicated, use another way)
' USERPROFILE is not available
'-----------------------------------------------------------------------------------------------------------------------------
' NAME         ! Content         !     wshSysEnv     !    wshUsrEnv     !       wshPrcEnv        !
'-----------------------------------------------------------------------------------------------------------------------------
' HOMEDRIVE    ! primary drive   !                   !                  ! C:                    !
' SYSTEMDRIVE  ! Windows drive   !                   !                  ! C:                    !
' SYSTEMROOT   ! Windows folder  !                   !                  ! C:\Windows            !
' WINDIR       ! Windows folder  ! %SystemRoot%      !                  ! C:\Windows            !
' TEMP, TMP    ! Temporary folder ! %SystemRoot%\TEMP ! %USERPROFILE%\Local Settings\Temp! C:\DOCUME~1\MyName\LOCALS~1\Temp !
'-----------------------------------------------------------------------------------------------------------------
'
' All Windows Environment variable (Process) are available through WshShell.ExpandEnvironmentStrings("%UserProfile%")
'-----------------------------------------------------------------------------------------------------------------
' Ex.: WshShell.ExpandEnvironmentStrings("%UserProfile%")
'
' Use the registry to get user's paths: WshShell.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\Name")
'----------------------------------------
' AppData
' Cookies
' Desktop
' Favorites
' NetHood
' Personal            (My Documents)
' PrintHood
' Recent
' SendTo
' Start Menu
' Templates
' Programs
' Startup
' Local Settings
' Local AppData
' Cache               (Temporary Internet Files)
' History
' My Pictures
' Fonts
' My Music
' Administrative Tools
' CD Burning
' My Video

'
'=====================================================================================================================

' Read the arguments
'--------------------
dim I
dim blnVerbose : blnVerbose = False
dim blnQuiet : blnQuiet = False
dim blnAskRegistry : blnAskRegistry = False
For I = 0 to wshArgs.Count - 1
  blnVerbose       = blnVerbose     Or (wshArgs(I)="/v") Or (wshArgs(I)="/V")
  blnQuiet         = blnQuiet       Or (wshArgs(I)="/q") Or (wshArgs(I)="/Q")
  blnAskRegistry   = blnAskRegistry Or (wshArgs(I)="/r") Or (wshArgs(I)="/R")
Next
dim blnShowErrors : blnShowErrors = Not blnQuiet

' Display help
' ------------
Wscript.Echo("DiskCleaner" & vbCrLf _
& " Delete useless files on the disk and useless registry keys" & vbCrLf _
& "    with no option : display warning messages" & vbCrLf _
& "    /v : verbose, display messages for every action" & vbCrLf _
& "    /q : quiet, does not display the default messages. Supersedes /v" & vbCrLf _
& "    /r : ask for confirmation before changing the registry" & vbCrLf _
& " (c) E. Marcon 2004-2005" & vbCrLf _
& " http://e.marcon.free.fr" & vbCrLf)

' List the folders to clean
'------------------------------
' Get the system temporary folder
dim strSysTempFolder : strSysTempFolder = wshSysEnv("TEMP")
' Develop %SystemRoot%
strSysTempFolder = Replace(strSysTempFolder, "%SystemRoot%", wshPrcEnv("SYSTEMROOT"), 1, -1, vbTextCompare)

' Get Office XP Recent Files folder
dim strOfficeRecent
'strOfficeRecent = WshShell.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\AppData") _ 
'    & "\Microsoft\Office\" & WshShell.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Office\10.0\Common\General\RecentFiles")

' List
dim arrFolderList
' Recent Files, System temp folder, User temp folder; Office recent files, Temporary internet files
arrFolderList = array( _
  wshShell.SpecialFolders("Recent"), _
  strSysTempFolder, _
  wshFSO.GetSpecialFolder(TemporaryFolder).Path, _
  strOfficeRecent, _
  WshShell.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\Cache") _
  )

' Clean the folders
'------------------------------
dim strFolderI
For Each strFolderI in arrFolderList
  If blnVerbose Then
     Echo("- " & strFolderI)
  End If
  FolderDelete strFolderI, True, blnShowErrors
Next

' Clean the registry
'-------------------
dim arrRegistryList
' Media Player's recent files, Explorer's recent files
arrRegistryList = array( _
  "[-HKEY_CURRENT_USER\Software\Microsoft\MediaPlayer\Player\RecentFileList]", _
  "[-HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\RecentDocs]" _
  )
  
' Create a temp file
Dim strTempName : strTempName = wshFSO.GetTempName
dim oTempFile : Set oTempFile = CreateTempFile(strTempName)
' Make it a registry file
oTempFile.WriteLine "REGEDIT4"

' Add each registry key
dim strRegistryI
For Each strRegistryI in arrRegistryList
  If blnVerbose Then
     Echo("- " & strRegistryI)
  End If
  oTempFile.WriteLine strRegistryI
Next
oTempFile.Close

' Call regedit to do the job (wshShell.RegDelete is very limited)
dim strCommand : strCommand = "Regedit "
' Silent or not, according to the arguments
If Not blnAskRegistry Then strCommand = strCommand & "/s "
strCommand = strCommand & strTempName
' Run Regedit
wshShell.Run strCommand, 1, True
' Delete the temp file
wshFSO.DeleteFile strTempName

' End of the main script
'------------------------

' FolderDelete:  Recursively delete a folder's content and optionaly the folder itself
'-------------------------------------------------------------------------------------
Sub FolderDelete(strBaseFolder, blnContentOnly, blnShowErrors)

If wshFSO.FolderExists(strBaseFolder) Then
      ' The folder might have been erased
      dim oBaseFolder : Set oBaseFolder = wshFSO.GetFolder(strBaseFolder)
      dim oFolderI, oFileI
      ' Subfolders first
      For Each oFolderI in oBaseFolder.SubFolders
          ' Recursive call to this procedure
          FolderDelete oFolderI.Path, False, blnShowErrors
      Next
      ' Files then
      For Each oFileI in oBaseFolder.Files
          On Error Resume Next
          ' Delete the file
          oFileI.Delete
          ' Check errors
          If Err.number <> 0 Then
              If blnShowErrors Then
                  Echo("! " & oFileI.Path & ": " & Err.Description)
              End If
              Err.Clear 
          End If
          On Error Goto 0
      Next
      ' Last, the folder itself
      If not blnContentOnly Then
          On Error Resume Next
          ' Delete the folder
          oBaseFolder.Delete
          If Err.number <> 0 Then
              If blnShowErrors Then
                  Echo("! " & oBaseFolder.Path & ": " & Err.Description)
              End If
              Err.Clear 
          End If
          On Error Goto 0
      End If
  End If
      
End Sub

' CreateTempFile:  Generate a text file in the temp folder
' Returns a textstream
' strTempName is the file name. After the file is created, strTempName contains its path
' since a textream does not have a .Name or .Path property
'--------------------------------------------------------------------------------------
Function CreateTempFile(ByRef strTempName)

Dim oTempFolder, oTempFile
  ' Get the temp folder
  Set oTempFolder = wshFSO.GetSpecialFolder(TemporaryFolder)
  ' Create the text file
  Set oTempFile = oTempFolder.CreateTextFile(strTempName)
  ' Return the file (textstream object) and the path
  strTempName = oTempFolder.Path & "\" & strTempName
  Set CreateTempFile = oTempFile

End Function

' Echo : display a message
'-------------------------
Sub Echo(ByVal strMessage)

If Not blnQuiet then
     Wscript.Echo(strMessage)
  End If

End Sub

'The End
'-------

//EDIT: added code tags

< Message edited by Snipah -- 10/9/2006 11:53:00 PM >

(in reply to morpheus83uk)

Post #: 21

RE: Run Maintenance on a PC through Script. - 9/6/2006 3:22:08 AM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Oh My word!!!!!

I have no idea what any of that means....

Ok from the top...

Disk Cleanup...

I have run the below command to setup Disk Cleanup automatically....

cleanmgr /d c: /sageset:100

I have set the options and ticked all the boxes....

Now I believe the values are stored here:

HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft \ Windows \ CurrentVersion \ Explorer \VolumeCaches

Which is fine... So if I use the cleanmgr /sagerun:100 could I import the settings from the registry onto another PC and then run the above command? (Through a Script)

Ok the defrag hard drive....

Kind of a little bit lost here... I am presuming that the whole thing defrags the C drive and forces it to do it now without analysis but checks to see if its a Saturday?? If this is true thats great it would indeed work for me but I need it to defrag all the hard disks on the drive... is there just a slight modification needed or am I completly wrong about the code???

Ok deleting the users accounts...

Would that remove the Admin2 account there? and remove the registry entries just like it would if you were to remove it from the system icon within control panel? and also I would need it to check and remove user accounts which havent been modified or accessed within the last 2 months.

Disk Cleaner...

I presume thats an alteernative to regseeker? I will have a look into it when I get a little time if I am right in thinking that thats for that much appreciated!!!

I take it then the mass of code below that is the code needed to clean up the registry and remove like temoray internet files etc? I mean I can possibly guess as some of it????

Many Thanks for you input thats great... I will throw it into a vbs and see what happens at some point and have a play but at the moment I am just on my way out!!!

Thanks again!!!!!! :)

James

(in reply to gdewrance)

Post #: 22

RE: Run Maintenance on a PC through Script. - 9/6/2006 9:08:10 PM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

this page my help with your questions on cleanmgr

http://www.ss64.com/nt/cleanmgr.html

Open The Command Prompt
START
RUN

cleanmgr /sageset:x (i recommend x=1) cleanmgr /sageset:1

a box will popup, then check mark all the items and click OK

then type:

cleanmgr /sagerun:x (if you choose 1...type 1) cleanmgr /sagerun:1

now...you can use the cleanmgr /sagerun:x as many times you want, ok ?... sageset is just one time or ...define it as many times you want it, by the way.. x is a # betwheen 0 and 65235

< Message edited by gdewrance -- 9/6/2006 9:14:45 PM >

(in reply to morpheus83uk)

Post #: 23

RE: Run Maintenance on a PC through Script. - 9/12/2006 2:23:26 AM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

hello,

I have followed the instructions on the website you have provided.

What happens with teh disk cleanup when I use the example the guy has on that website I use the same reg file as him and point it to the correct directory and everything and it runs gets to looking for the files to cleanup and then it just goes away....

Any ideas??

I will have a play with the other stuff you have posted hopefully a little later today :)

Many Thanks

James

(in reply to gdewrance)

Post #: 24

RE: Run Maintenance on a PC through Script. - 9/12/2006 5:10:00 PM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

I would have just run sageset number and extracted my own reg settings to install to other computers as this sets the flag value. then just use sagerun number to execute it

(in reply to morpheus83uk)

Post #: 25

RE: Run Maintenance on a PC through Script. - 9/13/2006 11:33:38 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Thanks for that I have done that and it seems to work... I will test on another PC to make sure all goes well...

As for the whole deleting a user thing I have been told about delprof which would work fine....

I cant seem to find out a way of deleting the Account Unknown Profiles uless that code above does that? If it does how could it be modified to remove ALL the Account Unkown Profiles?

Many Thanks

James

(in reply to gdewrance)

Post #: 26

RE: Run Maintenance on a PC through Script. - 9/14/2006 1:49:58 AM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Ok I have the following Code:

[Code]

'Install DELPROF
set WshShell = CreateObject("WScript.Shell")
WshShell.Run "\\scnsmssrvr\Software\Maintenance\delprof.msi"
WshShell.SendKeys "{ENTER}"
WshShell.SendKeys "{TAB}"
WshShell.SendKeys "{UP}"
WshShell.SendKeys "{ENTER}"
WshShell.SendKeys "{ENTER}"
WshShell.SendKeys "{ENTER}"
'Run Delprof Silently
WshShell.Run "cmd /c "c: && cd "\Program Files\Windows Resource Kits\Tools\" && delprof /q /d:62"
WshShell.SendKeys "{ENTER}"

[/Code]

It tellls me that it its expecting an end of statement when it gets to:

WshShell.Run "cmd /c "c

Any ideas why? or how I can rectify the problem?

Many Thanks

James

(in reply to morpheus83uk)

Post #: 27

RE: Run Maintenance on a PC through Script. - 9/18/2006 11:04:49 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Hello,

Has anyone got any ideas on how I might be able to do this?

I am working on one part of this at a time now so I dont get all confused...

Many Thanks

James

(in reply to morpheus83uk)

Post #: 28

RE: Run Maintenance on a PC through Script. - 9/18/2006 11:14:11 PM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

you may want to look here http://www.activexperts.com/activmonitor/windowsmanagement/adminscripts/usersgroups/localusers/

here are some scripts http://www.cruto.com/resources/vbscript/vbscript-examples/vbscript-sitemap.asp

< Message edited by gdewrance -- 9/18/2006 11:18:52 PM >

(in reply to morpheus83uk)

Post #: 29

RE: Run Maintenance on a PC through Script. - 9/24/2006 7:26:10 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Hi,

Thanks for them I have pulled some stuff off there...

Any ideas on how I can get my code to work though? with the command line I am trying to run?

Many Thanks

James

(in reply to gdewrance)

Post #: 30

RE: Run Maintenance on a PC through Script. - 9/26/2006 11:28:27 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Hello,

I have the following code:

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
   & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSoftware = objWMIService.ExecQuery _
   ("Select * from Win32_Product Where Name = 'Netscape Communicator 4.7'")
For Each objSoftware in colSoftware
   objSoftware.Uninstall()
Next

Thing is it does not actually remove netscape navigator...

Anyone any ideas on this?

Many Thanks

James

(in reply to morpheus83uk)

Post #: 31

RE: Run Maintenance on a PC through Script. - 9/26/2006 11:51:04 PM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

try modifying this

const HKEY_LOCAL_MACHINE = &H80000002
strComputer = "."
Set oReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
          strComputer & "\root\default:StdRegProv")
Set WshShell = WScript.CreateObject("WScript.Shell")

' Uninstall first application...
strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\1st JavaScript Editor 3" '<--- change as needed
strValueName = "UninstallString"
oReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strUninstallFullPath
If IsNull(strUninstallFullPath) Then
' wscript.echo "Uninstall path for app1 is null"
Else
' the following line -y switch suppresses the confirmation question from poping up
strUninstallFullPath=strUninstallFullPath & " -y"                                 '<--- change as needed
WshShell.Run strUninstallFullPath,8,true
End If

' Uninstall second application...
strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\SomeOtherApp"      '<--- change as needed
strValueName = "UninstallString"
oReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strUninstallFullPath
If IsNull(strUninstallFullPath) Then
' wscript.echo "Uninstall path for app2 is null"
Else
WshShell.Run strUninstallFullPath,8,true
End If

Set WshShell = Nothing
Set oReg = Nothing

(in reply to morpheus83uk)

Post #: 32

RE: Run Maintenance on a PC through Script. - 9/27/2006 6:45:32 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Hello,

Thanks for that it runs the uninstaller which is great but thing is I get an Error telling me the DEINSTALL path is not found....

I have found the Deinstall path which is located:

HKEY_LOCAL_MACHINE\Software\Netscape\Deinstall\4.7 (en)

In there theere are 2 keys one which are:

Deinstall Exe
Deinstall File Path

Anyone know where I put the path for the deinstall so it can continue removeing the application?

Its all slowely coming together and I am learning loads thats to you all! :)

Many Thanks

James

< Message edited by morpheus83uk -- 9/27/2006 6:50:36 PM >

(in reply to gdewrance)

Post #: 33

RE: Run Maintenance on a PC through Script. - 9/27/2006 7:04:46 PM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

did you check the path in the registry that the uninstall key points to

(in reply to morpheus83uk)

Post #: 34

RE: Run Maintenance on a PC through Script. - 9/27/2006 9:01:29 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

The path the registry points to is:

C:\WINDOWS\cd32.exe 4.7 (en)

so I presume the above exe runs it???

Possibly?

Or do we need to modify something first?

Many Thanks

James

(in reply to gdewrance)

Post #: 35

RE: Run Maintenance on a PC through Script. - 10/9/2006 11:43:15 PM

morpheus83uk

Posts: 435
Score: 0
Joined: 8/21/2006
Status: offline

Does anyone in here know how I could get the code to remove netscape for me with any modifications?

Oh and about the delprof thing anyone got any suggestions on how I can get it to work?

Many Thanks

James

(in reply to morpheus83uk)