Workstation cleanup

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Workstation cleanup

Logged in as: Guest

arrSession:exec spGetSession 2,16,44033

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Workstation cleanup
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Workstation cleanup - 3/3/2007 5:36:17 PM

tokiwoki

Posts: 8
Score: 0
Joined: 3/3/2007
Status: offline

Hi everyone, My boss asked me to write a script that silently uninstalls some software apps on workstations on our domain, so I wrote the following

'Option Explicit
On Error Resume Next

'define our variables
Dim str_base_registry, str_path, flag_debug

'enable debug mode?
flag_debug = 0

'create a command shell for use below
Set CommandShell = createobject("wscript.shell")

'WinRAR (fs)
str_path = "%ProgramFiles%\WinRAR" 'get the application's path
'execute its uninstaller
cmdline = chr(34) & str_path & "\Uninstall.exe" & chr(34) &  " /s"
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

'SpyBotSnD (fs)
str_path = "%ProgramFiles%\Spybot - Search & Destroy"
cmdline = chr(34) & str_path & "\unins000.exe" & chr(34) & " /SILENT"
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

'Spy Sweeper (fs)
str_path = "%ProgramFiles%\Webroot\Spy Sweeper"
cmdline = chr(34) & str_path & "\unins000.exe" & chr(34) & " /SP- /VERYSILENT /NORESTART"
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

'Skype (fs)
str_path = "%ProgramFiles%\Skype\Phone"
cmdline = chr(34) & str_path & "\unins000.exe" & chr(34) & " /SILENT /NORESTART /SUPPRESSMSGBOXES"
'TODO: kill the process iu14D2N.tmp
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

'Partition Magic 8 (msiexec)
cmdline = "msiexec /X {6BE2A4A4-99FB-48ED-AE1E-4E850389F804} /qn"
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

'Ad-Aware (msiexec)
cmdline = "msiexec /X {78CC3BAB-DE2A-4FB4-8FBB-E4DADDC26747} /qn"
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

'Norton Ghost 2003 (9) (msiexec)
cmdline = "msiexec /X {3C759736-8347-4031-BB9C-D75ADFE6B1013} /qn /norestart"
If flag_debug = 1 Then WScript.Echo cmdline End If
CommandShell.Run cmdline, 1, True

Any comments or suggestions would be great since this is my first vbs script. I noticed that trying to silently uninstall WinRar on one machine didn't do anything, but removing the /s flag asked the user for confirmation and then proceeded as normal.

Post #: 1

RE: Workstation cleanup - 3/5/2007 1:24:35 AM

DiGiTAL.SkReAM

Posts: 1097
Score: 6
Joined: 9/6/2005
From: Florida, USA
Status: offline

Very nice for a first script.
My only suggestions would be:
1.) Use Option Explicit
    -It forces you to Dim your variables, and helps promote good coding practices
2.) Don't use On Error Resume Next unless you have to.
    -It hides any error messages that might be needed for debugging/troubleshooting
3.) Try condensing your code a little.
    -It makes it easier to read, and easier to maintain. For example, if you wanted to run all of your commands in the background, with no windows, with your original script, you would have to change the ,1,true to ,0,true about 7 times. With the below script, just change it in one place.

Option Explicit

'Only use On Error Resume Next when absolutely necessary
'On Error Resume Next

'define our variables
Dim flag_debug, CommandShell, cmdline, oCmdDic

'enable debug mode?
'This is apparently used to just echo back the commandline you are using for each software uninstall.
flag_debug = 0

'create a command shell for use below
Set CommandShell = createobject("wscript.shell")

'create a dictionary object to hold your data pairs
Set oCmdDic = CreateObject("Scripting.Dictionary")

'using a dictionary allows you to add additional software packages with little to no recoding required.
'oCmdDic.Add "Package name", "uninstall commandline"
oCmdDic.Add "WinRAR (fs)", chr(34) & "%ProgramFiles%\WinRAR\Uninstall.exe" & chr(34) &  " /s"
oCmdDic.Add "SpyBotSnD (fs)", chr(34) & "%ProgramFiles%\Spybot - Search & Destroy\unins000.exe" & chr(34) & " /SILENT"
oCmdDic.Add "Spy Sweeper (fs)", chr(34) & "%ProgramFiles%\Webroot\Spy Sweeper\unins000.exe" & chr(34) & " /SP- /VERYSILENT /NORESTART"
oCmdDic.Add "Skype (fs)", chr(34) & "%ProgramFiles%\Skype\Phone\unins000.exe" & chr(34) & " /SILENT /NORESTART /SUPPRESSMSGBOXES"
oCmdDic.Add "Partition Magic 8 (msiexec)", "msiexec /X {6BE2A4A4-99FB-48ED-AE1E-4E850389F804} /qn"
oCmdDic.Add "Ad-Aware (msiexec)", "msiexec /X {78CC3BAB-DE2A-4FB4-8FBB-E4DADDC26747} /qn"
oCmdDic.Add "Norton Ghost 2003 (9) (msiexec)", "msiexec /X {3C759736-8347-4031-BB9C-D75ADFE6B1013} /qn /norestart"

'Iterate through each of the packages listed, running the same commands for each package
For Each cmdline In oCmdDic.Items 
  If flag_debug = 1 Then WScript.Echo cmdline 
 CommandShell.Run cmdline, 1, True
Next

_____________________________

"There's the one man who learns by reading, the two men that learn by watching, and the rest of us have to pee on the electric fence for ourselves." - Roy Rogers

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

(in reply to tokiwoki)

Post #: 2

RE: Workstation cleanup - 3/5/2007 10:45:16 PM

tokiwoki

Posts: 8
Score: 0
Joined: 3/3/2007
Status: offline

Cool thanks, that was very helpful!

(in reply to DiGiTAL.SkReAM)

Post #: 3

RE: Workstation cleanup - 3/6/2007 3:49:55 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

quote:

ORIGINAL: DiGiTAL.SkReAM

2.) Don't use On Error Resume Next unless you have to.
-It hides any error messages that might be needed for debugging/troubleshooting

except when you want to do your own error handling...

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to DiGiTAL.SkReAM)

Post #: 4

RE: Workstation cleanup - 3/7/2007 12:50:08 AM

DiGiTAL.SkReAM

Posts: 1097
Score: 6
Joined: 9/6/2005
From: Florida, USA
Status: offline

quote:

ORIGINAL: kirrilian

quote:

ORIGINAL: DiGiTAL.SkReAM

2.) Don't use On Error Resume Next unless you have to.
-It hides any error messages that might be needed for debugging/troubleshooting

except when you want to do your own error handling...