Start, Stop, & Restart Services (Incl. dependencies)

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Start, Stop, & Restart Services (Incl. dependencies)

Logged in as: Guest

arrSession:exec spGetSession 2,16,46455

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Start, Stop, & Restart Services (Incl. dependencies)
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Start, Stop, & Restart Services (Incl. dependencies) - 4/27/2007 5:42:37 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

Needed this for another script at work and couldnt find anything on the web that was complete and self-contained so I wrote this.
I forgot to mention that it checks for the service's state as well to ensure that it has indeed started/stopped

Usage:
service_control ".","IIS Admin","restart"
the arguments are commented in the sub

Sub service_control(strComputer,sname,purpose)
   'strComputer is the computer you want to connect to
   'sname is the service name
   'purpose is whether or not you want to start, stop or restart a service
   Dim delay, err_return
   delay = 20000    '20 seconds
   WScript.stdout.Write "*"
   Set objWMIService = GetObject("winmgmts:" _
       & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
   Set colListOfServices = objWMIService.ExecQuery _
           ("Select * from Win32_Service where DisplayName = '" & sname & "'")
   For Each objService In colListOfServices
       'Just to double check we have the right service
       If objService.displayname = sname Then
           WScript.stdout.Write "*"
           If purpose = "stop" Or purpose = "restart" Then
                   err_return = objService.stopservice
                   'service has dependencies, so we need to stop those first
                   If err_return = 3 Then
                       'GOTCHA - you have to use the service.name NOT service.displayname for this query!!
                       'even if you change Win32_Service.Name to Win32_Service.DisplayName
                       Set colServiceList2 = objWMIService.ExecQuery("Associators of " _
                          & "{Win32_Service.Name='" & objService.name & "'} Where " _
                               & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
                       For Each objService2 in colServiceList2
                           objService2.StopService()
                           If Not objService2.state = "Stopped" Then
                               'you have to pause because the service wont start unless it is completely stopped
                               WScript.Sleep delay
                               service_control strComputer,sname,"stop"
                           Else
                               'WScript.Echo objService2.displayname & " has been stopped."
                           End If
                       Next
                       'stop the original service that had dependencies
                       objService.stopservice
                   Else
                       If Not objService.state = "Stopped" Then
                           'you have to pause because the service wont start unless it is completely stopped
                           WScript.Sleep delay
                           service_control strComputer,sname,"stop"
                       Else
                           'WScript.Echo objService.displayname & " has been stopped."
                       End If
                   End If
                   'if restart was sent, start service after it has stopped
                   If purpose = "restart" Then service_control strComputer, sname, "start" End if
           Elseif purpose = "start" Then    
                   WScript.stdout.Write "*"
                   err_return = objService.startservice
                   If NOT err_return = 10 Then
                       'GOTCHA - you have to use the service.name NOT service.displayname for this query!!
                       'even if you change Win32_Service.Name to Win32_Service.DisplayName
                       Set colServiceList2 = objWMIService.ExecQuery("Associators of " _
                          & "{Win32_Service.Name='" & objService.name & "'} Where " _
                               & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
                       For Each objService2 in colServiceList2
                           objService2.StartService()
                           If Not objService2.state = "Running" Then
                               'you have to pause because the service wont start unless it is completely stopped
                               WScript.Sleep delay
                               service_control strComputer,sname,"start"
                           Else
                               WScript.Echo objService.displayname & " has been started."
                           End If
                       Next
                       err_return = objService.startservice
                       'service has dependencies, so we need to start those first
                       If err_return = 3 Then
                           'start the original service that had dependencies
                           objService.startservice
                           'End If
                           If Not objService.state = "Running" then
                               'you have to pause because the service wont start unless it is completely stopped
                               WScript.Sleep delay
                               service_control strComputer,sname,"start"
                           Else
                               'WScript.Echo objService.displayname & " has been started."
                           End If
                       End If
                   End If
                   'WScript.Echo objService.displayname & " has been started."
           End If
       End If
   Next
End Sub 'service_control

Code liberally borrowed from the scripting center

< Message edited by kirrilian -- 4/28/2007 4:07:18 PM >

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

Revisions: 1 | Post #: 1

RE: Start, Stop, & Restart Services (Incl. dependencies) - 5/5/2007 7:56:59 AM

dm_4ever

Posts: 2359
Score: 36
Joined: 6/29/2006
From: Orange County, California
Status: offline

I tried this out the other day and it worked great.

Just a thought...rather than waiting for an error to tell you there are dependent services, why not start off checking for dependent services and starting/stopping them accordingly?

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to kirrilian)

Post #: 2

RE: Start, Stop, & Restart Services (Incl. dependencies) - 5/7/2007 3:25:58 AM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

quote:

ORIGINAL: dm_4ever

I tried this out the other day and it worked great.

Just a thought...rather than waiting for an error to tell you there are dependent services, why not start off checking for dependent services and starting/stopping them accordingly?

so that if there arent any, it will go ahead and start the single service

btw, the return code was the fastest/easiest way to tell if there are dependent services

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to dm_4ever)

Post #: 3

RE: Start, Stop, & Restart Services (Incl. dependencies) - 1/15/2008 12:45:39 AM

kxrain

Posts: 1
Score: 0
Joined: 1/15/2008
Status: offline

Just a question you will save this as??

(in reply to kirrilian)

Post #: 4

RE: Start, Stop, & Restart Services (Incl. dependencies) - 1/15/2008 7:09:06 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

This is a subroutine that is intended to be included in a script that you are writing. It is not intended as a stand alone file.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to kxrain)

