Compare 2 File System Locations

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Compare 2 File System Locations

Logged in as: Guest

arrSession:exec spGetSession 2,16,48966

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Compare 2 File System Locations
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Compare 2 File System Locations - 7/2/2007 6:28:27 AM

prodonjs

Posts: 3
Score: 0
Joined: 6/19/2007
Status: offline

A coworker wanted a script to compare two directories against one another to see in a convenient report what the differences were between the directory and file structure of the two locations. This script takes two directories (or just a simple drive letter) as parameters and then tries to match each file and folder in the first location to a corresponding entry in the second location. Matches will only occur if the file exists and shares the same Modified On date.

This first version is probably a little bit crude, but it does give a nice, tab-indented report file to display the file-system hierarchy. I would really like to make the reports more useful. I would love if they could be in XML/HTML format with different color schemes to immediately give the user the information they want. If anyone is interested in expanding this, let me know as I feel this would be a useful enhancement.

' VBScript that prints a report listing the files of two distinct directories
' First it will list any files that are different between the directories pointed to,
' then recursively scan through each subdirectory contained in the current folders.
' Version 1.1, July 2nd, 2007
Option Explicit
Const PROG_SUCCESS = 0
Const PROG_ERROR = 1
' Global data for the script
Dim objFSO, objLeftDir, objRightDir, objReportFile
Dim iArgCount, iArgPosition
Dim strLeftDirToScan, strRightDirToScan, strLogFilePath
Dim bListDifferences
Set objFSO = CreateObject("Scripting.FileSystemObject")
iArgCount = WScript.Arguments.Count
' Make sure we have at least two arguments before proceeding
If(iArgCount < 2) Then
WScript.Echo("Displaying Help" & vbCrLf)
ShowUsage()
FailAndExit("")
Else
ParseArguments()
CreateReportFile()
End If
' Call the subroutine to begin comparing the contents of the left and right directories
' +++++ Main Execution Line
Call DisplayDifferences(objLeftDir, objRightDir, 0)
' ------ End of Main Execution Block
' After the recursive sequence of DisplayDifferences ends, the script successfully finishes
Set objFSO = Nothing
Set objLeftDir = Nothing
Set objRightDir = Nothing
Set objReportFile = Nothing
WScript.Quit(PROG_SUCCESS)
' -------------------------------------------------------------------- SUBROUTINES --------------------------------------------------------------------
' Scans through the arguments given to the script as it was called, validates them, and sets up the appropriate objects needed
Sub ParseArguments
' Both arguments must be valid directory locations
' First argument gets assigned to the left directory
strLeftDirToScan = WScript.Arguments(0)

' Second argument is assigned to the right directory
strRightDirToScan = WScript.Arguments(1)

' Now validate the directory strings and set up the Folder objects 
Call ValidateAndInstantiateFolderObj(strLeftDirToScan, strRightDirToScan)
End Sub
'=============================================================================================================
' Creates the report and initializes the header information
Sub CreateReportFile
'Creates or overwrites the report file in the directory of this script
Set objReportFile = objFSO.CreateTextFile("Dir_Compare_Report.TXT", True)

Call WriteReportLine("Report created: " & Date & " at " & Time, 0)
Call WriteReportLine("*Turn off word-wrap to view cleanly" & vbCrLf, 0) 
 
Call WriteReportLine("Starting Left Directory - " & objLeftDir, 0)
Call WriteReportLine("Starting Right Directory - " & objRightDir, 0)
End Sub
'=============================================================================================================
' Begins the recursive procedure to scan and examine the files from both directories given as parameters
Sub DisplayDifferences(objLeftDir, objRightDir, iTabLevel)
Dim objLeftFiles, objLeftFolders
Dim leftFile, leftSubFolder

Set objLeftFiles = objLeftDir.Files
Set objLeftFolders = objLeftDir.SubFolders

Call WriteReportLine(vbCrLf, iTabLevel)
Call WriteReportLine("Examining: " & objLeftDir & " , " & objRightDir, iTabLevel)

Call WriteReportLine("Files:", iTabLevel)
Call WriteReportLine("------------------------------------------------------------------", iTabLevel)
'For each file in the left directory, see if a match can be found in the right directory
For Each leftFile In objLeftFiles
 Call MatchingFileInRight (leftFile, objRightDir, iTabLevel)
Next

Call WriteReportLine(vbCrLf, iTabLevel)

Call WriteReportLine("Subfolders:", iTabLevel)
Call WriteReportLine("------------------------------------------------------------------", iTabLevel) 
'For each subfolder in the left directory, see if a match can be found in the right directory
For Each leftSubFolder In objLeftFolders
 Call MatchingFolderInRight (leftSubFolder, objRightDir, iTabLevel)
Next 
End Sub
'=============================================================================================================
' Begins the recursive procedure to scan and examine the files in each of the  directories given as parameters
Sub MatchingFileInRight(objFile, objRightDir, iTabLevel)
Dim strFileName
Dim objRightFile
 
strFileName = objRightDir & "\" & objFSO.GetFileName(objFile)

'First see if the file exists in the right directory
If(objFSO.FileExists(strFileName)) Then
 'If so, see if the modified dates match
 Set objRightFile = objFSO.GetFile(strFileName)
 If(Not objFile.DateLastModified = objRightFile.DateLastModified) Then
  Call WriteReportLine(vbTab & objFile & " was last modified on " & _
        objFile.DateLastModified, iTabLevel)
  Call WriteReportLine("-->" & vbTab & objRightFile & " was last modified on " & _
        objRightFile.DateLastModified, iTabLevel)
 End If
Else
 Call WriteReportLine(objFile.Name & " does not exist in " & "'" & objRightDir & "'", iTabLevel)
End If
End Sub
'=============================================================================================================
' Similar to the MatchingFileInRight subroutine, this sub tests to see if a folder exists on both directory trees
' If a match is found, the routine then makes a call to the DisplayDifferences routine using those two matched
' directories as parameters
Sub MatchingFolderInRight(objFolder, objRightDir, iTabLevel)
Dim strFolderName
Dim objRightFolder
  
strFolderName = objRightDir & "\" & objFSO.GetBaseName(objFolder)

'First see if the file exists in the right directory
'If so, see if the modified dates match
If(objFSO.FolderExists(strFolderName)) Then
 'If so, see if the modified dates match
 Set objRightFolder = objFSO.GetFolder(strFolderName)
 If(Not objFolder.DateLastModified = objRightFolder.DateLastModified) Then
  Call WriteReportLine(vbTab & objFolder & " was last modified on " & _
      objFolder.DateLastModified, iTabLevel)
  Call WriteReportLine(vbTab & "--> " &  objRightFolder & " was last modified on " & _
      objRightFolder.DateLastModified, iTabLevel)
 Else
  ' In this case, the folders exist in both locations, call display differences giving those two directories as the new bases
  Call DisplayDifferences(objFolder, objRightFolder, iTabLevel + 1)
 End If
Else
 Call WriteReportLine("\" & objFolder.Name & " does not exist in " & _
     "'" & objRightDir & "'", iTabLevel)
End If
End Sub
'=============================================================================================================
' Displays the syntax and options for calling the script
Sub ShowUsage
WScript.Echo("USAGE:" & vbCrLf & vbCrLf & _
    "1st argument is the left-directory to scan" & vbCrLf & _
    "2nd argument is the right-directory to scan" & vbCrLf & vbCrLf & _
    "ex: cscript compareDirectories C:\ D:\")
End Sub
'=============================================================================================================
' Takes two string parameters assumed to be the names of directories and validates them
' If the directories exist, Folder objects are created from their paths
Sub ValidateAndInstantiateFolderObj(strLeft, strRight)

' Checks to see whether each folder string is a valid directory
' Errors out if either of the two arguments is invalid and informs the user
If(objFSO.FolderExists(strLeft) ) Then
 Set objLeftDir = objFSO.GetFolder(strLeft)
 If(objFSO.FolderExists(strRight) ) Then
  Set objRightDir = objFSO.GetFolder(strRight)
 Else 
  FailAndExit("Sorry, " & strRight & " is not a valid directory location")
 End If 
Else
 FailAndExit("Sorry, " & strLeft & " is not a valid directory location")
End If
End Sub
'=============================================================================================================
' Prints the given error message, frees all global objects, exits the script with an error status code
Sub FailAndExit(strErrorMessage) 
WScript.Echo(strErrorMessage)

Set objFSO = Nothing
Set objLeftDir = Nothing
Set objRightDir = Nothing
Set objReportFile = Nothing

WScript.Quit(PROG_ERROR)
End Sub
'=============================================================================================================
' Prints a series of tabs initially to indicate file system hierarchy levels, then the message
Sub WriteReportLine(strLine, iTabCount)
Dim i
For i = 0 To iTabCount-1
 objReportFile.Write(vbTab)
Next

objReportFile.WriteLine(strLine)
End Sub

Post #: 1

RE: Compare 2 File System Locations - 7/2/2007 1:21:43 PM

dm_4ever

Posts: 2174
Score: 32
Joined: 6/29/2006
From: Orange County, California
Status: offline

Even thought there's apps out there like WinDiff that do similar things I like the idea.

_____________________________

dm_4ever

My philosophy: K.I.S.S - Keep It Simple Stupid
Read Me: http://www.visualbasicscript.com/m_24727/tm.htm
Frequently Asked Stuff: http://www.visualbasicscript.com/m_47117/tm.htm

(in reply to prodonjs)

Post #: 2

RE: Compare 2 File System Locations - 7/19/2007 11:59:24 PM

Singaravelan

Posts: 2
Score: 0
Joined: 6/15/2007
Status: offline

Thanks for the script. I guess this is exactly what i have been searching for.
Moreover even though windiff exists, it is not possible to customise as we want with that.

Regards
Velan

(in reply to dm_4ever)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> Compare 2 File System Locations

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts