Manipulating PDF

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Manipulating PDF

Logged in as: Guest

arrSession:exec spGetSession 2,2,40193

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Manipulating PDF
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Manipulating PDF - 11/29/2006 6:33:57 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

I am trying to write anything in VB5 that can access or just make minor changes;
such as the metadata in a PDF document;
Is that possible?

_____________________________

Thank you very much

Post #: 1

RE: Manipulating PDF - 11/29/2006 6:37:50 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

In VB5 or VBS?

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 2

RE: Manipulating PDF - 11/29/2006 6:40:57 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

Visual Basic Five;
By the way; what is (VBS)?

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 3

RE: Manipulating PDF - 11/29/2006 6:45:19 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

VBS is Visual Basic Script. It is the language that these fora are for. VB5 is not the same thing although the two languages are related. You will probably get a faster and more thorough answer at a VB5 forum. VB5 has not been supported for many years now so don't expect a huge outpouring of support from just about anywhere.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 4

RE: Manipulating PDF - 11/29/2006 6:46:16 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

Sorry;
I guess I have VB6 not VB5.

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 5

RE: Manipulating PDF - 11/29/2006 6:47:12 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Either way, while you may run accross someone here that has done this in VB, you would probably get a better and faster answer at a VB forum.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 6

RE: Manipulating PDF - 11/29/2006 6:48:53 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Searching for "visual basic open pdf" on google turned up several interesting sites that looked like they might have the code that you are looking for.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ebgreen)

Post #: 7

RE: Manipulating PDF - 11/29/2006 6:52:16 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

I tried so hard for long time, and that is how I found your forum;
But I did not get any answer to this question;
I just found sophisticated programs for sell in the internet...

I wouldn't mind replacing VB6 to VBS in my computer;
if I could get answer from you.

Cheers.

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 8

RE: Manipulating PDF - 11/29/2006 6:54:10 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

I agree;
That is what I've found,
but no one tell how to change the metadata of multiple files at once;
and without opening the files;
That is exactly what I am trying to do.

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 9

RE: Manipulating PDF - 11/29/2006 6:55:28 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Well, first of all I think you need to have the Adobe Writer program installed. The reader program does not expose an API as far as I know.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 10

RE: Manipulating PDF - 11/29/2006 6:59:22 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

I have Adobe full version.
Is it possible to access to multiple files throught it and change the metadata without opening them (for faster process)?

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 11

RE: Manipulating PDF - 11/29/2006 7:02:04 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

What sort of metadata do you want to change?

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 12

RE: Manipulating PDF - 11/29/2006 7:05:21 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

Author, Creator, and Producer.

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 13

RE: Manipulating PDF - 11/29/2006 7:18:08 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Quite a bit of the pdf file is saved in clear text. For instance if you open a pdf in notepad and poke around in it you can find where that metadata is stored and change it right there in notepad. This means that you should be able to use VBS (or VB6) to open the file and make modifications then write the file back out just like any other text file.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 14

RE: Manipulating PDF - 11/29/2006 7:23:34 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

WOW!

This is very clever way;
I did not think of it this way;

I will try it tonight and let you know the results.

again for the idea.

_____________________________

Thank you very much

(in reply to ebgreen)

Post #: 15

RE: Manipulating PDF - 11/29/2006 7:27:48 AM

CaffeineAddiction

Posts: 144
Score: 0
Joined: 2/9/2005
From:
Status: offline

Info found at:
http://www.accesspdf.com/index.php?topic=toolslibs

Scripting object required "pdftk.exe" can be found at:
http://www.accesspdf.com/pdftk/
Code Shown here

' ==========================================================================
' Name:          PDF Metadata Editor
' Version:       1.1
' Last Modified: 2005-05-31
' Program URL:   http://www.arilabs.com/software/pdfmeta/pdfmeta.vbs
' Filename:      pdfmeta.vbs
' Author:        Brian High <bkh AT arilabs DOT com>
' Copyright:     Analytical Resources, Inc. (2005)
' License:       GNU GPL version 2 (or greater).  See LICENSE section below.
' Description:   It allows you to edit Title, Author, Subject, and Keywords.
'                It is an easy to use, but limited front end to pdftk.
' Requires:      pdftk-1.12, VBScript language support (Windows Script Host)
' ==========================================================================

' ============
' Instructions
' ============

' (1) Requires this script (pdfmeta.vbs) to be in same folder as pdftk.exe.
' The easiest way to install pdftk is to install "PDFTK Builder" (free).
' http://users.on.net/~johnson/pdftkb/pdftkb_setup.exe
' PDFTK Builder is a GUI front end for pdftk and has many useful features.

'    --Or-- you can unzip pdftk.exe from the zip file found here:
'    http://www.accesspdf.com/pdftk/  (Click Download link and get zip.)
'    (Place pdftk.exe in an appropriately named and located folder.)

'    See also: http://hacks.oreilly.com/pub/h/2422

' (2) Place this script (pdfmeta.vbs) in the installation folder for the 
' pdftk package.  Make a shortcut to pdfmeta.vbs and place on your 
' desktop, if you like.

' (3) USAGE: Just drag the source PDF file onto this VBS script (or a 
' shortcut to it).  Follow prompts.  The temporary folder will open 
' and the new PDF will be inside.  Move the new PDF to its destination.

' ====================================================================
' LICENSE: GNU GPL v2 or greater:  http://www.gnu.org/licenses/gpl.txt
' ====================================================================

' This program is free software; you can redistribute it and/or modify
' it under the terms of the GNU General Public License as published by
' the Free Software Foundation; either version 2 of the License, or
' (at your option) any later version.
'
' This program is distributed in the hope that it will be useful,
' but WITHOUT ANY WARRANTY; without even the implied warranty of
' MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
' GNU General Public License for more details.

Option Explicit

' Declare Variables
Dim sInfile, sFileName, sTempFile, sCurrentDir, sCurrentDrive, sScriptName
Dim sComSpec, sMeta, sTempPath, sCmd, sPdftk, sAppTitle, sTKCmd, args

' Configure application title and filename of PDFTK command
sAppTitle = "PDF Metadata Editor v1.1"
sTKCmd = "pdftk.exe"

' To use different metadata fields, change this array definition
Dim aFields(3,1)
aFields(0,0) = "Title"
aFields(1,0) = "Subject"
aFields(2,0) = "Author"
aFields(3,0) = "Keywords"

' Set flag for "dictionary not found"
Dim noDict
noDict = False

' Define Constants
Const Create = True, DontCreate = False
Const HideWindow = 0, ShowWindow = 1
Const ForReading = 1, ForWriting = 2, ForAppending = 3

' Main Routine
GetArguments()
OpenPDFFile()
GetCurrentDirectory()
TryToAccessPDFTK()
GetTempFolder()
DeleteMetaFile()
CreateDumpDataCmd()
WriteMetaData()
DisplayMetaData()
PromptForMetaData()
WriteNewMetaData()
WriteMetaDataIntoNewPDF()

' Subroutines
Private Sub GetArguments
   Dim sErr, num, oShell 
   ' Get script arguments and check for at least one (the file name)
   Set oShell = WScript.CreateObject("WScript.Shell")
   Set args = WScript.Arguments
   sScriptName = WScript.ScriptFullName
   
   num = args.Count
   
   sErr = "Usage: [cscript | wscript] pdfmeta.vbs <filename>" & vbCRLF & _
      "(Just drag a PDF file onto this script and follow the prompts.)"
   
   If num = 0 Then
      WScript.Echo sErr
      WScript.Quit 1
   End If
   If InStr(UCase(args.Item(0)), ".PDF") = 0 Then
      WScript.Echo sErr
      WScript.Quit 1
   End If
End Sub

Private Sub OpenPDFFile
   Dim sErr, sFile, oFile, FSO
   ' Try to open the input file
   Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
   
   sFile = args.Item(0)
   sErr = sFile & " does not exist!"
   If FSO.FileExists(sFile) Then
      Set oFile = FSO.GetFile(sFile)
      sInfile = oFile.path
      sFileName = oFile.name
   Else
      WScript.Echo sErr
      WScript.Quit 1
   End If
End Sub

