detection of plugins (flash,shockwave,quicktime,java)

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

detection of plugins (flash,shockwave,quicktime,java)

Logged in as: Guest

arrSession:exec spGetSession 2,2,49935

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> detection of plugins (flash,shockwave,quicktime,java)
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

detection of plugins (flash,shockwave,quicktime,java) - 7/24/2007 9:02:24 PM

cyf

Posts: 20
Score: 0
Joined: 1/25/2007
Status: offline

Hi i tried searching for this but dont think anyone has a solution on here yet?

I have managed to get a vbs script working to detect if the installed version matches the current (hard coded) version but the way it does it im sure isnt the best. At present it tries to create an object if it succeed's then its installed otherwise it calls the .exe to install it.

Is there an easier way to check if Flash 9 for example is installed? in VBS WSH or ebven flash - i know the basics of all the scripting but cant seem to find and alternatives

Any help will be greatly appreciated!!

_____________________________

http://www.andigibson.co.uk
http://www.socialaddict.co.uk

Post #: 1

RE: detection of plugins (flash,shockwave,quicktime,java) - 7/24/2007 9:36:21 PM

ginolard

Posts: 1082
Score: 21
Joined: 8/10/2005
Status: offline

You could enumerate the keys under HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall and check the DisplayName of each one for the individual plugins

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to cyf)

Post #: 2

RE: detection of plugins (flash,shockwave,quicktime,java) - 7/24/2007 10:21:04 PM

mbouchard

Posts: 1924
Score: 16
Joined: 5/15/2003
From: USA
Status: offline

Here is my script that we use to install the latest version of Flash and Shockwave. You could probably do something similar with Quicktime but would probably have to go the reg route for Java as there can be multiple copies installed on the PC.

'==========================================================================
' Install Shockwave 10.1.0.11 and Flash 9
' NAME: Michael Bouchard
' DATE  : 3/16/2006
' COMMENT: Run with /silent to install quietly, no modul message boxes
' Dependency's - None
'==========================================================================

Option Explicit
Const STANDARDFOLDER       = "\\SERVER\SHARE$\standard"

Dim Fso : Set Fso = CreateObject("Scripting.FileSystemObject")
Dim WshShell : Set WshShell = createobject("wscript.shell")
Dim doSilent
Dim ret
Dim doFlash
Dim doShock
Dim doThing
Dim msg
Dim File
Dim SystemFolder : SystemFolder = fso.GetSpecialFolder(1) '1 = SystemFolder
Dim shockWaveMSI : shockWaveMSI = "sw_lic_full_installer.msi"
Dim shockWaveInstaller
Dim flashMSI : flashMSI = "Install Flash Player 9 ActiveX"
Dim flashInstaller

'Check if running script silently
If WScript.Arguments.Count=0 Then
   doSilent = False
Else
   If instr(lCase(Wscript.Arguments(0)),"silent") > 0 Then
       doSilent = True
   End If
End If

If doSilent = False Then
   ret = Msgbox("Installing Macromedia Shockwave 10 and Flash 9" & vbcr _
               & "Do you want to continue with the install?",vbYesNo,Wscript.ScriptName)
   If ret = vbNo Then 
       Msgbox "Exiting script " & Wscript.ScriptName
       Wscript.Quit
   End If
End If

shockWaveInstaller = fso.GetParentFolderName(wscript.ScriptFullName) & "\Players\Shockwave\10.1.0.11\" & shockWaveMSI
flashInstaller = fso.GetParentFolderName(wscript.ScriptFullName) & "\Players\flash\9.0\" & flashMSI

'==============================================================================
' Install Macromedia Shockwave 10.1.0.11 
'==============================================================================
doThing = False
doShock = False
If (fso.FileExists(SystemFolder & "\macromed\shockwave 10\control.dll")) Then
   If CompareVersion(fso.GetFileVersion(SystemFolder&"\macromed\shockwave 10\control.dll"),"10.1.0.11")=-1 Then
       doThing = True
   End If
Else
   doThing = True
End If

If doThing = True Then
   doShock = True
   Call WriteToLog("Installing Macromedia Shockwave 10.1.0.11 ")
   wshShell.Run "msiexec /i " & shockWaveInstaller & " /qb", 1, True
End If

'==============================================================================
' Install Macromedia Flash 9
'==============================================================================
doThing = False
doFlash = False
If (fso.FileExists(SystemFolder & "\macromed\Flash\Flash9b.ocx")) Then
   If CompareVersion(fso.GetFileVersion(SystemFolder&"\macromed\Flash\Flash9b.ocx"),"9.0.28.0")=-1 Then
       doThing = True
   End If
Else
   doThing = True
End If

If doThing = True Then
   doFlash = True
   Call WriteToLog("Installing Macromedia Flash 9")
   wshShell.Run "msiexec /i " & """" & flashInstaller & """" & " /qb", 1, True
End If

If Not Fso.FileExists(SystemFolder & "\macromed\flash\mms.cfg") Then
   Set file = fso.CreateTextFile(SystemFolder & "\macromed\flash\mms.cfg", True)
   file.WriteLine("AutoUpdateDisable=1")
   file.Close
End If

If doShock = True Then
   msg = "Shockwave has been installed" & vbcr
Else
   msg = "The Current or newer version of Shockwave is already installed." & vbcr
End If

If doFlash = True Then
   msg = msg & "Flash has been installed" & vbCr
Else
   msg = msg & "The Current or newer version of Flash is already installed." & vbcr
End If

If doFlash = True Or doShock = True Then
   msg = msg & "Please reboot the PC to complete the installation."
End If

If doSilent = False Then
   Msgbox msg
Else
   If Fso.FolderExists("c:\NT\FilesForScript") Then
       WshShell.Run "cmd /c echo Done >c:\NT\FilesForScript\shockflash.txt",0,True
   End If        
End If
WScript.Quit

Function CompareVersion(ByVal strVersion1, ByVal strVersion2)
   Dim v1, v2, t1, t2
   'Returns -1 if strVersion1<strVersion2
   'Returns 1 if strVersion1>strVersion2
   'Returns 0 if strVersion1=strVersion2
   CompareVersion = 0
   If strVersion1="" Or strVersion2="" Then
       If strVersion1<strVersion2 Then
           CompareVersion = -1
           Exit Function
       Else
           If v1>v2 Then
               CompareVersion = 1
               Exit Function
           Else
               CompareVersion = 0
               Exit Function
           End If
       End If
   End If
   t1 = Instr(strVersion1, ".")
   If t1 = 0 Then t1 = Len(strVersion1)+1
   t2 = Instr(strVersion2, ".")
   If t2 = 0 Then t2 = Len(strVersion2)+1
   Do While True
       v1 = CInt(Left(strVersion1,t1-1))
       v2 = CInt(Left(strVersion2,t2-1))
       If v1<v2 Then
           CompareVersion = -1
           Exit Function
       Else
           If v1>v2 Then
               CompareVersion = 1
               Exit Function
           End If
       End iF
       strVersion1 = Mid(strVersion1,t1+1)
       strVersion2 = Mid(strVersion2,t2+1)
       If strVersion1="" Or strVersion2="" Then
           If strVersion1<strVersion2 Then
               CompareVersion = -1
               Exit Function
           Else
               If v1>v2 Then
                   CompareVersion = 1
                   Exit Function
               Else
                   CompareVersion = 0
                   Exit Function
               End If
           End If
       End iF
       t1 = Instr(strVersion1, ".")
       If t1 = 0 Then t1 = Len(strVersion1)+1
       t2 = Instr(strVersion2, ".")
       If t2 = 0 Then t2 = Len(strVersion2)+1
   Loop
End Function

Sub WriteToLog(strMessage)
Const SOFTWARECONFIGLOG    = "c:\program files\Software Configuration.log"
   Dim file
   If Not fso.FileExists(SOFTWARECONFIGLOG) Then
       Set file = fso.CreateTextFile(SOFTWARECONFIGLOG, True)
       file.Close
   End If
   Set file = fso.OpenTextFile (SOFTWARECONFIGLOG, 8) '8 = ForAppending
   file.WriteLine(Now & "  " & strMessage)
   file.Close
End Sub

_____________________________

Mike

For useful Scripting links see the Read Me First stickey!

Always remember Search is your friend.

(in reply to cyf)

Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> WSH & Client Side VBScript >> detection of plugins (flash,shockwave,quicktime,java)

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts