Convert ANSI txt file to UTF-8 txt file

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Convert ANSI txt file to UTF-8 txt file

Logged in as: Guest

arrSession:exec spGetSession 2,2,50788

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> Convert ANSI txt file to UTF-8 txt file
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Convert ANSI txt file to UTF-8 txt file - 8/16/2007 1:28:18 AM

cmc

Posts: 13
Score: 0
Joined: 5/30/2007
Status: offline

Hi,

I'm working on the following script to convert ANSI to UTF-8, at present the below works for ASCII to unicode,
any ideas how to alter this for ANSI to UTF-8

thanks

' working for ASCII to Unicode
Const ForReading = 1
Const TriStateTrue = -1
Const ForWriting = 2

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("c:\cmc\VBscript\test33.txt", ForReading,False,TriStateTrue)
strText = objFile.ReadAll
Set objFile = objFSO.OpenTextFile("c:\cmc\VBscript\test45.txt", ForWriting,False,TriStateTrue)
objFile.WriteLine strText

objFile.Close
Wscript.Echo strText

Post #: 1

RE: Convert ANSI txt file to UTF-8 txt file - 8/16/2007 2:09:26 AM

ehvbs

Posts: 2223
Score: 50
Joined: 6/22/2005
From: Germany
Status: offline

Hi cmc,

you can't use the FileSystemObject for that; an ADODB.Stream may do what you want:

Const adTypeBinary = 1
 Const adTypeText   = 2
 Const bOverwrite   = True
 Const bAsASCII     = False

Dim oFS     : Set oFS    = CreateObject( "Scripting.FileSystemObject" )

Dim sTxt    : sTxt       = "a�o�u�"
 Dim sFiNa   : sFiNa      = ".\convcs"
 Dim oFrom   : Set oFrom  = CreateObject( "ADODB.Stream" )
 Dim sFrom   : sFrom      = "Windows-1252"
 Dim sFFSpec : sFFSpec    = oFS.GetAbsolutePathName( sFiNa & "-cp1252.txt" )
 Dim oTo     : Set oTo    = CreateObject( "ADODB.Stream" )
 Dim sTo     : sTo        = "utf-8"
 Dim sTFSpec : sTFSpec    = oFS.GetAbsolutePathName( sFiNa & "-utf8.txt" )

If oFS.FileExists( sTFSpec ) Then oFS.DeleteFile sTFSpec

oFS.CreateTextFile( sFFSpec, bOverwrite, bAsASCII ).WriteLine sTxt

oFrom.Type    = adTypeText
 oFrom.Charset = sFrom
 oFrom.Open
 oFrom.LoadFromFile sFFSpec
 WScript.Echo oFrom.Size & " Bytes in " & sFFSpec

oTo.Type    = adTypeText
 oTo.Charset = sTo
 oTo.Open
 oTo.WriteText oFrom.ReadText
 WScript.Echo oTo.Size & " Bytes in " & sTFSpec
 oTo.SaveToFile sTFSpec

oFrom.Close
 oTo.Close

(in reply to cmc)