Fix Remote Assistance w/o Domain rights

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Fix Remote Assistance w/o Domain rights

Logged in as: Guest

arrSession:exec spGetSession 2,16,50084

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Fix Remote Assistance w/o Domain rights
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Fix Remote Assistance w/o Domain rights - 7/27/2007 10:21:13 AM

itismike

Posts: 42
Score: 0
Joined: 7/7/2007
Status: offline

Hi Guys,

Hope you find this interesting. Let me know if it needs more comments.

Oops - I should have tested that last edit. This should work now:

'Force variable declaration
Option Explicit  '(encourages good programming practices)
'
'
'
'   *  *  *  *   D O    N O T    D I S T R I B U T E ! ! !    *  *  *  *
'    *  *  *  *   D O    N O T    D I S T R I B U T E ! ! !    *  *  *  *
'     *  *  *  *   D O    N O T    D I S T R I B U T E ! ! !    *  *  *  *
'
'                  until you have removed references to your
'              local environmental variables in the next section
'                                  below...
'                                     |
'                                     |
'                                     |
'                                    \ /
'                                     o
'******************************************************************************
'                  * * * ENVIRONMENTAL VARIABLES * * *
'                 * CHANGE THESE TO MATCH YOUR DOMAIN *
'     * DELETE YOUR ENVIRONMENT VARIABLES BEFORE DISTRIBUTING THIS SCRIPT *
'******************************************************************************

'ENTER YOUR DOMAIN NAME HERE:
  'Only enter the 'domain' portion of: "domain\username"
'dim strDomain : strDomain = "YOUR_DOMAIN_NAME"
dim strDomain : strDomain = "********"

'ENTER THE NAME OF THE ADMINISTRATOR PROFILE ON TARGET PC
   '(default is Administrator)
'dim strAdminAcct : strAdminAcct = "NAME_OF_ADMIN_ACCOUNT"
dim strAdminAcct : strAdminAcct = "********"

'ENTER NAME OF PRIVILAGED GROUP WITH LOCAL ADMIN RIGHTS ON ALL WORKSTATIONS
'dim strHelperGroup : strHelperGroup = "HELPER_GROUP_W/LOCAL_ADMIN_PRIVILAGES"
dim strHelperGroup : strHelperGroup = "********"

' ---------- TO BE IMPLIMENTED (TBI)------------------
 'SET HOSTNAME FORMAT: "[HostnameSyntaxHere]"
'dim HostnameFormat : HostnameFormat = "[Aa][Bb][*]######"
' ---------- END -  TO BE IMPLIMENTED -----------

'******************************************************************************
'                 * * * END ENVIRONMENTAL VARIABLES * * *
'******************************************************************************
'
'
'                 OFFER UNSOLICITED REMOTE ASSISTANCE
'
'
'******************************************************************************
'
'
'     Written by:
'
'          Michael Hughes
'
'
'     Coding contributions and testing by:
'
'          John Yi
'
'
'
'     Public code borrowed from: (in no particular order.  really.)
'
'          http://www.spoogenet.com/index.php?module=article&view=15
'          http://kirrilian.dyndns.org/projects/code/#vbs
'          http://my.opera.com/Lee_Harvey/blog/index.dml/tag/error%20handling
'          http://www.scit.wlv.ac.uk/~jphb/mynotes.html
'          http://blogs.dirteam.com/blogs/sanderberkouwer/archive/2006/08/21/
'            Unsolicited-Remote-Assistance.aspx
'          http://www.jsifaq.com/SF/Tips/Tip.aspx?id=8047
'          http://www.w3schools.com
'          http://www.visualbasicscript.com/
'          http://www.computerperformance.co.uk/Logon/VBScript/
'            VBScript_Windows_registry.htm
'          http://www.johnrostron.co.uk/bill/troubleshooting/programming/
'            windows_scripting.htm
'          http://msdn2.microsoft.com/En-US/library/aa389385.aspx
'          http://www.pctools.com/forum/showthread.php?p=166908
'          http://72.32.210.42/board/Forum12/HTML/000015.html
'          http://www.ureader.com/message/1277347.aspx
'
'     among others...
'
'
'
'     ABSOLUTELY NO WARRANTY - USE AT YOUR OWN RISK
'
'     Free for all to use and/or modify
'
'     July 2007
'
'
'
'  This script addresses three challenges encountered when attempting to use
'     Remote Assistance in a Windows Active Directory environment.  Typically
'     these challenges should be addressed by a Domain Administrator using GPO
'     and/or login scripts.  Alternatively, a tech with Local Admin rights can
'     use the following workaround to accomplish the same result on a PC-by-PC
'     basis, unless certain aspects have been specifically locked down by an
'     existing GPO.  It is my hope that this script is useful to you.
'
'  In the order in which they are resolved by this script, the challenges I
'    experienced in using Unsolicited Remote Assistance were:
'
'  1. HelperGroup is missing from the Administrator's group on several batches
'       of our images.  Helpdesk techs are members of 'HelperGroup', but without
'       this group existing in the list of allowed Administrators on a PC,
'       further administrative changes are not allowed.
'  2. As described on http://support.microsoft.com/kb/900904, the following
'       needs to be run in safe mode:  "sessmgr.exe -service".  But according
'       to http://www.ureader.com/message/1277347.aspx, this can be done under
'       the user account as long as the 'rdsessmgr' service is stopped then
'       restarted after execution.  Occasionally a reboot of the target PC will
'       be necessary when the script completes.
'  3. According to Sander Berkouwer from dirteam.com, a registry key and two
'       values must be present on the target PC.
'
'
'
'******************************************************************************
'                 * * * PREREQUISITES  * * *
'******************************************************************************
'
' Technician must be a member of [HelperGroup] privileged group, and must know
'   the admin password on target computer
'
'******************************************************************************
'                 * * * END PREREQUISITES  * * *
'******************************************************************************
'
'
'
'******************************************************************************
'                 * * * GENERAL VARIABLES * * *
'******************************************************************************
dim strComputer                           'hostname of target PC
dim strPassword                           'administrator password on target PC
dim strPrompt                             'used to display message
dim intSleep                              'seconds to sleep
dim strErrorDesc                          'used to describe error-prone code
dim boolFatal                             '0 = nonfatal, 1 = fatal

dim strService                            'name of service to stop or start
 strService = "'RDSessMgr'"       'strService IS CASE SENSITIVE (or is it?)

dim strExe                                 'process to be executed on remote PC
 strExe = "%systemroot%\system32\sessmgr.exe -service"    'cmd line
dim strStopService_or_StartService         '"Start" or "Stop" Service
dim intToggleServiceTimeout                'How many cycles sub ToggleService -
 intToggleServiceTimeout = 10               'will attempt before quitting

'Registry variables
dim strKeyRoot                             'registry key root (HKLM, HKU, etc)
dim strKeyPath                             'key path (SOFTWARE\Policies...)
dim strValueName                           'name of registry value
dim strValue                               'value of registry value

'******************************************************************************
'                 * * * END GENERAL VARIABLES * *
'******************************************************************************
'
'
'
'
'
'
'******************************************************************************

'***************************** ************************************************
'****************************   ***********************************************
'************************         *********************************************
'***************                             **********************************
'*******************    BEGIN SCRIPT     **************************************
'****************                           ***********************************
'************************         *********************************************
'****************************   ***********************************************
'***************************** ************************************************

'Force this entire script to run in CScript
ForceCScript

'Print script engine and version
WScript.Echo "WScript Version: " & WScript.Version
WScript.Echo "Build Version: " & WScript.BuildVersion

'TBI  if WScript.Version > X then pester user and quit

'Inform user to leave cmd window up
WScript.Echo Chr(10) & "Wait for entire script to terminate " _
 & "before closing this window." & Chr(10) & "Script will self-" _
 & "terminate in 3 minutes."

'pause for user to notice above message
'Pause 1

'Get hostname from popup message box and store result in strComputer
   'This popup also echoes all environmental variables as a sanity check
strComputer =  PromptForHostname _
              (strHelperGroup, strAdminAcct, strDomain, strService)

'pause for user to notice next message
'Pause 1

strPassword = AskForAndMaskAdminPassword _
              (strComputer, strAdminAcct)

AddHelperGroup _
   strHelperGroup, strDomain, strComputer, strAdminAcct, strPassword

'Stop service
 strStopService_or_StartService = "StopService"
 ToggleService _
    strStopService_or_StartService, strService, _
      intToggleServiceTimeout, strComputer

ExecuteCommandLine _
   strExe, strComputer

'Wait for remote process to execute
Wscript.Echo "Waiting 5 seconds for the remote process to complete..."
Pause 5
Wscript.Echo "Done."
Wscript.Echo Chr(13)

'Start service
strStopService_or_StartService = "StartService"
ToggleService _
   strStopService_or_StartService, strService, intToggleServiceTimeout, _
   strComputer

'Add "RAUunsolicit" key to registry
strKeyRoot = "HKLM"
strKeyPath = "SOFTWARE\Policies\Microsoft\Windows NT" _
 & "\Terminal Services\RAUunsolicit"  
 
AddRegKey _
   strKeyPath, strKeyRoot, strComputer

'Add dWord value "fAllowUnsolicit" = 1 to registry
strKeyRoot = "HKLM"
strKeyPath = "SOFTWARE\Policies\Microsoft\Windows NT" _
 & "\Terminal Services\RAUunsolicit"
strValueName = "fAllowUnsolicit"
strValue = "1"

AddDWordAndValueToKey _
   strValue, strValueName, strKeyPath, strKeyRoot, strComputer

'Add dWord value "fAllowUnsolicitFullControl" = 1 to registry
strKeyRoot = "HKLM"
strKeyPath = "SOFTWARE\Policies\Microsoft\Windows NT" _
 & "\Terminal Services\RAUunsolicit"
strValueName = "fAllowUnsolicitFullControl"
strValue = "1"

AddDWordAndValueToKey _
   strValue, strValueName, strKeyPath, strKeyRoot, strComputer

LaunchUnsolicitedRemoteAssistance strComputer

WScript.Quit

'***************************** ************************************************
'****************************   ***********************************************
'************************         *********************************************
'***************                             **********************************
'*******************      END SCRIPT     **************************************
'****************                           ***********************************
'************************         *********************************************
'****************************   ***********************************************
'***************************** ************************************************

' Begin Subroutines

'******************************************************************************

'Force script to execute in CScript, even if started from WScript
Sub ForceCScript

'Check to see if CScript was used to execute the script
   If InStr(1, WScript.FullName, "cscript", vbTextCompare) = 0 Then

'If it was NOT executed using CScript.exe, create a shell object
       dim objShell : Set objShell = CreateObject("WScript.Shell")

'Re-execute the script using cscript.exe with the following options:
         '   disable logo, set maximum script runtime to 180 seconds
       objShell.Run "%comspec% /c cscript.exe " & Chr(34) _
         & WScript.ScriptFullName & Chr(34) & " //NoLogo //T:180"

'quit the current script
       WScript.Quit
   End If
End Sub

'******************************************************************************

'Sleep for (Seconds * 1000) Miliseconds
Sub Pause (Seconds)
    WSCript.Sleep Seconds*1000
End Sub

'******************************************************************************

'Called after error-prone code executes to verify success or failure
Sub DisplayErr (ErrorDesc, Fatal)

'Echo any error to the console
   If Err.Number <> 0 Then
       WScript.Echo "FAILURE IN " & ErrorDesc
       WScript.Echo "error#: " & Err.Number
       WScript.Echo "description: " & Err.Description
       WScript.Echo Chr(10)
       pause 3

'If error is fatal, throw msgBox to screen and quit script
       If Fatal = 1 then
           msgBox "FATAL ERROR...QUITTING...", 0+16, "Fatal Error"
           wscript.quit
       End if

'If no error, print success message
   Else
       WScript.Echo "SUCCESS: " & ErrorDesc & Chr(10)
   End If
End Sub

'******************************************************************************

'Display variables for confirmation, and get hostname from user input
Function PromptForHostname (Helper_Group, AdminAcct, Domain, Service)

dim ComputerName

ComputerName=InputBox("This script will add " & Chr(91) _
     & Helper_Group & Chr(93) & " to the "  & Chr(10) & Chr(91) & AdminAcct _
     & Chr(93) & " group on a remote computer located on the " _
     & Chr(91) & Domain & Chr(93) & " domain, restart the " & Chr(10) _
     & Chr(91) & Service & Chr(93) & " service, and add registry keys and " _
     & "values to a remote PC to accept invitations.  It will then attempt " _
     & "to launch the " & Chr(34) & "Offer Unsolicited Remote Assistance" _
     & Chr(34) & " utility on your PC." _
     & VbCrlf  & VbCrlf  & "Paste the target PC name into " _
     & "this field:", "Remote Assistance Script", "Paste target PC " _
     & "name here")

PromptForHostname = ComputerName

If PromptForHostname = "" Then WScript.Quit
   If PromptForHostname = "Paste target PC name here" Then WScript.Quit

End Function

'******************************************************************************
 'Get password from user input (masked)
Function AskForAndMaskAdminPassword (ComputerName, AdminAcct)
   dim oPW, pswd
   WScript.Echo Chr(10) & "Enter password for the " & AdminAcct _
     & " account on " & ComputerName & " and press [Enter]." _
     & Chr(10) & "  (or press [Enter] to quit)"

'create masked input field
   Set oPW = CreateObject("ScriptPW.Password")
   pswd = oPW.GetPassword()
   
     'check for blank entry
   If pswd = "" Then WScript.Quit

AskForAndMaskAdminPassword = pswd
   WScript.Echo "password stored..." & Chr(10)
End Function

'******************************************************************************

'Add Helper_Group to Administrators group
Sub AddHelperGroup (Helper_Group, Domain, Computer, AdminAcct, pswd)

'  Check for existence of helper_group in Administrators group
'(TBI  If exists, exit status = success)

dim locator, objsvc, objWMIService, objInParam, objOutParams

'Create object for WBEM
   Set locator = CreateObject("WBEMScripting.SWBEMLocator")

'Set values for DisplayErr function
   on error resume next
   err.number = 0
   strErrorDesc = "Connect to remote computer"
   boolFatal = 1

