RE: Pull information from a file based on search criteria

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

RE: Pull information from a file based on search criteria

Logged in as: Guest

arrSession:exec spGetSession 2,2,40341

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> RE: Pull information from a file based on search criteria
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: << < prev 1 [2] 3 4 5 next > >>

Message

<< Older Topic Newer Topic >>

RE: Pull information from a file based on search criteria - 12/5/2006 9:31:28 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

Sordoff,
I am trying to create dhcp reservation for all machines on our network. However if you query the DHCP Server it is only giving me list of machines that are currently connected.(incomplete) So you willl get a text file that will just skip over the ips that are currently not in use.

So I was trying to create a script that would loop through all the available IP's 0 to 255. If the IP does not exist on DHCP Server text file then create a specialized entry.

I want to execute the Netsh command (Create Reservations) for all the IPs in the range I provide 0-255. But I want the script to pull the Reserved IP address and the MAC address and client name from the from the text file.

....Will the netsh commands for *10 and *.13 the same? If not - how would you like to specify
the different params No I want it to pull the data required from the text file.

PULL THE DATA FROM THE TEXT FILE FOR NETSH COMMAND

strScope = "100.10.9.0"
strReservedIP = "100.10.9.10"
strMAC = "000000000010"
strClientName = "Machine Name10"
strServer = "DHCP Server" ' leave blank for local server

strScope = "100.10.9.0"
strReservedIP = "100.10.9.13"
strMAC = "000000000013"
strClientName = "Machine Name13"
strServer = "DHCP Server" ' leave blank for local server

