Active Directory Query Template

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Active Directory Query Template

Logged in as: Guest

arrSession:exec spGetSession 2,16,40609

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Active Directory Query Template
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Active Directory Query Template - 12/7/2006 10:10:00 PM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

Here's an AD query template I use, pretty much, all the time.

Dim objConnection,objCommand,objRootLDAP,strDNSDomain,strUserorMachine
Const ADS_SCOPE_ONELEVEL = 1
Const ADS_SCOPE_SUBTREE = 2
Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000

Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
objConnection.Cursorlocation=3

Set objCommand =   CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection
objCommand.Properties("Page Size") = 1000

Set objRootLDAP = GetObject("LDAP://RootDSE")
strDNSDomain = objRootLDAP.Get("DefaultNamingContext")

GetInputs

Wscript.Echo "Searching " & strDNSDomain

Set objRecordSet = objCommand.Execute
objRecordSet.Sort="Name"

If objRecordSet.RecordCount = 0 Then WScript.Echo "No records found"

Do Until objRecordSet.Eof
   'WScript.Echo objRecordSet.Fields("sAMAccountName") & "," & objRecordSet.Fields("name") & "," & objRecordSet.Fields("distinguishedname")
   WScript.Echo "UserID/MachineName = " & objRecordSet.Fields("sAMAccountName") 
   wscript.Echo "Full Name = " & objRecordSet.Fields("name") 
   Wscript.Echo "LDAP Path = " & objRecordSet.Fields("distinguishedname")
   WScript.Echo
   objRecordSet.Movenext
Loop
WScript.Echo objRecordSet.RecordCount & " records were returned" & VbCrLf

objRecordSet.close
objConnection.close

Sub GetInputs
   
   QueryType1 = "1) Search for a single enabled user"
   QueryType2 = "2) Search for a single user (enabled OR disabled)"  
   QueryType3 = "3) Return all ENABLED users from the entire domain"
   QueryType4 = "4) Return all users (enabled AND disabled) from the entire domain"
   QueryType5 = "5) Return all ENABLED users from a single level" 
   QueryType6 = "6) Return all users (enabled AND disabled) from one level"
   QueryType7 = "7) Search for a single machine"
   QueryType8 = "8) Return all machines in the domain"  
   QueryType9 = "9) Return all machines from a single level"
   
   QueryChoice = InputBox(QueryType1 & VbCrLf & VbCrLf & QueryType2 & VbCrLf & VbCrLf & QueryType3 & VbCrLf & VbCrLf & _
                           QueryType4 & VbCrLf & VbCrLf & QueryType5 & VbCrLf & VbCrLf & QueryType6 & VbCrLf & VbCrLf & _
                           QueryType7 & VbCrLf & VbCrLf & QueryType8 & VbCrLf & VbCrLf & QueryType9, "Please select a query (1-9)")
   
   Set objRegExp = New RegExp
   With objRegExp
       .Pattern = "[0-9]"
       .IgnoreCase = True
       .Global = True
   End With
   
   If QueryChoice = "" Then 
       WScript.Quit
   ElseIf objRegExp.Test(QueryChoice) Then
   
       Select Case QueryChoice
           Case 1
               strUserorMachine = InputBox("Enter a userID to search for")
               If strUserorMachine = "" Then WScript.Quit
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=person)(objectClass=user)(!userAccountControl:1.2.840.113556.1.4.803:=2)(samaccountname=" & strUserorMachine & ")); sAMAccountName,distinguishedname,name ;subtree"
               objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
           Case 2
               strUserorMachine = InputBox("Enter a userID to search for")
               If strUserorMachine = "" Then WScript.Quit
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=person)(objectClass=user)(samaccountname=" & strUserorMachine & ")); sAMAccountName,distinguishedname,name ;subtree"
               objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
           Case 3
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=person)(objectClass=user)(!userAccountControl:1.2.840.113556.1.4.803:=2)); name,sAMAccountName,distinguishedname ;subtree"
               objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
           Case 4
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=person)(objectClass=user)); name,sAMAccountName,distinguishedname ;subtree"
               objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
           Case 5
               strDNSDomain = InputBox("Enter the OU/Container to be searched")
               If strDNSDomain = "" Then WScript.Quit
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=person)(objectClass=user)(!userAccountControl:1.2.840.113556.1.4.803:=2)); name,sAMAccountName,distinguishedname ;onelevel"
               objCommand.Properties("Searchscope") = ADS_SCOPE_ONELEVEL
           Case 6
               strDNSDomain = InputBox("Enter the OU/Container to be searched")
               If strDNSDomain = "" Then WScript.Quit
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=person)(objectClass=user)); name,sAMAccountName,distinguishedname ;onelevel"
               objCommand.Properties("Searchscope") = ADS_SCOPE_ONELEVEL
           Case 7
               strUserorMachine=InputBox("Enter a Machine name to search for")
               If strUserorMachine = "" Then WScript.Quit
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(&(objectCategory=computer)(name=" & strUserorMachine & ")); samAccountName,distinguishedname,name ;subtree"
               objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
           Case 8
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(objectCategory=computer); samAccountName,distinguishedname,name ;subtree"
               objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
           Case 9
               strDNSDomain = InputBox("Enter the OU/Container to be searched")
               If strDNSDomain = "" Then WScript.Quit
               objCommand.CommandText = "<LDAP://" & strDNSDomain & ">;(objectCategory=computer); samAccountName,distinguishedname,name ;onelevel"
               objCommand.Properties("Searchscope") = ADS_SCOPE_ONELEVEL
           Case Else
               GetInputs
       End Select
   Else
       GetInputs
   End If
               
                       
End Sub

Function PasswordExpires(strUser)

Set objUser = GetObject("LDAP://" & strUser)
   intUserAccountControl = objUser.Get("userAccountControl")
   
   If intUserAccountControl And ADS_UF_DONT_EXPIRE_PASSWD Then
       PasswordExpires=True
   Else
       PasswordExpires=False
   End If
End Function

< Message edited by ginolard -- 2/19/2007 8:43:06 PM >

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

Revisions: 2 | Post #: 1

RE: Active Directory Query Template - 2/19/2007 8:46:48 PM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

I've updated the above script to make a little more user-friendly. I've also added a few more query choices.

If you can think of any other queries that you might need, let me know and I can add them easily. A couple of notes

There is a small Function that can be used to test if a user's password has expired
You can have the output as comma-separated by commenting in the first Wscript.Echo line in the Do Loop of the main code

I really SHOULD convert this into an HTA....

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to ginolard)

Post #: 2

RE: Active Directory Query Template - 3/6/2007 9:51:14 AM

Diversion

Posts: 1
Score: 0
Joined: 3/6/2007
Status: offline

How bout a query to list all group a userID is a part of? Basically everything in the Members Of section in AD.

Jay

(in reply to ginolard)

Post #: 3

RE: Active Directory Query Template - 3/25/2007 9:30:19 PM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

I prefer to have a separate script for that ;)

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to Diversion)

Post #: 4

RE: Active Directory Query Template - 6/11/2007 9:43:00 PM

andy robinson

Posts: 2
Score: 0
Joined: 6/11/2007
Status: offline

Many thanks for that one, now the question is, can you do a script that would export to a csv,? just computer name, last logon to domain (date?) something like that.

after pressing the enter key for 543 computers, excuse spellink mistakes finger soar....

love these smileys

Andy

(in reply to ginolard)

Post #: 5

RE: Active Directory Query Template - 6/11/2007 10:26:07 PM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

Well, I *could* but we're not here to write scripts for you ;)

Writing to a CSV file is easy. You will need to read up the FileSystemObject and OpenTextFile/CreateTextFile

AD querying is a more complex subject admittedly but this template script should give you a fair understanding of how the query syntax is formed. You will just need to find the field for lastlogontime (ADSIEDIT could do that for you)

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to andy robinson)

Post #: 6

RE: Active Directory Query Template - 6/29/2007 11:17:12 AM

jrcochranusa

Posts: 25
Score: 0
Joined: 1/30/2007
Status: offline

Dude...this script is awesome...I use it for tons of stuff!!

Thanks,

_____________________________

Thanks,

jrc

(in reply to ginolard)

Post #: 7

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> Active Directory Query Template

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts