FileMagic Class - all-purpose file handler

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

FileMagic Class - all-purpose file handler

Logged in as: Guest

arrSession:exec spGetSession 2,16,50324

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> FileMagic Class - all-purpose file handler
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

FileMagic Class - all-purpose file handler - 8/2/2007 8:14:29 PM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

This is still a work in progress and I suspect I'll add stuff to it as I think of it. If you've any suggestions, post them there and I'll try to add them

Anyway, what is it? FileMagic is designed to be a general, all-purpose class for handling text files. All those common things you do with them are now bundled together in a single class.

'*****************************************************************************************************
'    Name:             FileMagic
'    Author:         M. Williams
'    Date Created:    03/08/07
'    Version:        1.21
'    Purpose:        FileMagic is designed to be an all-purpose class for handling text files
'
'    Input paramters: 
'        FileName = Full path of file to be used with Class
'        Delimiter = Delimiter used when splitting the file
'
'    Revision History:
'        03/08/07 - MWI - Initial Creation
'        03/08/07 - MWI - Some error checking added.  Rename function added
'        03/09/07 - MWI - FindLine function added
'        04/09/07 - MWI - TotalLines function added
'
'
'    Comments:
'        Thanks to everyone on VisualBasicScript.com for their input
'        TrimWS function courtesy of ehvbs
'*****************************************************************************************************

Class FileMagic
   Dim objFSO
      
   'Define our private variables.  Private variables are only seen by the Class
   Private int_File
   Private int_delimiter
   
   'Define the public properties of the Class
   Public Property Let FileName (ByVal val)
       int_File = val
   End Property
   
   Public Property Get FileName    
       FileName = int_File
   End Property
   
   Public Property Let Delimiter (ByVal val)
       int_delimiter = val
   End Property
   
   Public Property Get Delimiter    
       Delimiter = int_delimiter
   End Property
   
   Private Sub Class_Initialize()
       Set objFSO = CreateObject("Scripting.FileSystemObject")
   End Sub
   
   Public Function ReadAll
   'Reads in the complete file to a string variable.
       Const ForReading = 1
       ReadAll=trimWS(objFSO.OpenTextFile(FileName,ForReading).ReadAll)
   End Function
   
   Public Function ToArray
   'Splits the contents of the ReadAll function to an Array based on the delimiter property
       ToArray = Split(ReadAll,Delimiter)
   End Function
   
   Public Function TotalLines
   'Returns the total number of lines
       tempArray = ToArray
       TotalLines = "There are " & UBound(tempArray) + 1  & " lines in the file"
   End Function
   
   Public Function GetLastLine
   'Returns the last line of the text file
       tempArray = ToArray
       GetLastLine = tempArray(UBound(tempArray))
   End Function
   
   Public Function GetFirstLine
   'Returns the first line of the text file
       tempArray = ToArray
       GetFirstLine = tempArray(0)
   End Function    
   
   Public Function GetSpecificLine(linenum)
   'Returns a specific line of the text file.  As it uses the array (which is zero-based)
   'you will need to specify the actual line number - 1 (e.g. to return line 5, linenum should be 4)
       tempArray = ToArray
       GetSpecificLine = tempArray(linenum)
   End Function
   
   Public Function FindLine(strFind)
     'Returns the firest line containing the search string strFind
        Dim oRE  : Set oRE = New RegExp
        Dim strTxtJoined
        oRE.Pattern = "\r\n"
        oRE.Global  = True
        strTxtJoined=Join(ToArray,vbcrlf)
       Dim oMTS : Set oMTS = oRE.Execute( Left( strTxtJoined, InStr( strTxtJoined, strFind ) ) )
       If oMTS.Count > 0 Then
            findLine = strFind & " found at line " & oMTS.Count + 1
        Else
            FindLine = strFind & " was not found"
        End If
   End Function
   
   Public Function RemoveDuplicateLines
   'Removes duplicate lines from the text file
       tempArray = ToArray
       Set objDict = CreateObject("Scripting.Dictionary")
       For Each line In temparray
           If Not objDict.Exists(line) Then
               objDict.Add line,line
           End If
       Next
       RemoveDuplicateLines = Join(objDict.Keys,VbCrLf)
   End Function
   
   Public Function Search(SearchText)
   'Searches the text file for the string SearchText (e.g. Search (XYZ))
       Set objRegEx = CreateObject("VBScript.RegExp")
       objRegEx.Global = True   
       objRegEx.Pattern = SearchText
       
       tempArray = ToArray
       linenum = 1
       For Each line In tempArray
           Set colMatches = objRegEx.Execute(line)    
           If colMatches.Count > 0 Then           
                  For Each strMatch in colMatches   
                      strMessage = strMessage &  strMatch.Value & " was found at position " & strMatch.FirstIndex & " on line " & linenum  & VbCrLf
               Next
           End If
           linenum = linenum + 1
       Next
           Search = strMessage
   End Function
   
   Public Sub FindAndReplace(FindText,ReplaceText)
   'Replaces the string FindText with the string ReplaceText throughout the file
       Const ForWriting = 2
       strNewText     = Replace(ReadAll, FindText, ReplaceText)
       Set objFile = objFSO.OpenTextFile(FileName, ForWriting)
       objFile.WriteLine strNewText
       objFile.Close
   End Sub                
   
   Public Sub CopyTo (Destination)
       objFSO.CopyFile FileName,Destination,True
   End Sub
   
   Public Sub MoveTo (Destination)
       If Not objFSO.FileExists(Destination) Then
           objFSO.MoveFile FileName,Destination
       Else
           WScript.Echo "A file with the same name already exists at that location"
       End If
   End Sub
   
   Public Sub Rename (RenamedFileName)
   'Renames the file to filename specified by RenamedFileName
       Set objFile = objFSO.GetFile(FileName)
       If objFile.ShortName <> RenamedFileName Then
           objFile.Name = RenamedFileName
       Else
           WScript.Echo "File cannot be renamed to the same name."
       End If
   End Sub
   
   Public Sub Delete
       objFSO.DeleteFile FileName,True
   End Sub
   
   Private Function trimWS(sTxt)
       Dim oRE : Set oRE = New RegExp
       oRE.Pattern =  "(^\s+)|(\s+$)"
       oRE.Global  = True
       trimWS      = oRE.Replace( sTxt, "" )
   End Function    
       
   Private Sub Class_Terminate()
       'Destroys the objects created in the intialize event
       Set objFSO = Nothing
   End Sub

