Play Sound on Remote Computer

Forums

My Profile

Inbox

Address Book

My Subscription

My Forums

Play Sound on Remote Computer

Logged in as: Guest

arrSession:exec spGetSession 2,16,51727

	Active Users: There are 0 members and 0 guests.
	Users viewing this topic: none

Printable Version

All Forums >> [Scripting] >> Post a VBScript >> Play Sound on Remote Computer
Do you like VisualBasicScript.com? Link to us and help spread the word about our forum. Thanks!

Page: [1]

Message

<< Older Topic Newer Topic >>

Play Sound on Remote Computer - 9/10/2007 10:20:36 AM

Meg

Posts: 123
Score: 2
Joined: 7/13/2006
From: Australia
Status: offline

I saw Rischip's Play Media File script and could not make it play on a remote machine.
So I wrote this script using a bit of UnderCoverGuy's scheduled task code.
There are plenty of comments to work out how it works.
It has many posibilities, ie changing it to remotely run different tasks or adding a HTA frontend to make it cool.
Developed and tested on XP Pro SP2 only, enjoy.

'-----------------------------------------------------------------
' Script by mjp 2007
' RemotePlay.vbs
' Script primarily will play a sound file on a remote computer, could be changed to do some other remote execute task.
' When any variable is passed to script like this:- "RemotePlay.vbs setup" the script will enter setup mode.
' In setup mode the script will prompt for a media file name, remote machine name, etc. A feature is that script remembers last used values to save you typing them in again next time.
' script will save these values to an inf file and set a sheduled task on remote machine to play the specified media sound file via this same script. 
'-----------------------------------------------------------------
'Ensure Script and sound file are in same folder which remote machine can access via a UNC path.

option explicit
dim UNC_PATH   ' eg \\server\share\  -no spaces-
dim MEDIA_FILE ' eg xxx.mp3
dim TARGET     ' MachineNetbiosName
dim SetupMode
dim objFile
dim ObjFSO
dim ObjTextFile
dim strNextLine
dim RemotePlayList
dim objPlayer
dim infString
dim MEDIA_FILE_PATH
dim Task
dim RemotePlayScriptName
dim NewTime
dim NewDate
dim TaskID
dim TaskAccount     ' A userid that has permission to script path
dim TaskPassword    ' the password 
dim LaunchCommand
dim DelCommand
dim WshShell

'Set a fixed custom TaskId so we can manage this task. "Put it in inverted commas" using chr(34)
TaskID = "Sound1" : TaskID = chr(34) & TaskID & chr(34)

'Check for arguments passed to script
On Error Resume next
SetupMode=WScript.Arguments.Item(0)
On Error Goto 0

'Script is NOT running in setup mode
If SetupMode="" Then

' Srcipt is being run directly and there is no inf file with path to media file. 
If CHECKINF = "NotThere" then

'Error inf not found - you need to run script in setup mode first, quitting. 
Wscript.quit
else

' Read inf to determine where the media file is to play it. 
READINF

'Play media file and quit
MEDIA_FILE_PATH=UNC_PATH & MEDIA_FILE
PLAYFILE MEDIA_FILE_PATH
wscript.quit
End if
else

'Script IS running in setup mode
'Check if inf file exists 
If CHECKINF = "NotThere" then

' inf file not found, we will create a new one. 
CREATEINF

' Gather data to save back to inf file and to build a new scheduled task command.
PROMPTINF
else

' Read inf file to populate input fields with existing data.
READINF

' Gather data to save back to inf file and to build a new scheduled task command.
PROMPTINF
End if
end if

'Write back to inf file
infString=TARGET&","&MEDIA_FILE&","&UNC_PATH&","&TaskAccount
WRITEINF infstring

'Test play, we want to ensure a full and correct UNC path to media file has been given. 
MEDIA_FILE_PATH=UNC_PATH & MEDIA_FILE
'PLAYFILE MEDIA_FILE_PATH 'rem out this line for long media files