Post #: 5

RE: Start, Stop, & Restart Services (Incl. dependencies) - 1/18/2008 6:20:51 PM

kirrilian

Posts: 628
Score: 3
Joined: 3/15/2005
From:
Status: offline

quote:

ORIGINAL: kxrain

Just a question you will save this as??

You save this as a .vbs file and make sure you insert another line in the beginning like I stated in the Usage

Usage:
service_control ".","IIS Admin","restart"

otherwise the script wont do anything

_____________________________

Have you searched here ?
VBScript Fundamentals
My Site

(in reply to kxrain)

Post #: 6

RE: Start, Stop, & Restart Services (Incl. dependencies) - 1/21/2008 1:42:25 PM

victory73

Posts: 31
Score: 0
Joined: 12/3/2007
Status: offline

I modified this script a bit, but it does not work.

It did not return any errors, but did not stop the service.

Sub service_control(strComputer,sname,purpose)
strComputer="168.9.0.10"
sname="Microsoft Exchange Connectivity Controller"
purpose="stop"
 
Dim delay, err_return
 delay = 20000    '20 seconds
 WScript.stdout.Writeline "*"
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServices = objSWbemLocator.ConnectServer(strComputer, "root\cimv2", "administrator", "Password")
 
 Set colListOfServices = objSWbemServices.ExecQuery _
        ("Select * from Win32_Service where DisplayName = '" & sname & "'")
 For Each objService In colListOfServices
    
    If objService.displayname = sname Then
        WScript.stdout.Write "*"
        If purpose = "stop" Or purpose = "restart" Then
                err_return = objService.stopservice
                
                If err_return = 3 Then
                    
                    Set colServiceList2 = objSWbemServices.ExecQuery("Associators of " _
                       & "{Win32_Service.Name='" & objService.name & "'} Where " _
                            & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
                    For Each objService2 in colServiceList2
                        objService2.StopService()
                        If Not objService2.state = "Stopped" Then
                           
                            WScript.Sleep delay
                            service_control strComputer,sname,"stop"
                        Else
                            
                        End If
                    Next
                    
                    objService.stopservice
                Else
                    If Not objService.state = "Stopped" Then
                        
                        WScript.Sleep delay
                        service_control strComputer,sname,"stop"
                    Else
                        
                    End If
                End If
                
                If purpose = "restart" Then service_control strComputer, sname, "start" End if
        Elseif purpose = "start" Then    
                WScript.stdout.Write "*"
                err_return = objService.startservice
                If NOT err_return = 10 Then
                   
                    Set colServiceList2 = objSWbemServices.ExecQuery("Associators of " _
                       & "{Win32_Service.Name='" & objService.name & "'} Where " _
                            & "AssocClass=Win32_DependentService " & "Role=Antecedent" )
                    For Each objService2 in colServiceList2
                        objService2.StartService()
                        If Not objService2.state = "Running" Then
                            
                            WScript.Sleep delay
                            service_control strComputer,sname,"start"
                        Else
                            WScript.Echo objService.displayname & " has been started."
                        End If
                    Next
                    err_return = objService.startservice
                    
                    If err_return = 3 Then
                       
                        objService.startservice
                        
                        If Not objService.state = "Running" then
                           
                            WScript.Sleep delay
                            service_control strComputer,sname,"start"
                        Else
                            
                        End If

End If
                End If
                
        End If
    End If
 Next
End Sub 'service_control

//EDIT 1/22/2008: Added code tags - dm_4ever

< Message edited by dm_4ever -- 1/22/2008 1:17:48 PM >

(in reply to kirrilian)

Revisions: 1 | Post #: 7

RE: Start, Stop, & Restart Services (Incl. dependencies) - 1/22/2008 1:48:45 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

Well if that is your entire script, I don't see anwhere that you actually call the sub.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to victory73)

Post #: 8

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> Start, Stop, & Restart Services (Incl. dependencies)

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts