RE: Complicated: read a filename if its yesterdays date write CMD

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

RE: Complicated: read a filename if its yesterdays date write CMD

Logged in as: Guest

arrSession:exec spGetSession 2,2,41166

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> RE: Complicated: read a filename if its yesterdays date write CMD
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: << < prev 1 [2]

Message

<< Older Topic Newer Topic >>

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 3:44:20 AM

ehvbs

Posts: 2222
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi swerver,

I don't understand the need for any IFs in the first place. Arent't you concatenating
the suffix as you get it from

fileNumber = Mid(objFile.Name,22,2)

to the outputfilename regardlessly of its current value:

outputFileName = outputFolder & "\" & CheckYear & CheckMonth & CheckDate & "_" & FileNumber & ".txt"

What am I overlooking?

(in reply to swerver)

Post #: 21

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 3:45:05 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

fileNumber = Mid(objFile.Name,22,2)
Select Case fileNumber
   Case "02"
         outputFileName = outputFolder & "\" & CheckYear & CheckMonth & CheckDate & "_" & FileNumber & ".txt"
   Case "01"
         outputFileName = outputFolder & "\" & CheckYear & CheckMonth & CheckDate & "_" & FileNumber & ".txt"
     Case "00"
        outputFileName = outputFolder & "\" & CheckYear & CheckMonth & CheckDate & "_" & fileNumber & ".txt"
End Case

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to swerver)

Post #: 22

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 3:46:57 AM

ehvbs

Posts: 2222
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi ebgreen,

in exchange for "End Select" - can you answer my question?

(in reply to ebgreen)

Post #: 23

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 3:51:40 AM

ebgreen

Posts: 5246
Score: 31
Joined: 7/12/2005
Status: offline

Ooops....

Oh well. I didn't include a default case either which I usually consider to be a good thing. I can't answer your question however.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ehvbs)

Post #: 24

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 3:59:35 AM

swerver

Posts: 27
Score: 0
Joined: 12/18/2006
Status: offline

quote:

ORIGINAL: ehvbs

Hi swerver,

I don't understand the need for any IFs in the first place. Arent't you concatenating
the suffix as you get it from

fileNumber = Mid(objFile.Name,22,2)

to the outputfilename regardlessly of its current value:

outputFileName = outputFolder & "\" & CheckYear & CheckMonth & CheckDate & "_" & FileNumber & ".txt"

What am I overlooking?

Because there can be various filename endings that need to be added to the outputFileName ?
eg _000.mdf or _001.mdf or _002.mdf etc... in fact, I'm not sure what the limit could be... so need to loop really?

Would the case do that?

Computationaly, which is the best to use?

< Message edited by swerver -- 12/21/2006 4:04:02 AM >

(in reply to ehvbs)

Post #: 25

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 8:08:46 PM

ehvbs

Posts: 2222
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi swerver,

This is a simple proof of concept/test script, to experiment with 'numbered file copy':

' ############################################################################
 ''# swerver-03.vbs : exploring swerver's file processing problem
 ' ============================================================================
 ''# usage: cscript swerver-03.vbs <action> <numfiles>
 ''#  <action>   : gen  - generate <numfiles> files in .\test; each named like:
 ''#                      ISA_20061219_000.mdf, ISA_20061219_001.mdf => ISA_<date>_<num>.mdf
 ''#               proc - process (i.e. fake msdetotext.vbs's action by simple copy)
 ''#                      <numfiles> file; putting the result in .\test\processed;
 ''#                      files are named like 20061101_001.txt => <date>_<num>.txt
 ''#                                                   !!!! change from the first specs
 ''#               mult - generating <numfiles> copies of each file in .\test; resulting
 ''#                      files in .\test\processed are named like <date>_<num1>_<num2>.txt
 ''#                      num1 comes from the source file, num2 reflcts a persistent
 ''#                      copy count
 ''#  <numfiles> : number of files to generate resp. to process
 ' ############################################################################
 
 Option Explicit
 
 ' ############################################################################
 ''# global vars
 ' ############################################################################
 
 Dim goFS : Set goFS = CreateObject( "Scripting.FileSystemObject" )
 
 ' ############################################################################
 ''# main - dispatch to the sub function selected on the CLI
 ' ############################################################################
 
 WScript.Quit doMain00()
 
 ' ============================================================================
 ''= doMain00 - dispatch to the sub function selected on the CLI
 ' ============================================================================
 
 Function doMain00()
   Dim nRVal     : nRVal     = 0     ' errorlevel to return to the OS; not really used here
   Dim sAction   : sAction   = "gen" ' default action/function
   Dim nNumFiles : nNumFiles = 5     ' default numer of file to do (according to action)
   Dim sSrcDir   : sSrcDir   = ".\test"
   Dim sDstDir   : sDstDir   = ".\test\processed"
 
   If 1 <= WScript.Arguments.Count Then sAction   =       WScript.Arguments( 0 )
   If 2 <= WScript.Arguments.Count Then nNumFiles = CInt( WScript.Arguments( 1 ) )
 
   Select Case LCase( sAction )
      Case "gen"
        nRVal = createTestData( sSrcDir, nNumFiles )
      Case "proc"
        nRVal = processFiles( sSrcDir, sDstDir, nNumFiles )
      Case "mult"
        nRVal = multiplyFiles( sSrcDir, sDstDir, nNumFiles )
      Case Else
        nRVal = 2
        WScript.Echo "usage: cscript swerver-03.vbs gen|proc|mult <numfiles>"
   End Select
   doMain00 = nRVal
 End Function
 
 ' ============================================================================
 ''= createTestData - create nNumFiles files in sSrcDir; each named ISA_<date>_<num>.mdf
 ''=                  containing its full filespec
 ' ============================================================================
 
 Function createTestData( sSrcDir, nNumFiles )
   Dim nRVal : nRVal = 0
   WScript.Echo "createTestData(", sSrcDir, nNumFiles, ") called."
 
   zapDir sSrcDir + "\*.mdf"
 
   Dim nIdx
   For nIdx = 0 To (nNumFiles - 1)
       Dim dtToday : dtToday = Date()
       Dim nRange  : nRange  = nNumFiles \ 3
       Dim sDStamp : sDStamp = fmtYMD( DateAdd( "d", dtToday, IRandR( -nRange, nRange + 1 ) ) )
       Dim nNum    : nNum    = -1
       Do
           nNum = nNum + 1
           Dim sFSpec  : sFSpec  = goFS.GetAbsolutePathName( _
                                   sSrcDir + "\ISA_" + sDStamp + "_" + PadL( nNum, 3, "0" ) + ".mdf" )
       Loop While goFS.FileExists( sFSpec )
       With goFS.CreateTextFile( sFSpec, True )
          .WriteLine sFSpec
          .Close
       End With
       WScript.Echo sFSpec, "created"
   Next
 
   createTestData = nRVal
 End Function
 
 ' ============================================================================
 ''= processFiles - copy nNumFiles/oFiles.Count files from sSrcDir to sDstDir;
 ''=                don't touch existing files
 ' ============================================================================
 
 Function processFiles( sSrcDir, sDstDir, nNumFiles )
   Dim nRVal : nRVal = 0
   WScript.Echo "processFiles(", sSrcDir, sDstDir, nNumFiles, ") called."
 
   Dim oFiles : Set oFiles = goFS.GetFolder( sSrcDir ).Files
   WScript.Echo oFiles.Count, "files in", sSrcDir
 
   Dim nIdx : nIdx = 0
   Dim oFile
   For Each oFile In oFiles
       If nIdx >= nNumFiles Then
          WScript.Echo nIdx, "files processed - done."
          Exit For
       End If
       nIdx = nIdx + 1
 
       WScript.Echo "processing", oFile.Name
       Dim sNewFSpec : sNewFSpec = oFile.Name   ' new FSpec will be build from oFile.Name
                       sNewFSpec = Left( sNewFSpec, Len( sNewFSpec ) - 4 ) ' strip extension
       Dim aParts    : aParts    = Split( sNewFSpec, "_" )
                       sNewFSpec = sDstDir + "\" + aParts( 1 ) + "_" + aParts( 2 ) + ".txt"
                       sNewFSpec = goFS.GetAbsolutePathName( sNewFSpec )
       WScript.Echo "new File", sNewFSpec
       If goFS.FileExists( sNewFSpec ) Then
          WScript.Echo "found   ", sNewFSpec
       Else
          goFS.CopyFile  oFile.Path, sNewFSpec
          WScript.Echo "copied  ", sNewFSpec
       End If
 
   Next ' file in sSrcDir
 
   processFiles = nRVal
 End Function
 
 ' ============================================================================
 ''= multiplyFiles - copy each file nNumFiles times from sSrcDir to sDstDir;
 ''=                 use ebgreen's NumberCopy() to handle name and copy
 ' ============================================================================
 
 Function multiplyFiles( sSrcDir, sDstDir, nNumFiles )
   Dim nRVal : nRVal = 0
   WScript.Echo "processFiles(", sSrcDir, sDstDir, nNumFiles, ") called."
 
   zapDir sDstDir + "\*.*"
 
   Dim oFiles : Set oFiles = goFS.GetFolder( sSrcDir ).Files
   WScript.Echo oFiles.Count, "files in", sSrcDir
   Dim oFile, nIdx
   For Each oFile In oFiles
       For nIdx = 1 To nNumFiles
           NumberCopy oFile, sDstDir
       Next ' copy of current file
   Next ' file in sSrcDir
 
   multiplyFiles = nRVal
 End Function
 
 ' ############################################################################
 ''# utility funcs
 ' ############################################################################
 
 ' ============================================================================
 ''= generates 'random' integer between nFrom and (nTo - 1)
 ' ============================================================================
 
 Function IRandR( ByVal nFrom, ByVal nTo )
   IRandR = nFrom + Int( Rnd * (nTo - nFrom) )
 End Function
 
 ' ============================================================================
 ''= formats dtDate YYYYMMDD
 ' ============================================================================
 
 Function fmtYMD( dtDate )
   fmtYMD =   CStr( Year(  dtDate )         ) _
            + PadL( Month( dtDate ), 2, "0" ) _
            + PadL( Day(   dtDate ), 2, "0" )
 End Function
 
 ' ============================================================================
 ''= use the source!
 ' ============================================================================
 
 Function PadL( vVal, nWidth, sChr )
   PadL = Right( String( nWidth, sChr ) + CStr( vVal ), nWidth )
 End Function
 
 ' ============================================================================
 ''= zap dir by force
 ' ============================================================================
 
 Sub zapDir( sFSpecPat )
 On Error Resume Next
   goFS.DeleteFile sFSpecPat
   If 0 = Err Then
      WScript.Echo sFSpecPat, "zapped."
   Else
      WScript.Echo sFSpecPat, "was empty."
   End If
 On Error GoTo 0
 End Sub
 
 ' ============================================================================
 ''= idea, first implementation, good parts: (c) ebgreen
 ''= all errors caused by changing the code: (c) ehvbs
 ''=   (1) using global FSO (one of my exceptions to the "No Globals!" rule
 ''=   (2) add _ before nAppend
 ' ============================================================================
 
 Sub NumberCopy( oFile, strDestDir )
   Dim strRootName
   Dim strExt
   Dim nAppend
   Dim strNewName
 
   strNewName  = strDestDir & "\" & oFile.Name
   nAppend     = 0
   strRootName = Split( oFile.Name, "." )( 0 )
   strExt      = Split( oFile.Name, "." )( 1 )
 
   Do While goFS.FileExists( strNewName )
      nAppend = nAppend + 1
      strNewName = strDestDir & "\" & strRootName & "_" & nAppend & "." & strExt
   Loop
   oFile.Copy strNewName
 End Sub

Typical use:

cscript swerver-03.vbs gen 15
 createTestData( .\test 15 ) called.
 .\test\*.mdf zapped.
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061224_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061222_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061223_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061220_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061220_001.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061225_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061217_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061225_001.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061225_002.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061224_001.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061217_001.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061221_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061226_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061225_003.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061221_001.mdf created
 
 cscript swerver-03.vbs proc 2
 processFiles( .\test .\test\processed 2 ) called.
 15 files in .\test
 processing ISA_20061217_000.mdf
 new File C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_000.txt
 copied   C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_000.txt
 processing ISA_20061217_001.mdf
 new File C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_001.txt
 copied   C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_001.txt
 2 files processed - done.
 
 cscript swerver-03.vbs proc 4
 processFiles( .\test .\test\processed 4 ) called.
 15 files in .\test
 processing ISA_20061217_000.mdf
 new File C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_000.txt
 found    C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_000.txt
 processing ISA_20061217_001.mdf
 new File C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_001.txt
 found    C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061217_001.txt
 processing ISA_20061220_000.mdf
 new File C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061220_000.txt
 copied   C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061220_000.txt
 processing ISA_20061220_001.mdf
 new File C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061220_001.txt
 copied   C:\wis\_vbs\0506\dev\forum\misc\test\processed\20061220_001.txt
 4 files processed - done.
 
 dir .\test\processed
  Datentr�ger in Laufwerk C: hat keine Bezeichnung.
  Datentr�gernummer: F4C8-437E
 
  Verzeichnis von C:\wis\_vbs\0506\dev\forum\misc\test\processed
 
 22.12.2006  10:05       <DIR>          .
 22.12.2006  10:05       <DIR>          ..
 22.12.2006  10:03                   59 20061217_000.txt
 22.12.2006  10:03                   59 20061217_001.txt
 22.12.2006  10:03                   59 20061220_000.txt
 22.12.2006  10:03                   59 20061220_001.txt
                4 Datei(en)            236 Bytes
                2 Verzeichnis(se),   3.119.779.840 Bytes frei
 
 C:\wis\_vbs\0506\dev\forum\misc
 cscript swerver-03.vbs gen 3
 createTestData( .\test 3 ) called.
 .\test\*.mdf zapped.
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061223_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061222_000.mdf created
 C:\wis\_vbs\0506\dev\forum\misc\test\ISA_20061222_001.mdf created
 
 cscript swerver-03.vbs mult 3
 processFiles( .\test .\test\processed 3 ) called.
 .\test\processed\*.* zapped.
 3 files in .\test
 
 dir .\test\processed
  Datentr�ger in Laufwerk C: hat keine Bezeichnung.
  Datentr�gernummer: F4C8-437E
 
  Verzeichnis von C:\wis\_vbs\0506\dev\forum\misc\test\processed
 
 22.12.2006  10:07       <DIR>          .
 22.12.2006  10:07       <DIR>          ..
 22.12.2006  10:06                   59 ISA_20061222_000.mdf
 22.12.2006  10:06                   59 ISA_20061222_000_1.mdf
 22.12.2006  10:06                   59 ISA_20061222_000_2.mdf
 22.12.2006  10:06                   59 ISA_20061222_001.mdf
 22.12.2006  10:06                   59 ISA_20061222_001_1.mdf
 22.12.2006  10:06                   59 ISA_20061222_001_2.mdf
 22.12.2006  10:06                   59 ISA_20061223_000.mdf
 22.12.2006  10:06                   59 ISA_20061223_000_1.mdf
 22.12.2006  10:06                   59 ISA_20061223_000_2.mdf
                9 Datei(en)            531 Bytes
                2 Verzeichnis(se),   3.119.779.840 Bytes frei

Good luck!

ehvbs

(in reply to swerver)

Post #: 26

RE: Complicated: read a filename if its yesterdays date... - 12/21/2006 10:32:46 PM

swerver

Posts: 27
Score: 0
Joined: 12/18/2006
Status: offline

WOW...

I mean... WOW...

(now I am confused!)

(in reply to ehvbs)

Post #: 27

RE: Complicated: read a filename if its yesterdays date... - 12/22/2006 1:35:32 AM

ehvbs

Posts: 2222
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi swerver,

the script lets you do three things:

(1) generate a bunch of test files in .\test. The files are named according
     to the scheme you described in your first postings.
(2) process <nNumFiles> of these. "Process" here means only: copy using
      a new name derived from the old one to .\test\processed (I can't use
      msdetotext.vbs)
      As we know from the name whether a file is processed already, we can
      use the fact that a 'processed' file exists to control whether or not a
      copy is necessary
(3) to multiply the files from .\test. This demonstrates how to use ebgreen's
     Sub NumberCopy() to generate a sequence of numbered copies of a
     file. (Another application of the algorithm is used inline in the generate
     code)

Is there anything specific you want me to explain?

ehvbs

(in reply to swerver)