Dell Info

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Dell Info

Logged in as: Guest

arrSession:exec spGetSession 2,16,50755

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Dell Info
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Dell Info - 8/15/2007 4:48:32 AM

DiGiTAL.SkReAM

Posts: 1056
Score: 6
Joined: 9/6/2005
From: Florida, USA
Status: offline

For those of you out there that are admin'ing Dell servers or workstations, here is a function that will run against netbios names that, if you have admin priv. on the target computer, give you the service tag AND Express Service Code of the server/workstation in question.

Function fGetDellTagCode(sComputer)
'Returns an array containing the Dell Service Tag and Express Service Code of the computer
'named in the argument.
Dim J, K, iDecimalValue, X, sTagLength, sBaseNumericData, sServiceCode
Set oWMI = GetObject("winmgmts:\\" & sComputer & "\root\cimv2")
Set cItems = oWMI.ExecQuery("Select * from Win32_BIOS",,48)
 For Each oItem In cItems
  sServiceTag = oItem.SerialNumber
 Next
sBaseNumericData = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
'Convert sInput to Base 10
sTagLength = Len(sServiceTag)
iDecimalValue = 0
 For J = 1 To sTagLength
   For K = 1 To 36
     If Mid(sServiceTag, J, 1) = Mid(sBaseNumericData, K, 1) Then
      iDecimalValue = iDecimalValue + Int((K - 1) * (36^(sTagLength - J)) + .5)
     End If
   Next
 Next
sServiceCode = ""
 While iDecimalValue > 0
  X = Int(((iDecimalValue / 10) - Int(iDecimalValue / 10)) * 10 + 1.5)
  sServiceCode = Mid(sBaseNumericData, X, 1) & sServiceCode
  iDecimalValue = Int(iDecimalValue / 10)
 Wend
fGetDellTagCode = Array(sServiceTag,sServiceCode)
End Function

_____________________________

"There's the one man who learns by reading, the two men that learn by watching, and the rest of us have to pee on the electric fence for ourselves." - Roy Rogers

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

Post #: 1

RE: Dell Info - 8/15/2007 7:27:54 PM

gdewrance

Posts: 586
Score: 3
Joined: 3/16/2006
Status: offline

When Dell had the bad battery recall, Iused the following to get the Laptops information

Option Explicit 
dim oWMI, fso
Dim HW, HW2, instance, item, bversion
Dim  strComputer,strManufacturer,strModel,strBios,strserial
Dim BadList
Dim colBatteries, oBattery
Dim bFound, strMessage, iButtons, message
Dim bBatch
'****************************************************************************
'Run this script once to record all computers
Dim varToday, Verify, DellBattery, LastRun
Set WshShell = CreateObject("Wscript.Shell")

varToday = DellBattery

Verify = "HKLM\SOFTWARE\MyInstallsAndFixes\"

'Check if scan has run today and if so exit
On Error Resume Next
LastRun = WshShell.RegRead(Verify & "DellBattery")
If Err.Number = 0 Then
   WScript.Quit
Else
  WshShell.RegWrite Verify & "DellBattery", 0,"REG_DWORD"
End If
On Error GoTo 0 'This turns on error handling
'******************************************************************************
bBatch = True
bFound = False
Dim WshShell
Set WshShell = WScript.CreateObject("WScript.Shell")
dim quote, strArgs, i
quote=chr(34)
iButtons = 64 'vbinformation + vbOKOnly
BadList = Array("3K590","59474","6P922","C2603","C5339","C5340","C5446","C6269", _
"C6270",  "D2961","D5555","D6024","D6025","F2100","F5132","GD785","H3191","JD616", _ 
"JD617","KD494","M3006","RD857","TD349","U5867","U5882","W5915","X5308","X5329", _ 
"X5332","X5333","X5875","X5877","Y1333","Y4500","Y5466")
'On Error Resume Next

If WScript.Arguments.Count = 1 Then
strComputer = WScript.Arguments(0)
bBatch = True

If (Not IsCScript()) Then   'If not CScript, re-run with cscript...
For i  = WScript.Arguments.Count -1 to  0 Step -1
strArgs = WScript.Arguments(i) & Space(1) &  strArgs
Next

WshShell.Run "CScript.exe " & quote & WScript.ScriptFullName & quote & space(1) & strArgs, 1, true
  WScript.Quit             '...and stop running as WScript
End If

Else
strComputer = "."

End If 
If strcomputer = "" Then WScript.Quit
strComputer = UCase(strComputer)
'If bBatch Then 'If you got computername from command line, log results
Dim bHeader,logfile,appendout
'logfile = wshShell.ExpandEnvironmentStrings("%userprofile%") & "\desktop\DellBatteries.csv" 
logfile = "\\Server\share\DellBatteries.csv"

Const ForAppend = 8
Set fso = CreateObject("Scripting.FileSystemObject")
If Not fso.FileExists(logfile) then bHeader = True
Set appendout = fso.OpenTextFile(logfile, ForAppend, True)
If bHeader Then appendout.WriteLine "System,Man.,Model,BIOS,SN,Bat. DevID,Bat. Name,Message" 'Header only if new file
'End If 
Set oWMI = GetObject("winmgmts://"& strComputer)
If Err <> 0 Then
iButtons = 16
echoandlog ",,,,,,Failed:" & Err.Description 
WScript.Quit
End If
'HWInfo
Set HW = oWMI.ExecQuery("select Manufacturer,Model from Win32_ComputerSystem")
For each instance in HW
strManufacturer = trim(Instance.Manufacturer)
strModel = trim(Instance.Model)
strComputer = instance.name
Next
Set HW2 = oWMI.ExecQuery("select name,Version,SerialNumber from Win32_BIOS")
For each item in HW2 'not all manufacturers make this info available
if item.name = "Default System BIOS" then 
Bversion = trim(item.Version)
else
Bversion = item.name & " " & trim(item.Version)
End If

strBios = bversion
strSerial = trim(Item.SerialNumber)
Next

message = strManufacturer & ","  & strModel & "," & _
strBios & ","  & strserial 
Set colBatteries = oWMI.ExecQuery("SELECT deviceid, Name FROM Win32_Battery", ,48)

For Each oBattery In colBatteries
 check oBattery.Name, oBattery.DeviceID
Next
If Not bFound Then strMessage =  ",,No battery found"
If iButtons = 64 and bFound Then strMessage = strMessage & "Battery okay"
message = message & "," & strMessage 
echoandlog message
Set oWMI = Nothing
Set fso = Nothing
Set WshShell = Nothing
' Functions and subs 
Sub Check(strName, strID)
Dim i
bFound = True
strMessage =  strID & "," & strName & ","

For i = 0 To UBound(Badlist)
If instr(ucase(strName),badlist(i)) > 0  Then 
iButtons = 16
strMessage = strMessage & "This battery needs to be replaced!"  
End If 
Next
End Sub

Sub EchoAndLog (message)
Dim tArray
If bBatch = true Then
'Echo output and write to Log
message = strComputer & "," & message 
'Wscript.Echo message
AppendOut.WriteLine message
Else
tArray = Split(message,",")
message = "Man.:" & vbTab & tArray(0) & VbCrLf & _
"Model:" & vbTab & tArray(1) & VbCrLf & _
"BIOS:" & vbTab & tArray(2) & VbCrLf & _
"SN:" & vbTab & tArray(3) & VbCrLf

If UBound(tarray) >= 4 Then  
message = message & "DevID:" & vbTab & tArray(4) & VbCrLf
End If

If UBound(tarray) >= 5 Then  
message = message & "Name:" & vbTab & tArray(5) & VbCrLf 
End If

If UBound(tarray) >= 6 Then    
message = message & "Message:" & vbTab & tArray(6)
End If

MsgBox message, iButtons,strcomputer
End If 
End Sub

and for a quick Tag

(in reply to DiGiTAL.SkReAM)

Post #: 2

RE: Dell Info - 3/25/2008 4:24:41 PM

DiGiTAL.SkReAM

Posts: 1056
Score: 6
Joined: 9/6/2005
From: Florida, USA
Status: offline

Here's an HTA that I made that will look up the Service Tag and Express Service Code, or it will convert Service Tag to / from the Express Service Code.
I had to modify a VB.NET subroutine that I found to create the convert base36 to base10 functionality.

Don't hammer on it too hard, it is the first HTA that I've written in months, so I'm a bit rusty.

<html>
<head>
<title>Dell Service Tag Finder v1.00</title>
<script language="vbscript">

Dim oShell, oFSO, oEnv, oNet
Set oShell = CreateObject("Wscript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oEnv = oShell.Environment("Process")
Set oNet = CreateObject("WScript.Network")
Window.ReSizeTo 683, 400
Sub Window_OnLoad
End Sub 
Sub Main
End Sub 
Sub Query
Dim sTargetComputer, objWMIService, colItems, objItem
sTargetComputer = ComputerNameArea.Value
If Trim(sTargetComputer) = "" Then sTargetComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & sTargetComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_BIOS",,48)
For Each objItem in colItems
  If InStr(UCase(objItem.Manufacturer),"DELL") <> 0 Then
   GetDellTagCode sTargetComputer 
  Else
    If sTargetComputer = "." Then sTargetComputer = oNet.ComputerName
   MsgBox sTargetComputer & " is not a Dell or you do not have sufficient access to the computer."
   ServiceTagArea.Value = ""
   ExpressServiceCodeArea.Value = ""
  End If 
Next
End Sub
Sub GetDellTagCode(sComputer)
'Returns an array containing the Dell Service Tag and Express Service Code of the computer
'named in the argument.
Dim J, K, iDecimalValue, X, sTagLength, sBaseNumericData, sServiceCode
Dim oWMI, cItems, oItem, sServiceTag
Set oWMI = GetObject("winmgmts:\\" & sComputer & "\root\cimv2")
Set cItems = oWMI.ExecQuery("Select * from Win32_BIOS",,48)
For Each oItem In cItems
 sServiceTag = oItem.SerialNumber
Next
sBaseNumericData = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
'Convert sInput to Base 10
sTagLength = Len(sServiceTag)
iDecimalValue = 0
For J = 1 To sTagLength
  For K = 1 To 36
    If Mid(sServiceTag, J, 1) = Mid(sBaseNumericData, K, 1) Then
     iDecimalValue = iDecimalValue + Int((K - 1) * (36^(sTagLength - J)) + .5)
    End If
  Next
Next
sServiceCode = ""
While iDecimalValue > 0
 X = Int(((iDecimalValue / 10) - Int(iDecimalValue / 10)) * 10 + 1.5)
 sServiceCode = Mid(sBaseNumericData, X, 1) & sServiceCode
 iDecimalValue = Int(iDecimalValue / 10)
Wend
ServiceTagArea.Value = sServiceTag
ExpressServiceCodeArea.Value = Left(sServiceCode,3) & "-" & Mid(sServiceCode,4,3) & "-" & Mid(sServiceCode,7,3) & "-" & Right(sServiceCode,2)
End Sub
Sub Convert
Dim sTag, sCode
sTag = STagArea.Value
sCode = ESCodeArea.Value
Select Case True
Case Trim(sTag) <> "" And Trim(sCode) = ""
 ConvertTag sTag 
Case Trim(sTag) = "" And Trim(sCode) <> ""
 ConvertCode sCode  
Case Trim(sTag & sCode) = ""
 MsgBox "You need to fill in either a Service Tag or an Express Service Code before clicking Convert."
 ServiceTagArea.Value = ""
 ExpressServiceCodeArea.Value = ""
Case Trim(sTag) <> "" And Trim(sCode) <> ""
 MsgBox "You need to fill in either a Service Tag or an Express Service Code before clicking Convert." & VbCrLf & "NOT both."
 STagArea.value = ""
 ESCodeArea.Value = ""
Case Else 
End Select
End Sub
Sub ConvertTag(sServiceTag)
Dim sBaseNumericData, sTagLength, iDecimalValue, J, K, X, sServiceCode
sBaseNumericData = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
sTagLength = Len(sServiceTag)
iDecimalValue = 0
For J = 1 To sTagLength
  For K = 1 To 36
    If Mid(sServiceTag, J, 1) = Mid(sBaseNumericData, K, 1) Then
     iDecimalValue = iDecimalValue + Int((K - 1) * (36^(sTagLength - J)) + .5)
    End If
  Next
Next
sServiceCode = ""
While iDecimalValue > 0
 X = Int(((iDecimalValue / 10) - Int(iDecimalValue / 10)) * 10 + 1.5)
 sServiceCode = Mid(sBaseNumericData, X, 1) & sServiceCode
 iDecimalValue = Int(iDecimalValue / 10)
Wend
If Len(sServiceCode) = 11 Then 
 ServiceTagArea.Value = sServiceTag
 ExpressServiceCodeArea.Value = Left(sServiceCode,3) & "-" & Mid(sServiceCode,4,3) & "-" & Mid(sServiceCode,7,3) & "-" & Right(sServiceCode,2)
 STagArea.value = ""
 ESCodeArea.Value = ""
Else 
 MsgBox "Please enter a valid Service Tag."
 ServiceTagArea.Value = ""
 ExpressServiceCodeArea.Value = ""
End If 
End Sub
Sub ConvertCode(iBase10Number)
Dim sText, iTemp, iCount, iLast, iBaseSize, sNewBaseChars, bGood, i
Dim iInitialCode, iInitialCode2
bGood = False  
If Len(Replace(iBase10Number,"-","")) = 11 Then
 bGood = True 
  For i = 97 To 122
    If InStr(UCase(iBase10Number),Chr(i)) <> 0 Then
     bGood = False 
    End If 
  Next 
End If 
If bGood = False Then 
 MsgBox "Express Service Code should be a sequence of 11 numbers."
 ServiceTagArea.Value = ""
 ExpressServiceCodeArea.Value = ""
 Exit Sub
End If 
sNewBaseChars = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
iBaseSize = Len(sNewBaseChars)
iInitialCode = Replace(iBase10Number,"-","")
iInitialCode2 = Replace(iBase10Number,"-","")
Do While iInitialCode <> 0
 iTemp = iInitialCode
 iCount = 0
  Do While iTemp >= iBaseSize
   iCount = iCount + 1
   iTemp = iTemp / iBaseSize
  Loop
  If iCount <> iLast - 1 And iLast <> 0 Then sText = sText & String(iLast - iCount - 1, Left(sNewBaseChars, 1))
 iTemp = Int(iTemp)
 sText = sText + Mid(sNewBaseChars, iTemp + 1, 1)
 iInitialCode = iInitialCode - iTemp * (iBaseSize ^ iCount)
 iLast = iCount
Loop
sText = sText & String(iCount, Left(sNewBaseChars, 1))
ServiceTagArea.Value = sText 
ExpressServiceCodeArea.Value = Left(iInitialCode2,3) & "-" & Mid(iInitialCode2,4,3) & "-" & Mid(iInitialCode2,7,3) & "-" & Right(iInitialCode2,2)
STagArea.value = ""
ESCodeArea.Value = ""
End Sub

</script>
<HTA:APPLICATION
applicationname="Dell Service Tag Finder" 
border="no"
borderstyle="normal"
caption="Dell Service Tag Finder"
contextmenu="no"
icon="explorer.exe"
maximizebutton="no"
minimizebutton="yes"
navigable="no"
scroll="no"
selection="yes"
showintaskbar="yes"
singleinstance="no"
sysmenu="yes"
version="1.0"
windowstate="normal"
>
</HEAD>
<BODY style="font-family: verdana;font-size=12px;font-weight: bold;filter:progid:DXImageTransform.Microsoft.Gradient(endColorstr='#878787', startColorstr='#d9d9d9', gradientType='0');"> 

<STYLE>
input.button{cursor:hand;filter:progid:DXImageTransform.Microsoft.Gradient(GradientType=0,StartColorStr='#ffffffff',EndColorStr='#ffcccccc');font-weight: bold;font-size: 12px;font-family: verdana;}
</STYLE>
<div style="width: 650px;">
<center><FIELDSET>
<LEGEND align="center" style="font-weight: bold;">QUERY SERVICE TAG & EXPRESS SERVICE CODE</LEGEND><br>
Please enter the NETBIOS name of the computer to query<br>(Leave blank for this computer) : <input type="text" name="ComputerNameArea" size="30"><br><br>
<center><input id=querybutton  class="button" type="button" value="Run Query" name="run_query"  onClick="Query"></center>
</FIELDSET>
<BR>
<FIELDSET>
<LEGEND align="center" style="font-weight: bold;">CONVERT SERVICE TAG TO/FROM EXPRESS SERVICE CODE</LEGEND><br>
Please enter the known Service Tag you wish to convert : <input type="text" name="STagArea" size="10"><br>
Please enter the known Express Service Code you wish to convert : <input type="text" name="ESCodeArea" size="20"><br><br>
<center><input id=convertbutton  class="button" type="button" value="Convert" name="run_convert"  onClick="Convert"></center>

</FIELDSET>
<BR>
<FIELDSET>
<LEGEND align="center" style="font-weight: bold;">RESULTS</LEGEND><br>
<center>Service Tag : <textarea id="ServiceTagArea" rows="1" readonly="yes" cols="10" style="font-weight: bold;"></textarea></center>
<center>Express Service Code :<textarea id="ExpressServiceCodeArea" rows="1" readonly="yes" cols="20" style="font-weight: bold;"></textarea></center>
</FIELDSET></center>
</BODY>
</HTML>

Thumbnail Image

Attachment (1)

_____________________________

"There's the one man who learns by reading, the two men that learn by watching, and the rest of us have to pee on the electric fence for ourselves." - Roy Rogers

"Would you like to touch my monkey?" - Dieter (Mike Meyers)

(in reply to gdewrance)