Private Sub GetCurrentDirectory
   Dim aCurrentPath, FSO, sErr, oFile
   ' Get current directory (where script is located)
   Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
   Set oFile = FSO.GetFile(sScriptName)
   sCurrentDir = oFile.path
   aCurrentPath = split(sCurrentDir, ":")
   sCurrentDrive = aCurrentPath(0)
   sErr = "This program must reside on a local drive or mapped drive."
   If Len(sCurrentDrive) <> 1 Then 
      WScript.Echo sErr
      WScript.Quit 1
   End If
   sCurrentDir = aCurrentPath(1)
   sCurrentDir = Mid(sCurrentDir, 1, Len(sCurrentDir) - Len(oFile.name))
   sPdftk = sCurrentDrive & ":" & sCurrentDir & sTKCmd
End Sub
   
Private Sub TryToAccessPDFTK
   Dim sErr, FSO
   ' Try to access the pdftk.exe program
   Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
   
   sErr = sPdftk & " does not exist!"
   If FSO.FileExists(sPdftk) Then
      ' Found pdftk.exe in current directory...
   Else
      WScript.Echo sErr
      WScript.Quit 1
   End If
End Sub

Private Sub GetTempFolder
   Dim oShell
   ' Get the path of the temporary folder
   set oShell = CreateObject("WScript.Shell")
   sTempPath = oShell.ExpandEnvironmentStrings("%temp%")
   sComSpec = oShell.ExpandEnvironmentStrings("%comspec%")
   sTempFile = sTempPath & "\" & sFileName
End Sub
   
Private Sub DeleteMetaFile
   Dim FSO, oOrigMetaFile
   ' Delete the metadata file if it already exists
   sMeta = sTempPath & "\metadata.txt"
   Set FSO = CreateObject("Scripting.FileSystemObject")
   If FSO.FileExists(sMeta) Then 
      Set oOrigMetaFile = FSO.GetFile(sMeta)
      oOrigMetaFile.Delete
   End If
End Sub

