Set wallpaper for all users

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Set wallpaper for all users

Logged in as: Guest

arrSession:exec spGetSession 2,16,47074

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Set wallpaper for all users
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Set wallpaper for all users - 5/14/2007 6:23:55 PM

ginolard

Posts: 1044
Score: 21
Joined: 8/10/2005
Status: offline

I thought this might be useful for everyone. I've been looking to remove the wallpaper update functionality from our login script and make it a software package instead. I felt it was pointless having the logon script check every time whether or not there was a new wallpaper to be installed (and we don't insist our users have the corporate wallpaper all the time)

The problem, of course, is that the wallpaper info is stored in the Current User Hive. So, here's the code I came up with.

Option Explicit

Const HKUSERS = &H80000003
Dim WshShell : Set WshShell = CreateObject("Wscript.Shell")
Dim objReg : Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
Dim arrRegKeys,arrDesktopKeys,subkey
Dim strWallpaperPath : strWallpaperPath = PATH_TO_WALLPAPER_FILE_HERE
UserHives("Load")

objReg.EnumKey HKUSERS, "", arrRegKeys

For Each subkey In arrRegKeys
   objReg.EnumKey HKUSERS, subkey & "\Control Panel\Desktop", arrDesktopKeys
   If Not IsNull(arrDesktopKeys) Then 
       WshShell.regwrite "HKEY_USERS\" & subkey & "\Control Panel\Desktop\WallPaper", strWallpaperPath
       WshShell.regwrite "HKEY_USERS\" & subkey & "\Control Panel\Desktop\TileWallPaper", 0
   End If
Next

UserHives("Unload")

Sub UserHives(LoadUnload)
   
   'LoadUnload = Load => load user hives / Unload => Unload user hives 
   Dim strRegExe, strRegOpt, strDocSet, strcom, strFullHive, Windir,strDatFile
   Dim colSubfolders, objFolder, objSubfolder,objFSO
    
    Set WshShell = CreateObject("Wscript.Shell")
    WinDir = WshShell.ExpandEnvironmentStrings("%WinDir%")
    
    strDocSet = "C:\Documents and Settings"
    strRegExe = WinDir & "\System32\Reg.exe"
    
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder(strDocSet)
    Set colSubfolders = objFolder.Subfolders
    For Each objSubfolder in colSubfolders
         strDatFile = strDocSet & "\" & objSubfolder.Name & "\NTUser.dat"
         Select Case LoadUnload
              Case "Load" strcom = strRegExe & " LOAD " & Chr(34) & "HKU\" & objSubfolder.Name & Chr(34) & " " & chr(34) & strDatFile & Chr(34) 
              Case "Unload" strcom = strRegExe & " UNLOAD " & Chr(34) & "HKU\" & objSubfolder.Name & Chr(34)
         End Select
         
         WshShell.Run strcom,0,True
    Next
    
End Sub

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

Post #: 1

RE: Set wallpaper for all users - 5/15/2007 1:44:39 AM

dm_4ever

Posts: 2585
Score: 46
Joined: 6/29/2006
From: Orange County, California
Status: offline

Nice script...I particularly like that UserHives Sub.

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to ginolard)

Post #: 2

RE: Set wallpaper for all users - 5/15/2007 2:15:51 AM

ginolard

Posts: 1044
Score: 21
Joined: 8/10/2005
Status: offline

Yeah, I'm finding it more and more useful. Particularly with software packaging that requires entries in HKCU.

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to dm_4ever)

Post #: 3

RE: Set wallpaper for all users - 8/29/2007 5:38:30 AM

poon1972

Posts: 1
Score: 0
Joined: 8/29/2007
Status: offline

I got an error message at line 15 that the instruction was not right ended. I have changed the path in line 7 to "c:\windows\wallpaper.bmp"

(in reply to ginolard)

Post #: 4

RE: Set wallpaper for all users - 9/21/2007 5:03:56 AM

thefourthwall

Posts: 1
Score: 0
Joined: 8/1/2007
Status: offline

[quote ORIGINAL: ginolard]

I thought this might be useful for everyone. The problem, of course, is that the wallpaper info is stored in the Current User Hive. So, here's the code I came up with.[/quote]

Very useful code, thank you! It saved my deadline this week as your code did exactly what I was unable to do, write to each HKCU hive. The goal was to insert application-specific information and your code fit the bill perfectly.

-thefourthwall

(in reply to ginolard)

Post #: 5

RE: Set wallpaper for all users - 9/22/2007 2:21:06 AM

ebgreen

Posts: 4613
Score: 31
Joined: 7/12/2005
Status: offline

Depending on the situation, active setup keys are a better solution that writing to HKCU of every user in this fashion. They have the advantage that they will execute for new users as well as existing users.

_____________________________

"... when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick
Goog places to start:http://www.visualbasicscript.com/m_24727/tm.htm
http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to thefourthwall)