Adding processor, memory, and video information to report

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Adding processor, memory, and video information to report

Logged in as: Guest

arrSession:exec spGetSession 2,2,38818

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Adding processor, memory, and video information to report
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Adding processor, memory, and video information to report - 10/17/2006 6:43:54 AM

rsreese

Posts: 3
Score: 0
Joined: 10/17/2006
Status: offline

I've searched through several posts on this site and most of what came up *seems* to be much more complex then what I was using versus what I would like to add.

The script previously exported to a csv file and gave information such as OS information. I would like to add processor, memory, and video card memory to the report but I believe my trouble may be in requesting the processor information?

Here's what I have so far:

on error resume next
Set FileSystem = WScript.CreateObject("Scripting.FileSystemObject")
Set oFile = FileSystem.CreateTextFile("Computers.csv", True)
Const ADS_SCOPE_SUBTREE = 2
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCOmmand.ActiveConnection = objConnection
objCommand.CommandText =  "Select name, operatingsystemServicePack, operatingSystem, lastLogon, 
brand, maxclockspeed, TotalPhysicalMemory, VideoMemory??? from 'LDAP://OU=FRE, OU=IFAS, 
OU=Departments, OU=tttt, DC=ad, DC=tttt,DC=edu' where objectClass='computer'" 
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
objCommand.Properties("Cache Results") = False 
objCommand.Properties("Page Size") = 5000
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst
Do Until objRecordSet.EOF
Name = nothing
OS = nothing
SP = nothing
Logon = Nothing
Brand = nothing
ClockSpeed = nothing
objDate = Nothing
Memory = Nothing
VideoMemory = Nothing
Set objDate = objRecordSet.Fields("lastLogon").Value
Logon = #1/1/1601# + (((objDate.HighPart * (2 ^ 32)) + objDate.LowPart)/600000000 - 300)/1440
Name = objRecordSet.Fields("name").Value
OS = objRecordSet.Fields("operatingSystem").Value
SP = objRecordSet.Fields("operatingSystemServicePack").Value
Brand = objRecordSet.Fields("Manufacturer").value
ClockSpeed = objRecordSet.Fields("MaxClockSpeed").value
Memory = objRecordSet.Fields("(TotalPhysicalMemory/1024,1)").value
VideoMemory = objRecordSet.Fields("VideoMemory???/1024,1)").value
oFile.WriteLine (Name & "," & OS & "," & SP & "," & Logon & "," & Brand & "," & ClockSpeed & 
"," & Memory & "," && VideoMemory)
objRecordSet.MoveNext
Loop
Wscript.echo "Done Exporting Computers"
oFile.Close

Post #: 1

RE: Adding processor, memory, and video information to ... - 10/17/2006 5:48:02 PM

ginolard

Posts: 1051
Score: 21
Joined: 8/10/2005
Status: offline

You should consider using WMI to get this sort of information

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to rsreese)

Post #: 2

RE: Adding processor, memory, and video information to ... - 10/18/2006 4:21:37 AM

rsreese

Posts: 3
Score: 0
Joined: 10/17/2006
Status: offline

Is there a way to integrate the following into the code of my first post?

Const WBEM_RETURN_IMMEDIATELY = &h10
Const WBEM_FORWARD_ONLY = &h20

Set objWMIService = GetObject("winmgmts://" & strComputer & "/root/cimv2")

' Manufacturer is held in the Win32_ComputerSystem Namespace along with TotalPhysicalMemory:

Set colComputerSystem = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem",_
         "WQL", WBEM_RETURN_IMMEDIATELY + WBEM_FORWARD_ONLY)
For Each objItem in colComputerSystem
    WScript.Echo objItem.Manufacturer
    WScript.Echo objItem.TotalPhysicalMemory
Next
Set colComputerSystem = Nothing

' MaxClockSpeed in the Win32_Processor Namespace:

Set colProcessor = objWMIService.ExecQuery("SELECT * FROM Win32_Processor",_
         "WQL", WBEM_RETURN_IMMEDIATELY + WBEM_FORWARD_ONLY)
For Each objItem in colProcessor
         WScript.Echo objItem.MaxClockSpeed
Next
Set colProcessor = Nothing

' VideoMemory is in Win32_VideoController as AdapterRAM

(in reply to ginolard)

Post #: 3

RE: Adding processor, memory, and video information to ... - 10/23/2006 4:13:09 AM

rsreese

Posts: 3
Score: 0
Joined: 10/17/2006
Status: offline

Here's a copy of the updated script:

Const ADS_SCOPE_SUBTREE = 2
Const WBEM_RETURN_IMMEDIATELY = &h10
Const WBEM_FORWARD_ONLY = &h20

On Error Resume Next

Set objFileSystem = CreateObject("Scripting.FileSystemObject")
Set objFile = objFileSystem.CreateTextFile("Computers.csv", True)

objFile.WriteLine "System Name,Operating System,Service Pack,Last Logon,Manufacturer,Memory," &_
    "Clock Speed,Video RAM"

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection

objCommand.CommandText = "SELECT name, operatingsystemServicePack, operatingSystem, " &_
    "lastLogon FROM 'LDAP://OU=FRE,OU=IFAS,OU=Departments,OU=dom,DC=test,DC=ufl,DC=com' " &_
    "WHERE objectClass='computer'"

objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
objCommand.Properties("Cache Results") = False
objCommand.Properties("Page Size") = 5000

Set objRecordSet = objCommand.Execute

While Not objRecordSet.EOF
    strName = "" : strOS = "" : strLogon = "" : strSP
    strManufacturer = "" : strMemory = "" : strClockSpeed = "" : strVideoRAM = ""

strName = objRecordSet.Fields("name")
    strOS = objRecordSet.Fields("operatingSystem")
    strSP = objRecordSet.Fields("operatingSystemServicePack")

Set objDate = objRecordSet.Fields("lastLogon")
    strLogon = #1/1/1601# + _
         (((objDate.HighPart * (2^32)) + objDate.LowPart)/600000000 - 300)/1440

Err.Clear
    Set objWMIService = GetObject("winmgmts://" & strName & "/root/cimv2")

If Err.Number = 0 Then
         ' Manufacturer is held in the Win32_ComputerSystem Namespace
         ' along with TotalPhysicalMemory.

Set colComputerSystem = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem",_
                 "WQL", WBEM_RETURN_IMMEDIATELY + WBEM_FORWARD_ONLY)
         For Each objItem in colComputerSystem
              strMemory = Round(objItem.TotalPhysicalMemory/(1024^2), 2) & "Mb"
         Next
         Set colComputerSystem = Nothing

' MaxClockSpeed in the Win32_Processor Namespace:

Set colProcessor = objWMIService.ExecQuery("SELECT * FROM Win32_Processor",_
              "WQL", WBEM_RETURN_IMMEDIATELY + WBEM_FORWARD_ONLY)
         For Each objItem in colProcessor
              strManufacturer = Trim(objItem.Manufacturer)
              strClockSpeed = objItem.MaxClockSpeed/1000 & "GHz"
         Next
         Set colProcessor = Nothing

' VideoMemory is in Win32_VideoController as AdapterRAM

Set colVideoController = objWMIService.ExecQuery("SELECT * FROM Win32_VideoController",_
                        "WQL", WBEM_RETURN_IMMEDIATELY + WBEM_FORWARD_ONLY)
         For Each objItem in colVideoController
              strVideoRAM = Round(objItem.AdapterRAM/(1024^2), 2) & "Mb"
         Next
         Set colVideoController = Nothing
    End If
    
    Set objWMIService = Nothing

objFile.WriteLine strName & "," & strOS & "," & strSP & "," & strLogon & "," &_
         strManufacturer & "," & strMemory & "," & strClockSpeed & "," & strVideoRAM

objRecordSet.MoveNext
WEnd

Set objRecordSet = Nothing
Set objCommand = Nothing
Set objConnection = Nothing

objFile.Close

Set objFile = Nothing
Set objFileSystem = Nothing

Wscript.echo "Done Exporting Computers"

(in reply to rsreese)