'Set scheduled task
RemotePlayScriptName = WScript.ScriptName
Task = chr(34) & UNC_PATH & RemotePlayScriptName & chr(34)
SETTASK TARGET, TaskID, Task, TaskAccount, TaskPassword

'The end of the script. 
wscript.quit

'My Functions
'-----------------------------------------------------------------
Function CHECKINF()
Set objFSO = CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists("playfile.inf") Then
CHECKINF = "There"
else
CHECKINF = "NotThere"
end if
End Function
'-----------------------------------------------------------------
Function CREATEINF()
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.CreateTextFile("playfile.inf")
set objFile = nothing
End Function 
'-----------------------------------------------------------------
Function PROMPTINF()
'Prompt for TARGET, MEDIA_FILE, VIDEO, UNC_PATH
TARGET=InputBox("Enter Machine name:","Target Machine", TARGET)
MEDIA_FILE=InputBox("Enter Media File Name:", "File Name", MEDIA_FILE)
UNC_PATH=InputBox("Enter UNC path (with no spaces) to Media File, It must be Accessible from Target Machine, eg. \\server\share\", "UNC Path to Media",  UNC_PATH)
TaskAccount=InputBox("Enter User account that has permission to access UNC path entered, Try using account name <SYSTEM>:","UserID", TaskAccount)
TASKACCOUNT=UCase(TASKACCOUNT)
if TASKACCOUNT="SYSTEM" then
' No password is required for system account
else
TaskPassword=InputBox("Enter password for "&TaskAccount&":", "Password", "")
end if
End Function
'-----------------------------------------------------------------
Function READINF()
Const ForReading = 1
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile ("playfile.inf", ForReading)
Do Until objTextFile.AtEndOfStream
   strNextLine = objTextFile.Readline
   RemotePlayList = Split(strNextLine , ",")
TARGET=RemotePlayList(0)
MEDIA_FILE=RemotePlayList(1)
UNC_PATH=RemotePlayList(2)
TaskAccount=RemotePlayList(3)
Loop
End Function
'-----------------------------------------------------------------
Function WRITEINF(infString)
Const ForWriting = 2
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile ("playfile.inf", ForWriting, True)
   objTextFile.WriteLine(infstring)
objTextFile.Close
End Function
'-----------------------------------------------------------------
Function SETTASK(TARGET, TaskID, Task, TaskAccount, TaskPassword)
NewTime = FormatDateTime(DateAdd("n",2,Now),vbShortTime) & ":00" 
NewDate = FormatDateTime(DateAdd("n",1,Now),vbShortDate) 
If Mid(NewDate,3,1) <> "/" then NewDate = "0" & NewDate 
If Mid(NewDate,6,1) <> "/" then NewDate = Left(NewDate,3) & "0" & Right(NewDate,6) 
DelCommand = "SchTasks /DELETE /S " & TARGET & " /TN " & TaskID & " /F"
LaunchCommand = "SchTasks /create /s " & TARGET & " /tn " & TaskID & " /tr " & TASK & " /sc once /st " & NewTime & " /sd " & NewDate & " /ru " & TaskAccount & " /rp " & TaskPassword 
'wscript.echo(launchcommand)
Set WshShell = CreateObject("WScript.Shell") 
wshShell.Run DelCommand,0
wscript.sleep(5000)
wshShell.Run LaunchCommand,0 
wscript.sleep(125000)
wshShell.Run DelCommand,0   'I have put a command here to delete the task in case it fails (cleanup)
End Function
'-----------------------------------------------------------------
Function PLAYFILE(MEDIA_FILE_PATH)
Set objPlayer = CreateObject("WMPlayer.OCX.7" )
objPlayer.URL = MEDIA_FILE_PATH
while objPlayer.playstate = 9 OR objPlayer.playstate = 3
 wscript.sleep 500
wend
End Function
'-----------------------------------------------------------------
Function ScriptPath()
 ScriptPath = Left(WScript.ScriptFullName, _
   Len(WScript.ScriptFullName) - Len(WScript.ScriptName))
End Function
'-----------------------------------------------------------------