For IP 100.10.9.14 I want to netsh to enter this (tHIS WOULD BE AN ENTRY NOT IN THE TEXT FILE BUT IP WOULD BE IN THE RANGE.

strScope = "100.10.9.0"
strReservedIP = "100.10.9.14"
strMAC = "000000000000"
strClientName = "Machine NameUnknown"
strServer = "DHCP Server" ' leave blank for local server

Hopefully you can help me.

(in reply to ehvbs)

Post #: 21

RE: Pull information from a file based on search criteria - 12/5/2006 9:34:09 AM

ehvbs

Posts: 2078
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi ebgreen,

There are two possible problems with your (excellent) script:

    (a) you split on "ClientInfo : " (tailing blank); that failed for my sample file (no tailing blank);
         aburt should check his data

    (b) you search for "100.10.9." + i but the sample contains "100.10.12.*"

(just to eliminate needless problems)

(in reply to ehvbs)

Post #: 22

RE: Pull information from a file based on search criteria - 12/5/2006 10:03:42 AM

ehvbs

Posts: 2078
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

given this sample:

(note: *.11 and *.12 are connected/known; *.10 and *.13 can't be found)

what do you think of this output:

(I'm still at lost concerning the exact params for different ips not found)

(in reply to ehvbs)

Post #: 23

RE: Pull information from a file based on search criteria - 12/5/2006 11:47:49 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

ehvbs,

you got exactly what I am trying to do just at a loss on how to make it happen.

(in reply to ehvbs)

Post #: 24

RE: Pull information from a file based on search criteria - 12/5/2006 10:32:11 PM

ehvbs

Posts: 2078
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

one way to make it happen: start with this script netshrun.vbs

Now take the main problem "run netsh for a list of IPs" and split it into two
subproblems:

   (a) building the netsh command from suitable parameters

   (b) getting these parameters (from your dhcpouts.txt file)

Concentrate on (a). Your netsh command setup:



What about "strClientComment"? Let's assume you need it. Concatenating complex
strings like command lines is a bad idea; especially if you have to add quotes
and other special chars. An easier and more general way is to use replacement.
So add:

   (1) ''#             bldCmd1 - first try to build netsh command

   (2)      Case "bldcmd1"
               nRVal = bldCmd1()

   (3) ' ############################################################################
       ''# bldCmd1 - first try to build netsh command
       ' ############################################################################

       Function bldCmd1()
         Dim nRVal : nRVal = 1 ' assume bad
         WScript.Echo "ok, bldCmd1() was called."
         bldCmd1 = nRVal
       End Function

and run:

    cscript netshrun.vbs bldCmd1
    ok, bldCmd1() was called.

Taking advantage of the fact that the last version of a sequence of Subs/Functions
with the same name and parameter list 'wins', we can either put an enhanced version
of bldCmd1() in the script or - in a more orderly fashion - setup our embellished
function as bldCmd2(). Ok, I'm in a hurry:

Function bldCmd1()
   Dim nRVal : nRVal = 0 ' assume ok
 ' Start with the command containing place holders; use copy/paste if possible
   Dim sCmd  : sCmd = _
    "netsh dhcp server \\<ServerName> scope <ScopeID> add reservedip <ReservedIP> <MAC_Address> <ClientName> <ClientComment>"
 ' Show what we have
   WScript.Echo "sCmd:", "|" + sCmd + "|"
 ' Get the place holder into an array:
   Dim aNames : aNames = cutRE00( "(<\w+>)", sCmd )
 ' Show what we have
   WScript.Echo "aNames: (", Join( aNames, ", " ), ")"
 ' setup dictionary from aNames
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   Dim sKey
   For Each sKey In aNames
       dicParms( sKey ) = StrReverse( sKey ) ' just for testing
   Next
 ' Show what we have
   For Each sKey In dicParms.Keys
       WScript.Echo sKey, "=>", dicParms( sKey )
   Next
 ' Apply dicParms to sCmd and prove applyRpl
   WScript.Echo "sCmd:", "|" + sCmd + "|"
   WScript.Echo "sCmd:", "|" + applyRpl( dicParms, sCmd )  + "|"
 ' for the lazy programmer: build an assignment block for dicParms
   For Each sKey In dicParms.Keys
       WScript.Echo "dicParms( """ + sKey + """ ) = """" "
   Next
 
   bldCmd1 = nRVal
 End Function

Of course we need the functions used in bldCmd1():

' ############################################################################
 ''# cutRE00 - Q & Dirty: all matches.value into 1 dim array
 ' ############################################################################
 
 Function cutRE00( sPattern, sText )
   Dim aRVal : aRVal   = Array()
   Dim oRE   : Set oRE = New RegExp
   Dim oMTS, nIdx
   oRE.Pattern = sPattern
   oRE.Global  = True
   Set oMTS = oRE.Execute( sText )
   If 0 < oMTS.Count Then
      ReDim aRVal( oMTS.Count - 1 )
      For nIdx = 0 To UBound( aRVal )
          aRVal( nIdx ) = oMTS( nIdx ).Value
      Next
   End If
   cutRE00 = aRVal
 End Function
 
 ' ############################################################################
 ''# applyRpl - replace placeholders in sText with values from dicParms
 ' ############################################################################
 
 Function applyRpl( dicParms, ByVal sText )
   Dim sKey
   For Each sKey In dicParms
       sText = Replace( sText, sKey, dicParms( sKey ) )
   Next
   applyRpl = sText
 End Function

Output:

For the next step, we make dicParms (now called gdicDefParms) with suitable values
and sCmd (=> gsCmd) globally available. Furthermore we add a testCmd() func to make
sure we can do the main job if get the params right.

I post the whole (current version of the) script

Now for the second problem:

   getting these parameters (from your dhcpouts.txt file)

Start with a simple version of the parseDHCP() function:

    Function parseDHCP()
      Dim nRVal : nRVal = 1 ' assume bad
      WScript.Echo "ok, parseDHCP() was called."
      parseDHCP = nRVal
    End Function

Check output:

    cscript netshrun.vbs parsedhcp
    ok, parseDHCP() was called.

Use - a slightly modified version of - ebgreen's code to work thru
".\dhcpouts.txt". First simple version:



Version with dictionary:

Function parseDHCP()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, parseDHCP() was called."
 
   Dim dicClients  : Set dicClients = CreateObject( "Scripting.Dictionary" )
   Dim oFSO        : Set oFSO       = CreateObject( "Scripting.FileSystemObject" )
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim sDelim      : sDelim         = vbCrLf + "ClientInfo :" & vbCrLf ' maybe: "ClientInfo : " (trailing blank)
   Dim bVerbose    : bVerbose       = True ' set to False for big strDHCPFile
   Dim arrEntries, nIdx
 
   arrEntries = Split( oFSO.OpenTextFile( strDHCPFile ).ReadAll(), sDelim )
 ' Skip header!
   For nIdx = 1 To UBound( arrEntries )
 '     The entry is still just a block of text so break it into lines for processing
       Dim arrLines : arrLines = Split( arrEntries( nIdx ), vbCrLf )
       WScript.Echo arrLines( 0 )
       Dim dicTemp : Set dicTemp = CreateObject( "Scripting.Dictionary" )
       Dim strLine
       For Each strLine In arrLines
 '         Clean up
           strLine = Trim( strLine )
           If "" < strLine Then
              If "." = Right( strLine, 1 ) Then strLine = Left( strLine, Len( strLine ) - 1 )
 '            Split each line into a parameter and a value and add those to a temporary dictionary
              Dim arrParts : arrParts = Split( strLine, " = ")
              If 1 = UBound( arrParts ) Then
                 dicTemp.Add Trim( arrParts( 0 ) ), Trim( arrParts( 1 ) )
              Else
                 WScript.Echo "??? |" + strLine + "|"
              End If
           Else
 '            no need to process empty lines
           End If
       Next
 '     Now add that entry to the client dictionary with the IP address as the key
       Dim sIP : sIP = dicTemp( "IP Address" )
       WScript.Echo "Handling IP: |" + sIP + "|"
       If dicTemp.Exists( "IP Address" ) Then
          If dicClients.Exists( sIP ) Then
             WScript.Echo "??? - double IP: " + sIP
          Else
             dicClients.Add sIP, dicTemp
          End If
       Else
          WScript.Echo "??? - no IP Address found."
       End If
   Next
 ' Now we have a dictionary of all the clients reported in the file
 
 ' Dump the info to gain confidence
   If bVerbose Then
      Dim sKeyClient, dicParams, sKeyParam
      For Each sKeyClient In dicClients
          WScript.Echo "-------------", sKeyClient, "-------------"
          Set dicParams = dicClients( sKeyClient )
          For Each sKeyParam In dicParams
              WScript.Echo "", sKeyParam, "|" + dicParams( sKeyParam ) + "|"
          Next
      Next
   End If
 
   parseDHCP = nRVal
 End Function
 
 --------- output --------------
 
 cscript //D netshrun.vbs parsedhcp
 ok, parseDHCP() was called.
 IP Address = 100.10.12.11.
 Handling IP: |100.10.12.11|
 IP Address = 100.10.12.12.
 Handling IP: |100.10.12.12|
 ------------- 100.10.12.11 -------------
  IP Address |100.10.12.11|
  SubnetMask |255.255.254.0|
  Client Hardware Address |11-11-11-11-11-11|
  Name |MachineNameA.org.company.com|
  Comment |(null)|
  Type |DHCP|
  Expires |12/05/2006 08:07:58|
  Owner Host IP Address |100.10.12.11|
  Owner Host NetBios Name |Server|
  Owner Host Name |(null)|
 ------------- 100.10.12.12 -------------
  IP Address |100.10.12.12|
  SubnetMask |255.255.254.0|
  Client Hardware Address |12-12-12-12-12-12|
  Name |MachineNameb.org.company.com|
  Comment |(null)|
  Type |DHCP|
  Expires |12/05/2006 08:07:58|
  Owner Host IP Address |100.10.12.11|
  Owner Host NetBios Name |Server|
  Owner Host Name |(null)|

Now copy the code of parseDHCP() to an independent function to make it
reusable:

' ############################################################################
 ''# parseDHCPebgreen - parse strDHCPFile into a dictionary
 ' ############################################################################
 
 Function parseDHCPebgreen( strDHCPFile )
   Dim dicClients  : Set dicClients = CreateObject( "Scripting.Dictionary" )
   Dim oFSO        : Set oFSO       = CreateObject( "Scripting.FileSystemObject" )
   Dim sDelim      : sDelim         = vbCrLf + "ClientInfo :" & vbCrLf ' maybe: "ClientInfo : " (trailing blank)
   Dim arrEntries, nIdx
 
   arrEntries = Split( oFSO.OpenTextFile( strDHCPFile ).ReadAll(), sDelim )
 ' Skip header!
   For nIdx = 1 To UBound( arrEntries )
 '     The entry is still just a block of text so break it into lines for processing
       Dim arrLines : arrLines = Split( arrEntries( nIdx ), vbCrLf )
       Dim dicTemp : Set dicTemp = CreateObject( "Scripting.Dictionary" )
       Dim strLine
       For Each strLine In arrLines
 '         Clean up
           strLine = Trim( strLine )
           If "" < strLine Then
              If "." = Right( strLine, 1 ) Then strLine = Left( strLine, Len( strLine ) - 1 )
 '            Split each line into a parameter and a value and add those to a temporary dictionary
              Dim arrParts : arrParts = Split( strLine, " = ")
              If 1 = UBound( arrParts ) Then
                 dicTemp.Add Trim( arrParts( 0 ) ), Trim( arrParts( 1 ) )
              Else
 '               Add (better) error handling here
                 Err.Raise 4711, "??? |" + strLine + "|"
              End If
           Else
 '            no need to process empty lines
           End If
       Next
 '     Now add that entry to the client dictionary with the IP address as the key
       Dim sIP : sIP = dicTemp( "IP Address" )
       If dicTemp.Exists( "IP Address" ) Then
          If dicClients.Exists( sIP ) Then
 '           Add (better) error handling here
             Err.Raise 4711, "??? - double IP: " + sIP
          Else
             dicClients.Add sIP, dicTemp
          End If
       Else
 '        Add (better) error handling here
          Err.Raise 4711, "??? - no IP Address found."
       End If
   Next
 ' Now we have a dictionary of all the clients reported in the file
 ' return this to caller; remember the Set!!
   Set parseDHCPebgreen = dicClients
 End Function

I admit a bit of editing was necessary. To test it, add a first version
of cmdFound:

[/code]
Function cmdFound()
Dim nRVal : nRVal = 1 ' assume bad
WScript.Echo "ok, cmdFound() was called."

Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
Dim dicClients : Set dicClients = parseDHCPebgreen( strDHCPFile )

Dim sKeyClient, dicParams
For Each sKeyClient In dicClients
      WScript.Echo "-------------", sKeyClient, "-------------"
Next

cmdFound = nRVal
End Function

--- output ----------
ok, cmdFound() was called.
------------- 100.10.12.11 -------------
------------- 100.10.12.12 -------------

--- output after changing 100.10.12.12 to 100.10.12.11 in DHCPOuts.txt -----------
cscript netshrun.vbs cmdFound
ok, cmdFound() was called.
C:\wis\_vbs\0506\dev\forum\netshrun.vbs(448, 13) ??? - double IP: 100.10.12.11: Unbekannter Laufzeitfehler
[/code]

Next version of cmdFound() with mapping of dicClients to dicParams:

Function cmdFound()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, cmdFound() was called."
 
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim dicClients  : Set dicClients = parseDHCPebgreen( strDHCPFile )
 ' stolen from testCmd()
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   Dim sCmd, sRet
   Dim sKeyClient, dicParams
 
   For Each sKeyClient In dicClients
       WScript.Echo "-------------", sKeyClient, "-------------"
 '     copied from dox box
 ' IP Address |100.10.12.12|
 ' SubnetMask |255.255.254.0|
 ' Client Hardware Address |12-12-12-12-12-12|
 ' Name |MachineNameb.org.company.com|
 ' Comment |(null)|
 ' Type |DHCP|
 ' Expires |12/05/2006 08:07:58|
 ' Owner Host IP Address |100.10.12.11|
 ' Owner Host NetBios Name |Server|
 ' Owner Host Name |(null)|
 '     stolen from testCmd()
       dicParms( "<ServerName>"    ) = dicClients( sKeyClient )( "Owner Host NetBios Name" )
       dicParms( "<ScopeID>"       ) = "?<ScopeID>?"
       dicParms( "<ReservedIP>"    ) = dicClients( sKeyClient )( "IP Address" )
       dicParms( "<MAC_Address>"   ) = dicClients( sKeyClient )( "Client Hardware Address" )
       dicParms( "<ClientName>"    ) = dicClients( sKeyClient )( "Name" )
       dicParms( "<ClientComment>" ) = ""
       sCmd = applyRpl( dicParms, gsCmd )
       sRet = runCmd( sCmd )
       WScript.Echo "-------------", sKeyClient, "-------------"
   Next
   cmdFound = nRVal
 End Function
 
 ---------- output --------------
 cscript //D netshrun.vbs cmdFound
 ok, cmdFound() was called.
 ------------- 100.10.12.11 -------------
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope ?<ScopeID>? add reservedip 100.10.12.11 11-11-11-11-11-11 MachineNameA.org.company.com
 ------------- 100.10.12.11 -------------
 ------------- 100.10.12.12 -------------
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope ?<ScopeID>? add reservedip 100.10.12.12 12-12-12-12-12-12 MachineNameb.org.company.com
 ------------- 100.10.12.12 -------------

Puh, last lap! Let's risk to work in doTheRealWork()! First try:

Function doTheRealWork()
   Dim nRVal : nRVal = 0 ' assume ok
   WScript.Echo "ok, doTheRealWork() was called, but we aren't done yet!"
 
 ' stolen from Function cmdFound()
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim dicClients  : Set dicClients = parseDHCPebgreen( strDHCPFile )
   Dim dicParms    : Set dicParms   = CreateObject( "Scripting.Dictionary" )
   Dim sCmd, sRet
   Dim sKeyClient, dicParams
 ' first try to specify IPs to look for
   Dim aIPs        : aIPs   = Array( "10", "11", "12", "13" )
 ' that's my problem: sIPPfx/Scope/Netmask
   Dim sIPPfx      : sIPPfx = "100.10.12."
   Dim sIP
 
   For Each sIP In aIPs
       sIP = sIPPfx + sIP
       WScript.Echo "-------------", sIP, "-------------"
       If dicClients.Exists( sIP ) Then
          WScript.Echo "Found"
       Else
          WScript.Echo "Not Found"
       End If
       WScript.Echo "----------------------------------------"
   Next
   doTheRealWork = nRVal
 End Function
 
 --------- output ------------
 
 cscript //D netshrun.vbs
 ok, doTheRealWork() was called, but we aren't done yet!
 ------------- 100.10.12.10 -------------
 Not Found
 ----------------------------------------
 ------------- 100.10.12.11 -------------
 Found
 ----------------------------------------
 ------------- 100.10.12.12 -------------
 Found
 ----------------------------------------
 ------------- 100.10.12.13 -------------
 Not Found
 ----------------------------------------

output with the commandline building merged:

cscript //D netshrun.vbs
 ok, doTheRealWork() was called, but we aren't done yet!
 ------------- 100.10.12.10 -------------
 Not Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment
 ----------------------------------------
 ------------- 100.10.12.11 -------------
 Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope ?<ScopeID>? add reservedip 100.10.12.11 11-11-11-11-11-11 MachineNameA.org.company.com
 ----------------------------------------
 ------------- 100.10.12.12 -------------
 Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope ?<ScopeID>? add reservedip 100.10.12.12 12-12-12-12-12-12 MachineNameb.org.company.com
 ----------------------------------------
 ------------- 100.10.12.13 -------------
 Not Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment
 ----------------------------------------

And the current version of the whole script:

' ############################################################################
 ''# netshrun.vbs : run netsh for a list of IPs
 ' [ If you start a new project, first try to describe the purpose (task) of the
 '   script in one short sentence; I don't know enough about DHCP and its use
 '   and about your environment to do this properly, so update the second line.
 '   If you can't just implement the purpose, start with a script that makes it
 '   easy to work/experiment with the different sub parts of your main problem.
 ' ]
 ' ============================================================================
 ' (c) 2006 by YourCompany, Inc.
 '     77 YourStreet YourTown Whatever
 '     T: (+49) 123 45 67 89 * E: YourName@YourCompany.com
 ' ============================================================================
 ''# usage: cscript netshrun.vbs <action>
 ''#  <action> : frstest   - just show the 'call a func' part works
 ''#             sectest   - just show the 'call a func' part really works
 ''#             bldCmd1   - first try to build netsh command
 ''#             testCmd   - building netsh command from hardcoded params and .Run
 ''#             parseDHCP - parse DHCP output file into dictionary
 ''#             cmdFound  - netsh cmd for found IPs
 ' [ update this usage as you add more experimental functions ]
 ''# usage: cscript netshrun.vbs ???
 ' [ update this usage when erverything works as it should; for now we can't,
 '   because the main problem isn't solved yet.
 ' ]
 ' ############################################################################
 
 Option Explicit
 
 ' ############################################################################
 ''# global vars
 ' [ will grow as we proceed ]
 ' ############################################################################
 
 Dim gsCmd : gsCmd = _
    "netsh dhcp server \\<ServerName> scope <ScopeID> add reservedip <ReservedIP> <MAC_Address> <ClientName> <ClientComment>"
 Dim gdicDefParms : Set gdicDefParms = CreateObject( "Scripting.Dictionary" )
 
 ' ############################################################################
 ''# main - calls experimental func specified as first param on the command
 ' #        or - the now still empty - 'doTheRealWork' func
 ' ############################################################################
 
 WScript.Quit doMain()
 
 Function doMain()
   Dim nRVal : nRVal = 0 ' assume all is well
   Dim sFunc : sFunc = "doTheRealWork"
 ' ----------  init -----------
   gdicDefParms( "<ServerName>"    ) = "Server"         ' taken from aburt's postings,
   gdicDefParms( "<ScopeID>"       ) = "100.10.9.1"     ' check carefully! I'm still
   gdicDefParms( "<ReservedIP>"    ) = "100.10.9.189"   ' afraid we need *different*
   gdicDefParms( "<MAC_Address>"   ) = "000000000000"   ' params for the missing IPs
   gdicDefParms( "<ClientName>"    ) = "Machine Name"   ' ???
   gdicDefParms( "<ClientComment>" ) = "nocomment"      ' ???
 ' ----------  args -----------
   If 1 <= WScript.Arguments.Count Then sFunc = WSCript.Arguments( 0 )
 ' ----------  func -----------
   Select Case LCase( sFunc )
      Case "frstest"
        nRVal = frsTest()
      Case "sectest"
        nRVal = secTest()
      Case "bldcmd1"
        nRVal = bldCmd1()
      Case "testcmd"
        nRVal = testCmd()
      Case "parsedhcp"
        nRVal = parseDHCP()
      Case "cmdfound"
        nRVal = cmdFound()
      Case "dotherealwork"
        nRVal = doTheRealWork()
   End Select
 ' ----------  term -----------
   doMain = nRVal
 End Function
 
 ' ############################################################################
 ''# frsTest - just show the 'call a func' part works
 ' ############################################################################
 
 Function frsTest()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, frsTest() was called."
   frsTest = nRVal
 End Function
 
 ' ############################################################################
 ''# secTest - just show the 'call a func' part really works
 ' ############################################################################
 
 Function secTest()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, secTest() was called."
   secTest = nRVal
 End Function
 
 ' ############################################################################
 ''# bldCmd1 - first try to build netsh command
 ' ############################################################################
 
 Function bldCmd1()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, bldCmd1() was called."
   bldCmd1 = nRVal
 End Function
 
 Function bldCmd1()
   Dim nRVal : nRVal = 0 ' assume ok
 ' Start with the command containing place holders; use copy/paste if possible
   Dim sCmd  : sCmd = _
    "netsh dhcp server \\<ServerName> scope <ScopeID> add reservedip <ReservedIP> <MAC_Address> <ClientName> <ClientComment>"
 ' Show what we have
   WScript.Echo "sCmd:", "|" + sCmd + "|"
 ' Get the place holder into an array:
   Dim aNames : aNames = cutRE00( "(<\w+>)", sCmd )
 ' Show what we have
   WScript.Echo "aNames: (", Join( aNames, ", " ), ")"
 ' setup dictionary from aNames
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   Dim sKey
   For Each sKey In aNames
       dicParms( sKey ) = StrReverse( sKey ) ' just for testing
   Next
 ' Show what we have
   For Each sKey In dicParms.Keys
       WScript.Echo sKey, "=>", dicParms( sKey )
   Next
 ' Apply dicParms to sCmd and prove applyRpl
   WScript.Echo "sCmd:", "|" + sCmd + "|"
   WScript.Echo "sCmd:", "|" + applyRpl( dicParms, sCmd )  + "|"
 ' for the lazy programmer: build an assignment block for dicParms
   For Each sKey In dicParms.Keys
       WScript.Echo "dicParms( """ + sKey + """ ) = """" "
   Next
 
   bldCmd1 = nRVal
 End Function
 
 ' ############################################################################
 ''# testCmd - building netsh command from hardcoded params and .Run
 ' ############################################################################
 
 Function testCmd()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, testCmd() was called."
   testCmd = nRVal
 End Function
 
 Function testCmd()
   Dim nRVal : nRVal = 0 ' assume ok
   WScript.Echo "ok, testCmd() was called."
   WScript.Echo "Using gdicDefParms"
 
   Dim sCmd
   Dim sRet
   sCmd = applyRpl( gdicDefParms, gsCmd )
   sRet = runCmd( sCmd )
   If "" = sRet Then
      WScript.Echo "ok"
   Else
      WScript.Echo "error"
      WScript.Echo sRet
   End If
 
   WScript.Echo "Using dicParms"
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   dicParms( "<ServerName>" ) = "your"
   dicParms( "<ScopeID>" ) = "suitable"
   dicParms( "<ReservedIP>" ) = "test"
   dicParms( "<MAC_Address>" ) = "values"
   dicParms( "<ClientName>" ) = "here"
   dicParms( "<ClientComment>" ) = "please"
   sCmd = applyRpl( dicParms, gsCmd )
   sRet = runCmd( sCmd )
 
   testCmd = nRVal
 End Function
 
 ' ############################################################################
 ''# parseDHCP - parse DHCP output file into dictionary
 ' ############################################################################
 
 Function parseDHCP()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, parseDHCP() was called."
   parseDHCP = nRVal
 End Function
 
 Function parseDHCP()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, parseDHCP() was called."
 
   Dim oFSO        : Set oFSO    = CreateObject("Scripting.FileSystemObject")
   Dim strDHCPFile : strDHCPFile = ".\DHCPOuts.txt"
   Dim sDelim      : sDelim      = "ClientInfo :" & VbCrLf ' maybe: "ClientInfo : " (trailing blank)
   Dim arrEntries, nIdx
 
   arrEntries = Split( oFSO.OpenTextFile( strDHCPFile ).ReadAll(), sDelim )
 ' Skip header!
   For nIdx = 1 To UBound( arrEntries )
 '     The entry is still just a block of text so break it into lines for processing
       Dim arrLines : arrLines = Split( arrEntries( nIdx ), vbCrLf )
       WScript.Echo arrLines( 0 )
   Next
 
   parseDHCP = nRVal
 End Function
 
 Function parseDHCP()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, parseDHCP() was called."
 
   Dim dicClients  : Set dicClients = CreateObject( "Scripting.Dictionary" )
   Dim oFSO        : Set oFSO       = CreateObject( "Scripting.FileSystemObject" )
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim sDelim      : sDelim         = vbCrLf + "ClientInfo :" & vbCrLf ' maybe: "ClientInfo : " (trailing blank)
   Dim bVerbose    : bVerbose       = True ' set to False for big strDHCPFile
   Dim arrEntries, nIdx
 
   arrEntries = Split( oFSO.OpenTextFile( strDHCPFile ).ReadAll(), sDelim )
 ' Skip header!
   For nIdx = 1 To UBound( arrEntries )
 '     The entry is still just a block of text so break it into lines for processing
       Dim arrLines : arrLines = Split( arrEntries( nIdx ), vbCrLf )
       WScript.Echo arrLines( 0 )
       Dim dicTemp : Set dicTemp = CreateObject( "Scripting.Dictionary" )
       Dim strLine
       For Each strLine In arrLines
 '         Clean up
           strLine = Trim( strLine )
           If "" < strLine Then
              If "." = Right( strLine, 1 ) Then strLine = Left( strLine, Len( strLine ) - 1 )
 '            Split each line into a parameter and a value and add those to a temporary dictionary
              Dim arrParts : arrParts = Split( strLine, " = ")
              If 1 = UBound( arrParts ) Then
                 dicTemp.Add Trim( arrParts( 0 ) ), Trim( arrParts( 1 ) )
              Else
                 WScript.Echo "??? |" + strLine + "|"
              End If
           Else
 '            no need to process empty lines
           End If
       Next
 '     Now add that entry to the client dictionary with the IP address as the key
       Dim sIP : sIP = dicTemp( "IP Address" )
       WScript.Echo "Handling IP: |" + sIP + "|"
       If dicTemp.Exists( "IP Address" ) Then
          If dicClients.Exists( sIP ) Then
             WScript.Echo "??? - double IP: " + sIP
          Else
             dicClients.Add sIP, dicTemp
          End If
       Else
          WScript.Echo "??? - no IP Address found."
       End If
   Next
 ' Now we have a dictionary of all the clients reported in the file
 
 ' Dump the info to gain confidence
   If bVerbose Then
      Dim sKeyClient, dicParams, sKeyParam
      For Each sKeyClient In dicClients
          WScript.Echo "-------------", sKeyClient, "-------------"
          Set dicParams = dicClients( sKeyClient )
          For Each sKeyParam In dicParams
              WScript.Echo "", sKeyParam, "|" + dicParams( sKeyParam ) + "|"
          Next
      Next
   End If
 
   parseDHCP = nRVal
 End Function
 
 ' ############################################################################
 ''# cmdFound - netsh cmd for found IPs
 ' ############################################################################
 
 Function cmdFound()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, cmdFound() was called."
 
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim dicClients  : Set dicClients = parseDHCPebgreen( strDHCPFile )
 
   Dim sKeyClient, dicParams
   For Each sKeyClient In dicClients
       WScript.Echo "-------------", sKeyClient, "-------------"
   Next
 
   cmdFound = nRVal
 End Function
 
 Function cmdFound()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, cmdFound() was called."
 
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim dicClients  : Set dicClients = parseDHCPebgreen( strDHCPFile )
 ' stolen from testCmd()
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   Dim sCmd, sRet
   Dim sKeyClient, dicParams
 
   For Each sKeyClient In dicClients
       WScript.Echo "-------------", sKeyClient, "-------------"
 '     copied from dox box
 ' IP Address |100.10.12.12|
 ' SubnetMask |255.255.254.0|
 ' Client Hardware Address |12-12-12-12-12-12|
 ' Name |MachineNameb.org.company.com|
 ' Comment |(null)|
 ' Type |DHCP|
 ' Expires |12/05/2006 08:07:58|
 ' Owner Host IP Address |100.10.12.11|
 ' Owner Host NetBios Name |Server|
 ' Owner Host Name |(null)|
 '     stolen from testCmd()
       dicParms( "<ServerName>"    ) = dicClients( sKeyClient )( "Owner Host NetBios Name" )
       dicParms( "<ScopeID>"       ) = "?<ScopeID>?"
       dicParms( "<ReservedIP>"    ) = dicClients( sKeyClient )( "IP Address" )
       dicParms( "<MAC_Address>"   ) = dicClients( sKeyClient )( "Client Hardware Address" )
       dicParms( "<ClientName>"    ) = dicClients( sKeyClient )( "Name" )
       dicParms( "<ClientComment>" ) = ""
       sCmd = applyRpl( dicParms, gsCmd )
       sRet = runCmd( sCmd )
       WScript.Echo "-------------", sKeyClient, "-------------"
   Next
   cmdFound = nRVal
 End Function
 
 ' ############################################################################
 ''# doTheRealWork - not known yet
 ' ############################################################################
 
 Function doTheRealWork()
   Dim nRVal : nRVal = 0 ' assume ok
   WScript.Echo "ok, doTheRealWork() was called, but we aren't done yet!"
   doTheRealWork = nRVal
 End Function
 
 Function doTheRealWork()
   Dim nRVal : nRVal = 0 ' assume ok
   WScript.Echo "ok, doTheRealWork() was called, but we aren't done yet!"
 
 ' stolen from Function cmdFound()
   Dim strDHCPFile : strDHCPFile    = ".\DHCPOuts.txt"
   Dim dicClients  : Set dicClients = parseDHCPebgreen( strDHCPFile )
   Dim dicParms    : Set dicParms   = CreateObject( "Scripting.Dictionary" )
   Dim sCmd, sRet
   Dim sKeyClient, dicParams
 ' first try to specify IPs to look for
   Dim aIPs        : aIPs   = Array( "10", "11", "12", "13" )
 ' that's my problem: sIPPfx/Scope/Netmask
   Dim sIPPfx      : sIPPfx = "100.10.12."
   Dim sIP
 
   For Each sIP In aIPs
       sIP = sIPPfx + sIP
       WScript.Echo "-------------", sIP, "-------------"
       If dicClients.Exists( sIP ) Then
          WScript.Echo "Found"
 '        stolen from cmdFound()
          dicParms( "<ServerName>"    ) = dicClients( sIP )( "Owner Host NetBios Name" )
          dicParms( "<ScopeID>"       ) = "?<ScopeID>?"
          dicParms( "<ReservedIP>"    ) = dicClients( sIP )( "IP Address" )
          dicParms( "<MAC_Address>"   ) = dicClients( sIP )( "Client Hardware Address" )
          dicParms( "<ClientName>"    ) = dicClients( sIP )( "Name" )
          dicParms( "<ClientComment>" ) = ""
       Else
          WScript.Echo "Not Found"
          Dim sKey
          For Each sKey In gdicDefParms
              dicParms( sKey ) = gdicDefParms( sKey )
          Next
       End If
       sCmd = applyRpl( dicParms, gsCmd )
       sRet = runCmd( sCmd )
       WScript.Echo "----------------------------------------"
   Next
   doTheRealWork = nRVal
 End Function
 
 ' ############################################################################
 ''# runCmd - WShell.Exec sCmd (just echo the command for now; use copy/paste
 ''#          to run the command manually; fix all errors (gsCmd, gdicDefParms);
 ''#          then enable actual call
 ' ############################################################################
 
 Function runCmd( sCmd )
   Dim sRVal : sRVal = "" ' assume ok
   WScript.Echo "Run this from the commandline and hope for the best"
   WScript.Echo sCmd
 
 If False Then  ' fragment of aburt's code
   Dim objShell : Set objShell = CreateObject("Wscript.Shell")
   Dim objProc  : Set objProc  = objShell.Exec(strCommand)
 Do
   WScript.Sleep 100
   Loop Until objProc.Status <> 0
   If SomeError() Then sRVal = "suitable message"
 End If
 
   runCmd = sRVal
 End Function
 
 ' ############################################################################
 ''# cutRE00 - Q & Dirty: all matches.value into 1 dim array
 ' ############################################################################
 
 Function cutRE00( sPattern, sText )
   Dim aRVal : aRVal   = Array()
   Dim oRE   : Set oRE = New RegExp
   Dim oMTS, nIdx
   oRE.Pattern = sPattern
   oRE.Global  = True
   Set oMTS = oRE.Execute( sText )
   If 0 < oMTS.Count Then
      ReDim aRVal( oMTS.Count - 1 )
      For nIdx = 0 To UBound( aRVal )
          aRVal( nIdx ) = oMTS( nIdx ).Value
      Next
   End If
   cutRE00 = aRVal
 End Function
 
 ' ############################################################################
 ''# applyRpl - replace placeholders in sText with values from dicParms
 ' ############################################################################
 
 Function applyRpl( dicParms, ByVal sText )
   Dim sKey
   For Each sKey In dicParms
       sText = Replace( sText, sKey, dicParms( sKey ) )
   Next
   applyRpl = sText
 End Function
 
 ' ############################################################################
 ''# parseDHCPebgreen - parse strDHCPFile into a dictionary
 ' ############################################################################
 
 Function parseDHCPebgreen( strDHCPFile )
   Dim dicClients  : Set dicClients = CreateObject( "Scripting.Dictionary" )
   Dim oFSO        : Set oFSO       = CreateObject( "Scripting.FileSystemObject" )
   Dim sDelim      : sDelim         = vbCrLf + "ClientInfo :" & vbCrLf ' maybe: "ClientInfo : " (trailing blank)
   Dim arrEntries, nIdx
 
   arrEntries = Split( oFSO.OpenTextFile( strDHCPFile ).ReadAll(), sDelim )
 ' Skip header!
   For nIdx = 1 To UBound( arrEntries )
 '     The entry is still just a block of text so break it into lines for processing
       Dim arrLines : arrLines = Split( arrEntries( nIdx ), vbCrLf )
       Dim dicTemp : Set dicTemp = CreateObject( "Scripting.Dictionary" )
       Dim strLine
       For Each strLine In arrLines
 '         Clean up
           strLine = Trim( strLine )
           If "" < strLine Then
              If "." = Right( strLine, 1 ) Then strLine = Left( strLine, Len( strLine ) - 1 )
 '            Split each line into a parameter and a value and add those to a temporary dictionary
              Dim arrParts : arrParts = Split( strLine, " = ")
              If 1 = UBound( arrParts ) Then
                 dicTemp.Add Trim( arrParts( 0 ) ), Trim( arrParts( 1 ) )
              Else
 '               Add (better) error handling here
                 Err.Raise 4711, "??? |" + strLine + "|"
              End If
           Else
 '            no need to process empty lines
           End If
       Next
 '     Now add that entry to the client dictionary with the IP address as the key
       Dim sIP : sIP = dicTemp( "IP Address" )
       If dicTemp.Exists( "IP Address" ) Then
          If dicClients.Exists( sIP ) Then
 '           Add (better) error handling here
             Err.Raise 4711, "??? - double IP: " + sIP
          Else
             dicClients.Add sIP, dicTemp
          End If
       Else
 '        Add (better) error handling here
          Err.Raise 4711, "??? - no IP Address found."
       End If
   Next
 ' Now we have a dictionary of all the clients reported in the file
 ' return this to caller; remember the Set!!
   Set parseDHCPebgreen = dicClients
 End Function

(in reply to aburt)

Post #: 25

RE: Pull information from a file based on search criteria - 12/6/2006 2:39:23 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

Ehvbs, thoroughness be thy name.

As for the two issues that you raised with my script, both issues were based on the samples posted by the op. I used his sample text which did have "Client : ", and I used his loop which looped IPs other than what was in his sample (which I pointed out to him in a later post).

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ehvbs)

Post #: 26

RE: Pull information from a file based on search criteria - 12/6/2006 3:04:39 AM

ehvbs

Posts: 2078
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi ebgreen,

I'm grateful for your choice of words. (I expected - and deserve - pedantic; but I can't help it).
It wasn't my intention to put any blame on you; I just wanted to avoid additional problems caused
by such nearly invisible discrepancies.

ehvbs

(in reply to ebgreen)

Post #: 27

RE: Pull information from a file based on search criteria - 12/6/2006 3:12:26 AM