Mass user account change

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Mass user account change

Logged in as: Guest

arrSession:exec spGetSession 2,16,38622

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Mass user account change
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Mass user account change - 10/11/2006 11:41:23 PM

Meg

Posts: 125
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Wrote this script to automate some boring and error prone work for a lot of user accounts we are converting to XP

1. Script checks for variables and makes a nicely formated output log file
2. Prompts for 1 of 3 different senarios to run - easy to edit or add senarios
3. Senarios can contain:-
   a. Moving groups
   b. Adding to groups
   c. Setting or clearing profile paths
   d. Moving user's OU

Do a find and replace for dc=DOMAIN,dc=COM and replace with your own domain details.

If you run the script by just clicking on it, it will prompt for a single UserID and then senario, progress is echoed in message boxes.
Blank message boxes are echoed too, ignore these, it was my lazy way of formating the output of the txt log file.

'Script by MJP 2006
'Convert Account properties SUP
' Script edits profile path, moves groups, moves user OU and moves profile folder depending on 3 different senarios
' Usage:- cscript SUPUser.vbs user1 user2 user3 >log.txt
' or
' Just click on SUPUser.vbs for one user account to convert
' Script will prompt for OS conversion type, enter "XP", "W2K" or "BOTH" 
' Edit below "sub XPUser" or "Sub W2KUser" or "sub BothUser" sections to modify script parameters
'Need to run as Domain Admin from Domain Controller for the TS Profile part of the script to work

'Option Explicit
Dim k, num, args
Dim MSCAccountSAM
Dim ScriptType
Dim DistinguishedADPath, MSCAccountDistinguished, FullNameClean
Dim GroupA, GroupB
Dim VarR, VarS
Dim DestinationOU
Dim ProfileServer
Dim UserID

OSType

Set args = WScript.Arguments
num = args.Count
if num = 0 then
  WScript.Echo "Usage:- cscript SUPUser.vbs user1 user2 user3 >log.txt"&(Chr(13))&(Chr(10))&"Or just click on SUPUser.vbs for one user"&(Chr(13))&(Chr(10))&(Chr(13))&(Chr(10))&"No arguments supplied therefore will prompt for:-"&(Chr(13))&(Chr(10))&"One UserID and then prompt for XP, W2K or BOTH"
     MSCAccountSAM=InputBox("Enter UserID you would like To convert", "SUPUser")
  ' Check ScriptType is set
  ScriptTypeSet
  ' Run program for one user
  RunProgram
  wscript.quit   
end if
for k = 0 to num - 1
  MSCAccountSAM= args.Item(k)
     ' Check ScriptType is set
     ScriptTypeSet
     WScript.Echo "*************************************************"&(Chr(13))&(Chr(10))
     WScript.Echo " "&(Chr(13))&(Chr(10))&" "&(Chr(13))&(Chr(10))&"Converting "&MSCAccountSAM&"'s Account to:- "&ScriptType&(Chr(13))&(Chr(10))
     ' Run Program for all users supplied via command lind arguments
     RunProgram     
Next
Set args = Nothing
WScript.Quit
'---------------------------------------
Function OSType
'check OS is not xp or 2000 server - if it is then error bacause the TS-Profile part of the script can't run
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
Caption= objOperatingSystem.Caption
OSType = objOperatingSystem.OSType
Next
'wscript.echo Caption
If Caption = "Microsoft Windows XP Professional" or Caption = "Microsoft Windows 2000 Server"Then 
WScript.echo "Please run script from a 2003 server"
WScript.quit
End If
End function
'---------------------------------------
sub ScriptTypeSet
' Used to ensure a valid entry is entered
ScriptType = UCase(ScriptType)
If ScriptType="XP" Then
Exit sub
End if
If ScriptType="W2K" Then
Exit sub
End If
If ScriptType="BOTH" Then
Exit sub
Else
ScriptType=InputBox("Convert user(s) to XP or W2K or BOTH", "SUPUser")
ScriptType = UCase(ScriptType)
End If
If ScriptType="XP" Then
Exit sub
End if
If ScriptType="W2K" Then
Exit sub
End If
If ScriptType="BOTH" Then
Exit sub
Else
WScript.Echo "You failed to enter a valid OS Type to convert user account to"
End if
End sub
'---------------------------------------
sub RunProgram
' Launch main script code
If ScriptType="XP" Then
XPUser
End if
If ScriptType="W2K" Then
W2KUser
End If
If ScriptType="BOTH" Then
BothUser
End If
End sub
'---------------------------------------
sub BothUser
' This sub will convert user account properties 
' to allow them to log onto both XP and W2K
' Extract AD path and user name from UserID
ADPath
If UserID="Bad" Then
UserID="Clear"
Exit Sub
End if
' Set profile paths
VarR="none" 'Remove profile path
SetProfile
VarS="ts" 'Add \ts to terminal services profile path
SetTSProfile
' Check and move group
GroupA = "GinternetUsers" 'From Group
GroupB = "GinternetUsersXP" 'To Group
MoveGroupCheck
' Check and move group
GroupA = "TS_Desktop_XP" 'From Group
GroupB = "TSDesktop" 'To group
MoveGroupCheck
' Remove user from Groups
GroupA = "Win2000Users" 'Remove from this group
GroupB = "WinXPUsers" 'Remove from this group
RemoveGroup

' Move User OU
DestinationOU="LDAP://OU=Standard,OU=XPUsers,dc=DOMAIN,dc=COM" 'OU this user is to be moved into
MoveOU
End sub
'---------------------------------------
Sub W2KUser
' This sub will convert user account properties "BACK" to W2K
' Note user profile path is removed as it is assumed user has an XP profile
' Extract AD path and user name from UserID
ADPath
If UserID="Bad" Then
UserID="Clear"
Exit Sub
End if
' Set profile paths
VarR="none"       'Remove profile path
SetProfile
VarS="ts" 'Add \ts to terminal services profile path
SetTSProfile
' Check and move group
GroupA = "TS_Desktop_XP" 'From Group
GroupB = "TSDesktop" 'To group
MoveGroupCheck
' Check and move group
GroupA = "GinternetUsersXP" 'From group
GroupB = "GinternetUsers" 'To group
MoveGroupCheck
' Force group move
GroupB = "Win2000Users"  'Add to this group
GroupA = "WinXPUsers" 'Remove from this group
MoveGroupForce
' Move User OU
DestinationOU="LDAP://OU=General Users,OU=msc,dc=DOMAIN,dc=COM" 'OU this user is to be moved into
MoveOU
End sub
'---------------------------------------
sub XPUser
' This sub will convert user account properties to XP
' Extract AD path and user name from UserID
ADPath
If UserID="Bad" Then
UserID="Clear"
Exit Sub
End if
' Set profile paths
SetProfile
SetTSProfile
' Check and move group
GroupA = "TSDesktop" 'From this group
GroupB = "TS_Desktop_XP" 'To this group
MoveGroupCheck
' Check and move group
GroupA = "GinternetUsers" 'From this group
GroupB = "GinternetUsersXP" 'To this group
MoveGroupCheck
' Move profile folder
ProfileServer="mscsoe"      'rem out for testing
MoveProfile   
' Group Add
GroupA = "TSUsers"
AddGroup
' Group Add
GroupA = "TS_Desktop_XP"
AddGroup
' Force group move
GroupA = "Win2000Users" 'Remove from this group
GroupB = "WinXPUsers" 'Add to this group
MoveGroupForce
' Move User OU
DestinationOU="LDAP://OU=Standard,OU=XPUsers,dc=DOMAIN,dc=COM" 'OU this user is to be moved into
MoveOU
End sub
'---------------------------------------
Sub ADPath
'Find distinguished name and AD path from supplied UserID
DistinguishedADPath =""
On Error Resume Next
Const ADS_SCOPE_SUBTREE = 2
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
objCommand.CommandText = _
   "SELECT distinguishedName FROM 'LDAP://dc=DOMAIN,dc=COM' WHERE objectCategory='user' " & _
       "AND sAMAccountName='"&MSCAccountSAM&"'"
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst
Do Until objRecordSet.EOF
   DistinguishedADPath=objRecordSet.Fields("distinguishedName").Value
   objRecordSet.MoveNext
Loop
On Error Goto 0

' Check if above script failed to find user account
If DistinguishedADPath ="" Then
WScript.Echo "Bad UserID supplied"
UserID="Bad"
Exit Sub
End if
' Extract name from AD path
MSCAccountDistinguished = Replace(DistinguishedADPath, "cn=", "")
MSCAccountDistinguished = Replace(DistinguishedADPath, "CN=", "")
Comma = Instr(MSCAccountDistinguished, ",OU")-1
MSCAccountDistinguished = Left(MSCAccountDistinguished, Comma)
FullNameClean = Replace(MSCAccountDistinguished, "\", "")
End Sub
'---------------------------------------
sub SetProfile
' Set Profile Path
Set objUser = GetObject ("LDAP://"&DistinguishedADPath)
strCurrentProfilePath = objUser.profilePath
If VarR="none" then 
WScript.Echo "Removing profile path for "&FullNameClean
Const ADS_PROPERTY_CLEAR = 1 
objUser.PutEx ADS_PROPERTY_CLEAR, "profilePath", 0 
objUser.SetInfo 
Else
strNewProfilePath = "\\server\share$\" & MSCAccountSAM
WScript.Echo "Setting profile path for user "&FullNameClean&(Chr(13))&(Chr(10))&"From: "&strCurrentProfilePath&(Chr(13))&(Chr(10))& "To  : "&strNewProfilePath&(Chr(13))&(Chr(10))
objUser.Put "profilePath", strNewProfilePath
objUser.SetInfo
End if
End sub
'---------------------------------------
sub SetTSProfile
' Set TS Profile Path
Set objUser = GetObject ("LDAP://"&DistinguishedADPath)
strCurrentProfilePath = objUser.TerminalServicesProfilePath
If VarS="ts" then 
strNewProfilePath = "\\server\share$\" & MSCAccountSAM & "\ts"
Else
strNewProfilePath = "\\server\share$\" & MSCAccountSAM
End if
'strNewProfilePath = "\\server\share$\" & MSCAccountSAM & "\TS
WScript.Echo "Setting TS profile path for user "&FullNameClean&(Chr(13))&(Chr(10))&"From: "&strCurrentProfilePath&(Chr(13))&(Chr(10))& "To  : "&strNewProfilePath&(Chr(13))&(Chr(10))
objUser.TerminalServicesProfilePath = strNewProfilePath
objUser.SetInfo
End sub
'---------------------------------------
sub MoveGroupCheck
' Check if a user is a member of GroupA and move to GroupB 
' User does not go into GroupB unless they are already in GroupA
' Check if user is a member of GroupA
Set objGroupA = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupA.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is a member of "&GroupA
' Remove User from GroupA
Const ADS_PROPERTY_DELETE = 4 
Set objGroup = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_DELETE, "member",array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo "Removed "&FullNameClean&" from "&GroupA
' Check if user is a member of GroupB already
Set objGroupB = GetObject("LDAP://cn="& GroupB &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupB.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is already a member of "&GroupB&" skiping"
Else
' Add User to GroupB
Const ADS_PROPERTY_APPEND = 3 
Set objGroup = GetObject("LDAP://cn="& GroupB &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_APPEND, "member", array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo "Added "&FullNameClean&" to "&GroupB
End If
Else
WScript.Echo FullNameClean&" is not a member of "&GroupA&" skiping"
End If
WScript.Echo " "&(Chr(13))&(Chr(10))
End sub
'---------------------------------------
sub RemoveGroup
' Ensure User is removed from both GroupA and GroupB
' Check if user is a member of GroupA
Set objGroupA = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupA.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is a member of "&GroupA
' Remove User from GroupA
Const ADS_PROPERTY_DELETE = 4 
Set objGroup = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_DELETE, "member",array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo FullNameClean&" removed from "&GroupA
Else
WScript.Echo FullNameClean&" was not a member of "&GroupA
End if
' Check if user is a member of GroupB
Set objGroupB = GetObject("LDAP://cn="& GroupB &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupB.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is a member of "&GroupB
' Remove User from GroupB
Set objGroup = GetObject("LDAP://cn="& GroupB &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_DELETE, "member",array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo FullNameClean&" removed from "&GroupB
Else
WScript.Echo FullNameClean&" was not a member of "&GroupB
End If
WScript.Echo " "&(Chr(13))&(Chr(10))
End sub
'---------------------------------------
Sub AddGroup
' Add user to group
' Check if user is a member of GroupA already
Set objGroupA = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupA.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is already a member of "&GroupA
Else
' Add User to GroupA
Const ADS_PROPERTY_APPEND = 3 
Set objGroup = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_APPEND, "member", array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo "Added "&FullNameClean&" to "&GroupA
End If
WScript.Echo " "&(Chr(13))&(Chr(10))
End sub
'---------------------------------------
sub MoveGroupForce
' Make sure a user is a member of GroupB and not GroupA
' This is a mandatory user group move
' Check if user is a member of GroupA
Set objGroupA = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupA.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is a member of "&GroupA
' Remove User from GroupA
Const ADS_PROPERTY_DELETE = 4 
Set objGroup = GetObject("LDAP://cn="& GroupA &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_DELETE, "member",array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo FullNameClean&" removed from "&GroupA
Else
WScript.Echo FullNameClean&" was not a member of "&GroupA
End if
' Check if user is a member of GroupB already
Set objGroupB = GetObject("LDAP://cn="& GroupB &",ou=Groups,dc=DOMAIN,dc=COM")
If objGroupB.IsMember("LDAP://"&DistinguishedADPath) Then
WScript.Echo FullNameClean&" is already a member of "&GroupB
Else
' Add User to GroupB
Const ADS_PROPERTY_APPEND = 3 
Set objGroup = GetObject("LDAP://cn="& GroupB &",ou=Groups,dc=DOMAIN,dc=COM")
objGroup.PutEx ADS_PROPERTY_APPEND, "member", array(DistinguishedADPath)
objGroup.SetInfo
WScript.Echo "Added "&FullNameClean&" to "&GroupB
End If
WScript.Echo " "&(Chr(13))&(Chr(10))
End sub
'---------------------------------------
sub MoveProfile
' Move server profile folder to backup share
' Leave behind Internet favorites folder
' Do it in a way to preserve existing permissions on original share
' Copy folder to backup share
On Error Resume Next
Const OverWriteFiles = TRUE
Set objFSO = CreateObject("Scripting.FileSystemObject")
objFSO.CopyFolder "\\"&ProfileServer&"\profiles$\"&MSCAccountSAM , "\\"&ProfileServer&"\profilessup$\" , OverWriteFiles

' Delete contents of original profile folder
Set shell = CreateObject("WScript.Shell") 
shell.run ("cmd.exe /c rd \\"&ProfileServer&"\profiles$\"&MSCAccountSAM&" /S /Q >\\"&ProfileServer&"\profiles$\"&MSCAccountSAM&"\sup"),0 ,true
' Copy back Internet Favorites Folder
Set objFSO = CreateObject("Scripting.FileSystemObject")
objFSO.CopyFolder "\\"&ProfileServer&"\profilessup$\"&MSCAccountSAM&"\Favorites" , "\\"&ProfileServer&"\profiles$\"&MSCAccountSAM&"\Favorites" , OverWriteFiles
On Error goto 0
If objFSO.FolderExists("\\"&ProfileServer&"\profilessup$\"&MSCAccountSAM) Then
   Set objFolder = objFSO.GetFolder("\\"&ProfileServer&"\profilessup$\"&MSCAccountSAM)
   WScript.Echo "Moved folder:-"&(Chr(13))&(Chr(10))&"\\"&ProfileServer&"\profiles$\"&MSCAccountSAM&(Chr(13))&(Chr(10))&"To:-"&(Chr(13))&(Chr(10))&"\\"&ProfileServer&"\profilessup$\"
Else
   Wscript.Echo "Profile folder move for "&MSCAccountSAM&" failed"
End If
WScript.Echo " "&(Chr(13))&(Chr(10))
End sub
'---------------------------------------
sub MoveOU

' Move User OU
WScript.Echo "Moving "&FullNameClean&(Chr(13))&(Chr(10))&"From "&DistinguishedADPath&(Chr(13))&(Chr(10))& "To "&DestinationOU
Set objNewOU = GetObject(DestinationOU)
Set objMoveAccount = objNewOU.MoveHere ("LDAP://"&DistinguishedADPath, "CN="&MSCAccountDistinguished)
WScript.Echo " "&(Chr(13))&(Chr(10))
End sub
'---------------------------------------