Private Sub CreateDumpDataCmd
   Dim oShell
   ' Create a command shell object and dump pdf info to metadata file
   sCmd = sComSpec & " /c chdir /d """ & sCurrentDrive & ":" & sCurrentDir _
      & """ & " & sTKCmd & " """ & sInfile & """ dump_data " _
      & ">""" & sMeta & """ 2>&1"
   Set oShell =  WScript.CreateObject("Wscript.Shell")
   oShell.Run sCmd, HideWindow, True
End Sub

Private Sub FixBrokenDictionary
   Dim oShell
   ' Create a command shell object and "cat" pdf info new pdf
   sCmd = """" & sPdftk & """" & " " & """" & sInfile & """" & _ 
      " cat output " & """" & sTempFile & """" & " dont_ask"
   Set oShell =  WScript.CreateObject("Wscript.Shell")
   oShell.Run sCmd, HideWindow, True
   sCmd = sComSpec & " /c move /y " & """" & sTempFile & """" & " " & """" _
      & sInfile & """"
   Set oShell =  WScript.CreateObject("Wscript.Shell")
   oShell.Run sCmd, HideWindow, True
   CreateDumpDataCmd()
   WriteMetaData()
End Sub

Private Sub WriteMetaData
   Dim RE, FSO, TSO, sErr
   sErr = "Unable to repair info dictionary."
   ' Read from metadata file, test for expressions, 
   ' and store metadata values
   Set FSO = CreateObject("Scripting.FileSystemObject")
   If FSO.FileExists(sMeta) Then
      Set TSO = FSO.OpenTextFile(sMeta, ForReading, DontCreate)
      Set RE = New RegExp
      Dim i, sLine
      Do While Not TSO.AtEndOfStream
         sLine = TSO.ReadLine
         RE.Pattern = "no info dictionary found"
	 If RE.Test(sLine) Then
	    If noDict = True Then
               WScript.Echo sErr
               WScript.Quit 1
	    Else
	       noDict = True
               ' Close TextStreamObject
               TSO.Close
               FixBrokenDictionary()
	       Exit Sub
	    End If
	 Else
	    noDict = False
            For i = LBound(aFields) to UBound(aFields)
               RE.Pattern = "InfoKey: " & aFields(i,0)
               If RE.Test(sLine) Then 
                  sLine = TSO.ReadLine
                  aFields(i,1) = Mid(sLine, 12)
               End If
            Next
	 End If
      Loop
      ' Close TextStreamObject
      TSO.Close
   End If
End Sub

Private Sub DisplayMetaData
   Dim i, msg, tabs, retval
   msg = "Your PDF file has the following properties:" & vbCRLF & vbCRLF
   For i = LBound(aFields) to UBound(aFields)
      If Len(aFields(i,0)) > 7 Then tabs = vbTab Else tabs = vbTab & vbTab
      msg = msg & aFields(i,0) & ": " & tabs & aFields(i,1) & vbCRLF
   Next
   msg = msg & vbCRLF & vbCRLF & "Click OK to continue or Cancel to quit."
   retval = msgbox (msg, vbOKCancel, sAppTitle )
   If retval = vbCancel Then WScript.Quit 1
End Sub

Private Sub PromptForMetaData
   ' Prompt user for metadata, using metadata in original file as defaults
   Dim i
   For i = LBound(aFields) to UBound(aFields)
      aFields(i,1) = _
         InputBox("Enter the " & aFields(i,0) & ":", sAppTitle, aFields(i,1))
   Next
End Sub

Private Sub WriteNewMetaData
   Dim FSO, TSO
   ' Open a text file and write metadata to it
   Set FSO = CreateObject("Scripting.FileSystemObject")
   Set TSO = FSO.OpenTextFile(sMeta, ForWriting, Create)
   
   Dim i
   For i = LBound(aFields) to UBound(aFields)
      TSO.Write "InfoKey: " & aFields(i,0) & vbCrLf
      TSO.Write "InfoValue: " & aFields(i,1) & vbCrLf
   Next
   
   ' Close TextStreamObject
   TSO.Close
End Sub

Private Sub WriteMetaDataIntoNewPDF
   Dim oShell
   ' Create a command shell object and set pdftk command string variable
   set oShell = WScript.CreateObject("Wscript.Shell")
   sCmd = """" & sPdftk & """" & " " & """" & sInfile & """" & _ 
      " update_info " & """" & sMeta & """" & " output " & """" _
      & sTempFile & """" & " dont_ask"
   Dim retval
   ' Run pdftk command and destroy local variables to release memory
   oShell.run sCmd, HideWindow, True
   
   retval = msgbox ( "Look for the output file in the temporary folder" & _ 
      " which will open next." & vbCRLF & "The output file" & _
      " will have the same name as the original file.", _
      vbOKCancel, sAppTitle )
   
   If retval = vbCancel Then WScript.Quit 1
   
   ' Open explorer to temp folder
   oShell.run "Explorer " & sTempPath, 1, True
End Sub

Disclaimer: I havent tested or reviewed any of this code or checked out this executable ... this is just the simple results of a 5 min google search for "vbscript metadata"

_____________________________

Thanks for Answering my Questions ... I hope my Answer to your questions help!

(in reply to Abbas1)

Post #: 16

RE: Manipulating PDF - 11/29/2006 12:31:13 PM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

I tried both;

The text method did not work;
becasue simply, when I change anything using text, I could not open the file.

The other method, when I pasted the code, it did not work.

Any ideas?

_____________________________

Thank you very much

(in reply to CaffeineAddiction)

Post #: 17

RE: Manipulating PDF - 11/30/2006 2:20:22 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Well the pdf files use *nix style end of lines not windows style. Please post the code. When I open a pdf file using an editor that support *nix end of lines (Vi) and change the author, then the chage shows up in the PDF properties tab for the file and I can still open the file just fine.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to Abbas1)

Post #: 18

RE: Manipulating PDF - 11/30/2006 8:09:44 AM

Abbas1

Posts: 23
Score: 0
Joined: 11/28/2006
Status: offline

About the code, I still haven't started becasue I have no experience how to deal with PDFs.
I think I have to do more reading on the (nix), I am not familiar with this format;
Then I have to develope the code.

_____________________________

Thank you very much

(in reply to ebgreen)