'Connect to remote PC
   Set objsvc = locator.ConnectServer(Computer, "root/cimv2", Computer _
     & "\" & AdminAcct, pswd)

'Send error code to DisplayErr function
   DisplayErr strErrorDesc, boolFatal
   
     'reset Err values
   on error goto 0
   err.clear

'Set Impersonation Level
   objsvc.Security_.ImpersonationLevel = 3

'Set Authentication Level
   objsvc.Security_.AuthenticationLevel = 6

'
   Set objWMIService = Objsvc.Get("Win32_Process")

'
   Set objInParam = _
     objWMIService.Methods_("Create").inParameters.SpawnInstance_()

'Add the input parameters.
   objInParam.Properties_.item("CurrentDirectory") = NULL
   objInParam.Properties_.item("ProcessStartupInformation") = NULL

'Set values for DisplayErr function
   on error resume next
   err.number = 0
   strErrorDesc = "Add " & Chr(34) & Domain & "\" & Helper_Group _
     & Chr(34) & " to Administrator's account"
   boolFatal = 0

'Execute `net localgroup <group name> <"user or group name"> /add`
   objInParam.Properties_.item("CommandLine") = _
     "net localgroup Administrators " & Chr(34) & Domain & "\" & _
     Helper_Group & Chr(34) & " /add"

'
   Set objOutParams = objWMIService.ExecMethod_("Create", objInParam)

'Send error code to DisplayErr function
   DisplayErr strErrorDesc, boolFatal

'reset Err values
   on error goto 0
   err.clear
End Sub

'******************************************************************************

'Toggle a service on or off
Sub ToggleService _
(StopService_or_StartService, Service, ToggleServiceTimeout, Computer)

Dim objItem, objService, objWMIService, serviceState_now
   Dim colListOfServices, item, serviceState_goal, Counter, prompt
   Counter = 0
   Const wbemFlagReturnImmediately = &h10
   Const wbemFlagForwardOnly = &h20

If StopService_or_StartService="StopService" then
       serviceState_goal="Stopped"
   ElseIf StopService_or_StartService="StartService" then
       serviceState_goal="Running"
   Else
       wscript.echo "Error - neither start nor stop???"
       Pause 5 : wscript.quit
   End If

WScript.StdOut.Write "Attempting to " & StopService_or_StartService _
     & " on " & Service

Do Until serviceState_now=serviceState_goal

If Counter>=ToggleServiceTimeout then
           prompt = msgBox ("Timeout reached.  Unable to " _
             & StopService_or_StartService & " " & Service & " within " _
             & "specified time.  Retry?",2+32+256,"Service not responding")

'vbAbort 3 Abort, vbRetry 4 Retry, vbIgnore 5 Ignore
           If prompt = 3 Then
               WScript.Quit
           ElseIf prompt = 4 Then
               Counter = 0
           Else
               Exit Do
           End If
       End If
       
             'Set connection method
       Set objWMIService = GetObject("winmgmts:{impersonationLevel=" _
         & "impersonate}!\\" & Computer & "\root\cimv2")
   
         'Define query
       Set colListOfServices = objWMIService.ExecQuery ("Select State from " _
         & "Win32_Service Where Name =" & Service , "WQL", _
         wbemFlagReturnImmediately + wbemFlagForwardOnly)

'Execute query
       For each item in colListOfServices

serviceState_now=item.state

'Stop or Start service based on the value of 
               '"StopService_or_StartService"
           Execute ("item." & StopService_or_StartService & "()")

'give it a minute to work
           Pause 2

'increment counter and print progress
           Counter=Counter+1
           WScript.StdOut.Write "."
       Next
   Loop
   Wscript.echo Chr(13) & Chr(13)
   Wscript.echo Service & " is now " & serviceState_goal
   Wscript.echo Chr(13)
End Sub

'******************************************************************************

'Execute a process on a remote computer
 Sub ExecuteCommandLine (CmdLine, Computer)

Dim objWMIService, objProcess
   Dim strShell, objProgram, strInput

'Connect to WMI
   set objWMIService = getobject("winmgmts://"_
     & Computer & "/root/cimv2")

'Obtain the Win32_Process class of object.
   Set objProcess = objWMIService.Get("Win32_Process")

Set objProgram = objProcess.Methods_( _
     "Create").InParameters.SpawnInstance_
     objProgram.CommandLine = CmdLine

Wscript.Echo "Attempting: Execute " & CmdLine & " on " & Computer
   Wscript.Echo Chr(13)

'Set values for DisplayErr function
   on error resume next
   err.number = 0
   strErrorDesc = "Execute " & CmdLine & " on " & Computer
   boolFatal = 0

'Execute the program now at the command line.
   Set strShell = objWMIService.ExecMethod( _
     "Win32_Process", "Create", objProgram)

'Send error code to DisplayErr function
   DisplayErr strErrorDesc, boolFatal

'reset Err values
   On Error Goto 0
   err.clear

End Sub

'******************************************************************************

Sub AddRegKey (KeyPath, KeyRoot, Computer)

'Add registry key

dim oReg, Return, aKeyRoot, Key
   
 'translate keyRoot to valid HEX code
   select case KeyRoot
       case "HKCR" aKeyRoot = &H80000000    'HKEY_CLASSES_ROOT
       case "HKCU" aKeyRoot = &H80000001    'HKEY_CURRENT_USER
       case "HKLM" aKeyRoot = &H80000002    'HKEY_LOCAL_MACHINE
       case "HKU"  aKeyRoot = &H80000003    'HKEY_USERS
       case "HKCC" aKeyRoot = &H80000005    'HKEY_CURRENT_CONFIG
       case Else wscript.echo "Failed to recognize registry key root name: " _
         & KeyRoot & Chr(10) & "Quitting...." : pause 5 : wscript.quit
   end select

'DESCRIBE???
   Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
     Computer & "\root\default:StdRegProv")

'DESCRIBE???
   Return = oReg.CreateKey(aKeyRoot, KeyPath)

If (Return = 0) And (Err.Number = 0) Then

WScript.Echo KeyRoot & "\" & KeyPath & " created."

Else

Wscript.Echo "CreateKey failed. Error = " & Err.Number
       Pause 5
   End If

End Sub

'******************************************************************************

Sub AddDWordAndValueToKey (Value, ValueName, KeyPath, KeyRoot, Computer)
 
   dim oReg, Return, dwValue, aKeyRoot

'Registry Key Root Constants - from:
    'http://msdn2.microsoft.com/en-us/library/aa393297.aspx

select case KeyRoot
       case "HKCR" aKeyRoot = &H80000000    'HKEY_CLASSES_ROOT
       case "HKCU" aKeyRoot = &H80000001    'HKEY_CURRENT_USER
       case "HKLM" aKeyRoot = &H80000002    'HKEY_LOCAL_MACHINE
       case "HKU"  aKeyRoot = &H80000003    'HKEY_USERS
       case "HKCC" aKeyRoot = &H80000005    'HKEY_CURRENT_CONFIG
       case Else wscript.echo "Failed to recognize registry key root name: " _
         & KeyRoot & Chr(10) & "Quitting...." : pause 5 : wscript.quit
   end select

'Connect to Registry Object on remote PC
   Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\"&_ 
     Computer & "\root\default:StdRegProv")

'Add DWord
   oReg.SetDWORDValue aKeyRoot,KeyPath,ValueName,Value

If Err = 0 Then

oReg.GetDWORDValue aKeyRoot,KeyPath,ValueName,dwValue

WScript.Echo _
         KeyRoot & "\" & KeyPath & "\" & ValueName & " contains " & dwValue

Else

WScript.Echo "Error in creating key" & KeyRoot & "\" & KeyPath & "\" _
         & ValueName & " and DWORD value = " & Err.Number

End If

End Sub

'******************************************************************************

Sub LaunchUnsolicitedRemoteAssistance (Computer)
   dim shell, objWord, colTasks
   dim prompt
   Dim counter : counter = 0
   Const wdWindowStateMaximize = 1
   Set objWord = CreateObject("Word.Application")
   Set colTasks = objWord.Tasks
   Set shell = createobject("wscript.shell")

'open Remote Assistance window
   shell.run "hcp://CN=Microsoft%20Corporation,L=Redmond,S=Washington," _
     & "C=US/Remote%20Assistance/Escalation/Unsolicited/unsolicitedrcui.htm"

Do Until (colTasks.Exists("Help and Support Center") Or counter = 60)
       WScript.Sleep 500
       counter = counter + 1
       Set colTasks = objWord.Tasks
   Loop

'wait for program window to open - this time varies from PC to PC,
     'and may be much quicker if the program is already cached in memory
   If colTasks.Exists("Help and Support Center") Then
       WScript.Sleep 1000
       WScript.Echo "It exists " & counter & vbcrlf
       colTasks("Help and Support Center").Activate
       'colTasks("Help and Support Center").WindowState = wdWindowStateMaximize
  Else
      MsgBox "Remote Assistance Window Failed to Open", 0, "Remote Failed"
      WScript.Quit
  End If

prompt=msgBox("Click OK, then verify the name of the logged-in user " _
    & "and click Connect.",1+64+4096,"Verify Username")
  if prompt = 2 Then WScript.Quit
  If colTasks.Exists("Help and Support Center") Then
      colTasks("Help and Support Center").Activate
        'Do send keys here
        'paste computername into active field
      shell.sendkeys computer

'send "alt-c" (press the _C_onnect button)
      shell.sendkeys "%c"
  Else
      MsgBox "Remote Assistance Window Failed to Open", 0, "Remote Failed"
  End If
End Sub

'******************************************************************************

< Message edited by itismike -- 8/2/2007 4:48:26 AM >

Revisions: 5 | Post #: 1

RE: Fix Remote Assistance w/o Domain rights - 8/2/2007 4:51:00 AM

itismike

Posts: 42
Score: 0
Joined: 7/7/2007
Status: offline

Several edits later, and after some help from Rischip, it's working better.

-Mike

(in reply to itismike)

Post #: 2

RE: Fix Remote Assistance w/o Domain rights - 8/11/2007 10:44:24 PM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

Hi itsmike,

I saw your script which made me think of posting my Remote Assistance script, hope you find it interesting.
http://www.visualbasicscript.com/m_50614/tm.htm

(in reply to itismike)

Revisions: 1 | Post #: 3

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> Fix Remote Assistance w/o Domain rights

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts