Scripts Currently Running

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Scripts Currently Running

Logged in as: Guest

arrSession:exec spGetSession 2,16,41962

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Scripts Currently Running
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1] 2 next > >>

Message

<< Older Topic Newer Topic >>

Scripts Currently Running - 1/11/2007 5:50:34 PM 1 votes

dm_4ever

Posts: 2555
Score: 40
Joined: 6/29/2006
From: Orange County, California
Status: offline

Seems there are some admins that have scripts running in the background monitoring or gathering information they need or want. I've seen some posts where people want to know what scripts are running since you really can't tell by looking in task manager; all you see is wscript.exe or cscript.exe and maybe the PID. So I was at the end of running a fever and wanted to do something to take my mind off feeling ill and so I put this HTA together. I apologize if someone has already posted something like this. Also, forgive me if I didn't comment it well or didn't format it in the manner you are accustomed to (I have my preferred method of structuring my scripts that makes it easy for me to read).

Save the code below into a HTA file (i.e. "Get Running Scripts.hta") It uses WMI so you need to have Admin rights on the machine you run it on or query.
I've only tested the HTA on an XP & 2003 Server box. ConvertDT Function in the example below only work on XP or higher. Look at the end for a replacement function that should work on Win2k.

NOTE: The commandline property of the Win32_Process class was introduced with WinXP/Win2k3 so you can only see the name of the script running on those boxes. Also, the commandline property will return NULL if the HTA is launched using the RUNAS command (thanks to kirrilian for discovering this bug).

There are three version of this HTA. You can find two below and one submitted by NssB further down below.

Original Version:

<html>
<head>
<script language="vbscript">
Option Explicit

Dim intRefreshRt : intRefreshRt = 30000 '30 Second Refresh Rate in Milliseconds

Sub Window_OnLoad
'         On Error Resume Next
 
 Dim iTimerID
 
 window.document.title = "Scripts currently running on: " & GetLocCompName 'set title with local computername by calling function
 window.document.getElementById("PCName").InnerHTML = GetLocCompName 'set computername in header <h1> tag
 GetScripts
 window.document.getElementById("strComputerName").focus 'focus to the inputbox to specify another pc
 iTimerID = window.setInterval("GetScripts", intRefreshRt)
End Sub
 
Sub GetScripts
 'On Error Resume Next
 
 Dim wmiQuery, colItems, objItem, strCmdLine, strOutput, intPID, strComputer
 
 strComputer = UCase(window.document.getElementById("strComputerName").Value) 'get computername from input box
 If strComputer = "" Then
     strComputer = GetLocCompName 'if input box is empty, use local computer name by calling a function
 End If
 
 If Ping(strComputer) = False Then 'test connectivity with ping function
     alert "Computer specified is unreachable!!"
     window.document.getElementById("strComputerName").Value = "" 'reset input box if the machine is unreachable
     Exit Sub
 End If
 
 window.document.title = "Scripts currently running on: " & strComputer 'set title to new computer name if different from local
 window.document.getElementById("PCName").innerHTML = strComputer 'set computer name in header if different from local
 window.document.getElementById("TimeStamp").innerHTML = Now()
 
 wmiQuery = "Select * From Win32_Process Where (Name='wscript.exe' Or Name='cscript.exe')"  'define WMI query
 ' begin building table
 strOutput = "<table border=""0"" width=""100%"" id=""table1""><tr>" & _
     "<td><b>Script Name:</b></td><td><b>Process ID:</b></td>" & _
     "<td><b>Running Since:</b></td><td><b>Action</b></td></tr>"
 
 Set colItems = objWMI(strComputer, wmiQuery) 'retrieve WMI collection by calling the objWMI function
 
 For Each objItem In colItems 'loop through the collection
     strCmdLine = Replace(Replace(objItem.CommandLine, Chr(34), ""), "cscript.exe ", "")
     strCmdLine = Trim(strCmdLine) 'format string to pull out the script name being run
     intPID = objItem.ProcessID
     strOutput = strOutput & "<tr><td title='" & objItem.CommandLine & "'>" & Right(strCmdLine, Len(strCmdLine) - InStrRev(strCmdLine, "\")) & _
     "</td><td>" & intPID & "</td><td>" & ConvertDT(objItem.CreationDate) & "</td>" & _
     "<td><input type=""button"" value=""Terminate"" onclick=""KillScript('" & intPID & "')""></td></tr>"
 Next
 window.document.getElementById("RScripts").innerHTML = strOutput & "</table>" 'display data
 Set colItems = Nothing
End Sub
 
Sub KillScript(intPID)
 'On Error Resume Next
 
 Dim wmiQuery, colItems, objItem, strResponse, strComputer
 
 strResponse = MsgBox("Are you sure you want to terminate the script with Process ID of: " & intPID & "?", 36, "Confirm Script Termination")
 If strResponse = vbNo Then Exit Sub
 
 strComputer = UCase(window.document.getElementById("strComputerName").Value)
 If strComputer = "" Then
     strComputer = GetLocCompName
 End If
 
 wmiQuery = "Select * From Win32_Process Where ProcessID = " & intPID 'define WMI query
 
 Set colItems = objWMI(strComputer, wmiQuery)'retrieve WMI collection by calling the objWMI function
 
 For Each objItem In colItems
     objItem.Terminate 'terminate process with PID specified
 Next
 Set colItems = Nothing
 GetScripts 'refresh the process list displayed
End Sub
 
Function GetLocCompName
'         On Error Resume Next
 
 Dim objNetwork
 
 Set objNetwork = CreateObject("WScript.Network")
 GetLocCompName = UCase(objNetwork.ComputerName) 'get local computer name
 Set objNetwork = Nothing
End Function
 
Function Ping(strRmtPC)
'         On Error Resume Next
 
 Dim wmiQuery, objPing, objStatus, blnStatus
 
 wmiQuery = "Select * From Win32_PingStatus Where Address = '" & strRmtPC & "'"
 
 Set objPing = objWMI(".", wmiQuery)
 
 For Each objStatus in objPing
     If IsNull(objStatus.StatusCode) Or objStatus.Statuscode<>0 Then
         blnStatus = False 'Not Reachable
     Else
         blnStatus = True 'Reachable
     End If
 Next
 
 Ping = blnStatus
 Set objPing = Nothing
End Function
 
Function objWMI(strComputer, strWQL)
'         On Error Resume Next
 
 Dim wmiNS, objWMIService
 
 wmiNS = "\root\cimv2"
 
 Set objWMIService = GetObject("winmgmts:\\" & strComputer & wmiNS) 'connect to WMI
 Set objWMI = objWMIService.ExecQuery(strWQL) 'execute query
 Set objWMIService = Nothing
End Function
 
Function ConvertDT(strDT)
'         On Error Resume Next
 
 Dim objTime
 
 Set objTime = CreateObject("WbemScripting.SWbemDateTime")
 objTime.Value = strDT
 ConvertDT = objTime.GetVarDate 'convert UTC to Standard Time
 Set objTime = Nothing
End Function
</script>
<hta:application
applicationname="Get Running Scripts"    
border="dialog"
borderstyle="normal"
caption="Get Running Scripts"
contextmenu="yes"
icon="images\icon.ico"
maximizebutton="yes"
minimizebutton="yes"
navigable="yes"
scroll="no"
selection="yes"
showintaskbar="yes"
singleinstance="yes"
sysmenu="yes"
version="1.0"
windowstate="normal"
>
<style type="text/css">
td {
font-family: "Times New Roman", Times, serif;
font-size: 18px;
font-style: normal;
font-weight: normal;
font-variant: normal;
color: #FFFFFF;
vertical-align: top;
}
</style>
</head>
<body bgcolor="#272936" style="overflow:auto;color:#FFFFFF;">
<div align="center">
<h1>VBScripts Currently Running on: <span id="PCName"></span></h1>
Connect To: <input type="text" id="strComputerName" onKeyPress="if window.event.keycode = 13 then GetScripts">&nbsp;&nbsp;<input type="button" value="Connect" onclick="GetScripts">
<br /><br />
Last Updated: <span id="TimeStamp"></span>
</div>
<br />
<span id="RScripts"></span>
</body>
</html>

Version that accepts alternate credentials (thanks to NssB's contribution):
NOTE: You can NOT provide alternate credentials for the local machine. Queries will be executed using your credentials (impersonate) if no username/password is provided.
Updated 2/4/2007

<html>
<head>
<script language="vbscript">
Option Explicit 
Dim intRefreshRt : intRefreshRt = 30000 '30 Second Refresh Rate in Milliseconds
Sub Window_OnLoad
'  On Error Resume Next
 
Dim iTimerID

window.document.title = "Scripts currently running on: " & GetLocCompName 'set title with local computername by calling function
window.document.getElementById("PCName").InnerHTML = GetLocCompName 'set computername in header <h1> tag
GetScripts
window.document.getElementById("strComputerName").focus 'focus to the inputbox to specify another pc
iTimerID = window.setInterval("GetScripts", intRefreshRt)
End Sub
 
Sub GetScripts
'  On Error Resume Next
 
Dim wmiQuery, colItems, objItem, strCmdLine, strOutput, intPID, strComputer

strComputer = UCase(window.document.getElementById("strComputerName").Value) 'get computername from input box
If strComputer = "" Or strComputer = GetLocCompName Or strComputer = "LOCALHOST" Or strComputer = "127.0.0.1" Or strComputer = "." Then
strComputer = GetLocCompName 'if input box is empty, use local computer name by calling a Function
window.document.getElementById("strComputerName").Value = strComputer
window.document.getElementById("PCName").innerHTML = strComputer & " (Local)"
Else
window.document.getElementById("PCName").innerHTML = strComputer 'set computer name in header if different from local
End If

If Ping(strComputer) = False Then 'test connectivity with ping Function
alert "Computer specified is unreachable!!"
window.document.getElementById("strComputerName").Value = "" 'reset input box if the machine is unreachable
Exit Sub
End If 
 
window.document.title = "Scripts currently running on: " & strComputer 'set title to new computer name if different from local
window.document.getElementById("TimeStamp").innerHTML = Now()
wmiQuery = "Select * From Win32_Process Where (Name='wscript.exe' Or Name='cscript.exe' Or Name='mshta.exe')"  'define WMI query
' begin building table
strOutput = "<table border=""0"" width=""100%"" id=""table1""><tr>" & _
"<td><b>Script Name:</b></td><td><b>Process ID:</b></td>" & _
"<td><b>Running Since:</b></td><td><b>Action</b></td></tr>"

On Error Resume Next
Set colItems = objWMI(strComputer, wmiQuery) 'retrieve WMI collection by calling the objWMI function
If IsEmpty(colItems) Then
window.document.getElementById("RScripts").innerHTML = ""
Exit Sub
End If
On Error GoTo 0

For Each objItem In colItems 'loop through the collection
strCmdLine = Replace(Replace(objItem.CommandLine, Chr(34), ""), "cscript.exe ", "")
strCmdLine = Trim(strCmdLine) 'format string to pull out the script name being run
intPID = objItem.ProcessID
strOutput = strOutput & "<tr><td title='" & objItem.CommandLine & "'>" & Right(strCmdLine, Len(strCmdLine) - InStrRev(strCmdLine, "\")) & _
"</td><td>" & intPID & "</td><td>" & ConvertDT(objItem.CreationDate) & "</td>" & _
"<td><input type=""button"" value=""Terminate"" onclick=""KillScript('" & intPID & "')""></td></tr>"
Next
window.document.getElementById("RScripts").innerHTML = strOutput & "</table>" 'display data
Set colItems = Nothing
End Sub
 
Sub KillScript(intPID)
'  On Error Resume Next

Dim wmiQuery, colItems, objItem, strResponse, strComputer

strResponse = MsgBox("Are you sure you want to terminate the script with Process ID of: " & intPID & "?", 36, "Confirm Script Termination")
If strResponse = vbNo Then Exit Sub

strComputer = UCase(window.document.getElementById("strComputerName").Value)
If strComputer = "" Or strComputer = GetLocCompName Or strComputer = "LOCALHOST" Or strComputer = "127.0.0.1" Or strComputer = "." Then
strComputer = GetLocCompName 'if input box is empty, use local computer name by calling a function
End If

wmiQuery = "Select * From Win32_Process Where ProcessID = " & intPID 'define WMI query

Set colItems = objWMI(strComputer, wmiQuery)'retrieve WMI collection by calling the objWMI function

For Each objItem In colItems
objItem.Terminate 'terminate process with PID specified
Next
Set colItems = Nothing
GetScripts 'refresh the process list displayed
End Sub
 
Function GetLocCompName
'  On Error Resume Next
 
Dim objNetwork

Set objNetwork = CreateObject("WScript.Network")
GetLocCompName = UCase(objNetwork.ComputerName) 'get local computer name
Set objNetwork = Nothing
End Function
 
Function Ping(strRmtPC)
'  On Error Resume Next
 
 Dim wmiQuery, objPing, objStatus, blnStatus
 
 wmiQuery = "Select * From Win32_PingStatus Where Address = '" & strRmtPC & "'"
 Set objPing = objWMI(".", wmiQuery)
 
 For Each objStatus in objPing
     If IsNull(objStatus.StatusCode) Or objStatus.Statuscode<>0 Then
         blnStatus = False 'Not Reachable
     Else
         blnStatus = True 'Reachable
     End If
 Next
 Ping = blnStatus
 Set objPing = Nothing
End Function
 
Function objWMI(strComputer, strWQL)
'  On Error Resume Next
Dim wmiNS, objWMIService, objSWbemLocator, objSWbemServices
Dim strUID, strPwd

wmiNS = "\root\cimv2"
strUID = window.document.getElementById("strUserID").value
strPwd = window.document.getElementById("strPass").value

If strComputer = "." Or strComputer = GetLocCompName Then
strUID = ""
strPwd = ""
End If

Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
On Error Resume Next
Set objSWbemServices = objSWbemLocator.ConnectServer _
(strComputer, wmiNS, strUID, strPwd)
Select Case Err.Number
 Case -2147024891
  window.document.getElementById("accessdenied").innerHTML = "Access Denied! Please check the credentials supplied."
  Exit Function
End Select
On Error GoTo 0
window.document.getElementById("accessdenied").innerHTML = ""
Set objWMI = objSWbemServices.ExecQuery(strWQL)
Set objSWbemServices = Nothing 
Set objSWbemLocator = Nothing
End Function
 
Function ConvertDT(strDT)
'  On Error Resume Next

Dim objTime: Set objTime = CreateObject("WbemScripting.SWbemDateTime")
objTime.Value = strDT
ConvertDT = objTime.GetVarDate 'convert UTC to Standard Time
Set objTime = Nothing
End Function
</script>
<hta:application
applicationname="Get Running Scripts"    
border="dialog"
borderstyle="normal"
caption="Get Running Scripts"
contextmenu="yes"
icon="images\icon.ico"
maximizebutton="yes"
minimizebutton="yes"
navigable="yes"
scroll="no"
selection="yes"
showintaskbar="yes"
singleinstance="yes"
sysmenu="yes"
version="1.0"
windowstate="normal"
>
<style type="text/css">
td {
font-family: "Times New Roman", Times, serif;
font-size: 18px;
font-style: normal;
font-weight: normal;
font-variant: normal;
color: #FFFFFF;
vertical-align: top;
}
.access {
color:#ffffff;
font-size:20px;
font-family:"Times New Roman", Times, serif;
}
</style>
</head>
<body bgcolor="#272936" style="overflow:auto;color:#FFFFFF;">
<div align="left">
<h1>VBScripts Currently Running on: <span id="PCName"></span></h1>
Connect To: <input type="text" id="strComputerName" onKeyPress="if window.event.keycode = 13 then GetScripts">&nbsp;&nbsp;
UserName: <input type="text" id="strUserID" value="">&nbsp;&nbsp; Password: <input type="password" id="strPass" value="">&nbsp;&nbsp; <input type="submit" value="Connect" onclick="GetScripts">
<br /><br />
Last Updated: <span id="TimeStamp"></span>
</div>
<div align="center" class="access"><span id="accessdenied"></span></div>
<br />
<span id="RScripts"></span>
</body>
</html>

UPDATED: 1/12/2007
Date/Time Conversition Function for Win2k, just replace the ConverDT function in the example above with this one:

< Message edited by dm_4ever -- 2/8/2007 9:04:29 AM >

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

Revisions: 16 | Post #: 1

RE: Scripts Currently Running - 1/11/2007 8:17:11 PM

TNO

Posts: 1074
Score: 10
Joined: 12/18/2004
From: thenewobjective.com
Status: offline

Holy Running Scripts BatMan

_____________________________

To iterate is human, to recurse divine. -- L. Peter Deutsch

(in reply to dm_4ever)

Post #: 2

RE: Scripts Currently Running - 1/12/2007 3:28:30 AM

Country73

Posts: 716
Score: 8
Joined: 8/25/2004
From: USA
Status: offline

Pretty slick; I believe I will be able to put this to some good use!

(in reply to dm_4ever)

Post #: 3

RE: Scripts Currently Running - 1/15/2007 8:51:58 AM

mrmore

Posts: 5
Score: 0
Joined: 11/9/2006
Status: offline

Nice one. Thank you

(in reply to Country73)

Post #: 4

RE: Scripts Currently Running - 1/16/2007 12:28:57 AM

DiGiTAL.SkReAM

Posts: 1170
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

Very nice. Unfortunately, we have about 600+ NT 4.0 servers that we have to support, so I can't use this right now. *sounds of cursing*

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to mrmore)

Post #: 5

RE: Scripts Currently Running - 1/19/2007 3:52:38 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

quote:

ORIGINAL: DiGiTAL.SkReAM

Very nice. Unfortunately, we have about 600+ NT 4.0 servers that we have to support, so I can't use this right now. *sounds of cursing*

no wonder youre a little "off" somtimes LOL

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to DiGiTAL.SkReAM)

Post #: 6

RE: Scripts Currently Running - 1/19/2007 8:02:46 AM

DiGiTAL.SkReAM

Posts: 1170
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

Yeah, well..... I have a bigger smiley avatar than you do! So there!

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to kirrilian)

Post #: 7

RE: Scripts Currently Running - 1/19/2007 1:02:41 PM

dm_4ever

Posts: 2555
Score: 40
Joined: 6/29/2006
From: Orange County, California
Status: offline

Just wanted to say thank you for the compliments and laughs. You guys are great

quote:

ORIGINAL: kirrilian
no wonder youre a little "off" somtimes LOL

and

quote:

ORIGINAL: DiGiTAL.SkReAM
Yeah, well..... I have a bigger smiley avatar than you do! So there!

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to DiGiTAL.SkReAM)

Post #: 8

RE: Scripts Currently Running - 1/19/2007 5:06:40 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

DOH!!

<--- pwned!!

Just for that, here is a dancing pink elephant and an angry off topic "smiley"

(i know its a cop out...)

< Message edited by kirrilian -- 1/19/2007 5:11:35 PM >

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to dm_4ever)

Revisions: 1 | Post #: 9

RE: Scripts Currently Running - 1/19/2007 5:11:14 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

btw, dm_4ever, back on topic, when i ran your hta as another user (i do my everyday work as a normal unprivileged user, so i had to run it under my admin acct) i got an error when i tried to run against the local machine. i dont think it was returning the name of the script that was running when i put in a 'on error resume next' statement. i didnt dig in too deeply as to why, i will do that on monday when i get back to work

excellent hta otherwise

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to kirrilian)

Post #: 10

RE: Scripts Currently Running - 1/21/2007 4:04:24 AM

dm_4ever

Posts: 2555
Score: 40
Joined: 6/29/2006
From: Orange County, California
Status: offline

Definitely let me know what error you're getting so I can take a look. I tried it in a Virtual Machine (WinXP) with an unprivileged user and it seemed to work.

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to kirrilian)

Post #: 11

RE: Scripts Currently Running - 1/22/2007 1:59:27 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

i think you misunderstood the user part of it, both of my users are local admins on my workstation, but in order to have admin access on the servers i have to use runas. so i was running your script as my superuser and when it tried to pull the data from the local machine it failed on the script name

this is the process i followed:
use runas to start cmd as my superuser account
start the hta via the terminal
as soon as it opens i get this error:
Line: 48
Error: Invalid use of Null: 'Replace'
I uncommented your on error resume next and it works, but it doesnt print out the script name.

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to dm_4ever)

Post #: 12

RE: Scripts Currently Running - 1/22/2007 4:42:35 AM

DiGiTAL.SkReAM

Posts: 1170
Score: 7
Joined: 9/6/2005
From: Florida, USA
Status: offline

As an aside, to view which scripts were running on our NT4.0 boxen, I modified the batch file that calls the script (we use AT to schedule our jobs, and have AT run a cmd file that then runs the script, rather than having it call the .vbs directly.)
ScriptRunner.cmd

And then once a night, we have another cmd file that ckicks off that does nothing but delete the extra copies of wscript.exe that we have laying around.
It is kind of a kludge, but... this way we can just pull a list of processes and see what ws_<scriptname>.exe's are running.

_____________________________

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

"It is better to die like a tiger, than to live like a pussy."
-Master Wong, from Balls of Fury

(in reply to kirrilian)

Post #: 13

RE: Scripts Currently Running - 1/22/2007 1:48:57 PM

dm_4ever

Posts: 2555
Score: 40
Joined: 6/29/2006
From: Orange County, California
Status: offline

Thank you for that information kirrilian. I followed your steps and was able to duplicate the error. It appears that when querying the Win32_Process class after using the runas cmd, the commandline property appears as null. I'm not too sure how to fix this or get around it at this time, but I'll take a look...perhaps find an alternate method to get the info.

< Message edited by dm_4ever -- 1/22/2007 1:51:58 PM >

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to kirrilian)

Revisions: 1 | Post #: 14

RE: Scripts Currently Running - 1/27/2007 5:26:16 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

quote:

ORIGINAL: dm_4ever

Thank you for that information kirrilian. I followed your steps and was able to duplicate the error. It appears that when querying the Win32_Process class after using the runas cmd, the commandline property appears as null. I'm not too sure how to fix this or get around it at this time, but I'll take a look...perhaps find an alternate method to get the info.

ive thought about it since, it may be related to the fact that runas dumps most of your environment somewhat like cron does in linux, it runs in its own space. i havent tried the runas switches that allow runas to replicate the current environment, but that may be an option.

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to dm_4ever)

Post #: 15

RE: Scripts Currently Running - 1/30/2007 3:30:43 AM

NssB

Posts: 30
Score: 0
Joined: 6/25/2006
Status: offline

Hi,

Made a few ammendments to this code. See objWMI function and GetScripts sub. Also a little HTML modded.
Using the SWbem locator/services to connect to a WMI namespace with credentials provided where a remote host is specified.
Normal mgmt: used where host is local. CommandLine method still proving elusive, but perhaps a little easier to manage alternate credentials :)
Oh, and since I like HTA's, I added the MSHTA host controller. My bad

Please do comment.

<html>
<head>
<script language="vbscript">
Option Explicit

Dim intRefreshRt : intRefreshRt = 30000 '30 Second Refresh Rate in Milliseconds

strComputer = UCase(window.document.getElementById("strComputerName").Value) 'get computername from input box

If strComputer = "" Then
       strComputer = "LOCALHOST" 'if input box is empty, use local computer name by calling a function
   End If
   If strComputer = "LOCALHOST" or strComputer = "127.0.0.1" then
       intStat = 1
   End If
   If intStat = 0 then
   If strUserID.value = "" OR strPass.Value = "" then
       MsgBox "You must enter a username AND password for remote hosts"
           Exit Sub
       End If
   End If
   If Ping(strComputer) = False Then 'test connectivity with ping function
       alert "Computer specified is unreachable!!"
       window.document.getElementById("strComputerName").Value = "" 'reset input box if the machine is unreachable
       Exit Sub
   End If
   
   window.document.title = "Scripts currently running on: " & strComputer 'set title to new computer name if different from local
   window.document.getElementById("PCName").innerHTML = strComputer 'set computer name in header if different from local
   window.document.getElementById("TimeStamp").innerHTML = Now()

wmiQuery = "Select * From Win32_Process Where (Name='wscript.exe' Or Name='cscript.exe' Or Name='mshta.exe')"  'define WMI query
   ' begin building table
   strOutput = "<table border=""0"" width=""100%"" id=""table1""><tr>" & _
       "<td><b>Script Name:</b></td><td><b>Process ID:</b></td>" & _
       "<td><b>Running Since:</b></td><td><b>Action</b></td></tr>"
   
   Set colItems = objWMI(strComputer, wmiQuery, intStat) 'retrieve WMI collection by calling the objWMI function
   
   For Each objItem In colItems 'loop through the collection
       strCmdLine = Replace(Replace(objItem.CommandLine, Chr(34), ""), "cscript.exe ", "")
       strCmdLine = Trim(strCmdLine) 'format string to pull out the script name being run
       intPID = objItem.ProcessID
       strOutput = strOutput & "<tr><td title='" & objItem.CommandLine & "'>" & Right(strCmdLine, Len(strCmdLine) - InStrRev(strCmdLine, "\")) & _
       "</td><td>" & intPID & "</td><td>" & ConvertDT(objItem.CreationDate) & "</td>" & _
       "<td><input type=""button"" value=""Terminate"" onclick=""KillScript('" & intPID & "')""></td></tr>"
   Next
   window.document.getElementById("RScripts").innerHTML = strOutput & "</table>" 'display data
   Set colItems = Nothing
End Sub
   
Sub KillScript(intPID)
   On Error Resume Next
   
   Dim wmiQuery, colItems, objItem, strResponse, strComputer
   
   strResponse = MsgBox("Are you sure you want to terminate the script with Process ID of: " & intPID & "?", 36, "Confirm Script Termination")
   If strResponse = vbNo Then Exit Sub
   
   strComputer = UCase(window.document.getElementById("strComputerName").Value)
   If strComputer = "" Then
       strComputer = GetLocCompName
   End If
   
   wmiQuery = "Select * From Win32_Process Where ProcessID = " & intPID 'define WMI query
   
   Set colItems = objWMI(strComputer, wmiQuery)'retrieve WMI collection by calling the objWMI function
   
   
   For Each objItem In colItems
       objItem.Terminate 'terminate process with PID specified
   Next
   Set colItems = Nothing
   GetScripts 'refresh the process list displayed
End Sub
   
Function GetLocCompName
'         On Error Resume Next
   
   Dim objNetwork
   
   Set objNetwork = CreateObject("WScript.Network")
   GetLocCompName = UCase(objNetwork.ComputerName) 'get local computer name
   Set objNetwork = Nothing
End Function
   
Function Ping(strRmtPC)
'         On Error Resume Next
   
   Dim wmiQuery, objPing, objStatus, blnStatus, intStat
   
   wmiQuery = "Select * From Win32_PingStatus Where Address = '" & strRmtPC & "'"
   intStat = 1
   Set objPing = objWMI(".", wmiQuery, intStat)
   
   For Each objStatus in objPing
       If IsNull(objStatus.StatusCode) Or objStatus.Statuscode<>0 Then
           blnStatus = False 'Not Reachable
       Else
           blnStatus = True 'Reachable
       End If
   Next
   
   Ping = blnStatus
   Set objPing = Nothing
End Function
   
Function objWMI(strComputer, strWQL, intStat)
   'On Error Resume Next
   Dim wmiNS, objWMIService, objSWbemLocator, objSWbemServices
   wmiNS = "\root\cimv2"
   if intStat = 0 then
       Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
       Set objSWbemServices = objSWbemLocator.ConnectServer _
         (strComputer, wmiNS, strUserID.value, strPass.value)
       Set objWMI = objSWbemServices.ExecQuery(strWQL)
       Set objSWbemServices = nothing 
   Else
       Set objWMIService = GetObject("winmgmts:\\" & strComputer & wmiNS) 'connect to WMI
       Set objWMI = objWMIService.ExecQuery(strWQL) 'execute query
       Set objWMIService = Nothing
   End If
End Function
   
Function ConvertDT(strDT)
'         On Error Resume Next
   
   Dim objTime
   
   Set objTime = CreateObject("WbemScripting.SWbemDateTime")
   objTime.Value = strDT
   ConvertDT = objTime.GetVarDate 'convert UTC to Standard Time
   Set objTime = Nothing
End Function
</script>
<hta:application
applicationname="Get Running Scripts"    
border="dialog"
borderstyle="normal"
caption="Get Running Scripts"
contextmenu="yes"
icon="images\icon.ico"
maximizebutton="yes"
minimizebutton="yes"
navigable="yes"
scroll="no"
selection="yes"
showintaskbar="yes"
singleinstance="yes"
sysmenu="yes"
version="1.0"
windowstate="normal"
>
<style type="text/css">
td {
font-family: "Times New Roman", Times, serif;
font-size: 18px;
font-style: normal;
font-weight: normal;
font-variant: normal;
color: #FFFFFF;
vertical-align: top;
}
</style>
</head>
<body bgcolor="#272936" style="overflow:auto;color:#FFFFFF;">
<div align="left">
<h1>VBScripts Currently Running on: <span id="PCName"></span></h1>
Connect To: <input type="text" id="strComputerName" onKeyPress="if window.event.keycode = 13 then GetScripts">&nbsp;&nbsp;
UserName: <input type="text" name="strUserID" value="">&nbsp;&nbsp; Password: <input type="password" name="strPass" value="">&nbsp;&nbsp; <input type="submit" value="Connect" onclick="GetScripts">
<br /><br />
Last Updated: <span id="TimeStamp"></span>
</div>
<br />
<span id="RScripts"></span>
</body>
</html>

< Message edited by NssB -- 1/30/2007 3:40:28 AM >

_____________________________

Its all about the code!

(in reply to dm_4ever)

Revisions: 3 | Post #: 16

RE: Scripts Currently Running - 1/30/2007 5:11:55 AM

dm_4ever

Posts: 2555
Score: 40
Joined: 6/29/2006
From: Orange County, California
Status: offline

I was actually thinking of changing the method of connection to use SWbemLocator "connectserver" to allow for alternate credentials, so thanks!

I just noticed the KillScript Sub needs to be updated to reflect the changes.

< Message edited by dm_4ever -- 1/30/2007 5:42:10 AM >

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to NssB)

Revisions: 1 | Post #: 17

RE: Scripts Currently Running - 1/30/2007 6:06:22 AM

dm_4ever

Posts: 2555
Score: 40
Joined: 6/29/2006
From: Orange County, California
Status: offline

I made a few more changes.

- KillScript sub should work
- Added error handeling if credentials supplied are invalid