Error Persistence Class

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Error Persistence Class

Logged in as: Guest

arrSession:exec spGetSession 2,16,44278

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Error Persistence Class
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Error Persistence Class - 3/9/2007 2:55:52 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

I had written a class similar to this in the past and now I can't find it so I just re-wrote it real quick because someone had requested it. Basically it allows you to keep a running persistent list of error that you won't lose by performing an Err.Clear. Here is the code and I think it is pretty self explanatory, but I can add comments if others don't agree.

Option Explicit
Dim oPE : Set oPE = New PersistentErrors
Dim oFSO : Set oFSO = CreateObject("Scripting.FileSystemObject")
Dim a
Dim oErr
Dim strKey
On Error Resume Next
a = 10/0
oPE.AddError Err, "Division by zero test"
Err.Clear
On Error Resume Next
oFSO.OpenTextFile("C:\foo\bar.txt")
oPE.AddError Err, "Missing file test"
Err.Clear
For Each oErr In oPE.GetErrors()
WScript.Echo "ERROR:"
For Each strKey In oErr.Keys()
 WScript.Echo vbTab & strKey & " = " & oErr(strKey)
Next
WScript.Echo ""
Next

Class PersistentErrors
Private arrErrors()
Private nErrorCount
Sub Class_Initialize()
 nErrorCount = 0
End Sub

Public Property Get ErrorCount
 ErrorCount = nErrorCount
End Property

Public Sub AddError(oError, strComment)
 Dim dicTemp
 Set dicTemp = CreateObject("Scripting.Dictionary")
 dicTemp.Add "Number", oError.Number
 dicTemp.Add "Description", oError.Description
 dicTemp.Add "HelpContext", oError.HelpContext
 dicTemp.Add "HelpFile", oError.HelpFile
 dicTemp.Add "Source", oError.Source
 dicTemp.Add "Comment", strComment
 dicTemp.Add "TimeStamp", Now()
 ReDim Preserve arrErrors(nErrorCount)
 Set arrErrors(nErrorCount) = dicTemp
 nErrorCount = UBound(arrErrors) + 1 
End Sub

Public Function GetErrors()
 GetErrors = arrErrors
End Function

End Class

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm