RE: Pull information from a file based on search criteria

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

RE: Pull information from a file based on search criteria

Logged in as: Guest

arrSession:exec spGetSession 2,2,40341

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> RE: Pull information from a file based on search criteria
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: << < prev 1 2 3 [4] 5 next > >>

Message

<< Older Topic Newer Topic >>

RE: Pull information from a file based on search criteria - 12/7/2006 7:43:15 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

DHCP Server version 5.6
Num Client info read = 273.
Total Client count = 273.
ClientInfo :
IP Address = 100.10.12.11.
SubnetMask = 255.255.254.0.
Client Hardware Address = 00-11-43-13-1f-f6.
Name = Machinea.company.com.
Comment = (null).
Type = DHCP
Expires = 12/05/2006 08:07:58.
Owner Host IP Address = 100.10.12.189.
Owner Host NetBios Name = DHCPSERVER.
Owner Host Name = (null).
ClientInfo :
IP Address = 100.10.12.12.
SubnetMask = 255.255.254.0.
Client Hardware Address = 00-0b-db-cb-b1-d9.
Name = Machineb.company.com.
Comment = (null).
Type = DHCP
Expires = 12/02/2006 10:51:13.
Owner Host IP Address = 100.10.12.189.
Owner Host NetBios Name = DHCPSERVER.
Owner Host Name = (null).

(in reply to ehvbs)

Post #: 61

RE: Pull information from a file based on search criteria - 12/7/2006 8:22:58 AM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Sorry aburt, *posting* the data won't help me - if I copy it from the forum HTML,
all tabs are lost (and I don't know what else was changed). I know it's a lot to
ask, but: could you *send* it to me (attachment, email)?

In exchange, I promise you a revised netshrun.vbs that will parse your
original sample.

By the way: There are two spaces after the = in

Name = Machineb.company.com.

I say that not to keep the blame from me, but to show the factual difficulties
we have to cope with.

(in reply to aburt)

Post #: 62

RE: Pull information from a file based on search criteria - 12/7/2006 8:31:07 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

No problem. I know this has been a pain. I have emailed you the text file. There should be one space before equal and one space after the equal.

(in reply to ehvbs)

Post #: 63

RE: Pull information from a file based on search criteria - 12/7/2006 9:02:34 AM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Thanks aburt, got it. While it look like the sample you posted, this is what
you get if you change spaces to ~ and tabs to �:

(in reply to aburt)

Post #: 64

RE: Pull information from a file based on search criteria - 12/7/2006 9:26:22 AM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

look what I got from seekc-02i.vbs:

cscript seekci-02.vbs
Got 744 chars form .\data\dhcpoutsam.txt
Found |ClientInfo| at Pos 85
065 69 i
066 65 e
067 6E n
068 74 t
069 20 .
070 63 c
071 6F o
072 75 u
073 6E n
074 74 t
075 20 .
076 3D =
077 20 .
078 32 2
079 37 7
080 33 3
081 2E .
082 20 .    no tab
083 20 .    still no tab
084 0A .    LF only
085 43 C
086 6C l
087 69 i
088 65 e
089 6E n
090 74 t
091 49 I
092 6E n
093 66 f
094 6F o
095 20 .
096 3A :
097 20 .     no tab
098 20 .     but a second blank
099 0A .     LF only
100 09 .     here comes the tab!
101 49 I
102 50 P
103 20 .
104 41 A
105 64 d
106 64 d
107 72 r
108 65 e
109 73 s
110 73 s
111 20 .
112 3D =
113 20 .
114 31 1
115 30 0

I think we'll have to change the parsing method; Split() is ok, if you can specify the delimiter
exactly, for moving targets (and I don't think we can garantee a fixed format for the whitespace)
you need regular expression. I'm working on this - but don't hold your breath.

(in reply to ehvbs)

Post #: 65

RE: Pull information from a file based on search criteria - 12/7/2006 12:18:43 PM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Not quick & very dirty:

' ############################################################################
 ''# netshrun-02.vbs : run netsh for a list of IPs
 ' ============================================================================
 ' (c) 2006 by YourCompany, Inc.
 '     77 YourStreet YourTown Whatever
 '     T: (+49) 123 45 67 89 * E: YourName@YourCompany.com
 ' ============================================================================
 ''# usage: cscript netshrun-02.vbs <action>
 ''#  <action> : bldCmd1   - first try to build netsh command
 ''#             testCmd   - building netsh command from hardcoded params and .Run
 ''#             parseDHCP - parse DHCP output file into dictionary
 ''#             parseAll  - parse all DHCP output files in gsDFolder into dictionary
 ''#             cmdFound  - netsh cmd for found IPs
 ''#             ip22dbl   - convert IR <-> double number
 ''#             seekCI    - seek ClientInfo
 ' [ update this usage as you add more experimental functions ]
 ''# usage: cscript netshrun-02.vbs ???
 ' [ update this usage when everything works as it should; for now we can't,
 '   because the main problem isn't solved yet.
 ' ]
 ' ############################################################################
 
 Option Explicit
 
 ' ############################################################################
 ''# global vars
 ' [ will grow as we proceed ]
 ' ############################################################################
 
 Dim goFS         : Set goFS  = CreateObject( "Scripting.FileSystemObject" )
 Dim gsCmd        : gsCmd     = _
    "netsh dhcp server \\<ServerName> scope <ScopeID> add reservedip <ReservedIP> <MAC_Address> <ClientName> <ClientComment>"
 Dim gdicDefParms : Set gdicDefParms = CreateObject( "Scripting.Dictionary" )
 Dim gsPatCI      : gsPatCI   = "\s*ClientInfo\s+:\s*"
 Dim gsPatLI      : gsPatLI   = "\s*\r?\n\s*"
 Dim gsPatKV      : gsPatKV   = "\s*=\s*"
 Dim gnVerbose    : gnVerbose = 1
 Dim gsDFolder    : gsDFolder = goFS.GetAbsolutePathName( ".\Data" )
 Dim gsFSpec      : gsFSpec   = goFS.GetAbsolutePathName( ".\Data\dhcpoutsam.txt" )
 
 ' ############################################################################
 ''# main - calls experimental func specified as first param on the command
 ' #        or - the now still empty - 'doTheRealWork' func
 ' ############################################################################
 
 WScript.Quit doMain()
 
 Function doMain()
   Dim nRVal : nRVal = 0 ' assume all is well
   Dim sFunc : sFunc = "doTheRealWork"
 ' ----------  init -----------
   gdicDefParms( "<ServerName>"    ) = "Server"         ' taken from aburt's postings,
   gdicDefParms( "<ScopeID>"       ) = "100.10.9.1"     ' check carefully! I'm still
   gdicDefParms( "<ReservedIP>"    ) = "100.10.9.189"   ' afraid we need *different*
   gdicDefParms( "<MAC_Address>"   ) = "000000000000"   ' params for the missing IPs
   gdicDefParms( "<ClientName>"    ) = "Machine Name"   ' ???
   gdicDefParms( "<ClientComment>" ) = "nocomment"      ' ???
 ' ----------  args -----------
   If 1 <= WScript.Arguments.Count Then sFunc = WSCript.Arguments( 0 )
 ' ----------  func -----------
   Select Case LCase( sFunc )
      Case "bldcmd1"
        nRVal = bldCmd1()
      Case "testcmd"
        nRVal = testCmd()
      Case "parsedhcp"
        nRVal = parseDHCP()
      Case "parseall"
        nRVal = parseAll()
      Case "cmdfound"
        nRVal = cmdFound()
      Case "ip22dbl"
        nRVal = ip22dbl()
      Case "seekci"
        nRVal = seekCI()
      Case "dotherealwork"
        nRVal = doTheRealWork()
      Case Else
        nRVal = 1
        WScript.Echo "??", sFunc, "??"
   End Select
 ' ----------  term -----------
   doMain = nRVal
 End Function
 
 ' ############################################################################
 ''# bldCmd1 - first try to build netsh command
 ' ############################################################################
 
 Function bldCmd1()
   Dim nRVal : nRVal = 0 ' assume ok
 ' Start with the command containing place holders; use copy/paste if possible
   Dim sCmd  : sCmd = _
    "netsh dhcp server \\<ServerName> scope <ScopeID> add reservedip <ReservedIP> <MAC_Address> <ClientName> <ClientComment>"
 ' Show what we have
   WScript.Echo "sCmd:", "|" + sCmd + "|"
 ' Get the place holder into an array:
   Dim aNames : aNames = cutRE00( "(<\w+>)", sCmd )
 ' Show what we have
   WScript.Echo "aNames: (", Join( aNames, ", " ), ")"
 ' setup dictionary from aNames
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   Dim sKey
   For Each sKey In aNames
       dicParms( sKey ) = StrReverse( sKey ) ' just for testing
   Next
 ' Show what we have
   For Each sKey In dicParms.Keys
       WScript.Echo sKey, "=>", dicParms( sKey )
   Next
 ' Apply dicParms to sCmd and prove applyRpl
   WScript.Echo "sCmd:", "|" + sCmd + "|"
   WScript.Echo "sCmd:", "|" + applyRpl( dicParms, sCmd )  + "|"
 ' for the lazy programmer: build an assignment block for dicParms
   For Each sKey In dicParms.Keys
       WScript.Echo "dicParms( """ + sKey + """ ) = """" "
   Next
 
   bldCmd1 = nRVal
 End Function
 
 ' ############################################################################
 ''# testCmd - building netsh command from hardcoded params and .Run
 ' ############################################################################
 
 Function testCmd()
   Dim nRVal : nRVal = 0 ' assume ok
   WScript.Echo "ok, testCmd() was called."
   WScript.Echo "Using gdicDefParms"
 
   Dim sCmd
   Dim sRet
   sCmd = applyRpl( gdicDefParms, gsCmd )
   sRet = runCmd( sCmd )
   If "" = sRet Then
      WScript.Echo "ok"
   Else
      WScript.Echo "error"
      WScript.Echo sRet
   End If
 
   WScript.Echo "Using dicParms"
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   dicParms( "<ServerName>" ) = "your"
   dicParms( "<ScopeID>" ) = "suitable"
   dicParms( "<ReservedIP>" ) = "test"
   dicParms( "<MAC_Address>" ) = "values"
   dicParms( "<ClientName>" ) = "here"
   dicParms( "<ClientComment>" ) = "please"
   sCmd = applyRpl( dicParms, gsCmd )
   sRet = runCmd( sCmd )
 
   testCmd = nRVal
 End Function
 
 ' ############################################################################
 ''# parseDHCP - parse DHCP output file into dictionary
 ' ############################################################################
 
 Function parseDHCP()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, parseDHCP() was called."
 
   Dim strDHCPFile : strDHCPFile    = gsFSpec
   Dim sAll        : sAll           = goFS.OpenTextFile( strDHCPFile ).ReadAll
   Dim dicClients  : Set dicClients = parseDHCPRE( sAll )
 
 ' Dump the info to gain confidence
   If 1 <= gnVerbose Then
      WScript.Echo "=============", strDHCPFile, "============="
      Dim sKeyClient, dicParams, sKeyParam
      For Each sKeyClient In dicClients
          WScript.Echo "-------------", sKeyClient, "-------------"
          Set dicParams = dicClients( sKeyClient )
          For Each sKeyParam In dicParams
              WScript.Echo "", sKeyParam, "|" + dicParams( sKeyParam ) + "|"
          Next
      Next
      WScript.Echo "==========================================="
   End If
 
   parseDHCP = nRVal
 End Function
 
 ' ############################################################################
 ''# parseAll  - parse all DHCP output files in gsDFolder into dictionary
 ''#             allows pedantic test of the gsPat*
 ' ############################################################################
 
 Function parseAll()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, parseAll() was called."
 
   Dim oFile
   For Each oFile In goFS.GetFolder( gsDFolder ).Files
       Dim sAll       : sAll           = oFile.OpenAsTextStream().ReadAll
       Dim dicClients : Set dicClients = parseDHCPRE( sAll )
 
 '     Dump the info to gain confidence
       If 1 <= gnVerbose Then
          WScript.Echo "=============", oFile.Path, "============="
          Dim sKeyClient, dicParams, sKeyParam
          For Each sKeyClient In dicClients
              WScript.Echo "-------------", sKeyClient, "-------------"
              Set dicParams = dicClients( sKeyClient )
              For Each sKeyParam In dicParams
                  WScript.Echo "", sKeyParam, "|" + dicParams( sKeyParam ) + "|"
              Next
          Next
          WScript.Echo "==========================================="
       End If
   Next
 
   parseAll = nRVal
 End Function
 
 
 
 
 ' ############################################################################
 ''# cmdFound - netsh cmd for found IPs
 ' ############################################################################
 
 Function cmdFound()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, cmdFound() was called."
 
   Dim strDHCPFile : strDHCPFile    = gsFSpec
   Dim sAll        : sAll           = goFS.OpenTextFile( strDHCPFile ).ReadAll
   Dim dicClients  : Set dicClients = parseDHCPRE( sAll )
 ' stolen from testCmd()
   Dim dicParms : Set dicParms = CreateObject( "Scripting.Dictionary" )
   Dim sCmd, sRet
   Dim sKeyClient, dicParams
 
   For Each sKeyClient In dicClients
       WScript.Echo "-------------", sKeyClient, "-------------"
 '     copied from dox box
 ' IP Address |100.10.12.12|
 ' SubnetMask |255.255.254.0|
 ' Client Hardware Address |12-12-12-12-12-12|
 ' Name |MachineNameb.org.company.com|
 ' Comment |(null)|
 ' Type |DHCP|
 ' Expires |12/05/2006 08:07:58|
 ' Owner Host IP Address |100.10.12.11|
 ' Owner Host NetBios Name |Server|
 ' Owner Host Name |(null)|
 '     stolen from testCmd()
       dicParms( "<ServerName>"    ) = dicClients( sKeyClient )( "Owner Host NetBios Name" )
       dicParms( "<ScopeID>"       ) = "?<ScopeID>?"
       dicParms( "<ReservedIP>"    ) = dicClients( sKeyClient )( "IP Address" )
       dicParms( "<MAC_Address>"   ) = dicClients( sKeyClient )( "Client Hardware Address" )
       dicParms( "<ClientName>"    ) = dicClients( sKeyClient )( "Name" )
       dicParms( "<ClientComment>" ) = ""
       sCmd = applyRpl( dicParms, gsCmd )
       sRet = runCmd( sCmd )
       WScript.Echo "-------------", sKeyClient, "-------------"
   Next
   cmdFound = nRVal
 End Function
 
 ' ############################################################################
 ''# ip22dbl -  - convert IR <-> double number
 ' ############################################################################
 
 Function ip22dbl()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, ip22dbl() was called."
 
   Dim aTests
   Dim sIP, dblIP, sIP2, dblIP2
 
   aTests = Array( _
       "100.10.12.0"    , "100.10.12.1", "100.10.13.0"      _
     , "100.10.9.0"     , "100.10.9.1" , "200.10.9.0"       _
     , "255.255.255.255", "0.0.0.0"    , "127.0.0.1"        _
                 )
   For Each sIP In aTests
       dblIP = convIP2Dbl( sIP )
       sIP2  = convDBL2IP( dblIP )
       WScript.Echo sIP, vbTab, dblIP, vbTab, sIP2, vbTab, CStr( (sIP2 = sIP) )
   Next
 
   aTests = Array( _
       0.0, 1.0, 255.0, 256.0, (256.0 * 256)  _
     , ((256.0 * 256.0) + 1.0) _
     , ((256.0 * 256.0 * 256.0)), ((256.0 * 256.0 * 256.0) + 1)  _
     , ((256.0 * 256.0 * 256.0 * 256.0) - 1)  _
                 )
   For Each dblIP In aTests
       sIP2   = convDBL2IP( dblIP )
       dblIP2 = convIP2Dbl( sIP2 )
       WScript.Echo sIP, vbTab, dblIP, vbTab, sIP2, vbTab, CStr( (dblIP = dblIP2) )
   Next
 
   dblIP2 = 0
   WScript.Echo "From", dblIP2, convDBL2IP( dblIP2 )
   For dblIP = dblIP2 To convIP2Dbl( "0.0.255.255" ) ' don't get �berm�tig (wanton?)
       If dblIP <> convIP2Dbl( convDBL2IP( dblIP ) ) Then
       End If
   Next
   WScript.Echo "To", dblIP, convDBL2IP( dblIP )
   ip22dbl = nRVal
 End Function
 
 ' ############################################################################
 ''# seekCI - seek ClientInfo
 ' ############################################################################
 
 Function seekCI()
   Dim nRVal : nRVal = 1 ' assume bad
   WScript.Echo "ok, seekCI() was called."
 
   Dim sFSpec : sFSpec   = gsFSpec
   Dim sCI    : sCI      = "ClientInfo"
   Dim sAll   : sAll     = goFS.OpenTextFile( sFSpec ).ReadAll
 
   WScript.Echo "Got", Len( sAll ), " chars from", sFSpec
 
   Dim nPos   : nPos     = InStr( 1, sAll, sCI, vbBinaryCompare )
   If 0 < nPos Then
      WScript.Echo "Found |" + sCI + "| at Pos", nPos
      Dim nFrom : nFrom = nPos - 20   ' should be checked vs. 0
      Dim nTo   : nTo   = nPos + 30   ' should be checked vs. Len( All )
      dumpHex sALL, nFrom, nTo
   Else
      WScript.Echo "Can't find |" + sCI + "|"
   End If
 
   seekCI = nRVal
 End Function
 
 ' ############################################################################
 ''# doTheRealWork - not known yet
 ' ############################################################################
 
 Function doTheRealWork()
   Dim nRVal : nRVal = 0 ' assume ok
   WScript.Echo "ok, doTheRealWork() was called, but we aren't done yet!"
 
   Dim strDHCPFile : strDHCPFile    = gsFSpec
   Dim sAll        : sAll           = goFS.OpenTextFile( strDHCPFile ).ReadAll
   Dim dicClients  : Set dicClients = parseDHCPRE( sAll )
   Dim dicParms    : Set dicParms   = CreateObject( "Scripting.Dictionary" )
   Dim sCmd, sRet
   Dim sKeyClient, dicParams
 ' first try to specify IPs to look for
   Dim aIPs        : aIPs   = Array( "10", "11", "12", "13" )
 ' that's my problem: sIPPfx/Scope/Netmask
   Dim sIPPfx      : sIPPfx = "100.10.12."
   Dim sIP
 
   For Each sIP In aIPs
       sIP = sIPPfx + sIP
       WScript.Echo "-------------", sIP, "-------------"
       If dicClients.Exists( sIP ) Then
          WScript.Echo "Found"
 '        stolen from cmdFound()
          dicParms( "<ServerName>"    ) = dicClients( sIP )( "Owner Host NetBios Name" )
          dicParms( "<ScopeID>"       ) = "?<ScopeID>?"
          dicParms( "<ReservedIP>"    ) = dicClients( sIP )( "IP Address" )
          dicParms( "<MAC_Address>"   ) = dicClients( sIP )( "Client Hardware Address" )
          dicParms( "<ClientName>"    ) = dicClients( sIP )( "Name" )
          dicParms( "<ClientComment>" ) = ""
       Else
          WScript.Echo "Not Found"
          Dim sKey
          For Each sKey In gdicDefParms
              dicParms( sKey ) = gdicDefParms( sKey )
          Next
       End If
       sCmd = applyRpl( dicParms, gsCmd )
       sRet = runCmd( sCmd )
       WScript.Echo "----------------------------------------"
   Next
   doTheRealWork = nRVal
 End Function
 
 ' ############################################################################
 ''# runCmd - WShell.Exec sCmd (just echo the command for now; use copy/paste
 ''#          to run the command manually; fix all errors (gsCmd, gdicDefParms);
 ''#          then enable actual call
 ' ############################################################################
 
 Function runCmd( sCmd )
   Dim sRVal : sRVal = "" ' assume ok
   WScript.Echo "Run this from the commandline and hope for the best"
   WScript.Echo sCmd
 
 If False Then  ' fragment of aburt's code
   Dim objShell : Set objShell = CreateObject("Wscript.Shell")
   Dim objProc  : Set objProc  = objShell.Exec(strCommand)
 Do
   WScript.Sleep 100
   Loop Until objProc.Status <> 0
   If SomeError() Then sRVal = "suitable message"
 End If
 
   runCmd = sRVal
 End Function
 
 ' ############################################################################
 ''# cutRE00 - Q & Dirty: all matches.value into 1 dim array
 ' ############################################################################
 
 Function cutRE00( sPattern, sText )
   Dim aRVal : aRVal   = Array()
   Dim oRE   : Set oRE = New RegExp
   Dim oMTS, nIdx
   oRE.Pattern = sPattern
   oRE.Global  = True
   Set oMTS = oRE.Execute( sText )
   If 0 < oMTS.Count Then
      ReDim aRVal( oMTS.Count - 1 )
      For nIdx = 0 To UBound( aRVal )
          aRVal( nIdx ) = oMTS( nIdx ).Value
      Next
   End If
   cutRE00 = aRVal
 End Function
 
 ' ############################################################################
 ''# applyRpl - replace placeholders in sText with values from dicParms
 ' ############################################################################
 
 Function applyRpl( dicParms, ByVal sText )
   Dim sKey
   For Each sKey In dicParms
       sText = Replace( sText, sKey, dicParms( sKey ) )
   Next
   applyRpl = sText
 End Function
 
 ' ############################################################################
 ''# convIP2Dbl - convert IP (1.2.3.4) to double number
 ' ############################################################################
 
 Function convIP2Dbl( sIP )
   Dim dblRVal   : dblRVal   = 0.0
   Dim lngFaktor : lngFaktor = 1
   Dim aParts    : aParts    = Split( sIP, "." )
   Dim nIdx
   If 3 <> UBound( aParts ) Then Err.Raise 4711, "Bad sIP |" + sIP + "| in convIP2Dbl()"
   For nIdx = 3 To 0 Step -1
       dblRVal   = dblRVal + (CLng( aParts( nIdx ) ) * lngFaktor)
       lngFaktor = lngFaktor * 256
   Next
   convIP2Dbl = dblRVal
 End Function
 
 ' ############################################################################
 ''# convDBL2IP - convert double number to IP (1.2.3.4)
 ' ############################################################################
 
 Function convDBL2IP( ByVal nDbl )
   Dim sRVal     : sRVal = ""
   Dim lngFaktor : lngFaktor = 256 * 256 * 256
   Dim nIdx, nRes
   For nIdx = 0 To 2
 '     WScript.Echo lngFaktor, Hex( lngFaktor ), TypeName( nDbl )
 '     nRes      = nDbl \ lngFaktor
       nRes      = Fix( nDbl / lngFaktor )
       sRVal     = sRVal + CStr( nRes ) + "."
       nDbl      = nDbl - (nRes * lngFaktor)
       lngFaktor = lngFaktor \ 256
   Next
   sRVal = sRVal + CStr( nDbl )
   convDBL2IP = sRVal
 End Function
 
 ' ############################################################################
 ''# dumpHex - quick & dirty Hexdump (todo: wide format, checks, output method,
 ''#           make callable like cscript netshrun-02.vbs file from to)
 ' ############################################################################
 
 Sub dumpHex( sStr, nFrom, nTo )
    Dim nPos, sChr, nChr
    For nPos = nFrom To nTo
        sChr = Mid( sStr, nPos, 1 )
        nChr = Asc( sChr )
        If nChr <= 32 Then
           sChr = "."
        End If
        WScript.Echo Right( "00" & nPos, 3 ), Right( "0" & Hex( nChr ), 2 ), sChr
    Next
 End Sub
 
 ' ############################################################################
 ''# TrimWSRE - zap leading and trailing whitespace (can't use trim, because that
 ''#            deletes only blanks) (todo: cache oRE (class), what about CtrZ?)
 ' ############################################################################
 
 Function TrimWSRE( sStr )
   Dim oRE : Set oRE = CreateObject( "VBScript.RegExp" )
   oRE.Pattern    = "(^[\s]+)|([\s]+$)"  ' todo: optimize!
   oRE.Global     = True
   oRE.IgnoreCase = True ' irrelevant (?!)
   oRE.MultiLIne  = False
   TrimWSRE = oRE.Replace( sStr, "" )
 End Function
 
 ' ############################################################################
 ''# SplitRE00 - Q&D regexp split, specialized for mburt/dhcp
 ' ############################################################################
 
 Function SplitRE00( sStr, sPat, bMultiLine )
   Dim aRVal : aRVal   = Array()
   Dim oRE   : Set oRE = CreateObject( "VBScript.RegExp" )
   oRE.Pattern    = sPat
   oRE.Global     = True
   oRE.IgnoreCase = True ' relevant, I won't start again for "clientinfo"
   oRE.MultiLIne  = bMultiLine
   Dim oMTS  : Set oMTS = oRE.Execute( sStr )
   If 0 < oMTS.Count Then
      ReDim aRVal( oMTS.Count )
      Dim   nIdx : nIdx = 0
      Dim   nPos : nPos = 1
      Dim   oMT
      For Each oMT in oMTS
          aRVal( nIdx ) = Mid( sStr, nPos, oMT.FirstIndex - nPos + 1 )
          nIdx = nIdx + 1
          nPos = oMT.FirstIndex + oMT.Length + 1
      Next
      aRVal( nIdx ) = Mid( sStr, nPos )
   End If
   SplitRE00 = aRVal
 End Function
 
 ' ############################################################################
 ''# parseDHCPRE - parse !String! sStr into a dictionary using RegExps
 ' ############################################################################
 
 Function parseDHCPRE( ByVal sStr )
   Dim dicClients  : Set dicClients = CreateObject( "Scripting.Dictionary" )
 
 ' Clean: No leading or trailing whitespace & let's zap CtrZ too
   If 2 <= gnVerbose Then WScript.Echo Len( sStr )
   sStr = TrimWSRE( sStr )
   If 2 <= gnVerbose Then WScript.Echo Len( sStr )
 
   Dim aItems : aItems = SplitRE00( sStr, gsPatCI, False )
   Dim nUB    : nUB    = UBound( aItems )
   Dim nItems
   WScript.Echo "nUB", nUB, "Count", (nUB + 1), "Clients", nUB
 
   For nItems = 1 To nUB
       If 2 <= gnVerbose Then WScript.Echo Left( aItems( nItems ), 10 ), "...", Right( aItems( nItems ), 10 )
       Dim aPairs  : aPairs = SplitRE00( TrimWSRE( aItems( nItems ) ), gsPatLI, False )
       Dim dicTemp : Set dicTemp = CreateObject( "Scripting.Dictionary" )
       Dim strLine
       For Each strLine In aPairs
           If "." = Right( strLine, 1 ) Then strLine = Left( strLine, Len( strLine ) - 1 )
           Dim arrParts : arrParts = SplitRE00( strLine, gsPatKV, False )
           If 1 = UBound( arrParts ) Then
              If 2 <= gnVerbose  Then WScript.Echo "|" + Join( arrParts, "|" ) + "|"
              dicTemp.Add arrParts( 0 ), arrParts( 1 )
           Else
 '            Add (better) error handling here
              Err.Raise 4711, "??? |" + strLine + "|"
           End If
       Next
       Dim sIP : sIP = dicTemp( "IP Address" )
       If dicTemp.Exists( "IP Address" ) Then
          If dicClients.Exists( sIP ) Then
 '           Add (better) error handling here
             Err.Raise 4711, "??? - double IP: " + sIP
          Else
             dicClients.Add sIP, dicTemp
          End If
       Else
 '        Add (better) error handling here
          Err.Raise 4711, "??? - no IP Address found."
       End If
   Next
 
   Set parseDHCPRE = dicClients
 End Function
 
 ------------------- output (using mburt's original sample -------------------
 
 cscript netshrun-02.vbs
 ok, doTheRealWork() was called, but we aren't done yet!
 nUB 2 Count 3 Clients 2
 ------------- 100.10.12.10 -------------
 Not Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment
 ----------------------------------------
 ------------- 100.10.12.11 -------------
 Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\DHCPSERVER scope ?<ScopeID>? add reservedip 100.10.12.11 00-11-43-13-1f-f6 Machinea.company.com
 ----------------------------------------
 ------------- 100.10.12.12 -------------
 Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\DHCPSERVER scope ?<ScopeID>? add reservedip 100.10.12.12 00-0b-db-cb-b1-d9 Machineb.company.com
 ----------------------------------------
 ------------- 100.10.12.13 -------------
 Not Found
 Run this from the commandline and hope for the best
 netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment
 ----------------------------------------

(in reply to ehvbs)

Post #: 66

RE: Pull information from a file based on search criteria - 12/8/2006 3:10:46 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

Ok Some progress is being made :) Got a few questions.

I ran the new script heres the output

ok, doTheRealWork() was called, but we aren't done yet!
nUB 2 Count 3 Clients 2
------------- 100.10.12.10 -------------
Not Found
Run this from the commandline and hope for the best
netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment
----------------------------------------
------------- 100.10.12.11 -------------
Found
Run this from the commandline and hope for the best
netsh dhcp server \\DHCPSERVER scope ?<ScopeID>? add reservedip 100.10.12.11 00-11-43-13-1f-f6 Machinea.company.com
----------------------------------------
------------- 100.10.12.12 -------------
Found
Run this from the commandline and hope for the best
netsh dhcp server \\DHCPSERVER scope ?<ScopeID>? add reservedip 100.10.12.12 00-0b-db-cb-b1-d9 Machineb.company.com
----------------------------------------
------------- 100.10.12.13 -------------
Not Found
Run this from the commandline and hope for the best
netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment
----------------------------------------
Exit code: 0 , 0000h

*******************************************************
But It does not create a dhcp reservation for any IP (found or not found.)

(in reply to ehvbs)

Post #: 67

RE: Pull information from a file based on search criteria - 12/8/2006 4:51:54 AM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

if you look at the code:

' ############################################################################
''# runCmd - WShell.Exec sCmd (just echo the command for now; use copy/paste
''#          to run the command manually; fix all errors (gsCmd, gdicDefParms);
''#          then enable actual call
' ############################################################################

Function runCmd( sCmd )
   Dim sRVal : sRVal = "" ' assume ok
   WScript.Echo "Run this from the commandline and hope for the best"
   WScript.Echo sCmd

If False Then ' fragment of aburt's code
   Dim objShell : Set objShell = CreateObject("Wscript.Shell")
   Dim objProc : Set objProc = objShell.Exec(strCommand)
Do
   WScript.Sleep 100
   Loop Until objProc.Status <> 0
   If SomeError() Then sRVal = "suitable message"
End If

   runCmd = sRVal
End Function

you'll realize, that the

netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.9.189 000000000000 Machine Name nocomment

is just echoed to screen. I sincerely advise to check the generated commands very carefully before you enable the
actual execution by

     If True Then

Did you spare a thought on possible error and how to handle them?

Good luck!

(in reply to aburt)

Post #: 68

RE: Pull information from a file based on search criteria - 12/8/2006 6:57:44 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

Ehvbs,

Are u saying that if I rewrite the code to If True Then, It would then create the reservation. How can i echo the netsh command line to make sure it is entered in correctly.

As far as errors are concerned, The complexity of this script is has gone beyond my current skill set. Is it possible to output everything to a text file including errors?

(in reply to ehvbs)

Post #: 69

RE: Pull information from a file based on search criteria - 12/8/2006 7:29:07 AM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

If you replace "False" with "True" the code in the IF-THEN-Block will be executed. That is
not the same as "create the reservation" - the last is what we programmers hope.
Seriously: The script echos the command it would send to the .Exec() method to give
you the chance to check its validity.
If you are sure the 4 four commands echoed by a run on the short test file are correct
you can use copy/paste to execute them from the command line.
You could device reroute a run on your real data to file

netshrun-02.vbs >log.tmp

and study that. I can't really help you there, because I know next to nothing about
DHCP server administration.

As to the error handling (in general and especially for the .Exec()) - I'll have to think
about that (i.e. need some time).

(in reply to aburt)

Post #: 70

RE: Pull information from a file based on search criteria - 12/10/2006 3:35:43 PM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

hey it me again

I have been testing this script all weekend :( Trying to understand how it worksgetting much closer.) Took your advice on copy paste for the netsh run command.

problem: for the not found address i need there reserved IP to be the IP address that is NOt found instead of gdicDefParms( "<ReservedIP>" ) = "0.0.0.0"

output should look like this
------------- 100.10.12.14 -------------
Not Found
Run this from the commandline and hope for the best
netsh dhcp server \\ scope 100.10.12.0 add reservedip 100.10.12.14 000000000000 Machine Name

I need to remove the dashes from the mac address on the Found IPs the netsh command line will error out if the dashes r included

Can you help out?

(in reply to ehvbs)

Post #: 71

RE: Pull information from a file based on search criteria - 12/10/2006 8:47:54 PM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

I changed the "not found" part of doTheRealWork() to

and got

------------- 100.10.12.13 -------------
Not Found
Run this from the commandline and hope for the best
netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.12.13 000000000000 Machine Name nocomment
----------------------------------------

(Sorry for being terse, being pressed for time just now)

(in reply to aburt)

Post #: 72

RE: Pull information from a file based on search criteria - 12/11/2006 9:05:51 AM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

Ok I got a new problem the now the found IPs have dashes where they didnt have dashed before. Also I have tested the run command with copy paste how can I get them to execute.

(in reply to ehvbs)

Post #: 73

RE: Pull information from a file based on search criteria - 12/11/2006 9:35:26 AM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

nice to see/read from you again. As to the first problem:

If I run my netshrun-02.vbs on my sample file, I get

cscript netshrun-02.vbs
ok, doTheRealWork() was called, but we aren't done yet!
nUB 2 Count 3 Clients 2
------------- 100.10.12.10 -------------
Not Found
Run this from the commandline and hope for the best
netsh dhcp server \\Server scope 100.10.9.1 add reservedip 100.10.12.10 000000000000 Machine Name nocomment
----------------------------------------
------------- 100.10.12.11 -------------
Found
Run this from the commandline and hope for the best
netsh dhcp server \\DHCPSERVER scope ?<ScopeID>? add reservedip 100.10.12.11 00-11-43-13-1f-f6 Machinea.company.com
----------------------------------------

because my sample files contains:

ClientInfo :
    IP Address = 100.10.12.11.
    SubnetMask = 255.255.254.0.
    Client Hardware Address = 00-11-43-13-1f-f6.
    Name = Machinea.company.com.

So:

(a) double check your input file
(b) if you can't guarantee a consistent format, use the Replace(..) strategy on the data red
        as we did on the default data

( I'm not complaining or chiding, but in my last post I wrote:

'        we could/should remove dashes once for all at init/when reading it for the found IPs
'        but doing it here keeps all changes at one place; you can do the Replace() wherever
'        it's necessary
)

The "executing", well, yes. As I can't test it here, I really hesitate to say something like: "use
the script on a input file with just 1 ClientInfo; look once again at the output; change the
"False" we talked about to "True"; cross your fingers and run the script".

You'll have to do your own risk assessment, of course.

Good luck!

(in reply to aburt)

Post #: 74

RE: Pull information from a file based on search criteria - 12/11/2006 2:41:06 PM

aburt

Posts: 104
Score: 0
Joined: 12/4/2006
Status: offline

hey ehvbs,

While waiting on your response I took a stab at fixing the dashes and added this line to the do the real work function
dicParms( "<MAC_Address>" ) = Replace (dicClients( sIP )( "Client Hardware Address" ), "-", "" )

Seems to be working. Thanks for not busting my chops for all repeated posts I feel really guilty that I been so needy on this one.

When I saw the first post I knew that it was over my head but I have been trying to work through it, so again thank you for carrying me.

But, I have learned oh so much from trying to disect this script even if there are still a few parts I dont quite understand.

I am actually testing this on a test box with the sample text file. It works. Your a genious.

Ok forgive me.

Also I added the following where SomeScript Error.

if objProc.ExitCode <> 0 then
WScript.Echo "EXIT CODE: " & objProc.ExitCode
WScript.Echo "ERROR: " & objProc.StdErr.ReadAll
end if

How can I change the range of ips to look for.

Currently we have
Dim aIPs : aIPs = Array( "1", "2", "3", "4" )

But I need the range of 1 to 255.

In other words the script should run through a range of ips I specify. ie 100.10.12.1 to 100.10.12.255

(in reply to ehvbs)

Post #: 75

RE: Pull information from a file based on search criteria - 12/11/2006 7:47:55 PM

ehvbs

Posts: 2077
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi aburt,

(1) Your enhancement to the error handling looks ok to me. I do like that you
    used a component/concept (WshScriptExec object) from the script to look up
    its method/properties and on your own applied that knowledge to a problem.
    Of course, every solution may be improved:

        Perhaps objProc.StdOut should be taken into consideration too

        plain .ReadAll is dangerous because it will fail on a file of size 0, so
        maybe it should be guarded by an .AtEndOfStream test (yes I know, I'm
        guilty of quick & dirty work "goFS.OpenTextFile( strDHCPFile ).ReadAll"
        too)

        Using .Exec or .Run is a frequent task. Just look at
           http://www.visualbasicscript.com/m_40768/tm.htm
        So having a reusable function or class would be desirable

    If you are interested (and have a (not so) little bit of free time) we
    could start a new topic ".Exec/.Run command". How do you feel about that?

(2) The