End Class

'Create a new instance of the class and assign the various properties
Dim myFileMagic
Set myFileMagic = New FileMagic

myFileMagic.FileName = "C:\temp\test.txt"
myFileMagic.Delimiter = VbCrLf

For Each line In myFileMagic.ToArray
   WScript.Echo line
Next
WScript.Echo myFileMagic.TotalLines
WScript.Echo myFileMagic.FindLine("foo")
WScript.Echo myFileMagic.FindAndReplace("foo","XXX")
WScript.Echo myFileMagic.Search("foo")
Wscript.Echo myFileMagic.GetFirstLine
Wscript.Echo myFileMagic.GetLastLine
Wscript.Echo myFileMagic.GetSpecificLine(1)
WScript.Echo myFileMagic.RemoveDuplicateLines
myFileMagic.CopyTo("C:\temp\Crack\")
myFileMagic.MoveTo("C:\temp\Crack\test.txt")
myFileMagic.Rename("test.txt")
myFileMagic.Delete

< Message edited by ginolard -- 9/3/2007 10:50:33 PM >

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

Revisions: 5 | Post #: 1

RE: FileMagic Class - all-purpose file handler - 8/3/2007 8:16:04 AM

CondoPC

Posts: 118
Score: 0
Joined: 7/23/2007
Status: offline

the only thing I can think of is adding comment to the functions specifying what the input and output is.

(in reply to ginolard)

Post #: 2

RE: FileMagic Class - all-purpose file handler - 8/6/2007 8:14:18 PM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

Updated with comments and examples

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to CondoPC)

Post #: 3

RE: FileMagic Class - all-purpose file handler - 9/3/2007 1:10:01 AM

ginolard

Posts: 1021
Score: 21
Joined: 8/10/2005
Status: offline

updated with a modified version of ehvbs's FindLine function

_____________________________

Author of ManagePC - http://managepc.net
AD Query Template - http://www.visualbasicscript.com/m_40609/tm.htm
Consolidated Scripting Framework - http://www.visualbasicscript.com/m_59109/tm.htm

(in reply to ginolard)

Post #: 4

If you found our site useful please link to us <a href="http://www.visualbasicscript.com">VisualBasicScript.com</a>.

All Forums >> [Scripting] >> Post a VBScript >> FileMagic Class - all-purpose file handler

Page: [1]

Jump to:

New Messages	No New Messages
Hot Topic w/ New Messages	Hot Topic w/o New Messages
Locked w/ New Messages	Locked w/o New Messages

Post New Thread

Reply to Message

Post New Poll

Submit Vote

Delete My Own Post

Delete My Own Thread

Rate Posts