Prevent logoff

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Prevent logoff

Logged in as: Guest

arrSession:exec spGetSession 2,16,49262

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Prevent logoff
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Prevent logoff - 7/10/2007 4:26:56 AM

kbern3

Posts: 1
Score: 0
Joined: 7/10/2007
Status: offline

This script is designed to prevent a logoff from happening if a specific program is running, otherwise, if the program isn't found, let the logoff process continue. I don't know everyone's script knowledge level so just in case I need to clarify I use the words process/program/executible interchangeably throughout the following explanation:

When the script is double-clicked it searches through the process list for a specific executible file. If this process is running on the computer the script will display a message to the user stating "x processes found. Please close before continuing to logoff". If the process is not found the script will logoff the user. In order for this to work you need to put a shortcut to this script in the Start menu (and/or desktop) and edit local group policy so that the logoff button no longer appears in the Start or Ctrl+Alt+Del menu. This will force users to click on the script whenever they want to logoff. You also need to change where it states insert program name name to whatever program you want the script to search for. You can also use this script to prevent shutdown and restart. I made a comment towards the end of the script as to how.

'************************************************************
' PREVENT LOGOFF SCRIPT
' Created: 6/14/2007
' Updated: 7/3/2007
' 
' A big THANK YOU to Adam, Jaker, Guy Thomas, and Lisa
' ***********************************************************
' Require all variables to be declared before they can be used.  
' This helps with debugging issues
Option Explicit

' Define all of the variables
Dim strComputer, objWMIService, colProcesses, 
Dim objProcess, strList, Count

' Establish variables
strComputer = "." 'setting strComputer to "." connects to the local machine.
Count = 0 'starts the process count at 0

' All WMI scripts begin by connecting to the Windows Management Instruments interface
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" _ 
& strComputer & "\root\cimv2")

' Get a collection of all running processes
Set colProcesses = objWMIService.ExecQuery("Select * FROM Win32_Process")

' Cycle through every currently running process
For Each objProcess in colProcesses
'Check to see if the program is currently running 
       If objProcess.Name = "[insert program name]" Then 
       'the program is running if the above statement is true.
                  Count = Count + 1 'Count the number of running processes
       End If
Next

If Count > 0 Then 
       'Build the message box text notifying the user of any running processes
       strList = strList & Count _ 
        & " [insert program name] process(es) running." _
        & "  Please close before continuing to logoff." & vbCr
       'This message box will only appear if the process was found
       WSCript.Echo strList 
Else
         'Create another variable to connect to the Windows shell service.
         Dim objWSHShell
         'Connect to the Windows shell service
         Set objWSHShell = CreateObject("WScript.Shell")
         'Execute the logoff command to logoff
         objWSHShell.Run "shutdown -l" 'change to -s to shutdown or -r to restart
End if

'Quit the script
WScript.Quit

< Message edited by kbern3 -- 7/10/2007 4:39:18 AM >