I need the following script...

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

I need the following script...

Logged in as: Guest

arrSession:exec spGetSession 2,2,51045

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> WSH & Client Side VBScript >> I need the following script...
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

I need the following script... - 8/22/2007 4:39:45 AM

wsmoth

Posts: 2
Score: 0
Joined: 8/22/2007
Status: offline

I currently have a Kixtart script that we use after a patching window that does the following five things:

It uses an input file will the names of all the servers we patched.
It pings the server until it responds from the reboot.
It then does a net view to the server to enumerate the shares. If the enumeration succeeds, it continues, if it fales, it writes it to a log.
It reports how long the server has been up.
It check which services start automatically and if they start autmatically if they are started. If they are not, it writes it to a log.

My company wants to move away from Kixtart to vbscript. I do not have the skill to do this in vb, could someone help me?

Here is the script in Kix:

Break On CLS Del '%windir%\RebootCheckError.log' Del '%Windir%\RebootCheck.log' Del '%windir%\RebootCheckServices.log' $Error = "N" $LoggedErrorOnce = "N" ;********************** ; ; Main ; ;********************** :Main If Open(1,"c:\servers.txt") = 0 $Server = ReadLine(1) While @ERROR = 0 $Continue = "Y" $LogText = "@CRLF------------------------------------------------------------@CRLFChecking $Server started @Date @Time@CRLF------------------------------------------------------------" Gosub LogIt Gosub PingTest If $Continue = "Y" Gosub NetView EndIf If $Continue = "Y" Gosub Uptime EndIf If $Continue = "Y" Gosub CheckServices EndIf $LoggedErrorOnce = "N" $Server = ReadLine(1) Loop $CloseFile = Close(1) EndIf Gosub Results Quit ;********************** ; ; Ping Test ; ;********************** :PingTest ? "Pinging $Server....@CRLF@CRLF" Shell '%Comspec% /c Ping $Server -n 3 |find /I "Reply from"' If @ERROR = 0 $LogText = "PING RESULT - Ping successful" $Continue = "Y" Else If $LoggedErrorOnce = "N" Shell '%Comspec% /c Echo $Server - Ping failed.>>%windir%\RebootCheckError.log' $LoggedErrorOnce = "Y" EndIf $Error = "Y" $LogText = "PING RESULT - Ping failed." $Continue = "N" EndIf Gosub LogIt Return ;********************** ; ; Net View Test ; ;********************** :NetView ? "@CRLF@CRLFNet viewing $Server...@CRLF@CRLF" Shell '%Comspec% /c Net View \\$Server' If @ERROR = 0 $LogText = "NET VIEW RESULT - Net View successful" $Continue = "Y" Else If $LoggedErrorOnce = "N" Shell '%Comspec% /c Echo $Server - Net view failed>>%windir%\RebootCheckError.log' $LoggedErrorOnce = "Y" EndIf $Error = "Y" $LogText = "NET VIEW RESULT - Net view failed" $Continue = "N" EndIf Gosub LogIt Return ;********************** ; ; Uptime ; ;********************** :Uptime ? "@CRLF@CRLFQuerying uptime for $Server...@CRLF" $LogText = "UPTIME RESULT - " Gosub LogIt Shell '%Comspec% /c Uptime >%windir%\RebootCheck.Log'">\\$Server>>%windir%\RebootCheck.Log' Shell '%Comspec% /c Uptime \\$Server' Return ;********************** ; ; Check Services ; ;********************** :CheckServices $objWMIService = GetObject("winmgmts:\\"+ $Server + "\root\cimv2") $colItems = $objWMIService.ExecQuery("Select * from Win32_Service") For Each $objItem in $colItems ? "Checking Service - " + $objItem.Name If $objItem.StartMode = "Auto" ? " " + $objItem.Name + " is set to auto, querying status..." If $objItem.State <> "Started" And $objItem.State <> "Running" $LogText = "SERVICE CHECK - " + $objItem.DisplayName + " - NOT STARTED!!!" Gosub LogIt $Error = "Y" Shell '%Comspec% /c Echo $Server - SERVICE ' + $objItem.DisplayName + ' - NOT STARTED!!!>>%windir%\RebootCheckError.log' Else ; $LogText = " Started - "+ $objItem.DisplayName EndIf Else ? " " + $objItem.Name + " not set to auto, skipping." EndIf Next Return ;********************** ; ; Results ; ;********************** :Results If $Error = "Y" $Msg = MessageBox("One or more errors were encountered on one or more servers.@CRLF@CRLFTwo log files have been created:@CRLF - RebootCheck.Log - Contains a list of all output from tests.@CRLF - RebootCheckError.Log - A list of servers that an error was produced on@CRLF@CRLFLogs are located at %windir%\RebootCheck.log and %windir%\RebootCheckError.log.","Errors encountered.",48) Run '%Comspec% /c Notepad %windir%\RebootCheck.log' Run '%Comspec% /c Notepad %windir%\RebootCheckError.log' Else $Msg = MessageBox("No errors were encountered. Opening %windir%\RebootCheck.log.","No Errors",64) Run '%Comspec% /c Notepad %windir%\RebootCheck.log' EndIf Return ;********************** ; ; Logging ; ;********************** :LogIt $Log = RedirectOutput("%Windir%\RebootCheck.log") ? "$LogText" $Log = RedirectOutput("") ? "$LogText" Return

//EDIT: Added code blocks - dm_4ever

Thanks in advance all!

< Message edited by dm_4ever -- 8/22/2007 3:18:19 PM >

Post #: 1

RE: I need the following script... - 8/22/2007 6:01:03 AM

LANlazy

Posts: 82
Score: 0
Joined: 4/11/2007
Status: offline

Please read the "Read Me First" on this forum. Below is a quote from that page.

quote:

We are not here to write scripts for you, we can fully support you in you writing your scripts. If you make the attempt and are still having issues, we can and will gladly
help you out, you can Search our site for up-to-date information on retrieving objects from AD, read/write to the registry, etc...

If you have searched and still can't find what you are looking for, then make sure you include what you have searched for in your post, it will both show that you have made
the attempt, which will prevent the "Search first" posts and possibly someone can help refine your search terms to help you find the post you are looking for.

(in reply to wsmoth)

Post #: 2

RE: I need the following script... - 8/23/2007 12:48:44 AM

gdewrance

Posts: 587
Score: 3
Joined: 3/16/2006
Status: offline

here is a script I used to use check servers.

'========================
 '
 ' Title: Server Check Script
 '
 ' Filename: servchk.vbs
 ' Author: Leslie Maclachlan
 ' Modified by: Ariston Collander, Cox Computer Service
 ' Modified beyond all recognition by: Rob Dunn
 '
 '========================
 On Error GoTo 0
 '==System variables - dont change==
 Const HKEY_LOCAL_MACHINE = &H80000002
 Const ForWriting = 2
 Const ForReading = 1
 Const ForAppending = 8
 Const cdoSendUsingMethod = "http://schemas.microsoft.com/cdo/configuration/sendusing", _
 cdoSendUsingPort = 2, _
 cdoSMTPServer = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
 
 Dim strScriptPath, strMessage, Count, strBgcolor, IntDebug, blnErrors, strMsg, objargs, strWarnings
 Dim blnServices, blnDiskSpace, blnAV, blnEvents, strValue, blnSend, strComputer, StrComp, blnOnline
 Dim strReadFromFile, strEventCount, strSpace, strService, strAntiVirus, intVirusDefAge
 Dim summaryfile, intAV, l, ws, strSourceFile, strBootTime
 'below variables for progress indicators
 
 Dim objShell, objProcessEnv, objSystemEnv, objNet, objFso, objSwitches, WShSysEnv, WshShell
 Dim query, item, acounter, blnExtendedWMI, blnProcessEvents
 Dim dlgBarWidth, dlgBarHeight, dlgBarTop, dlgBarLeft, dlgProgBarWidth, dlgProgBarHeight
 Dim dlgProgBarTop, dlgProgBarLeft
 Dim dlgBar, dlgProgBar, wdBar, objPBar, objBar, blnSearchWildcard
 Dim blnProgressMode, blnDebugMode, dbgTitle
 Dim dbgToolBar, dbgStatusBar, dbgResizable
 Dim IE, objDIV, objDBG, strMyDocPath, strSubFolder, strTempFile, f1, ts, File2Load, objFlash
 Dim dbgWidth, dbgHeight, dbgLeft, dbgTop, dbgVisible, strDestFolder1, strHideRows, strDestFolder
 Dim strIPAddress
 
 Set WshShell = WScript.CreateObject("WScript.Shell")
 Set WshSysEnv = WshShell.Environment("PROCESS")
 Set objArgs = WScript.Arguments
 Set ws = wscript.CreateObject("Scripting.FileSystemObject")
 
 strScriptPath = replace(wscript.scriptfullname,"\" & wscript.scriptname,"")
 resultsfolder = strScriptPath & "\serverhealth\results"
 logfolder = strScriptPath & "\serverhealth\logs"
 logfile = logfolder & "\" & replace(Date,"/","_") & "-" & replace(Time,":","'") & " server health.txt"
 MakeSureDirectoryTreeExists(logfolder)
 'wscript.echo resultsfolder
 MakeSureDirectoryTreeExists(resultsfolder)
 Set l = ws.OpenTextFile (logfile, ForAppending, True)
 l.writeline "************************************************"
 l.writeline "Server Health script executed at " & Now
 
 'above variables for progress indicators
 
 IntDebug = 0
 
 
 '==Configure User defined Variables==
 CurrentDate = Now
 strMailto = "yourmail@.com"     
 'who are you mailing to? Input mode only. Command-line
 ' parameters take precedence
 
 strMailFrom = "serverhealth@.com"     'reply address
 strSMTPServer = "192.x.x.x"     'set SMTP email server address here
 
 SourceFile = "C:\servers.txt" 'list of your servers or write your own ping function
 'Where is the master list of servers being pulled from?
 ' For input mode only. Command-line parameters take precedence
 
 bgcolor0 = "white"        'Colors for computer health page
 bgcolor1 = "aliceblue"
 strSummaryFileName = "summary.htm"
 
 intAV = 0             '0 = McAfee VirusScan Enterprise
                 '1 = Norton Antivirus
                 '2 = Trend Officescan
                 'Need people to test this (NAV)
 'Event Log variable(s)
 IntDaysBack = 2 'how many days prior you would like to pull event log entries from
 
 strEventCount = 50        'Amount of events you want to count. If this number is
     ' exceeded, then the script will stop checking events and move on to the next
     ' server. This is useful if you have a LOT of errors, but want to quickly
     ' scan the servers without holding up the entire process. If you have more
     ' events that occurred in the last 2 days (for example) than what you have
     ' specified here, you will only see the most recent events that fall within
     ' this count.
 
 Set ws = CreateObject ("Scripting.FileSystemObject")
 Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
 Set objDictionary = CreateObject("Scripting.Dictionary")
 
 blnSendMail = false 'send individual mails for each server checked - server list mode only.
 blnCopyFile = true 'copy the summary files to a remote path - server list mode only.
 
 strDestFolder = "C:\serverhealth"
             ' add ---> & WeekdayName(weekday(now)) 'to retain daily backups
             ' This is the remote path to copy files to, when run against server
             ' list ONLY
 
 intFreeSpaceThreshold = 10 'set critical threshold for drive space (shows up in red if free
             'percentage is lower than this number)
 
 intVirusDefAge = 4     'set how many days back you might consider the virus definitions to be
             ' too old.
 
 blnSendSummary = true     'send a single summary email after everything is all done? (when running
              ' against server list ONLY
 
 strCheckAccount = ""     'type a string of text that you wish to check your services against.
                 ' for example, if you are phasing out old accounts or domains, the
                 ' script will generate an alert if it finds that a service is starting
                 ' with credentials that contain this string.
                 ' If you don't want to process this value, just set the variable to ""
                 
 '------------------
 'End of User-configurable variables
 '------------------
 
 'Finds name of computer running the script
 strSourceComputer = WshShell.ExpandEnvironmentStrings("%computername%")
 'Finds source credentials of account running the script
 strSourceDomain = WshShell.ExpandEnvironmentStrings("%userdomain%")
 strSourceUser = WshShell.ExpandEnvironmentStrings("%username%")
 
 blnSkipComputer = false 'do not modify
 strReadFromFile = "yes"
 'If objargs.count > 1 Then change this line to If objargs.count < 1 Then       This will now ask questions
 If objargs.count > 1 Then
     Call fctInput
 Else
     'strSourceFile = Chr(34) & objargs(0) & Chr(34)
 
     'wscript.echo strSourceFile
 
 For I = 0 to objArgs.Count - 1
 
 If InStr(1,LCase(objargs(I)),"list:") Then
     strMDArray = split(objargs(I),"list:")
     'set sourcefile to be what follows the ':'
     SourceFile = replace(strMDArray(1),Chr(34),"")
     blnOK1 = true
 l.writeline time & " - Pulling source listing from " & SourceFile
 Set objTextFile = objFSO.OpenTextFile(sourcefile, ForReading)
 
 ElseIf InStr(1,LCase(objargs(I)),"computer:") Then
     strMDArray = split(objargs(I),"computer:")
     strReadFromFile = "no"
     blnSendMail = true
     blnSend = true
     blnSendSummary = false
 
     'set sourcefile to be what follows the ':'
     strComputer = replace(strMDArray(1),Chr(34),"")
     blnOK1 = true
 l.writeline time & " - Server specified: " & strComputer
 
 ElseIf InStr(1,LCase(objargs(I)),"email:") Then
     strMDArray = split(objargs(I),"email:")
     'set sourcefile to be what follows the ':'
     strMailTo = strMDArray(1)
     blnOK2 = true
     l.writeline Time & " - Email recipient specified as " & strMailto
 Else
     sourcefile = objargs(0)
 l.writeline time & " - Pulling source listing from " & SourceFile
 Set objTextFile = objFSO.OpenTextFile(sourcefile, ForReading)
 
 End If
 Next
 
 End If
 
 If IntDebug = 0 then On Error Resume Next
 
 IntCopyCount = 0
 CutOff = Date() - 1
 Count = 0
 strHDRColor1 = "'#AACFE4'"
 strHDRColor2 = "'#6E8BB6'"
 strFontColor1 = "'white'"
 strFontColor2 = "'black'"
 strFontStyle = "'Tahoma'"
 strBodyBGColor = "'aliceblue'"
 blnProgressMode = true
 
 
 'wscript.echo "Calling IEStatus - blnProgressMode is: " & blnProgressMode
 
 If objargs.count < 1 Then Call IEStatus
 
 'strServerTable = "<Table border=1 width='100%'><tr><td bgcolor=" & strHDRColor2 _
 ' & ">Computer </td>" _
 ' & "<td bgcolor=" & strHDRColor2 & ">Warnings</td>" _
 ' & "<td bgcolor=" & strHDRColor2 & ">Booted</td>" _
 ' & "<td bgcolor=" & strHDRColor2 & ">Scanned</tr>"
 strServerTable = "Server Health Check " _
 & Now & "<Table border=0 cellspacing=0 width='100%'><tr>" _
 & "<td colspan='33%' bgcolor=" & strHDRColor2 & ">Warnings</td>" _
 & "<td colspan='33%' bgcolor=" & strHDRColor2 & ">Booted</td>" _
 & "<td colspan='33%' bgcolor=" & strHDRColor2 & ">Scanned</td></tr></table>"
 
 strEndTable = "</table>"
 strBeginLine = "<TD>"
 strMiddleLine = "</TD><TD>"
 strEndLine = "</TD>"
 
 l.writeline time & " - Generating HTML for server tables..."
 'wscript.echo strServertable
 
 If IntDebug = 0 then On Error Resume Next
 
 
 'wscript.echo strReadfromFile
 If strReadFromFile = "yes" Then
     Dim fso, MyFile
     Set fso = CreateObject("Scripting.FileSystemObject")
     
 
     Call ReadTextFile
 Else
     objDictionary.Add 0, strComputer
 End If
 
 
 '==Assign each item in the text file to the Dictionary object==
 For Each objItem in objDictionary
 
 '===Assign each item in Dictionary to strComputer variable===
 strWarnings = ""
 blnServices = false
 blnOnline = true
 blnDiskSpace = false
 blnEvents = false
 blnAV = false
 blnErrors = false
 strBootTime = ""
 strIPAddress = ""
 strComputer = objDictionary.Item(objItem)
 'wscript.echo strComputer
 blnSkipComputer = false
 strMsg = "Checking computer ["_
 & strComputer & "] "
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg
 l.writeline time & " - Now running check against " & strComputer
 '===Assign results file===
 resultsfile = resultsfolder & "\" & strComputer & ".htm "
 
 '===Assign resultsfile to res variable===
 l.writeline time & " - Generating output file: " & resultsfile
 Set res = objFSO.CreateTextFile(resultsfile, True)
 
 '===Create the HTML code for results file===
 res.Writeline ("<html>")
 res.Writeline ("<body bgcolor=" & strBodyBGColor & ">")
 res.Writeline ("<h1>Server check performed for computer [" & strComputer & "]: " & Now & "</h1>")
 '===Run the checks function===
 Call checks(strComputer)
 l.writeline time & " - Now running main check routine"
 
 If blnSkipComputer = true Then
     l.writeline Now & ": skipping " & strComputer & ". This computer is either not accessible via " _
      & "this script or is not powered on."
     l.writeline time & " - Generating warnings..."
     Call fctWarnings
     l.writeline time & " - Generating email body..."
     Call WriteMail
 Else
     If blnCopyFile = true then
      strDestFolder1 = strDestFolder & "\" & strComputer
 l.writeline time & " - Verifying that " & strDestFolder1 & " exists..."
 
      MakeSureDirectoryTreeExists(strDestFolder1)
 
 l.writeline time & " - Generating warnings..."
 Call fctWarnings
     
      l.writeline time & " - Copying file from " & resultsfile & " to " & strDestfolder1
      Call fctCopyFile(resultsfile,strDestFolder1)
 
     Else
         strServerTable = ""
     End If
 
 If blnSend = true Then
 
      If blnSendMail = true then
 
          Call Sendmail(strMailTo,strMailFrom,"[Server health] - " & ucase(strComputer) & " health report",strMessage)
      'strServerTable = ""
      End If
 
 
     End If
 End If
 tempvar = split(sourcefile,"\")
 tempvar1 = UBound(tempvar)
 'wscript.echo tempvar(tempvar1)
 On Error GoTo 0
 summaryfile = strDestFolder & "\" & replace(tempvar(tempvar1),".txt","") & "_" & strSummaryFileName
 'wscript.echo summaryfile
 Call WriteSummary
 
 blnskipcomputer = false
 
 Next
 
 'strServerTable = StrServerTable & StrEndTable
 
 If blnSendSummary = true then
     If strReadFromFile = "no" Then
         SourceFile = "(computername specified: " & strComputer & ")"
         
     Else
          SourceFile = "<a href='" & SourceFile & "'>" & SourceFile & "</a>"
     End If
     strServerTable = strServerTable & " " _
      & "This file is also located here: <a href='" & summaryfile & "'>" & SummaryFile & "</a> " _
      & "output generated by Server Health Script " & strScriptVer _
      & ""
     strMessage = " Server health script " _
      & "completed at " & Now & ". Please check <a href='" & strDestFolder & "'>" _
      & strDestFolder & "</a> to view the server files. You may also click the server name below to " _
      & "review each server's health stats directly. Listing generated by: " _
      & "Computer: " & strSourceComputer & " User Credentials: " & strSourceDomain & "\" & strSourceUser _
      & " Script path: " & strScriptPath & "\" & wscript.scriptname & " Source server listing " _
      & "was pulled from " & replace(SourceFile,Chr(34),"") & " " & strServerTable
     If InStr(sourcefile,"\") Then
      myarray = split(sourcefile,"\")
      For i = 0 to UBound(myarray)
         
          sourcefile1 = replace(myarray(i),"</a>","")
      Next
     Else
      sourcefile1 = strComputer
     End If
     Call SendMail(strMailFrom,strMailto,"[Server health] - " & sourcefile1,strMessage)
 End If
 'WScript.echo ("Complete")
 If dbgTitle <> "" Then objDIV.InnerHTML = "Server query completed at " & Now & ""
 
 On Error GoTo 0
 If blnSend = 0 and blnSendSummary = false Then
 l.writeline Now & " - no email will be sent, now running " & resultsfile
 WshShell.Run Chr(34) & ResultsFile & Chr(34),3,false    
 End If
 
 l.close
 
 '##################
 'FUNCTIONS
 '##################
 Function fctInput
 l.writeline time & " - Input mode requested, no command-line parameters given."
     strComputer = InputBox("Enter name of computer to query " _
 & "system stats from. " & vbcrlf & vbcrlf _
 & "Click 'OK' without entering a " _
      & "computer name to pull server listing from: " _
      & vbcrlf & SourceFile & " " & vbcrlf & vbcrlf & "use '" _
 & wscript.scriptname & " ?' for complete help.", "Query which computer?",strComputer)
 strReadFromFile = "no"
     
     If IsNull(strComputer) Then
         wscript.quit
     ElseIf strComputer = "" or strComputer = null Then
         strReadFromFile = "yes"
         l.writeline time & " - No computer entered to query, defaulting to " & SourceFile
     End If
     'wscript.echo strReadFromFile
     'strComputer = Trim(strComputer)
     strOutput = InputBox("Would you like to: " & vbcrlf & vbcrlf _
      & "1 - send summary to email recipient(s) " & vbcrlf _
 & "2 - open summary after execution", "Output method","1")
 If strOutput = 1 Then strOutputdef = " - send summary to email recipient(s)"
 If strOutput = 2 Then strOutputdef = " - open summary after execution"
 
 'strReadFromFile = "no"
     If IsEmpty(strOutput) Then
         wscript.quit
     End If
     l.writeline time & " - Output mode requested: " & strOutput & strOutputdef
     If strOutput > 0 and strOutput < 3 Then
      If strOutput = 1 Then
          strMailto = InputBox("Type in a valid email address " _
           & "to which you will send the output summary report." _
           & vbcrlf & vbcrlf & "Multiple recipients can be entered, " _
           & "but they must be separated by a semicolon (;).", "Enter recipient(s)" _
           & "on SMTP host " & strSMTPServer,strMailto)
         If strMailto = "" Then
          StrErr = "No email address provided. Defaulting to display mode."
          wscript.echo strErr
          blnSend = false
          blnSendSummary = false
         Else
          strErr = "Summary email will be sent to " & strMailto
          wscript.echo strErr
          blnSend = true
          blnSendMail = true
 blnSendSummary = false
 
          If strReadfromfile = "yes" Then
              blnSendMail = false
              blnSendSummary = true
          End If
         End If
      ElseIf strOutput = 2 Then
          blnSend = false
          blnSendSummary = false
      End If            
      l.writeline strErr
 
     End If
 
 End Function
 
 '==Extract arguments from text file==
 Function ReadTextFile
     i = 0
     
     If objargs.count = 0 Then Set objTextFile = objFSO.OpenTextFile(SourceFile, ForReading)
 l.writeline time & " - Now reading from " & sourcefile
     Do While objTextFile.AtEndOfStream <> True
      If objTextFile.AtEndOfStream <> True Then
          strNextLine = objTextFile.Readline
         If Trim(strNextLine) <> "" Then objDictionary.Add i, Trim(strNextLine)
          i = i + 1
      End If    
     Loop
 End Function
 
 Function fctWarnings
 On Error GoTo 0
 
 If blnServices = true Then strWarnings = strWarnings & " " _
 & "Services that need attention " & strService
 If blnDiskSpace = true Then strWarnings = strWarnings & " " _
 & "Locally attached drives with less than " _
 & intFreeSpaceThreshold & "% free " & strSpace
 If blnEvents = true Then strWarnings = strWarnings & " " _
 & " Event log errors were detected Check the server log file for details "
 If blnAV = true Then strWarnings = strWarnings & " " _
 & "Antivirus warning detected " & strAntiVirus
 If blnOnline = false Then strWarnings = strWarnings & " " _
 & "System did not respond to WMI queries or may be offline"
 'wscript.echo "strWarnings: " & strWarnings    
 strSpace = ""
 strService= ""
 strAntiVirus = ""
 End Function
 
 
 Function fctCopyFile(strSource,strDestFolder)
 
 'wscript.echo strWarnings
 Dim indexfile
     Set MyFile = fso.GetFile(strSource)
     'wscript.echo strDestFolder & strComputer & "_health.htm"
     MyFile.Copy (strDestFolder1 & "\" & strComputer & "_health.htm")
     'If blnSkipComputer = false Then
     Call WriteMail
     
     'End If
 
 End Function
 
 Function WriteMail
 If strWarnings <> "" Then
     strWarningColor = "#FFCC99"
 Else
     strWarningColor = "#DBFFED"
 End If
 strServerTable = strServerTable & vbcrlf & "<table cellspacing=0 border=0 width='100%'><tr style='cursor:pointer' onclick='showrows(tbl" & strComputer & ")' bgcolor='" & strWarningColor & "'><td width='20%'>" _
 & "<a href='" & resultsfile & "'>" & strComputer & "</a></td><td>(" & strIPAddress & ")" _
 & "</td></tr><tr><td colspan='100%'>" _
 & "<table width='100%'><tr id='tbl" & strComputer & "'><td colspan='33%'>" _
 & strWarnings & "</td><td colspan='33%'>" & strBootTime & "</td>" _
 & "<td colspan='33%'>" _
 & Now & "</td></tr></table></td></tr></table>"
 
 strHideRows = strHideRows & "tbl" & strComputer & ".style.display = " & Chr(34) & "none" & Chr(34) & vbcrlf
 
 End Function
 
 Function WriteSummary
     Dim oldfile
     On Error GoTo 0
     'Checks to see if the output file exists, then deletes it prior to making a new
     ' one (otherwise it would append to the end of the file).
 
 
     If ReportFileStatus(summaryfile) = "exists" Then
         l.writeline time & " - Deleting " & summaryfile
         Set oldfile = ws.GetFile(summaryfile)
         If intDebug = 1 Then wscript.echo summaryfile & " exists. Now deleting."
         oldfile.Delete
         
      If CStr(err.number) <> 0 Then
          strErr = "You do not have sufficient permissions to delete " & oldfile & "."
          l.writeline strErr
         If intDebug = 1 Then wscript.echo strErr
      End If
     
     End If
     'wscript.echo strDestFolder & "\summary.htm"
 l.writeline time & " - Generating summary file: " & summaryfile    
 'If intdebug = 0 Then wscript.echo summaryfile
     Set index = ws.OpenTextFile(summaryfile, ForAppending, True)
     If CStr(err.number) <> 0 Then
         strMsg = "Error saving " & summaryfile & ". Be sure that this " _
           & "path exists." & vbcrlf & vbcrlf & "Actual error was - " & err.description
          l.writeline strMsg
          wscript.echo strMsg
          wscript.quit
     End If
     'Set indexfile = objFSO.CreateTextFile( & Chr(34), True)
     l.writeline time & " - Writing summary information for " & strComputer & " to " & summaryfile
     'wscript.echo strServerTable
     index.writeline strServerTable & "<table width='100%'><tr bgcolor='black'><td colspan='100%'>" _
      & "Finished server indexing at " & Now & "</td></tr></table>"
     index.writeline "<script language=" & Chr(34) & "VBSCRIPT" & Chr(34) & ">"
     index.writeline strHideRows
     index.writeline "Function ShowRows(strRow)" & vbcrlf
     index.writeline "if strRow.style.display = " & Chr(34) & "inline" & Chr(34) & " then" & vbcrlf
     index.writeline " strRow.style.display = " & Chr(34) & "none" & Chr(34) & vbcrlf
     index.writeline "else" & vbcrlf
     index.writeline " strRow.style.display = " & Chr(34) & "inline" & Chr(34) & vbclrf
     index.writeline "end if" & vbcrlf
     index.writeline "End Function" & vbcrlf
     index.writeline "</script></body></html>"
     index.close
 End Function
 
 '####Main function for running server checks####
 Function checks (strComp)
 
 '==Run the check subroutines/functions==
 
 chkopsys(strComp) 'Func
 'wscript.echo "blnSkipComputer = " & blnSkipComputer
 If blnSkipComputer = False Then
 chkComputer(strComp) 'Func
 chkdiskspace (strComp) 'Sub
 l.writeline time & " - Checking AV details."
 On Error Resume Next
 If intAV = 0 Then
     l.writeline time & " - McAfee VirusScan was specified (IntAV = " & intAV & ")."
 
     begintable("McAfee Anti-Virus")
      chkav "Product Name:","Software\Network Associates\TVD\VirusScan Enterprise\CurrentVersion","Product", "string" 'Sub
      chkav "Product Version:","Software\Network Associates\TVD\VirusScan Enterprise\CurrentVersion","szProductVer", "string"
      chkav "Virus Definition:","Software\Network Associates\TVD\VirusScan Enterprise\CurrentVersion","szVirDefVer", "string"
      chkav "Virus Definition Date:","Software\Network Associates\TVD\VirusScan Enterprise\CurrentVersion","szVirDefDate", "string"
      chkav "Product Engine:","Software\Network Associates\TVD\VirusScan Enterprise\CurrentVersion","szEngineVer", "string"
     endtable
 ElseIf intAV = 1 Then
     l.writeline time & " - Norton Antivirus was specified (IntAV = " & intAV & ")."
 begintable("Norton Antivirus")
 chkav "NAV Definition Version:","SOFTWARE\Symantec\SharedDefs","DEFWATCH_10"
 endtable
 ElseIf intAV = 2 Then
     l.writeline Time & " - Trend OfficeScan was specified (IntAV = " & intAV & ")."
     begintable("Trend OfficeScan")
         chkav "Product Version:","SOFTWARE\TrendMicro\PCCillinNTCorp\CurrentVersion\Misc.","ProgramVer", "string"
         chkav "Internal Pattern Version:","SOFTWARE\TrendMicro\PCCillinNTCorp\CurrentVersion\Misc.","InternalPatternVer", "dword"
         chkav "Pattern Date:","SOFTWARE\TrendMicro\PCCillinNTCorp\CurrentVersion\Misc.","PatternDate", "string"
     endtable
     
 End If
 
     chkservices(strComp) 'Func
     chkevents (strComp) 'Func
 
     Set w = ws.OpenTextFile(resultsfile, ForReading, False, TristateUseDefault)
     strMessage = w.ReadAll
     'MsgBox strMessage
     w.close
 Else
 
 End If
     
 
 res.Writeline ("</html>")
 res.close
 
 '==End Function==
 End Function
 
 '####Check OS Version and Free Physical Memory####
 Function chkopsys (strComp)
 If intDebug = 0 Then On Error Resume Next
 l.writeline time & " - Checking OS details."
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg & "" _
 & "Checking Operating System... "
 
 'wscript.echo StrComp
 '==Connect to winmgmts==
 Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComp & "\root\cimv2")
 
 Call fctErrorHandling
 
 Set colopsys = objWMIService.ExecQuery _
 ("Select Caption, CSDVersion, FreePhysicalMemory from Win32_OperatingSystem")
 
 '==Write header to htm file==
 res.Writeline ("<table bgcolor=" & strHDRColor2 & " BORDER=1 width=100% cellspacing=0 cellpadding=3>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor1 & " colspan=6 width=400>")
 res.Writeline ("")
 res.Writeline ("Operating System information")
 res.Writeline ("</th>")
 res.Writeline ("</tr>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Operating System</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Last Booted</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Service Pack</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Free Memory</th>")
 res.Writeline ("</tr>")
 'endtable
 
 '==Write results to htm file==
 For each objopsys in colopsys
 res.Writeline ("<TR>" & strbeginline & objopsys.Caption & strMiddleLine & GetBootTime(StrComp) & strEndLine)
 res.Writeline (strbeginline & objopsys.CSDVersion & strEndline)
 res.Writeline (strbeginline & round(objopsys.FreePhysicalMemory/1000,2) & "Mb" & strEndLine & "</TR>")
 Next
 
     Set colAdapters = objWMIService.ExecQuery ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")
     For Each objAdapter in colAdapters
         If Not IsNull(objAdapter.IPAddress) Then
          For i = LBound(objAdapter.IPAddress) To UBound(objAdapter.IPAddress)
             'Wscript.Echo "IP address: " & objAdapter.IPAddress(i)
             strIPAddress = objAdapter.IPAddress(i) & ";" & strIPAddress
          Next
 
         End If
     Next
 'round(objItem.FreeSpace/1000000000,2)
 '==End Function==
 End Function
 
 '####Check OS Version and Free Physical Memory####
 Function chkComputer (strComp)
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg & "" _
 & "Checking computer hardware ... "
 '==Connect to winmgmts==
 l.writeline time & " - Checking computer hardware details."
 Set objWMIService = GetObject("winmgmts:" _
 & "{impersonationLevel=impersonate}!\\" & strComp & "\root\cimv2")
 
 Set colCompItems = objWMIService.ExecQuery _
 ("Select Manufacturer, Model, Username from Win32_ComputerSystem")
 
 '==Write header to htm file==
 res.Writeline ("<table BORDER=1 width=100% cellspacing=0 cellpadding=3>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor1 & " colspan=6 width=400>")
 res.Writeline ("")
 res.Writeline ("Computer Hardware information")
 res.Writeline ("</th>")
 res.Writeline ("</tr>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Manufacturer</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Model</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Logged on User</th>")
 res.Writeline ("</tr>")
 
 '==Write results to htm file==
 For each objItem in ColCompItems
 res.Writeline ("<TR>" & strbeginline & objItem.Manufacturer & strEndLine)
 res.Writeline (strbeginline & objItem.Model & strEndline)
 res.Writeline (strbeginline & objItem.Username & strEndLine & "</TR>")
 Next
 
 '==End Function==
 End Function
 
 
 '####Check started and stopped services####
 Function chkservices (strComp)
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg & "" _
 & "Checking automatic services... "
 l.writeline time & " - Checking services."
 '==Connect to winmgmts==
 Set objWMIService = GetObject("winmgmts:" _
 & "{impersonationLevel=impersonate}!\\" & strComp & "\root\cimv2")
 
 
 '==Run query to get all services with Auto start==
 Set colsvc = objWMIService.ExecQuery _
 ("Select DisplayName, StartMode, StartName, State from Win32_Service Where StartMode = 'Auto'")
 
 '==Write heard to htm file==
 res.Writeline ("<table border=1 width=100% cellspacing=0 cellpadding=3>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor1 & " colspan=6 width=400>")
 res.Writeline ("")
 res.Writeline ("Services alerts")
 res.Writeline ("</th>")
 res.Writeline ("</tr>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Service Name</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Logon Account</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Startup Method</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=59>Current State</th>")
 res.Writeline ("</tr>")
 
 '==Write results to htm file==
 For each objsvc in colsvc
 On Error GoTo 0
 'wscript.echo objsvc.startname
 
 Call bgcolor
 If InStr(objsvc.StartName,strCheckAccount) and strCheckAccount <> "" Then
 'wscript.echo objsvc.startname
 res.Writeline ("<TR bgcolor='" & strbgcolor & "'>" & strBeginLine & objsvc.DisplayName & strMiddleLine _
 & "" & objsvc.StartName & "" _
 & strMiddleLine & objsvc.StartMode & "</td><td>" _
 & "" & objsvc.State & strEndLine)
 strService = strService & objsvc.DisplayName & " is running via credentials: " & objsvc.StartName & " "     
 End If
 
 Call bgcolor
 If LCase(objsvc.State) = "stopped" Then
 
 serviceerr = "failed"
 res.Writeline ("<TR bgcolor='" & strbgcolor & "'>" & strBeginLine & objsvc.DisplayName & strMiddleLine _
 & objsvc.StartName & strMiddleLine & objsvc.StartMode & "</td><td>" _
 & "" & objsvc.State & strEndLine)
 strService = strService & objsvc.DisplayName & " is currently " & objsvc.State & " "
 Else
 End If
 Next
 
 
 
 If serviceerr = "failed" then
 blnErrors = true
 blnServices = true
 Else
 res.Writeline ("<TR>"& strbeginline & "No services are in alarm status" & strendline)
 End If
 res.Writeline ("</table>")
 
 '==End Function==
 End Function
 
 
 '*****************************************************************
 '* Get boot up time of the server
 '*****************************************************************
 Function GetBootTime(StrComp)
 
 Const wbemFlagReturnImmediately = &h10
 Const wbemFlagForwardOnly = &h20
 
 Set objWMIService = GetObject("winmgmts:\\" & StrComp & "\root\CIMV2")
 Set colOperatingSystems = objWMIService.ExecQuery("SELECT * FROM Win32_OperatingSystem", "WQL", _
 wbemFlagReturnImmediately + wbemFlagForwardOnly)
 On Error Resume Next
 'If CStr(err.number) <> "" Then Call fcterrorhandling
     
 For Each objOS in colOperatingSystems
         dtmBootup = objOS.LastBootUpTime
         Dim dtmTimeUp
         
         'wscript.echo dtmBootup
         
         dtmLastBootupTime = WMIDateStringToDate(dtmBootup)
 
         dtmSystemUpTime = DateDiff("h", dtmLastBootUpTime, Now)
         
         If dtmSystemUptime > 24 Then
             dtmTimeUp = DateDiff("d",dtmLastBootUpTime, Now) & " day(s)"
         Else
             dtmTimeUp = dtmSystemUptime & " hour(s)"
         End If
 
         strBootTime = dtmLastBootupTime & " (" & dtmTimeUp & " ago)"
         GetBootTime = strBootTime
 
         'dtmSystemUptimeHours
         'Wscript.Echo "Last booted: " & dtmLastBootupTime & " (" & dtmSystemUptime & " hours)"
 Next
 End Function
 
 
 '####Check status of backups (To be writte)####
 Function chkbackups ()
 
 '==End Function==
 End Function
 
 '####Check event logs for warnings and errors####
 Function chkevents (strComp)
 On Error Resume Next
 l.writeline time & " - Checking the " & strEventCount & " last occurences of events during the last " & IntDaysBack & " days."
 Const CONVERT_TO_LOCAL_TIME = True
 On Error GoTo 0
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg & "" _
 & "Checking the " & strEventCount & " most recent entries occuring during the last " & IntDaysBack & " day(s) of event logs... "
 Set dtmStartDate = CreateObject("WbemScripting.SWbemDateTime")
 Set dtmEndDate = CreateObject("WbemScripting.SWbemDateTime")
 DateToCheck = Date
 dtmStartDate.SetVarDate DateToCheck - IntDaysBack, CONVERT_TO_LOCAL_TIME
 dtmEndDate.SetVarDate DateToCheck + IntDaysBack, CONVERT_TO_LOCAL_TIME
 Set objWMIService = GetObject("winmgmts:" _
 & "{impersonationLevel=impersonate,(Security)}!\\" & StrComp & "\root\cimv2")
 
 Set colEvents = objWMIService.ExecQuery _
 ("Select ComputerName, EventCode, Logfile, SourceName, TimeWritten, Type, Message from Win32_NTLogEvent Where " _
 & "TimeWritten >= '" _
 & dtmStartDate & "' and TimeWritten < '" & dtmEndDate & "' and Type = 'error' or TimeWritten >= '" _
 & dtmStartDate & "' and TimeWritten < '" & dtmEndDate & "' and Type = 'warning' and Type = 'failure'")
 
 '==Run query to get errors and warnings==
 'Set colLoggedEvents = objWMIService.ExecQuery _
 ' ("Select ComputerName, EventCode, SourceName, TimeGenerated, Type, Message from Win32_NTLogEvent where Type = 'error' or Type = 'warning'")
 
 '==Write header to htm file==
 res.Writeline ("<table border=1 width=100% cellspacing=0 cellpadding=3>")
 res.Writeline ("<tr colspan='100%'>")
 res.Writeline ("<th bgcolor=" & strHDRColor1 & " colspan='100%'>")
 res.Writeline ("")
 res.Writeline ("Last " & strEventCount & " events occurring within the previous " & IntDaysBack & " day(s)")
 res.Writeline ("</th>")
 res.Writeline ("</tr>")
 res.Writeline ("<tr>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=60>Computer Name</td>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=200>Logfile</td>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=200>Event Code/Log</td>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=60>Source Name</td>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=60>Time Written</td>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=60>Type</td>")
 res.Writeline ("<td bgcolor=" & strHDRColor2 & " width=60>Message</td>")
 res.Writeline ("</tr>")
 
 '==Write results to htm file==
 
 Dim strEventCount1
 strEventCount1 = -1
 
 For Each objEvent in colEvents
 
 Call bgcolor
 On Error GoTo 0
 
 res.Writeline ("<TR bgcolor='" & strbgcolor & "'>")
 'res.Writeline (strbeginline & objEvent.Category & strendline)
 res.Writeline (strbeginline & objEvent.ComputerName & strendline)
 res.Writeline (strbeginline & objEvent.logfile & strendline)
 
 res.Writeline (strbeginline & "<a href='http://www.google.com/search?hl=en&q=%22event%22+%22" _
 & objEvent.EventCode & "%22+%22ID%22+%22windows%22+%22" & objEvent.SourceName & "%22' target='_blank'>" & objEvent.EventCode & "</a>" & strendline)
 
 res.Writeline (strbeginline & objEvent.SourceName & strendline)
 res.Writeline (strbeginline & WMIDateStringToDate(objEvent.TimeWritten) & strendline)
 strEventCount1 = strEventCount1 + 1
 
 If LCase(objEvent.Type) = "error" Then
 
     res.Writeline ("<TD>" & objEvent.Type & strendline)
     blnErrors = true
     blnEvents = true
 
 Else
     res.Writeline (strbeginline & objEvent.Type & strendline)
 End If
 res.Writeline (strbeginline & objEvent.Message & strendline)
 res.Writeline ("</TR>")
 
 If strEventCount1 > strEventCount Then
     'wscript.echo "Count is " & strEventCount1
 Exit For
 End If
 Next
 res.Writeline ("<tr><td colspan='100%' bgcolor='black'>Health check finished at: " & Now & "" & strendline)
 
 '==End Function==
 End Function
 
 Function BGColor
     If Count = 0 or IntCopyCount = 0 Then    
         strbgcolor = bgcolor0
         Count = 1
         IntCopyCount = 1
     ElseIf Count = 1 or IntCopyCount = 1 Then
         strbgcolor = bgcolor1
         Count = 0
         IntCopyCount = 0
     End If
 End Function
 
 Function fctErrorHandling
 If cstr(err.number) <> 0 then
     'wscript.echo err.number & " - " & err.description
     l.writeline Time & " - Error: " & err.number & " " & err.description
     blnOnline = false
     blnSkipComputer = true
 
     Exit Function
 End If
 End Function
 
 
 '------------------
 'Function EmailFile - email the warning file
 '------------------
 Function SendMail(strFrom,strTo,strSubject,strMessage)
 Dim iMsg, iConf, Flds
 
 l.writeline time & " - Calling sendmail routine"
 l.writeline time & " - To: " & strMailto
 l.writeline time & " - From: " & strMailFrom
 l.writeline time & " - Subject: " & strSubject
 l.writeline time & " - SMTP Server: " & strSMTPServer
 
 If dbgTitle <> "" Then objdiv.innerhtml = "" _
 & "sending mail to " & strMailTo & "... "
 
 '// Create the CDO connections.
 Set iMsg = CreateObject("CDO.Message")
 Set iConf = CreateObject("CDO.Configuration")
 Set Flds = iConf.Fields
 
 
 '// SMTP server configuration.
 With Flds
 .Item(cdoSendUsingMethod) = cdoSendUsingPort
 
 '// Set the SMTP server address here.
 .Item(cdoSMTPServer) = strSMTPServer
 .Update
 End With
 
 '// Set the message properties.
 With iMsg
 Set .Configuration = iConf
 .To = strMailTo
 .From = strMailFrom
 .Subject = strSubject
 '.TextBody = strMessage
 End With
 
 
 iMsg.HTMLBody = strMessage
 
 
 '// Send the message.
 On Error Resume Next
 iMsg.Send ' send the message.
 If CStr(err.number) <> 0 Then
     l.writeline Time & " - Problem sending mail to " & strSMTPServer & "."
     l.writeline Time & " - Error: " & err.description
 Else
     l.writeline Time & " - Connected successfully to " & strSMTPServer
 End If
 End Function
 
 '###################
 ' SUBROUTINES
 '###################
 
 '####Check disk space subroutine####
 Sub chkdiskspace (strComp)
 
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg & "" _
 & "Checking disk space... "
 l.writeline time & " - Checking disk space."
 '==Connect to winmgmts==
 Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComp & "\root\cimv2")
 
 
 '==Run query to identify logical disks==
 Set colDisks = objWMIService.ExecQuery _
 ("Select Freespace, Name, Size from Win32_LogicalDisk where DriveType = 3")
 Call fctErrorHandling
 
 '==Write header to htm file==
 res.Writeline ("<table border=1 width=100% cellspacing=0 cellpadding=3>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor1 & " colspan=6 width=200>")
 res.Writeline ("")
 res.Writeline ("Disk space")
 res.Writeline ("</th>")
 res.Writeline ("</tr>")
 res.Writeline ("<tr>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Disk ID</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Percentage Free Space</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Free Space</th>")
 res.Writeline ("<th bgcolor=" & strHDRColor2 & " width=60>Total Space</th>")
 res.Writeline ("</tr>")
 
 '==Write results to htm file==
 For each objDisk in colDisks
 Call bgcolor
 res.Writeline ("<TR bgcolor='" & strbgcolor & "'><TD> " & objDisk.Name & strendline)
 
 If (objDisk.Freespace/objDisk.Size)*100 <=10 Then
 
 fontcol = "#FF0000"
 Else
 fontcol = "#666666"
 End If
 If objDisk.Freespace > 10000 Then
     strUnit = "GB"
     strDiskSize = FormatNumber(objDisk.Freespace / 1073741824,2)
     strDiskTotal = FormatNumber(objDisk.Size / 1073741824,2)
 ElseIf objDisk.Freespace < 1 Then
     strUnit = "KB"
     strDiskSize = FormatNumber(objDisk.Freespace / 1024,2)
     strDiskTotal = FormatNumber(objDisk.Size / 1024,2)
 ElseIf objDisk.Freespace < 1000 Then
     strUnit = "MB"
     strDiskSize = FormatNumber(objDisk.Freespace/1048576,2)
     strDiskTotal = FormatNumber(objDisk.Size / 1048576,2)
 End If
 strPercentFree = round((objDisk.Freespace/objDisk.Size)*100,2)
 
 If strPercentFree < intFreeSpaceThreshold then
 'wscript.echo strPercentFree
 strSpace = strSpace & objDisk.Name & " - " & round((objDisk.Freespace/objDisk.Size)*100,2) _
 & "% free (" & FormatNumber(objDisk.Freespace / 1073741824,2) & "Gb remaining) "
     res.Writeline ("<TD>" & strPercentFree & "%" & strendline)
     blnErrors = true
     blnDiskSpace = true
 Else
     res.Writeline ("<TD>" & strPercentFree & "%" & strendline)
 End If
 
 res.Writeline ("<TD>" & strDiskSize & strUnit & strendline)
 res.Writeline ("<TD>" & strDiskTotal & strUnit & strendline & "</TR>")
 
 Next
 
 '==End Subroutine==
 End sub
 
 '####Check for AV definition files####
 Function chkav (strDescription, strKeyPath, strValueName, strRegType)
 On Error Resume Next
 
 'wscript.echo strValueName
 
 If dbgTitle <> "" Then objdiv.innerhtml = strMsg & "" _
 & "Checking AV status... "
 
 '==Connect to winmgmts==
 Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
 strComputer & "\root\default:StdRegProv")
 
 
 '==Get definition version from registry==
 If strRegType = "dword" Then
     oReg.GetDWordValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strValue
 ElseIf strRegType = "string" Then
     oReg.GetStringValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,strValue
 End If
 
 'wscript.echo strValue
 
 If strValueName = "szVirDefDate" or strValueName = "PatternDate" Then
     If strValueName = "PatternDate" Then
         
         defRest = Right(strValue,4)
         strValue = Left(defRest,2) & "/" & Right(defRest,2) & "/" & Left(strValue,4)
 
     End If
     strDiff = Date - CDate(strValue)
     If strDiff > intVirusDefAge Then
         strAntivirus = "AV definitions last updated: " & CDate(strValue) _
          & " - Virus definitions appear to be " _
           & "more than " & intVirusDefAge & " days old."
         strTempColor = "'red'"
         blnAV = true
     Else
         strTempColor = strFontColor2
         blnAV = false
     End If            
     
     res.Writeline ("<TR><TD> " & strDescription _
      & "</td><td> " & strValue & "</TD></TR>")
 
 ElseIf strValueName <> "" Then
     res.Writeline ("<TR><TD> " & strDescription _
      & "</td><td> " & strValue & "</TD></TR>")
 
 End If
 
 On Error Resume Next
 If strValue = "" Then
 strAntiVirus = "The defined virus software may not be installed on this computer."
 blnAV = true
 Else
 'wscript.echo "no av..."
 
 strValue = "n/a"
 End If
 'wscript.quit
 
 '==Write results to htm file==
 
 
 
 '==End subroutine==
 End Function
 '~~[/script]~~
 
 Sub BeginTable(strTableHeader)
     res.Writeline ("<table border=1 width=100% cellspacing=0 cellpadding=3>")
     res.Writeline ("<tr>")
     res.Writeline ("<th bgcolor=" & strHDRColor1 & " colspan=6 width=400>")
     res.Writeline ("")
     res.Writeline ("" & strTableHeader & "")
     res.Writeline ("</th>")
     res.Writeline ("</tr>")
 End Sub
 
 Sub EndTable
     res.Writeline ("</table>")
 End Sub
 
 Function WMIDateStringToDate(dtmDate)
 'wscript.echo dtmBootup
 'Thanks to Piers Dickinson!
     WMIDateStringToDate = CDate(Mid(dtmDate, 5, 2) & "/" & _
     Mid(dtmDate, 7, 2) & "/" & Left(dtmDate, 4) _
     & " " & Mid (dtmDate, 9, 2) & ":" & Mid(dtmDate, 11, 2) & ":" & Mid(dtmDate,13, 2))
     If CStr(err.number) <> "0" Then Call fcterrorhandler
     
 End Function
 
 ' The MakeSureDirectoryTreeExists Function
 
 ' Although the FSO model doesn't have a direct method to create nested
 ' folders, you can use the following function. This VBScript function uses
 ' VBScript's Split function to break the folder path it receives into
 ' components. From those components, the MakeSureDirectoryTreeExists
 ' creates subfolders, one at a time. Because the function checks for the
 ' folder's existence before proceeding, you can pass it any tree, as long as
 ' you make sure that, after it returns, the entire tree exists as you specified.
 ' With the MakeSureDirectoryTreeExists function, a call such as
 
 '    MakeSureDirectoryTreeExists "C:\one\two\three"
 
 ' is legitimate and won't result in an error message.
 
 ' The MakeSureDirectoryTreeExists Function
 
 ' Although the FSO model doesn't have a direct method to create nested
 ' folders, you can use the following function. This VBScript function uses
 ' VBScript's Split function to break the folder path it receives into
 ' components. From those components, the MakeSureDirectoryTreeExists
 ' creates subfolders, one at a time. Because the function checks for the
 ' folder's existence before proceeding, you can pass it any tree, as long as
 ' you make sure that, after it returns, the entire tree exists as you specified.
 ' With the MakeSureDirectoryTreeExists function, a call such as
 
 '    MakeSureDirectoryTreeExists "C:\one\two\three"
 
 ' is legitimate and won't result in an error message.
 
 Function MakeSureDirectoryTreeExists(dirName)
 Dim aFolders, newFolder
     dim delim
     ' Creates the FSO object.
     Set fso = CreateObject("Scripting.FileSystemObject")
 
     ' Checks the folder's existence.
     If Not fso.FolderExists(dirName) Then
 
         ' Splits the various components of the folder name.
         If instr(dirname,"\\") then
          delim = "-_-_-_-"
             dirname = replace(dirname,"\\",delim)
             'wscript.echo dirname
         End if
 
         aFolders = split(dirName, "\")
 
         If InStr(dirname,delim) Then
             dirname = replace(aFolders(0),delim,"\\")
             'wscript.echo "aFolders = " & dirname
         End if
 
         ' Obtains the drive's root folder.
         
         newFolder = fso.BuildPath(dirname, "\")
     
         ' Scans each component in the array, and create the appropriate folder.
         For i=1 to UBound(aFolders)
             If IntDebug = 1 Then
                 strTempVar = "Checking to see if " & newfolder _
                   & " exists..."
                 Call writedebug(strtempvar)
             End If
             newFolder = fso.BuildPath(newFolder, aFolders(i))
             'wscript.echo newfolder
             
             
             If Not fso.FolderExists(newFolder) Then
                 If IntDebug = 1 Then
                     strTempVar = "Creating " & newfolder
                     Call writedebug(strTempVar)
                 End If
                 fso.CreateFolder newFolder
                 err.clear
             End If
         Next
     End If
 End Function
 
 '-----------------
 'Function IE Status
 '-----------------
 Function IEStatus
 
 'added by Rob - IE status indicator code
 If blnProgressMode = true Then
     If blnDebugMode Then
         dbgTitle = "Server Health Check"
     Else
         dbgTitle = "Server Health Check"
     End If    
     dbgToolBar = False
     dbgStatusBar = False
     If blnDebugMode Then
         dbgResizable = True
     Else
         dbgResizable = False
     End If
     dbgWidth = 500
     dbgHeight = 320
     dbgLeft = 0
     dbgTop = 0
     dbgVisible = True
     dlgBarWidth = 380
     dlgBarHeight = 23
     dlgBarTop = 80
     dlgBarLeft = 50
     dlgProgBarWidth = 0
     dlgProgBarHeight = 18
     dlgProgBarTop = 82
     dlgProgBarLeft = 50
     dlgBar = "left: " & dlgBarLeft & "; top: " & dlgBarTop & "; width: " & dlgBarWidth _
      & "; height: " & dlgBarHeight & ";"
     dlgProgBar = "left: " & dlgProgBarLeft & "; top: " & dlgProgBarTop & "; width: " _
      & dlgProgBarWidth & "; height: " & dlgProgBarHeight & ";"
     wdBar = 1 * dlgBarWidth
 End If
 
 If blnProgressMode = true Then
     Set IE = CreateObject("InternetExplorer.Application")
     'strScriptVer = "version would go here"
 
     strTempFile = WshSysEnv("TEMP") & "\progress.htm"
     ws.CreateTextFile (strTempFile)
 Set f1 = ws.GetFile(strTempFile)
 Set ts = f1.OpenAsTextStream(2, True)
 ts.WriteLine("")
 ts.WriteLine("<html><head><title>" & dbgTitle & " " & strScriptVer & " </title>")
 ts.WriteLine("<style>.errortext {color:red}")
     ts.WriteLine(".hightext {color:blue}</style>")
     ts.WriteLine("</head>")
     ts.WriteLine(strHDRCode & " " _
          & "  Querying " & strComputer & "... " _
          & "   ")
     ts.WriteLine("<center><table width='100%' bgcolor='" & bgcolor1 & "'><tr><td>")
     If blnDebugMode Then
         ts.WriteLine("<body bgcolor ='" & stsBGColor & "' scroll='yes' topmargin='0' leftmargin='0'"_
         & " style='font-family: " & fstyle & "; font-size: 0.6em color: #000000;"_
         & " font-weight: bold; text-align: left'><center>"_
         & " <hr color='blue'>")
     Else
         ts.WriteLine("<body bgcolor = '" & stsBGColor & "' scroll='no' topmargin='0' leftmargin='0' "_
         & " style='font-family: " & fstyle & "; font-size: 0.6em color: #000000;"_
         & " font-weight: bold; text-align: left'><center>"_
         & " <hr color='blue'>")
     End If
     ts.WriteLine("<div id='ProgObject' align='left'align='left' style='width: 450px;height: 140px;overflow:scroll'></div><hr color='blue'>")            
     If blnDebugMode Then
         ts.WriteLine("<div id='ProgDebug' align='left'></div>")
     End If
 
     ts.WriteLine("<script LANGUAGE='JavaScript1.2'>")
     ts.WriteLine("")
     ts.WriteLine("</script>")
     ts.WriteLine("<div id='ProgBarId' align='left'></div>")
     ts.WriteLine("</center>")
     ts.WriteLine("</tr></td>")
     ts.WriteLine("</table></center>")
     ts.WriteLine("</body></html>")
     ts.Close
     fctSetupIE(strTempFile)
     Set objDIV = IE.Document.All("ProgObject")
     If blnDebugMode Then
         Set objDBG = IE.Document.All("ProgDebug")
     End If
     Set objFlash = IE.Document.All("ProgFlash")
     Set objPBar = IE.Document.All("ProgBarId")
     Set objBar = IE.Document
 End If
 End Function
 
 '*******************************************************************
 '*    Name:    fctSetupIE
 '*    Function:    Setup an IE windows of 540 x 200 to display
 '*     progress information.
 '*******************************************************************
 Sub fctSetupIE(File2Load)
     IE.Navigate File2Load
     IE.ToolBar = dbgToolBar
     IE.StatusBar = dbgStatusBar
     IE.Resizable = dbgResizable
     Do
     Loop While IE.Busy
     IE.Width = dbgWidth
     IE.Height = dbgHeight
     IE.Left = dbgLeft
     IE.Top = dbgTop
     IE.Visible = dbgVisible
     wshshell.AppActivate("Microsoft Internet Explorer")
 End Sub
 
 '===================
 'Function to see if outputfile already exists
 '===================
 
 Function ReportFileStatus(filespec)
 
 Dim fso, msg
 Set fso = CreateObject("Scripting.FileSystemObject")
 If (fso.FileExists(filespec)) Then
 msg = "exists"
 Else
 msg = "does not exist"
 End If
 
 ReportFileStatus = msg
 If IntDebug = 1 Then wscript.echo filespec & " " & msg
 
 End Function

(in reply to wsmoth)

Post #: 3

RE: I need the following script... - 8/23/2007 2:50:54 AM

mcds99

Posts: 434
Score: 4
Joined: 2/28/2006
Status: online

OMG the third one today.

You need to buy several books on VBScript.

VBScript in a Nutshell (for specific refrence)
Any beginning VBScript book so you can get a handle on the language.

We will help you when you have made an effort to learn.

_____________________________

Sam

Keep it Simple Make it Fun KiSMiF

(in reply to wsmoth)

Post #: 4

RE: I need the following script... - 8/23/2007 5:42:31 AM

wsmoth

Posts: 2
Score: 0
Joined: 8/22/2007
Status: offline

gdewrance,
YOU ROCK!!!!!

That is exactly what I needed!!!!

Man, you have saved me! Thanks soooo much!

- Will

(in reply to gdewrance)

Post #: 5

RE: I need the following script... - 11/16/2007 2:26:53 AM

ashok123

Posts: 3
Score: 0
Joined: 11/16/2007
Status: offline